Context Navigation

← Previous Revision
Next Revision →
Blame
Revision Log

dynhpg.F90

Last change on this file was 15529, checked in by techene, 2 years ago
#2695 : isf+qco are now compatible
Property svn:keywords set to `Id`
File size: 75.8 KB

Line
1	MODULE dynhpg
2	!!======================================================================
3	!! * MODULE dynhpg *
4	!! Ocean dynamics: hydrostatic pressure gradient trend
5	!!======================================================================
6	!! History : OPA ! 1987-09 (P. Andrich, M.-A. Foujols) hpg_zco: Original code
7	!! 5.0 ! 1991-11 (G. Madec)
8	!! 7.0 ! 1996-01 (G. Madec) hpg_sco: Original code for s-coordinates
9	!! 8.0 ! 1997-05 (G. Madec) split dynber into dynkeg and dynhpg
10	!! 8.5 ! 2002-07 (G. Madec) F90: Free form and module
11	!! 8.5 ! 2002-08 (A. Bozec) hpg_zps: Original code
12	!! NEMO 1.0 ! 2005-10 (A. Beckmann, B.W. An) various s-coordinate options
13	!! ! Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14	!! - ! 2005-11 (G. Madec) style & small optimisation
15	!! 3.3 ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase
16	!! 3.4 ! 2011-11 (H. Liu) hpg_prj: Original code for s-coordinates
17	!! ! (A. Coward) suppression of hel, wdj and rot options
18	!! 3.6 ! 2014-11 (P. Mathiot) hpg_isf: original code for ice shelf cavity
19	!! 4.2 ! 2020-12 (M. Bell, A. Young) hpg_djc: revised djc scheme
20	!!----------------------------------------------------------------------
21
22	!!----------------------------------------------------------------------
23	!! dyn_hpg : update the momentum trend with the now horizontal
24	!! gradient of the hydrostatic pressure
25	!! dyn_hpg_init : initialisation and control of options
26	!! hpg_zco : z-coordinate scheme
27	!! hpg_zps : z-coordinate plus partial steps (interpolation)
28	!! hpg_sco : s-coordinate (standard jacobian formulation)
29	!! hpg_isf : s-coordinate (sco formulation) adapted to ice shelf
30	!! hpg_djc : s-coordinate (Density Jacobian with Cubic polynomial)
31	!! hpg_prj : s-coordinate (Pressure Jacobian with Cubic polynomial)
32	!!----------------------------------------------------------------------
33	USE oce ! ocean dynamics and tracers
34	USE isf_oce , ONLY : risfload ! ice shelf (risfload variable)
35	USE isfload , ONLY : isf_load ! ice shelf (isf_load routine )
36	USE sbc_oce ! surface variable (only for the flag with ice shelf)
37	USE dom_oce ! ocean space and time domain
38	USE wet_dry ! wetting and drying
39	USE phycst ! physical constants
40	USE trd_oce ! trends: ocean variables
41	USE trddyn ! trend manager: dynamics
42	USE zpshde ! partial step: hor. derivative (zps_hde routine)
43	!
44	USE in_out_manager ! I/O manager
45	USE prtctl ! Print control
46	USE lbclnk ! lateral boundary condition
47	USE lib_mpp ! MPP library
48	USE eosbn2 ! compute density
49	USE timing ! Timing
50	USE iom
51
52	IMPLICIT NONE
53	PRIVATE
54
55	PUBLIC dyn_hpg ! routine called by step module
56	PUBLIC dyn_hpg_init ! routine called by opa module
57
58	! !!* Namelist namdyn_hpg : hydrostatic pressure gradient
59	LOGICAL, PUBLIC :: ln_hpg_zco !: z-coordinate - full steps
60	LOGICAL, PUBLIC :: ln_hpg_zps !: z-coordinate - partial steps (interpolation)
61	LOGICAL, PUBLIC :: ln_hpg_sco !: s-coordinate (standard jacobian formulation)
62	LOGICAL, PUBLIC :: ln_hpg_djc !: s-coordinate (Density Jacobian with Cubic polynomial)
63	LOGICAL, PUBLIC :: ln_hpg_prj !: s-coordinate (Pressure Jacobian scheme)
64	LOGICAL, PUBLIC :: ln_hpg_isf !: s-coordinate similar to sco modify for isf
65
66	! !! Flag to control the type of hydrostatic pressure gradient
67	INTEGER, PARAMETER :: np_ERROR =-10 ! error in specification of lateral diffusion
68	INTEGER, PARAMETER :: np_zco = 0 ! z-coordinate - full steps
69	INTEGER, PARAMETER :: np_zps = 1 ! z-coordinate - partial steps (interpolation)
70	INTEGER, PARAMETER :: np_sco = 2 ! s-coordinate (standard jacobian formulation)
71	INTEGER, PARAMETER :: np_djc = 3 ! s-coordinate (Density Jacobian with Cubic polynomial)
72	INTEGER, PARAMETER :: np_prj = 4 ! s-coordinate (Pressure Jacobian scheme)
73	INTEGER, PARAMETER :: np_isf = 5 ! s-coordinate similar to sco modify for isf
74	!
75	INTEGER, PUBLIC :: nhpg !: type of pressure gradient scheme used ! (deduced from ln_hpg_... flags) (PUBLIC for TAM)
76	!
77	LOGICAL :: ln_hpg_djc_vnh, ln_hpg_djc_vnv ! flag to specify hpg_djc boundary condition type
78	REAL(wp), PUBLIC :: aco_bc_hor, bco_bc_hor, aco_bc_vrt, bco_bc_vrt !: coefficients for hpg_djc hor and vert boundary conditions
79
80	!! * Substitutions
81	# include "do_loop_substitute.h90"
82	# include "domzgr_substitute.h90"
83
84	!!----------------------------------------------------------------------
85	!! NEMO/OCE 4.0 , NEMO Consortium (2018)
86	!! $Id$
87	!! Software governed by the CeCILL license (see ./LICENSE)
88	!!----------------------------------------------------------------------
89	CONTAINS
90
91	SUBROUTINE dyn_hpg( kt, Kmm, puu, pvv, Krhs )
92	!!---------------------------------------------------------------------
93	!! * ROUTINE dyn_hpg *
94	!!
95	!! ** Method : Call the hydrostatic pressure gradient routine
96	!! using the scheme defined in the namelist
97	!!
98	!! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
99	!! - send trends to trd_dyn for futher diagnostics (l_trddyn=T)
100	!!----------------------------------------------------------------------
101	INTEGER , INTENT( in ) :: kt ! ocean time-step index
102	INTEGER , INTENT( in ) :: Kmm, Krhs ! ocean time level indices
103	REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) :: puu, pvv ! ocean velocities and RHS of momentum equation
104	!
105	REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: ztrdu, ztrdv
106	!!----------------------------------------------------------------------
107	!
108	IF( ln_timing ) CALL timing_start('dyn_hpg')
109	!
110	IF( l_trddyn ) THEN ! Temporary saving of puu(:,:,:,Krhs) and pvv(:,:,:,Krhs) trends (l_trddyn)
111	ALLOCATE( ztrdu(jpi,jpj,jpk) , ztrdv(jpi,jpj,jpk) )
112	ztrdu(:,:,:) = puu(:,:,:,Krhs)
113	ztrdv(:,:,:) = pvv(:,:,:,Krhs)
114	ENDIF
115	!
116	SELECT CASE ( nhpg ) ! Hydrostatic pressure gradient computation
117	CASE ( np_zco ) ; CALL hpg_zco ( kt, Kmm, puu, pvv, Krhs ) ! z-coordinate
118	CASE ( np_zps ) ; CALL hpg_zps ( kt, Kmm, puu, pvv, Krhs ) ! z-coordinate plus partial steps (interpolation)
119	CASE ( np_sco ) ; CALL hpg_sco ( kt, Kmm, puu, pvv, Krhs ) ! s-coordinate (standard jacobian formulation)
120	CASE ( np_djc ) ; CALL hpg_djc ( kt, Kmm, puu, pvv, Krhs ) ! s-coordinate (Density Jacobian with Cubic polynomial)
121	CASE ( np_prj ) ; CALL hpg_prj ( kt, Kmm, puu, pvv, Krhs ) ! s-coordinate (Pressure Jacobian scheme)
122	CASE ( np_isf ) ; CALL hpg_isf ( kt, Kmm, puu, pvv, Krhs ) ! s-coordinate similar to sco modify for ice shelf
123	END SELECT
124	!
125	IF( l_trddyn ) THEN ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
126	ztrdu(:,:,:) = puu(:,:,:,Krhs) - ztrdu(:,:,:)
127	ztrdv(:,:,:) = pvv(:,:,:,Krhs) - ztrdv(:,:,:)
128	CALL trd_dyn( ztrdu, ztrdv, jpdyn_hpg, kt, Kmm )
129	DEALLOCATE( ztrdu , ztrdv )
130	ENDIF
131	!
132	IF(sn_cfctl%l_prtctl) CALL prt_ctl( tab3d_1=puu(:,:,:,Krhs), clinfo1=' hpg - Ua: ', mask1=umask, &
133	& tab3d_2=pvv(:,:,:,Krhs), clinfo2= ' Va: ', mask2=vmask, clinfo3='dyn' )
134	!
135	IF( ln_timing ) CALL timing_stop('dyn_hpg')
136	!
137	END SUBROUTINE dyn_hpg
138
139
140	SUBROUTINE dyn_hpg_init( Kmm )
141	!!----------------------------------------------------------------------
142	!! * ROUTINE dyn_hpg_init *
143	!!
144	!! ** Purpose : initializations for the hydrostatic pressure gradient
145	!! computation and consistency control
146	!!
147	!! ** Action : Read the namelist namdyn_hpg and check the consistency
148	!! with the type of vertical coordinate used (zco, zps, sco)
149	!!----------------------------------------------------------------------
150	INTEGER, INTENT( in ) :: Kmm ! ocean time level index
151	!
152	INTEGER :: ioptio = 0 ! temporary integer
153	INTEGER :: ios ! Local integer output status for namelist read
154	!!
155	INTEGER :: ji, jj, jk, ikt ! dummy loop indices ISF
156	REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: zts_top, zrhd ! hypothesys on isf density
157	REAL(wp), ALLOCATABLE, DIMENSION(:,:) :: zrhdtop_isf ! density at bottom of ISF
158	REAL(wp), ALLOCATABLE, DIMENSION(:,:) :: ziceload ! density at bottom of ISF
159	!!
160	NAMELIST/namdyn_hpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco, &
161	& ln_hpg_djc, ln_hpg_prj, ln_hpg_isf, &
162	& ln_hpg_djc_vnh, ln_hpg_djc_vnv
163	!!----------------------------------------------------------------------
164	!
165	READ ( numnam_ref, namdyn_hpg, IOSTAT = ios, ERR = 901)
166	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in reference namelist' )
167	!
168	READ ( numnam_cfg, namdyn_hpg, IOSTAT = ios, ERR = 902 )
169	902 IF( ios > 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in configuration namelist' )
170	IF(lwm) WRITE ( numond, namdyn_hpg )
171	!
172	IF(lwp) THEN ! Control print
173	WRITE(numout,*)
174	WRITE(numout,*) 'dyn_hpg_init : hydrostatic pressure gradient initialisation'
175	WRITE(numout,*) '~~~~~~~~~~~~'
176	WRITE(numout,*) ' Namelist namdyn_hpg : choice of hpg scheme'
177	WRITE(numout,*) ' z-coord. - full steps ln_hpg_zco = ', ln_hpg_zco
178	WRITE(numout,*) ' z-coord. - partial steps (interpolation) ln_hpg_zps = ', ln_hpg_zps
179	WRITE(numout,*) ' s-coord. (standard jacobian formulation) ln_hpg_sco = ', ln_hpg_sco
180	WRITE(numout,*) ' s-coord. (standard jacobian formulation) for isf ln_hpg_isf = ', ln_hpg_isf
181	WRITE(numout,*) ' s-coord. (Density Jacobian: Cubic polynomial) ln_hpg_djc = ', ln_hpg_djc
182	WRITE(numout,*) ' s-coord. (Pressure Jacobian: Cubic polynomial) ln_hpg_prj = ', ln_hpg_prj
183	ENDIF
184	!
185	IF( .NOT.ln_linssh .AND. (ln_hpg_zco.OR.ln_hpg_zps) ) &
186	& CALL ctl_stop( 'dyn_hpg_init : non-linear free surface incompatible with hpg_zco or hpg_zps' )
187	!
188	IF( (.NOT.ln_hpg_isf .AND. ln_isfcav) .OR. (ln_hpg_isf .AND. .NOT.ln_isfcav) ) &
189	& CALL ctl_stop( 'dyn_hpg_init : ln_hpg_isf=T requires ln_isfcav=T and vice versa' )
190	!
191	!
192	! ! Set nhpg from ln_hpg_... flags & consistency check
193	nhpg = np_ERROR
194	ioptio = 0
195	IF( ln_hpg_zco ) THEN ; nhpg = np_zco ; ioptio = ioptio +1 ; ENDIF
196	IF( ln_hpg_zps ) THEN ; nhpg = np_zps ; ioptio = ioptio +1 ; ENDIF
197	IF( ln_hpg_sco ) THEN ; nhpg = np_sco ; ioptio = ioptio +1 ; ENDIF
198	IF( ln_hpg_djc ) THEN ; nhpg = np_djc ; ioptio = ioptio +1 ; ENDIF
199	IF( ln_hpg_prj ) THEN ; nhpg = np_prj ; ioptio = ioptio +1 ; ENDIF
200	IF( ln_hpg_isf ) THEN ; nhpg = np_isf ; ioptio = ioptio +1 ; ENDIF
201	!
202	IF( ioptio /= 1 ) CALL ctl_stop( 'NO or several hydrostatic pressure gradient options used' )
203	!
204	IF(lwp) THEN
205	WRITE(numout,*)
206	SELECT CASE( nhpg )
207	CASE( np_zco ) ; WRITE(numout,*) ' ==>>> z-coord. - full steps '
208	CASE( np_zps ) ; WRITE(numout,*) ' ==>>> z-coord. - partial steps (interpolation)'
209	CASE( np_sco ) ; WRITE(numout,*) ' ==>>> s-coord. (standard jacobian formulation)'
210	CASE( np_djc ) ; WRITE(numout,*) ' ==>>> s-coord. (Density Jacobian: Cubic polynomial)'
211	CASE( np_prj ) ; WRITE(numout,*) ' ==>>> s-coord. (Pressure Jacobian: Cubic polynomial)'
212	CASE( np_isf ) ; WRITE(numout,*) ' ==>>> s-coord. (standard jacobian formulation) for isf'
213	END SELECT
214	WRITE(numout,*)
215	ENDIF
216	!
217	IF ( ln_hpg_djc ) THEN
218	IF (ln_hpg_djc_vnh) THEN ! Von Neumann boundary condition
219	IF(lwp) WRITE(numout,*) ' horizontal bc: von Neumann '
220	aco_bc_hor = 6.0_wp/5.0_wp
221	bco_bc_hor = 7.0_wp/15.0_wp
222	ELSE ! Linear extrapolation
223	IF(lwp) WRITE(numout,*) ' horizontal bc: linear extrapolation'
224	aco_bc_hor = 3.0_wp/2.0_wp
225	bco_bc_hor = 1.0_wp/2.0_wp
226	END IF
227	IF (ln_hpg_djc_vnv) THEN ! Von Neumann boundary condition
228	IF(lwp) WRITE(numout,*) ' vertical bc: von Neumann '
229	aco_bc_vrt = 6.0_wp/5.0_wp
230	bco_bc_vrt = 7.0_wp/15.0_wp
231	ELSE ! Linear extrapolation
232	IF(lwp) WRITE(numout,*) ' vertical bc: linear extrapolation'
233	aco_bc_vrt = 3.0_wp/2.0_wp
234	bco_bc_vrt = 1.0_wp/2.0_wp
235	END IF
236	END IF
237	!
238	END SUBROUTINE dyn_hpg_init
239
240
241	SUBROUTINE hpg_zco( kt, Kmm, puu, pvv, Krhs )
242	!!---------------------------------------------------------------------
243	!! * ROUTINE hpg_zco *
244	!!
245	!! ** Method : z-coordinate case, levels are horizontal surfaces.
246	!! The now hydrostatic pressure gradient at a given level, jk,
247	!! is computed by taking the vertical integral of the in-situ
248	!! density gradient along the model level from the suface to that
249	!! level: zhpi = grav .....
250	!! zhpj = grav .....
251	!! add it to the general momentum trend (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)).
252	!! puu(:,:,:,Krhs) = puu(:,:,:,Krhs) - 1/e1u * zhpi
253	!! pvv(:,:,:,Krhs) = pvv(:,:,:,Krhs) - 1/e2v * zhpj
254	!!
255	!! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
256	!!----------------------------------------------------------------------
257	INTEGER , INTENT( in ) :: kt ! ocean time-step index
258	INTEGER , INTENT( in ) :: Kmm, Krhs ! ocean time level indices
259	REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) :: puu, pvv ! ocean velocities and RHS of momentum equation
260	!
261	INTEGER :: ji, jj, jk ! dummy loop indices
262	REAL(wp) :: zcoef0, zcoef1 ! temporary scalars
263	REAL(wp), DIMENSION(A2D(nn_hls)) :: zhpi, zhpj
264	!!----------------------------------------------------------------------
265	!
266	IF( .NOT. l_istiled .OR. ntile == 1 ) THEN ! Do only on the first tile
267	IF( kt == nit000 ) THEN
268	IF(lwp) WRITE(numout,*)
269	IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
270	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ z-coordinate case '
271	ENDIF
272	ENDIF
273	!
274	zcoef0 = - grav * 0.5_wp ! Local constant initialization
275	!
276	DO_2D( 0, 0, 0, 0 ) ! Surface value
277	zcoef1 = zcoef0 * e3w(ji,jj,1,Kmm)
278	! ! hydrostatic pressure gradient
279	zhpi(ji,jj) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) * r1_e1u(ji,jj)
280	zhpj(ji,jj) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) * r1_e2v(ji,jj)
281	! ! add to the general momentum trend
282	puu(ji,jj,1,Krhs) = puu(ji,jj,1,Krhs) + zhpi(ji,jj)
283	pvv(ji,jj,1,Krhs) = pvv(ji,jj,1,Krhs) + zhpj(ji,jj)
284	END_2D
285	!
286	DO_3D( 0, 0, 0, 0, 2, jpkm1 ) ! interior value (2=<jk=<jpkm1)
287	zcoef1 = zcoef0 * e3w(ji,jj,jk,Kmm)
288	! ! hydrostatic pressure gradient
289	zhpi(ji,jj) = zhpi(ji,jj) + zcoef1 * ( ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) ) &
290	& - ( rhd(ji ,jj,jk)+rhd(ji ,jj,jk-1) ) ) * r1_e1u(ji,jj)
291
292	zhpj(ji,jj) = zhpj(ji,jj) + zcoef1 * ( ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) ) &
293	& - ( rhd(ji,jj, jk)+rhd(ji,jj ,jk-1) ) ) * r1_e2v(ji,jj)
294	! ! add to the general momentum trend
295	puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + zhpi(ji,jj)
296	pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + zhpj(ji,jj)
297	END_3D
298	!
299	END SUBROUTINE hpg_zco
300
301
302	SUBROUTINE hpg_zps( kt, Kmm, puu, pvv, Krhs )
303	!!---------------------------------------------------------------------
304	!! * ROUTINE hpg_zps *
305	!!
306	!! ** Method : z-coordinate plus partial steps case. blahblah...
307	!!
308	!! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
309	!!----------------------------------------------------------------------
310	INTEGER , INTENT( in ) :: kt ! ocean time-step index
311	INTEGER , INTENT( in ) :: Kmm, Krhs ! ocean time level indices
312	REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) :: puu, pvv ! ocean velocities and RHS of momentum equation
313	!!
314	INTEGER :: ji, jj, jk ! dummy loop indices
315	INTEGER :: iku, ikv ! temporary integers
316	REAL(wp) :: zcoef0, zcoef1, zcoef2, zcoef3 ! temporary scalars
317	REAL(wp), DIMENSION(A2D(nn_hls),jpk ) :: zhpi, zhpj
318	REAL(wp), DIMENSION(A2D(nn_hls),jpts) :: zgtsu, zgtsv
319	REAL(wp), DIMENSION(A2D(nn_hls) ) :: zgru, zgrv
320	!!----------------------------------------------------------------------
321	!
322	IF( .NOT. l_istiled .OR. ntile == 1 ) THEN ! Do only on the first tile
323	IF( kt == nit000 ) THEN
324	IF(lwp) WRITE(numout,*)
325	IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
326	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ z-coordinate with partial steps - vector optimization'
327	ENDIF
328	ENDIF
329
330	! Partial steps: Compute NOW horizontal gradient of t, s, rd at the last ocean level
331	CALL zps_hde( kt, Kmm, jpts, ts(:,:,:,:,Kmm), zgtsu, zgtsv, rhd, zgru , zgrv )
332
333	! Local constant initialization
334	zcoef0 = - grav * 0.5_wp
335
336	! Surface value (also valid in partial step case)
337	DO_2D( 0, 0, 0, 0 )
338	zcoef1 = zcoef0 * e3w(ji,jj,1,Kmm)
339	! hydrostatic pressure gradient
340	zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj ,1) - rhd(ji,jj,1) ) * r1_e1u(ji,jj)
341	zhpj(ji,jj,1) = zcoef1 * ( rhd(ji ,jj+1,1) - rhd(ji,jj,1) ) * r1_e2v(ji,jj)
342	! add to the general momentum trend
343	puu(ji,jj,1,Krhs) = puu(ji,jj,1,Krhs) + zhpi(ji,jj,1)
344	pvv(ji,jj,1,Krhs) = pvv(ji,jj,1,Krhs) + zhpj(ji,jj,1)
345	END_2D
346
347	! interior value (2=<jk=<jpkm1)
348	DO_3D( 0, 0, 0, 0, 2, jpkm1 )
349	zcoef1 = zcoef0 * e3w(ji,jj,jk,Kmm)
350	! hydrostatic pressure gradient
351	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) &
352	& + zcoef1 * ( ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) ) &
353	& - ( rhd(ji ,jj,jk) + rhd(ji ,jj,jk-1) ) ) * r1_e1u(ji,jj)
354
355	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) &
356	& + zcoef1 * ( ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) ) &
357	& - ( rhd(ji,jj, jk) + rhd(ji,jj ,jk-1) ) ) * r1_e2v(ji,jj)
358	! add to the general momentum trend
359	puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + zhpi(ji,jj,jk)
360	pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + zhpj(ji,jj,jk)
361	END_3D
362
363	! partial steps correction at the last level (use zgru & zgrv computed in zpshde.F90)
364	DO_2D( 0, 0, 0, 0 )
365	iku = mbku(ji,jj)
366	ikv = mbkv(ji,jj)
367	zcoef2 = zcoef0 * MIN( e3w(ji,jj,iku,Kmm), e3w(ji+1,jj ,iku,Kmm) )
368	zcoef3 = zcoef0 * MIN( e3w(ji,jj,ikv,Kmm), e3w(ji ,jj+1,ikv,Kmm) )
369	IF( iku > 1 ) THEN ! on i-direction (level 2 or more)
370	puu (ji,jj,iku,Krhs) = puu(ji,jj,iku,Krhs) - zhpi(ji,jj,iku) ! subtract old value
371	zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1) & ! compute the new one
372	& + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + zgru(ji,jj) ) * r1_e1u(ji,jj)
373	puu (ji,jj,iku,Krhs) = puu(ji,jj,iku,Krhs) + zhpi(ji,jj,iku) ! add the new one to the general momentum trend
374	ENDIF
375	IF( ikv > 1 ) THEN ! on j-direction (level 2 or more)
376	pvv (ji,jj,ikv,Krhs) = pvv(ji,jj,ikv,Krhs) - zhpj(ji,jj,ikv) ! subtract old value
377	zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1) & ! compute the new one
378	& + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + zgrv(ji,jj) ) * r1_e2v(ji,jj)
379	pvv (ji,jj,ikv,Krhs) = pvv(ji,jj,ikv,Krhs) + zhpj(ji,jj,ikv) ! add the new one to the general momentum trend
380	ENDIF
381	END_2D
382	!
383	END SUBROUTINE hpg_zps
384
385
386	SUBROUTINE hpg_sco( kt, Kmm, puu, pvv, Krhs )
387	!!---------------------------------------------------------------------
388	!! * ROUTINE hpg_sco *
389	!!
390	!! ** Method : s-coordinate case. Jacobian scheme.
391	!! The now hydrostatic pressure gradient at a given level, jk,
392	!! is computed by taking the vertical integral of the in-situ
393	!! density gradient along the model level from the suface to that
394	!! level. s-coordinates (ln_sco): a corrective term is added
395	!! to the horizontal pressure gradient :
396	!! zhpi = grav ..... + 1/e1u mi(rhd) di[ grav dep3w ]
397	!! zhpj = grav ..... + 1/e2v mj(rhd) dj[ grav dep3w ]
398	!! add it to the general momentum trend (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)).
399	!! puu(:,:,:,Krhs) = puu(:,:,:,Krhs) - 1/e1u * zhpi
400	!! pvv(:,:,:,Krhs) = pvv(:,:,:,Krhs) - 1/e2v * zhpj
401	!!
402	!! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
403	!!----------------------------------------------------------------------
404	INTEGER , INTENT( in ) :: kt ! ocean time-step index
405	INTEGER , INTENT( in ) :: Kmm, Krhs ! ocean time level indices
406	REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) :: puu, pvv ! ocean velocities and RHS of momentum equation
407	!!
408	INTEGER :: ji, jj, jk, jii, jjj ! dummy loop indices
409	REAL(wp) :: zcoef0, zuap, zvap, ztmp ! local scalars
410	LOGICAL :: ll_tmp1, ll_tmp2 ! local logical variables
411	REAL(wp), DIMENSION(A2D(nn_hls),jpk) :: zhpi, zhpj
412	REAL(wp), DIMENSION(:,:), ALLOCATABLE :: zcpx, zcpy !W/D pressure filter
413	!!----------------------------------------------------------------------
414	!
415	IF( ln_wd_il ) ALLOCATE(zcpx(A2D(nn_hls)), zcpy(A2D(nn_hls)))
416	!
417	IF( .NOT. l_istiled .OR. ntile == 1 ) THEN ! Do only on the first tile
418	IF( kt == nit000 ) THEN
419	IF(lwp) WRITE(numout,*)
420	IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
421	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ s-coordinate case, OCE original scheme used'
422	ENDIF
423	ENDIF
424	!
425	zcoef0 = - grav * 0.5_wp
426	!
427	IF( ln_wd_il ) THEN
428	DO_2D( 0, 0, 0, 0 )
429	ll_tmp1 = MIN( ssh(ji,jj,Kmm) , ssh(ji+1,jj,Kmm) ) > &
430	& MAX( -ht_0(ji,jj) , -ht_0(ji+1,jj) ) .AND. &
431	& MAX( ssh(ji,jj,Kmm) + ht_0(ji,jj), ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) ) &
432	& > rn_wdmin1 + rn_wdmin2
433	ll_tmp2 = ( ABS( ssh(ji,jj,Kmm) - ssh(ji+1,jj,Kmm) ) > 1.E-12 ) .AND. ( &
434	& MAX( ssh(ji,jj,Kmm) , ssh(ji+1,jj,Kmm) ) > &
435	& MAX( -ht_0(ji,jj) , -ht_0(ji+1,jj) ) + rn_wdmin1 + rn_wdmin2 )
436
437	IF(ll_tmp1) THEN
438	zcpx(ji,jj) = 1.0_wp
439	ELSE IF(ll_tmp2) THEN
440	! no worries about ssh(ji+1,jj,Kmm) - ssh(ji ,jj,Kmm) = 0, it won't happen ! here
441	zcpx(ji,jj) = ABS( (ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
442	& / (ssh(ji+1,jj,Kmm) - ssh(ji ,jj,Kmm)) )
443	ELSE
444	zcpx(ji,jj) = 0._wp
445	END IF
446
447	ll_tmp1 = MIN( ssh(ji,jj,Kmm) , ssh(ji,jj+1,Kmm) ) > &
448	& MAX( -ht_0(ji,jj) , -ht_0(ji,jj+1) ) .AND. &
449	& MAX( ssh(ji,jj,Kmm) + ht_0(ji,jj), ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) ) &
450	& > rn_wdmin1 + rn_wdmin2
451	ll_tmp2 = ( ABS( ssh(ji,jj,Kmm) - ssh(ji,jj+1,Kmm) ) > 1.E-12 ) .AND. ( &
452	& MAX( ssh(ji,jj,Kmm) , ssh(ji,jj+1,Kmm) ) > &
453	& MAX( -ht_0(ji,jj) , -ht_0(ji,jj+1) ) + rn_wdmin1 + rn_wdmin2 )
454
455	IF(ll_tmp1) THEN
456	zcpy(ji,jj) = 1.0_wp
457	ELSE IF(ll_tmp2) THEN
458	! no worries about ssh(ji,jj+1,Kmm) - ssh(ji,jj ,Kmm) = 0, it won't happen ! here
459	zcpy(ji,jj) = ABS( (ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
460	& / (ssh(ji,jj+1,Kmm) - ssh(ji,jj ,Kmm)) )
461	ELSE
462	zcpy(ji,jj) = 0._wp
463	END IF
464	END_2D
465	END IF
466	!
467	DO_2D( 0, 0, 0, 0 ) ! Surface value
468	! ! hydrostatic pressure gradient along s-surfaces
469	zhpi(ji,jj,1) = zcoef0 * r1_e1u(ji,jj) &
470	& * ( e3w(ji+1,jj ,1,Kmm) * rhd(ji+1,jj ,1) &
471	& - e3w(ji ,jj ,1,Kmm) * rhd(ji ,jj ,1) )
472	zhpj(ji,jj,1) = zcoef0 * r1_e2v(ji,jj) &
473	& * ( e3w(ji ,jj+1,1,Kmm) * rhd(ji ,jj+1,1) &
474	& - e3w(ji ,jj ,1,Kmm) * rhd(ji ,jj ,1) )
475	! ! s-coordinate pressure gradient correction
476	zuap = -zcoef0 * ( rhd (ji+1,jj,1) + rhd (ji,jj,1) ) &
477	& * ( gde3w(ji+1,jj,1) - gde3w(ji,jj,1) ) * r1_e1u(ji,jj)
478	zvap = -zcoef0 * ( rhd (ji,jj+1,1) + rhd (ji,jj,1) ) &
479	& * ( gde3w(ji,jj+1,1) - gde3w(ji,jj,1) ) * r1_e2v(ji,jj)
480	!
481	IF( ln_wd_il ) THEN
482	zhpi(ji,jj,1) = zhpi(ji,jj,1) * zcpx(ji,jj)
483	zhpj(ji,jj,1) = zhpj(ji,jj,1) * zcpy(ji,jj)
484	zuap = zuap * zcpx(ji,jj)
485	zvap = zvap * zcpy(ji,jj)
486	ENDIF
487	! ! add to the general momentum trend
488	puu(ji,jj,1,Krhs) = puu(ji,jj,1,Krhs) + zhpi(ji,jj,1) + zuap
489	pvv(ji,jj,1,Krhs) = pvv(ji,jj,1,Krhs) + zhpj(ji,jj,1) + zvap
490	END_2D
491	!
492	DO_3D( 0, 0, 0, 0, 2, jpkm1 ) ! interior value (2=<jk=<jpkm1)
493	! ! hydrostatic pressure gradient along s-surfaces
494	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 * r1_e1u(ji,jj) &
495	& * ( e3w(ji+1,jj,jk,Kmm) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) ) &
496	& - e3w(ji ,jj,jk,Kmm) * ( rhd(ji ,jj,jk) + rhd(ji ,jj,jk-1) ) )
497	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 * r1_e2v(ji,jj) &
498	& * ( e3w(ji,jj+1,jk,Kmm) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) ) &
499	& - e3w(ji,jj ,jk,Kmm) * ( rhd(ji,jj, jk) + rhd(ji,jj ,jk-1) ) )
500	! ! s-coordinate pressure gradient correction
501	zuap = -zcoef0 * ( rhd (ji+1,jj ,jk) + rhd (ji,jj,jk) ) &
502	& * ( gde3w(ji+1,jj ,jk) - gde3w(ji,jj,jk) ) * r1_e1u(ji,jj)
503	zvap = -zcoef0 * ( rhd (ji ,jj+1,jk) + rhd (ji,jj,jk) ) &
504	& * ( gde3w(ji ,jj+1,jk) - gde3w(ji,jj,jk) ) * r1_e2v(ji,jj)
505	!
506	IF( ln_wd_il ) THEN
507	zhpi(ji,jj,jk) = zhpi(ji,jj,jk) * zcpx(ji,jj)
508	zhpj(ji,jj,jk) = zhpj(ji,jj,jk) * zcpy(ji,jj)
509	zuap = zuap * zcpx(ji,jj)
510	zvap = zvap * zcpy(ji,jj)
511	ENDIF
512	!
513	! add to the general momentum trend
514	puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + zhpi(ji,jj,jk) + zuap
515	pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + zhpj(ji,jj,jk) + zvap
516	END_3D
517	!
518	IF( ln_wd_il ) DEALLOCATE( zcpx , zcpy )
519	!
520	END SUBROUTINE hpg_sco
521
522
523	SUBROUTINE hpg_isf( kt, Kmm, puu, pvv, Krhs )
524	!!---------------------------------------------------------------------
525	!! * ROUTINE hpg_isf *
526	!!
527	!! ** Method : s-coordinate case. Jacobian scheme.
528	!! The now hydrostatic pressure gradient at a given level, jk,
529	!! is computed by taking the vertical integral of the in-situ
530	!! density gradient along the model level from the suface to that
531	!! level. s-coordinates (ln_sco): a corrective term is added
532	!! to the horizontal pressure gradient :
533	!! zhpi = grav ..... + 1/e1u mi(rhd) di[ grav dep3w ]
534	!! zhpj = grav ..... + 1/e2v mj(rhd) dj[ grav dep3w ]
535	!! add it to the general momentum trend (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)).
536	!! puu(:,:,:,Krhs) = puu(:,:,:,Krhs) - 1/e1u * zhpi
537	!! pvv(:,:,:,Krhs) = pvv(:,:,:,Krhs) - 1/e2v * zhpj
538	!! iceload is added
539	!!
540	!! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
541	!!----------------------------------------------------------------------
542	INTEGER , INTENT( in ) :: kt ! ocean time-step index
543	INTEGER , INTENT( in ) :: Kmm, Krhs ! ocean time level indices
544	REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) :: puu, pvv ! ocean velocities and RHS of momentum equation
545	!!
546	INTEGER :: ji, jj, jk ! dummy loop indices
547	INTEGER :: ikt , ikti1, iktj1 ! local integer
548	REAL(wp) :: ze3w, ze3wi1, ze3wj1 ! local scalars
549	REAL(wp) :: zcoef0, zuap, zvap ! - -
550	REAL(wp), DIMENSION(A2D(nn_hls),jpk ) :: zhpi, zhpj
551	REAL(wp), DIMENSION(A2D(nn_hls),jpts) :: zts_top
552	REAL(wp), DIMENSION(A2D(nn_hls)) :: zrhd_top, zdep_top
553	!!----------------------------------------------------------------------
554	!
555	zcoef0 = - grav * 0.5_wp ! Local constant initialization
556	!
557	! ! iniitialised to 0. zhpi zhpi
558	zhpi(:,:,:) = 0._wp ; zhpj(:,:,:) = 0._wp
559
560	! compute rhd at the ice/oce interface (ocean side)
561	! usefull to reduce residual current in the test case ISOMIP with no melting
562	DO_2D( nn_hls, nn_hls, nn_hls, nn_hls )
563	ikt = mikt(ji,jj)
564	zts_top(ji,jj,1) = ts(ji,jj,ikt,1,Kmm)
565	zts_top(ji,jj,2) = ts(ji,jj,ikt,2,Kmm)
566	zdep_top(ji,jj) = MAX( risfdep(ji,jj) , gdept(ji,jj,1,Kmm) )
567	END_2D
568	CALL eos( zts_top, zdep_top, zrhd_top )
569
570	! !===========================!
571	! !===== surface value =====!
572	! !===========================!
573	DO_2D( 0, 0, 0, 0 )
574	ikt = mikt(ji ,jj ) ; ze3w = e3w(ji ,jj ,ikt ,Kmm)
575	ikti1 = mikt(ji+1,jj ) ; ze3wi1 = e3w(ji+1,jj ,ikti1,Kmm)
576	iktj1 = mikt(ji ,jj+1) ; ze3wj1 = e3w(ji ,jj+1,iktj1,Kmm)
577	! ! hydrostatic pressure gradient along s-surfaces and ice shelf pressure
578	! ! we assume ISF is in isostatic equilibrium
579	zhpi(ji,jj,1) = zcoef0 * r1_e1u(ji,jj) * ( risfload(ji+1,jj) - risfload(ji,jj) &
580	& + 0.5_wp * ( ze3wi1 * ( rhd(ji+1,jj,ikti1) + zrhd_top(ji+1,jj) ) &
581	& - ze3w * ( rhd(ji ,jj,ikt ) + zrhd_top(ji ,jj) ) ) )
582	zhpj(ji,jj,1) = zcoef0 * r1_e2v(ji,jj) * ( risfload(ji,jj+1) - risfload(ji,jj) &
583	& + 0.5_wp * ( ze3wj1 * ( rhd(ji,jj+1,iktj1) + zrhd_top(ji,jj+1) ) &
584	& - ze3w * ( rhd(ji,jj ,ikt ) + zrhd_top(ji,jj ) ) ) )
585	! ! s-coordinate pressure gradient correction (=0 if z coordinate)
586	zuap = -zcoef0 * ( rhd (ji+1,jj,1) + rhd (ji,jj,1) ) &
587	& * ( gde3w(ji+1,jj,1) - gde3w(ji,jj,1) ) * r1_e1u(ji,jj)
588	zvap = -zcoef0 * ( rhd (ji,jj+1,1) + rhd (ji,jj,1) ) &
589	& * ( gde3w(ji,jj+1,1) - gde3w(ji,jj,1) ) * r1_e2v(ji,jj)
590	! ! add to the general momentum trend
591	puu(ji,jj,1,Krhs) = puu(ji,jj,1,Krhs) + (zhpi(ji,jj,1) + zuap) * umask(ji,jj,1)
592	pvv(ji,jj,1,Krhs) = pvv(ji,jj,1,Krhs) + (zhpj(ji,jj,1) + zvap) * vmask(ji,jj,1)
593	END_2D
594	!
595	! !=============================!
596	! !===== interior values =====!
597	! !=============================!
598	DO_3D( 0, 0, 0, 0, 2, jpkm1 )
599	ze3w = e3w(ji ,jj ,jk,Kmm)
600	ze3wi1 = e3w(ji+1,jj ,jk,Kmm)
601	ze3wj1 = e3w(ji ,jj+1,jk,Kmm)
602	! ! hydrostatic pressure gradient along s-surfaces
603	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj) &
604	& * ( ze3wi1 * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) ) * wmask(ji+1,jj,jk) &
605	& - ze3w * ( rhd(ji ,jj,jk) + rhd(ji ,jj,jk-1) ) * wmask(ji ,jj,jk) )
606	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj) &
607	& * ( ze3wj1 * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) ) * wmask(ji,jj+1,jk) &
608	& - ze3w * ( rhd(ji,jj, jk) + rhd(ji,jj ,jk-1) ) * wmask(ji,jj ,jk) )
609	! ! s-coordinate pressure gradient correction
610	zuap = -zcoef0 * ( rhd (ji+1,jj ,jk) + rhd (ji,jj,jk) ) &
611	& * ( gde3w(ji+1,jj ,jk) - gde3w(ji,jj,jk) ) / e1u(ji,jj)
612	zvap = -zcoef0 * ( rhd (ji ,jj+1,jk) + rhd (ji,jj,jk) ) &
613	& * ( gde3w(ji ,jj+1,jk) - gde3w(ji,jj,jk) ) / e2v(ji,jj)
614	! ! add to the general momentum trend
615	puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + (zhpi(ji,jj,jk) + zuap) * umask(ji,jj,jk)
616	pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + (zhpj(ji,jj,jk) + zvap) * vmask(ji,jj,jk)
617	END_3D
618	!
619	END SUBROUTINE hpg_isf
620
621
622	SUBROUTINE hpg_djc( kt, Kmm, puu, pvv, Krhs )
623	!!---------------------------------------------------------------------
624	!! * ROUTINE hpg_djc *
625	!!
626	!! ** Method : Density Jacobian with Cubic polynomial scheme
627	!!
628	!! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
629	!!----------------------------------------------------------------------
630	INTEGER , INTENT( in ) :: kt ! ocean time-step index
631	INTEGER , INTENT( in ) :: Kmm, Krhs ! ocean time level indices
632	REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) :: puu, pvv ! ocean velocities and RHS of momentum equation
633	!!
634	INTEGER :: ji, jj, jk ! dummy loop indices
635	INTEGER :: iktb, iktt ! jk indices at tracer points for top and bottom points
636	REAL(wp) :: zcoef0, zep, cffw ! temporary scalars
637	REAL(wp) :: z_grav_10, z1_12, z1_cff
638	REAL(wp) :: cffu, cffx ! " "
639	REAL(wp) :: cffv, cffy ! " "
640	LOGICAL :: ll_tmp1, ll_tmp2 ! local logical variables
641	REAL(wp), DIMENSION(A2D(nn_hls),jpk) :: zhpi, zhpj
642
643	REAL(wp), DIMENSION(A2D(nn_hls),jpk) :: zdzx, zdzy, zdzz ! Primitive grid differences ('delta_xyz')
644	REAL(wp), DIMENSION(A2D(nn_hls),jpk) :: zdz_i, zdz_j, zdz_k ! Harmonic average of primitive grid differences ('d_xyz')
645	REAL(wp), DIMENSION(A2D(nn_hls),jpk) :: zdrhox, zdrhoy, zdrhoz ! Primitive rho differences ('delta_rho')
646	REAL(wp), DIMENSION(A2D(nn_hls),jpk) :: zdrho_i, zdrho_j, zdrho_k ! Harmonic average of primitive rho differences ('d_rho')
647	REAL(wp), DIMENSION(A2D(nn_hls),jpk) :: z_rho_i, z_rho_j, z_rho_k ! Face intergrals
648	REAL(wp), DIMENSION(A2D(nn_hls)) :: zz_dz_i, zz_dz_j, zz_drho_i, zz_drho_j ! temporary arrays
649	REAL(wp), DIMENSION(:,:), ALLOCATABLE :: zcpx, zcpy !W/D pressure filter
650	!!----------------------------------------------------------------------
651	!
652	IF( ln_wd_il ) THEN
653	ALLOCATE( zcpx(A2D(nn_hls)) , zcpy(A2D(nn_hls)) )
654	DO_2D( 0, 0, 0, 0 )
655	ll_tmp1 = MIN( ssh(ji,jj,Kmm) , ssh(ji+1,jj,Kmm) ) > &
656	& MAX( -ht_0(ji,jj) , -ht_0(ji+1,jj) ) .AND. &
657	& MAX( ssh(ji,jj,Kmm) + ht_0(ji,jj), ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) ) &
658	& > rn_wdmin1 + rn_wdmin2
659	ll_tmp2 = ( ABS( ssh(ji,jj,Kmm) - ssh(ji+1,jj,Kmm) ) > 1.E-12 ) .AND. ( &
660	& MAX( ssh(ji,jj,Kmm) , ssh(ji+1,jj,Kmm) ) > &
661	& MAX( -ht_0(ji,jj) , -ht_0(ji+1,jj) ) + rn_wdmin1 + rn_wdmin2 )
662	IF(ll_tmp1) THEN
663	zcpx(ji,jj) = 1.0_wp
664	ELSE IF(ll_tmp2) THEN
665	! no worries about ssh(ji+1,jj,Kmm) - ssh(ji ,jj,Kmm) = 0, it won't happen ! here
666	zcpx(ji,jj) = ABS( (ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
667	& / (ssh(ji+1,jj,Kmm) - ssh(ji ,jj,Kmm)) )
668	ELSE
669	zcpx(ji,jj) = 0._wp
670	END IF
671
672	ll_tmp1 = MIN( ssh(ji,jj,Kmm) , ssh(ji,jj+1,Kmm) ) > &
673	& MAX( -ht_0(ji,jj) , -ht_0(ji,jj+1) ) .AND. &
674	& MAX( ssh(ji,jj,Kmm) + ht_0(ji,jj), ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) ) &
675	& > rn_wdmin1 + rn_wdmin2
676	ll_tmp2 = ( ABS( ssh(ji,jj,Kmm) - ssh(ji,jj+1,Kmm) ) > 1.E-12 ) .AND. ( &
677	& MAX( ssh(ji,jj,Kmm) , ssh(ji,jj+1,Kmm) ) > &
678	& MAX( -ht_0(ji,jj) , -ht_0(ji,jj+1) ) + rn_wdmin1 + rn_wdmin2 )
679
680	IF(ll_tmp1) THEN
681	zcpy(ji,jj) = 1.0_wp
682	ELSE IF(ll_tmp2) THEN
683	! no worries about ssh(ji,jj+1,Kmm) - ssh(ji,jj ,Kmm) = 0, it won't happen ! here
684	zcpy(ji,jj) = ABS( (ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
685	& / (ssh(ji,jj+1,Kmm) - ssh(ji,jj ,Kmm)) )
686	ELSE
687	zcpy(ji,jj) = 0._wp
688	END IF
689	END_2D
690	END IF
691
692	IF( .NOT. l_istiled .OR. ntile == 1 ) THEN ! Do only on the first tile
693	IF( kt == nit000 ) THEN
694	IF(lwp) WRITE(numout,*)
695	IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
696	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ s-coordinate case, density Jacobian with cubic polynomial scheme'
697	ENDIF
698	ENDIF
699
700	! Local constant initialization
701	zcoef0 = - grav * 0.5_wp
702	z_grav_10 = grav / 10._wp
703	z1_12 = 1.0_wp / 12._wp
704
705	!----------------------------------------------------------------------------------------
706	! 1. compute and store elementary vertical differences in provisional arrays
707	!----------------------------------------------------------------------------------------
708
709	!!bug gm Not a true bug, but... zdzz=e3w for zdzx, zdzy verify what it is really
710
711	DO_3D( 1, 1, 1, 1, 2, jpkm1 )
712	zdrhoz(ji,jj,jk) = rhd (ji ,jj ,jk) - rhd (ji,jj,jk-1)
713	zdzz (ji,jj,jk) = - gde3w(ji ,jj ,jk) + gde3w(ji,jj,jk-1)
714	END_3D
715
716	!-------------------------------------------------------------------------
717	! 2. compute harmonic averages for vertical differences using eq. 5.18
718	!-------------------------------------------------------------------------
719	zep = 1.e-15
720
721	!! mb zdrho_k, zdz_k, zdrho_i, zdz_i, zdrho_j, zdz_j re-centred about the point (ji,jj,jk)
722	zdrho_k(:,:,:) = 0._wp
723	zdz_k (:,:,:) = 0._wp
724
725	DO_3D( 1, 1, 1, 1, 2, jpk-2 )
726	cffw = MAX( 2._wp * zdrhoz(ji,jj,jk) * zdrhoz(ji,jj,jk+1), 0._wp )
727	z1_cff = zdrhoz(ji,jj,jk) + zdrhoz(ji,jj,jk+1)
728	zdrho_k(ji,jj,jk) = cffw / SIGN( MAX( ABS(z1_cff), zep ), z1_cff )
729	zdz_k(ji,jj,jk) = 2._wp * zdzz(ji,jj,jk) * zdzz(ji,jj,jk+1) &
730	& / ( zdzz(ji,jj,jk) + zdzz(ji,jj,jk+1) )
731	END_3D
732
733	!----------------------------------------------------------------------------------
734	! 3. apply boundary conditions at top and bottom using 5.36-5.37
735	!----------------------------------------------------------------------------------
736
737	! mb for sea-ice shelves we will need to re-write this upper boundary condition in the same form as the lower boundary condition
738	DO_2D( 1, 1, 1, 1 )
739	zdrho_k(ji,jj,1) = aco_bc_vrt * ( rhd (ji,jj,2) - rhd (ji,jj,1) ) - bco_bc_vrt * zdrho_k(ji,jj,2)
740	zdz_k (ji,jj,1) = aco_bc_vrt * (-gde3w(ji,jj,2) + gde3w(ji,jj,1) ) - bco_bc_vrt * zdz_k (ji,jj,2)
741	END_2D
742
743	DO_2D( 1, 1, 1, 1 )
744	IF ( mbkt(ji,jj)>1 ) THEN
745	iktb = mbkt(ji,jj)
746	zdrho_k(ji,jj,iktb) = aco_bc_vrt * ( rhd(ji,jj,iktb) - rhd(ji,jj,iktb-1) ) - bco_bc_vrt * zdrho_k(ji,jj,iktb-1)
747	zdz_k (ji,jj,iktb) = aco_bc_vrt * (-gde3w(ji,jj,iktb) + gde3w(ji,jj,iktb-1) ) - bco_bc_vrt * zdz_k (ji,jj,iktb-1)
748	END IF
749	END_2D
750
751	!--------------------------------------------------------------
752	! 4. Compute side face integrals
753	!-------------------------------------------------------------
754
755	!! ssh replaces e3w_n ; gde3w is a depth; the formulae involve heights
756	!! rho_k stores grav * FX / rho_0
757
758	!--------------------------------------------------------------
759	! 4. a) Upper half of top-most grid box, compute and store
760	!-------------------------------------------------------------
761	! *** AY note: ssh(ji,jj,Kmm) + gde3w(ji,jj,1) = e3w(ji,jj,1,Kmm)
762	DO_2D( 0, 1, 0, 1)
763	z_rho_k(ji,jj,1) = grav * ( ssh(ji,jj,Kmm) + gde3w(ji,jj,1) ) &
764	& * ( rhd(ji,jj,1) &
765	& + 0.5_wp * ( rhd (ji,jj,2) - rhd (ji,jj,1) ) &
766	& * ( ssh (ji,jj,Kmm) + gde3w(ji,jj,1) ) &
767	& / ( - gde3w(ji,jj,2) + gde3w(ji,jj,1) ) )
768	END_2D
769
770	!--------------------------------------------------------------
771	! 4. b) Interior faces, compute and store
772	!-------------------------------------------------------------
773
774	DO_3D( 0, 1, 0, 1, 2, jpkm1 )
775	z_rho_k(ji,jj,jk) = zcoef0 * ( rhd (ji,jj,jk) + rhd (ji,jj,jk-1) ) &
776	& * ( - gde3w(ji,jj,jk) + gde3w(ji,jj,jk-1) ) &
777	& + z_grav_10 * ( &
778	& ( zdrho_k (ji,jj,jk) - zdrho_k (ji,jj,jk-1) ) &
779	& * ( - gde3w(ji,jj,jk) + gde3w(ji,jj,jk-1) - z1_12 * ( zdz_k (ji,jj,jk) + zdz_k (ji,jj,jk-1) ) ) &
780	& - ( zdz_k (ji,jj,jk) - zdz_k (ji,jj,jk-1) ) &
781	& * ( rhd (ji,jj,jk) - rhd (ji,jj,jk-1) - z1_12 * ( zdrho_k(ji,jj,jk) + zdrho_k(ji,jj,jk-1) ) ) &
782	& )
783	END_3D
784
785	!----------------------------------------------------------------------------------------
786	! 5. compute and store elementary horizontal differences in provisional arrays
787	!----------------------------------------------------------------------------------------
788	zdrhox(:,:,:) = 0._wp
789	zdzx (:,:,:) = 0._wp
790	zdrhoy(:,:,:) = 0._wp
791	zdzy (:,:,:) = 0._wp
792
793	DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpkm1 )
794	zdrhox(ji,jj,jk) = rhd (ji+1,jj ,jk) - rhd (ji ,jj ,jk)
795	zdzx (ji,jj,jk) = gde3w(ji ,jj ,jk) - gde3w(ji+1,jj ,jk)
796	zdrhoy(ji,jj,jk) = rhd (ji ,jj+1,jk) - rhd (ji ,jj ,jk)
797	zdzy (ji,jj,jk) = gde3w(ji ,jj ,jk) - gde3w(ji ,jj+1,jk)
798	END_3D
799
800	IF( nn_hls == 1 ) CALL lbc_lnk( 'dynhpg', zdrhox, 'U', -1._wp, zdzx, 'U', -1._wp, zdrhoy, 'V', -1._wp, zdzy, 'V', -1._wp )
801
802	!-------------------------------------------------------------------------
803	! 6. compute harmonic averages using eq. 5.18
804	!-------------------------------------------------------------------------
805
806	DO_3D( 0, 1, 0, 1, 1, jpkm1 )
807	cffu = MAX( 2._wp * zdrhox(ji-1,jj,jk) * zdrhox(ji,jj,jk), 0._wp )
808	z1_cff = zdrhox(ji-1,jj,jk) + zdrhox(ji,jj,jk)
809	zdrho_i(ji,jj,jk) = cffu / SIGN( MAX( ABS(z1_cff), zep ), z1_cff )
810
811	cffx = MAX( 2._wp * zdzx(ji-1,jj,jk) * zdzx(ji,jj,jk), 0._wp )
812	z1_cff = zdzx(ji-1,jj,jk) + zdzx(ji,jj,jk)
813	zdz_i(ji,jj,jk) = cffx / SIGN( MAX( ABS(z1_cff), zep ), z1_cff )
814
815	cffv = MAX( 2._wp * zdrhoy(ji,jj-1,jk) * zdrhoy(ji,jj,jk), 0._wp )
816	z1_cff = zdrhoy(ji,jj-1,jk) + zdrhoy(ji,jj,jk)
817	zdrho_j(ji,jj,jk) = cffv / SIGN( MAX( ABS(z1_cff), zep ), z1_cff )
818
819	cffy = MAX( 2._wp * zdzy(ji,jj-1,jk) * zdzy(ji,jj,jk), 0._wp )
820	z1_cff = zdzy(ji,jj-1,jk) + zdzy(ji,jj,jk)
821	zdz_j(ji,jj,jk) = cffy / SIGN( MAX( ABS(z1_cff), zep ), z1_cff )
822	END_3D
823
824	!!! Note that zdzx, zdzy, zdzz, zdrhox, zdrhoy and zdrhoz should NOT be used beyond this point
825
826	!----------------------------------------------------------------------------------
827	! 6B. apply boundary conditions at side boundaries using 5.36-5.37
828	!----------------------------------------------------------------------------------
829
830	DO jk = 1, jpkm1
831	zz_drho_i(:,:) = zdrho_i(:,:,jk)
832	zz_dz_i (:,:) = zdz_i (:,:,jk)
833	zz_drho_j(:,:) = zdrho_j(:,:,jk)
834	zz_dz_j (:,:) = zdz_j (:,:,jk)
835	! Walls coming from left: should check from 2 to jpi-1 (and jpj=2-jpj)
836	DO_2D( 0, 0, 0, 1 )
837	IF ( umask(ji,jj,jk) > 0.5_wp .AND. umask(ji-1,jj,jk) < 0.5_wp .AND. umask(ji+1,jj,jk) > 0.5_wp) THEN
838	zz_drho_i(ji,jj) = aco_bc_hor * ( rhd (ji+1,jj,jk) - rhd (ji,jj,jk) ) - bco_bc_hor * zdrho_i(ji+1,jj,jk)
839	zz_dz_i (ji,jj) = aco_bc_hor * (-gde3w(ji+1,jj,jk) + gde3w(ji,jj,jk) ) - bco_bc_hor * zdz_i (ji+1,jj,jk)
840	END IF
841	END_2D
842	! Walls coming from right: should check from 3 to jpi (and jpj=2-jpj)
843	DO_2D( -1, 1, 0, 1 )
844	IF ( umask(ji,jj,jk) < 0.5_wp .AND. umask(ji-1,jj,jk) > 0.5_wp .AND. umask(ji-2,jj,jk) > 0.5_wp) THEN
845	zz_drho_i(ji,jj) = aco_bc_hor * ( rhd (ji,jj,jk) - rhd (ji-1,jj,jk) ) - bco_bc_hor * zdrho_i(ji-1,jj,jk)
846	zz_dz_i (ji,jj) = aco_bc_hor * (-gde3w(ji,jj,jk) + gde3w(ji-1,jj,jk) ) - bco_bc_hor * zdz_i (ji-1,jj,jk)
847	END IF
848	END_2D
849	! Walls coming from left: should check from 2 to jpj-1 (and jpi=2-jpi)
850	DO_2D( 0, 1, 0, 0 )
851	IF ( vmask(ji,jj,jk) > 0.5_wp .AND. vmask(ji,jj-1,jk) < 0.5_wp .AND. vmask(ji,jj+1,jk) > 0.5_wp) THEN
852	zz_drho_j(ji,jj) = aco_bc_hor * ( rhd (ji,jj+1,jk) - rhd (ji,jj,jk) ) - bco_bc_hor * zdrho_j(ji,jj+1,jk)
853	zz_dz_j (ji,jj) = aco_bc_hor * (-gde3w(ji,jj+1,jk) + gde3w(ji,jj,jk) ) - bco_bc_hor * zdz_j (ji,jj+1,jk)
854	END IF
855	END_2D
856	! Walls coming from right: should check from 3 to jpj (and jpi=2-jpi)
857	DO_2D( 0, 1, -1, 1 )
858	IF ( vmask(ji,jj,jk) < 0.5_wp .AND. vmask(ji,jj-1,jk) > 0.5_wp .AND. vmask(ji,jj-2,jk) > 0.5_wp) THEN
859	zz_drho_j(ji,jj) = aco_bc_hor * ( rhd (ji,jj,jk) - rhd (ji,jj-1,jk) ) - bco_bc_hor * zdrho_j(ji,jj-1,jk)
860	zz_dz_j (ji,jj) = aco_bc_hor * (-gde3w(ji,jj,jk) + gde3w(ji,jj-1,jk) ) - bco_bc_hor * zdz_j (ji,jj-1,jk)
861	END IF
862	END_2D
863	zdrho_i(:,:,jk) = zz_drho_i(:,:)
864	zdz_i (:,:,jk) = zz_dz_i (:,:)
865	zdrho_j(:,:,jk) = zz_drho_j(:,:)
866	zdz_j (:,:,jk) = zz_dz_j (:,:)
867	END DO
868
869	!--------------------------------------------------------------
870	! 7. Calculate integrals on side faces
871	!-------------------------------------------------------------
872
873	DO_3D( 0, 0, 0, 0, 1, jpkm1 )
874	! two -ve signs cancel in next two lines (within zcoef0 and because gde3w is a depth not a height)
875	z_rho_i(ji,jj,jk) = zcoef0 * ( rhd (ji+1,jj,jk) + rhd (ji,jj,jk) ) &
876	& * ( gde3w(ji+1,jj,jk) - gde3w(ji,jj,jk) )
877	IF ( umask(ji-1, jj, jk) > 0.5 .OR. umask(ji+1, jj, jk) > 0.5 ) THEN
878	z_rho_i(ji,jj,jk) = z_rho_i(ji,jj,jk) - z_grav_10 * ( &
879	& ( zdrho_i (ji+1,jj,jk) - zdrho_i (ji,jj,jk) ) &
880	& * ( - gde3w(ji+1,jj,jk) + gde3w(ji,jj,jk) - z1_12 * ( zdz_i (ji+1,jj,jk) + zdz_i (ji,jj,jk) ) ) &
881	& - ( zdz_i (ji+1,jj,jk) - zdz_i (ji,jj,jk) ) &
882	& * ( rhd (ji+1,jj,jk) - rhd (ji,jj,jk) - z1_12 * ( zdrho_i(ji+1,jj,jk) + zdrho_i(ji,jj,jk) ) ) &
883	& )
884	END IF
885
886	z_rho_j(ji,jj,jk) = zcoef0 * ( rhd (ji,jj+1,jk) + rhd (ji,jj,jk) ) &
887	& * ( gde3w(ji,jj+1,jk) - gde3w(ji,jj,jk) )
888	IF ( vmask(ji, jj-1, jk) > 0.5 .OR. vmask(ji, jj+1, jk) > 0.5 ) THEN
889	z_rho_j(ji,jj,jk) = z_rho_j(ji,jj,jk) - z_grav_10 * ( &
890	& ( zdrho_j (ji,jj+1,jk) - zdrho_j (ji,jj,jk) ) &
891	& * ( - gde3w(ji,jj+1,jk) + gde3w(ji,jj,jk) - z1_12 * ( zdz_j (ji,jj+1,jk) + zdz_j (ji,jj,jk) ) ) &
892	& - ( zdz_j (ji,jj+1,jk) - zdz_j (ji,jj,jk) ) &
893	& * ( rhd (ji,jj+1,jk) - rhd (ji,jj,jk) - z1_12 * ( zdrho_j(ji,jj+1,jk) + zdrho_j(ji,jj,jk) ) ) &
894	& )
895	END IF
896	END_3D
897
898	!--------------------------------------------------------------
899	! 8. Integrate in the vertical
900	!-------------------------------------------------------------
901	!
902	! ---------------
903	! Surface value
904	! ---------------
905	DO_2D( 0, 0, 0, 0 )
906	zhpi(ji,jj,1) = ( z_rho_k(ji,jj,1) - z_rho_k(ji+1,jj ,1) - z_rho_i(ji,jj,1) ) * r1_e1u(ji,jj)
907	zhpj(ji,jj,1) = ( z_rho_k(ji,jj,1) - z_rho_k(ji ,jj+1,1) - z_rho_j(ji,jj,1) ) * r1_e2v(ji,jj)
908	IF( ln_wd_il ) THEN
909	zhpi(ji,jj,1) = zhpi(ji,jj,1) * zcpx(ji,jj)
910	zhpj(ji,jj,1) = zhpj(ji,jj,1) * zcpy(ji,jj)
911	ENDIF
912	! add to the general momentum trend
913	puu(ji,jj,1,Krhs) = puu(ji,jj,1,Krhs) + zhpi(ji,jj,1)
914	pvv(ji,jj,1,Krhs) = pvv(ji,jj,1,Krhs) + zhpj(ji,jj,1)
915	END_2D
916
917	! ----------------
918	! interior value (2=<jk=<jpkm1)
919	! ----------------
920	DO_3D( 0, 0, 0, 0, 2, jpkm1 )
921	! hydrostatic pressure gradient along s-surfaces
922	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) &
923	& + ( ( z_rho_k(ji,jj,jk) - z_rho_k(ji+1,jj,jk ) ) &
924	& - ( z_rho_i(ji,jj,jk) - z_rho_i(ji ,jj,jk-1) ) ) * r1_e1u(ji,jj)
925	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) &
926	& + ( ( z_rho_k(ji,jj,jk) - z_rho_k(ji,jj+1,jk ) ) &
927	& -( z_rho_j(ji,jj,jk) - z_rho_j(ji,jj ,jk-1) ) ) * r1_e2v(ji,jj)
928	IF( ln_wd_il ) THEN
929	zhpi(ji,jj,jk) = zhpi(ji,jj,jk) * zcpx(ji,jj)
930	zhpj(ji,jj,jk) = zhpj(ji,jj,jk) * zcpy(ji,jj)
931	ENDIF
932	! add to the general momentum trend
933	puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + zhpi(ji,jj,jk)
934	pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + zhpj(ji,jj,jk)
935	END_3D
936	!
937	IF( ln_wd_il ) DEALLOCATE( zcpx, zcpy )
938	!
939	END SUBROUTINE hpg_djc
940
941
942	SUBROUTINE hpg_prj( kt, Kmm, puu, pvv, Krhs )
943	!!---------------------------------------------------------------------
944	!! * ROUTINE hpg_prj *
945	!!
946	!! ** Method : s-coordinate case.
947	!! A Pressure-Jacobian horizontal pressure gradient method
948	!! based on the constrained cubic-spline interpolation for
949	!! all vertical coordinate systems
950	!!
951	!! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
952	!!----------------------------------------------------------------------
953	INTEGER, PARAMETER :: polynomial_type = 1 ! 1: cubic spline, 2: linear
954	INTEGER , INTENT( in ) :: kt ! ocean time-step index
955	INTEGER , INTENT( in ) :: Kmm, Krhs ! ocean time level indices
956	REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) :: puu, pvv ! ocean velocities and RHS of momentum equation
957	!!
958	INTEGER :: ji, jj, jk, jkk ! dummy loop indices
959	REAL(wp) :: zcoef0, znad ! local scalars
960	!
961	!! The local variables for the correction term
962	INTEGER :: jk1, jis, jid, jjs, jjd
963	LOGICAL :: ll_tmp1, ll_tmp2 ! local logical variables
964	REAL(wp) :: zuijk, zvijk, zpwes, zpwed, zpnss, zpnsd, zdeps
965	REAL(wp) :: zrhdt1
966	REAL(wp) :: zdpdx1, zdpdx2, zdpdy1, zdpdy2
967	REAL(wp), DIMENSION(A2D(nn_hls)) :: zpgu, zpgv ! 2D workspace
968	REAL(wp), DIMENSION(A2D(nn_hls)) :: zsshu_n, zsshv_n
969	REAL(wp), DIMENSION(A2D(nn_hls),jpk) :: zdept, zrhh
970	REAL(wp), DIMENSION(A2D(nn_hls),jpk) :: zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp
971	REAL(wp), DIMENSION(:,:), ALLOCATABLE :: zcpx, zcpy !W/D pressure filter
972	!!----------------------------------------------------------------------
973	!
974	IF( .NOT. l_istiled .OR. ntile == 1 ) THEN ! Do only on the first tile
975	IF( kt == nit000 ) THEN
976	IF(lwp) WRITE(numout,*)
977	IF(lwp) WRITE(numout,*) 'dyn:hpg_prj : hydrostatic pressure gradient trend'
978	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ s-coordinate case, cubic spline pressure Jacobian'
979	ENDIF
980	ENDIF
981
982	! Local constant initialization
983	zcoef0 = - grav
984	znad = 1._wp
985	IF( ln_linssh ) znad = 1._wp
986	!
987	! ---------------
988	! Surface pressure gradient to be removed
989	! ---------------
990	DO_2D( 0, 0, 0, 0 )
991	zpgu(ji,jj) = - grav * ( ssh(ji+1,jj,Kmm) - ssh(ji,jj,Kmm) ) * r1_e1u(ji,jj)
992	zpgv(ji,jj) = - grav * ( ssh(ji,jj+1,Kmm) - ssh(ji,jj,Kmm) ) * r1_e2v(ji,jj)
993	END_2D
994	!
995	IF( ln_wd_il ) THEN
996	ALLOCATE( zcpx(A2D(nn_hls)) , zcpy(A2D(nn_hls)) )
997	DO_2D( 0, 0, 0, 0 )
998	ll_tmp1 = MIN( ssh(ji,jj,Kmm) , ssh(ji+1,jj,Kmm) ) > &
999	& MAX( -ht_0(ji,jj) , -ht_0(ji+1,jj) ) .AND. &
1000	& MAX( ssh(ji,jj,Kmm) + ht_0(ji,jj), ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) ) > &
1001	& rn_wdmin1 + rn_wdmin2
1002	ll_tmp2 = ( ABS( ssh(ji,jj,Kmm) - ssh(ji+1,jj,Kmm) ) > 1.E-12 ) .AND. &
1003	& ( MAX( ssh(ji,jj,Kmm) , ssh(ji+1,jj,Kmm) ) > &
1004	& MAX( -ht_0(ji,jj) , -ht_0(ji+1,jj) ) + rn_wdmin1 + rn_wdmin2 )
1005
1006	IF(ll_tmp1) THEN
1007	zcpx(ji,jj) = 1.0_wp
1008	ELSE IF(ll_tmp2) THEN
1009	! no worries about ssh(ji+1,jj,Kmm) - ssh(ji ,jj,Kmm) = 0, it won't happen ! here
1010	zcpx(ji,jj) = ABS( (ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
1011	& / (ssh(ji+1,jj,Kmm) - ssh(ji ,jj,Kmm)) )
1012	zcpx(ji,jj) = MAX(MIN( zcpx(ji,jj) , 1.0_wp),0.0_wp)
1013	ELSE
1014	zcpx(ji,jj) = 0._wp
1015	END IF
1016
1017	ll_tmp1 = MIN( ssh(ji,jj,Kmm) , ssh(ji,jj+1,Kmm) ) > &
1018	& MAX( -ht_0(ji,jj) , -ht_0(ji,jj+1) ) .AND. &
1019	& MAX( ssh(ji,jj,Kmm) + ht_0(ji,jj), ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) ) > &
1020	& rn_wdmin1 + rn_wdmin2
1021	ll_tmp2 = ( ABS( ssh(ji,jj,Kmm) - ssh(ji,jj+1,Kmm) ) > 1.E-12 ) .AND. &
1022	& ( MAX( ssh(ji,jj,Kmm) , ssh(ji,jj+1,Kmm) ) > &
1023	& MAX( -ht_0(ji,jj) , -ht_0(ji,jj+1) ) + rn_wdmin1 + rn_wdmin2 )
1024
1025	IF(ll_tmp1) THEN
1026	zcpy(ji,jj) = 1.0_wp
1027	ELSE IF(ll_tmp2) THEN
1028	! no worries about ssh(ji,jj+1,Kmm) - ssh(ji,jj ,Kmm) = 0, it won't happen ! here
1029	zcpy(ji,jj) = ABS( (ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
1030	& / (ssh(ji,jj+1,Kmm) - ssh(ji,jj ,Kmm)) )
1031	zcpy(ji,jj) = MAX(MIN( zcpy(ji,jj) , 1.0_wp),0.0_wp)
1032	ELSE
1033	zcpy(ji,jj) = 0._wp
1034	ENDIF
1035	END_2D
1036	ENDIF
1037
1038	! Clean 3-D work arrays
1039	zhpi(:,:,:) = 0._wp
1040	zrhh(:,:,:) = rhd(A2D(nn_hls),:)
1041
1042	! Preparing vertical density profile "zrhh(:,:,:)" for hybrid-sco coordinate
1043	DO_2D( 1, 1, 1, 1 )
1044	jk = mbkt(ji,jj)
1045	IF( jk <= 1 ) THEN ; zrhh(ji,jj, : ) = 0._wp
1046	ELSEIF( jk == 2 ) THEN ; zrhh(ji,jj,jk+1:jpk) = rhd(ji,jj,jk)
1047	ELSEIF( jk < jpkm1 ) THEN
1048	DO jkk = jk+1, jpk
1049	zrhh(ji,jj,jkk) = interp1(gde3w(ji,jj,jkk ), gde3w(ji,jj,jkk-1), &
1050	& gde3w(ji,jj,jkk-2), zrhh (ji,jj,jkk-1), zrhh(ji,jj,jkk-2))
1051	END DO
1052	ENDIF
1053	END_2D
1054
1055	! Transfer the depth of "T(:,:,:)" to vertical coordinate "zdept(:,:,:)"
1056	DO_2D( 1, 1, 1, 1 )
1057	zdept(ji,jj,1) = 0.5_wp * e3w(ji,jj,1,Kmm) - ssh(ji,jj,Kmm)
1058	END_2D
1059
1060	DO_3D( 1, 1, 1, 1, 2, jpk )
1061	zdept(ji,jj,jk) = zdept(ji,jj,jk-1) + e3w(ji,jj,jk,Kmm)
1062	END_3D
1063
1064	fsp(:,:,:) = zrhh (:,:,:)
1065	xsp(:,:,:) = zdept(:,:,:)
1066
1067	! Construct the vertical density profile with the
1068	! constrained cubic spline interpolation
1069	! rho(z) = asp + bspz + cspz^2 + dsp*z^3
1070	CALL cspline( fsp, xsp, asp, bsp, csp, dsp, polynomial_type )
1071
1072	! Integrate the hydrostatic pressure "zhpi(:,:,:)" at "T(ji,jj,1)"
1073	DO_2D( 0, 1, 0, 1 )
1074	zrhdt1 = zrhh(ji,jj,1) - interp3( zdept(ji,jj,1), asp(ji,jj,1), bsp(ji,jj,1), &
1075	& csp(ji,jj,1), dsp(ji,jj,1) ) * 0.25_wp * e3w(ji,jj,1,Kmm)
1076
1077	! assuming linear profile across the top half surface layer
1078	zhpi(ji,jj,1) = 0.5_wp * e3w(ji,jj,1,Kmm) * zrhdt1
1079	END_2D
1080
1081	! Calculate the pressure "zhpi(:,:,:)" at "T(ji,jj,2:jpkm1)"
1082	DO_3D( 0, 1, 0, 1, 2, jpkm1 )
1083	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + &
1084	& integ_spline( zdept(ji,jj,jk-1), zdept(ji,jj,jk), &
1085	& asp (ji,jj,jk-1), bsp (ji,jj,jk-1), &
1086	& csp (ji,jj,jk-1), dsp (ji,jj,jk-1) )
1087	END_3D
1088
1089	! Z coordinate of U(ji,jj,1:jpkm1) and V(ji,jj,1:jpkm1)
1090
1091	! Prepare zsshu_n and zsshv_n
1092	DO_2D( 0, 0, 0, 0 )
1093	!!gm BUG ? if it is ssh at u- & v-point then it should be:
1094	! zsshu_n(ji,jj) = (e1e2t(ji,jj) * ssh(ji,jj,Kmm) + e1e2t(ji+1,jj) * ssh(ji+1,jj,Kmm)) * &
1095	! & r1_e1e2u(ji,jj) * umask(ji,jj,1) * 0.5_wp
1096	! zsshv_n(ji,jj) = (e1e2t(ji,jj) * ssh(ji,jj,Kmm) + e1e2t(ji,jj+1) * ssh(ji,jj+1,Kmm)) * &
1097	! & r1_e1e2v(ji,jj) * vmask(ji,jj,1) * 0.5_wp
1098	!!gm not this:
1099	zsshu_n(ji,jj) = (e1e2u(ji,jj) * ssh(ji,jj,Kmm) + e1e2u(ji+1, jj) * ssh(ji+1,jj,Kmm)) * &
1100	& r1_e1e2u(ji,jj) * umask(ji,jj,1) * 0.5_wp
1101	zsshv_n(ji,jj) = (e1e2v(ji,jj) * ssh(ji,jj,Kmm) + e1e2v(ji+1, jj) * ssh(ji,jj+1,Kmm)) * &
1102	& r1_e1e2v(ji,jj) * vmask(ji,jj,1) * 0.5_wp
1103	END_2D
1104
1105	DO_2D( 0, 0, 0, 0 )
1106	zu(ji,jj,1) = - ( e3u(ji,jj,1,Kmm) - zsshu_n(ji,jj) )
1107	zv(ji,jj,1) = - ( e3v(ji,jj,1,Kmm) - zsshv_n(ji,jj) )
1108	END_2D
1109
1110	DO_3D( 0, 0, 0, 0, 2, jpkm1 )
1111	zu(ji,jj,jk) = zu(ji,jj,jk-1) - e3u(ji,jj,jk,Kmm)
1112	zv(ji,jj,jk) = zv(ji,jj,jk-1) - e3v(ji,jj,jk,Kmm)
1113	END_3D
1114
1115	DO_3D( 0, 0, 0, 0, 1, jpkm1 )
1116	zu(ji,jj,jk) = zu(ji,jj,jk) + 0.5_wp * e3u(ji,jj,jk,Kmm)
1117	zv(ji,jj,jk) = zv(ji,jj,jk) + 0.5_wp * e3v(ji,jj,jk,Kmm)
1118	END_3D
1119
1120	DO_3D( 0, 0, 0, 0, 1, jpkm1 )
1121	zu(ji,jj,jk) = MIN( zu(ji,jj,jk) , MAX( -zdept(ji,jj,jk) , -zdept(ji+1,jj,jk) ) )
1122	zu(ji,jj,jk) = MAX( zu(ji,jj,jk) , MIN( -zdept(ji,jj,jk) , -zdept(ji+1,jj,jk) ) )
1123	zv(ji,jj,jk) = MIN( zv(ji,jj,jk) , MAX( -zdept(ji,jj,jk) , -zdept(ji,jj+1,jk) ) )
1124	zv(ji,jj,jk) = MAX( zv(ji,jj,jk) , MIN( -zdept(ji,jj,jk) , -zdept(ji,jj+1,jk) ) )
1125	END_3D
1126
1127
1128	DO_3D( 0, 0, 0, 0, 1, jpkm1 )
1129	zpwes = 0._wp; zpwed = 0._wp
1130	zpnss = 0._wp; zpnsd = 0._wp
1131	zuijk = zu(ji,jj,jk)
1132	zvijk = zv(ji,jj,jk)
1133
1134	!!!!! for u equation
1135	IF( jk <= mbku(ji,jj) ) THEN
1136	IF( -zdept(ji+1,jj,jk) >= -zdept(ji,jj,jk) ) THEN
1137	jis = ji + 1; jid = ji
1138	ELSE
1139	jis = ji; jid = ji +1
1140	ENDIF
1141
1142	! integrate the pressure on the shallow side
1143	jk1 = jk
1144	DO WHILE ( -zdept(jis,jj,jk1) > zuijk )
1145	IF( jk1 == mbku(ji,jj) ) THEN
1146	zuijk = -zdept(jis,jj,jk1)
1147	EXIT
1148	ENDIF
1149	zdeps = MIN(zdept(jis,jj,jk1+1), -zuijk)
1150	zpwes = zpwes + &
1151	integ_spline(zdept(jis,jj,jk1), zdeps, &
1152	asp(jis,jj,jk1), bsp(jis,jj,jk1), &
1153	csp(jis,jj,jk1), dsp(jis,jj,jk1))
1154	jk1 = jk1 + 1
1155	END DO
1156
1157	! integrate the pressure on the deep side
1158	jk1 = jk
1159	DO WHILE ( -zdept(jid,jj,jk1) < zuijk )
1160	IF( jk1 == 1 ) THEN
1161	zdeps = zdept(jid,jj,1) + MIN(zuijk, ssh(jid,jj,Kmm)*znad)
1162	zrhdt1 = zrhh(jid,jj,1) - interp3(zdept(jid,jj,1), asp(jid,jj,1), &
1163	bsp(jid,jj,1) , csp(jid,jj,1), &
1164	dsp(jid,jj,1)) * zdeps
1165	zpwed = zpwed + 0.5_wp * (zrhh(jid,jj,1) + zrhdt1) * zdeps
1166	EXIT
1167	ENDIF
1168	zdeps = MAX(zdept(jid,jj,jk1-1), -zuijk)
1169	zpwed = zpwed + &
1170	integ_spline(zdeps, zdept(jid,jj,jk1), &
1171	asp(jid,jj,jk1-1), bsp(jid,jj,jk1-1), &
1172	csp(jid,jj,jk1-1), dsp(jid,jj,jk1-1) )
1173	jk1 = jk1 - 1
1174	END DO
1175
1176	! update the momentum trends in u direction
1177	zdpdx1 = zcoef0 * r1_e1u(ji,jj) * ( zhpi(ji+1,jj,jk) - zhpi(ji,jj,jk) )
1178	IF( .NOT.ln_linssh ) THEN
1179	zdpdx2 = zcoef0 * r1_e1u(ji,jj) * &
1180	& ( REAL(jis-jid, wp) * (zpwes + zpwed) + (ssh(ji+1,jj,Kmm)-ssh(ji,jj,Kmm)) )
1181	ELSE
1182	zdpdx2 = zcoef0 * r1_e1u(ji,jj) * REAL(jis-jid, wp) * (zpwes + zpwed)
1183	ENDIF
1184	IF( ln_wd_il ) THEN
1185	zdpdx1 = zdpdx1 * zcpx(ji,jj) * wdrampu(ji,jj)
1186	zdpdx2 = zdpdx2 * zcpx(ji,jj) * wdrampu(ji,jj)
1187	ENDIF
1188	puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + (zdpdx1 + zdpdx2 - zpgu(ji,jj)) * umask(ji,jj,jk)
1189	ENDIF
1190
1191	!!!!! for v equation
1192	IF( jk <= mbkv(ji,jj) ) THEN
1193	IF( -zdept(ji,jj+1,jk) >= -zdept(ji,jj,jk) ) THEN
1194	jjs = jj + 1; jjd = jj
1195	ELSE
1196	jjs = jj ; jjd = jj + 1
1197	ENDIF
1198
1199	! integrate the pressure on the shallow side
1200	jk1 = jk
1201	DO WHILE ( -zdept(ji,jjs,jk1) > zvijk )
1202	IF( jk1 == mbkv(ji,jj) ) THEN
1203	zvijk = -zdept(ji,jjs,jk1)
1204	EXIT
1205	ENDIF
1206	zdeps = MIN(zdept(ji,jjs,jk1+1), -zvijk)
1207	zpnss = zpnss + &
1208	integ_spline(zdept(ji,jjs,jk1), zdeps, &
1209	asp(ji,jjs,jk1), bsp(ji,jjs,jk1), &
1210	csp(ji,jjs,jk1), dsp(ji,jjs,jk1) )
1211	jk1 = jk1 + 1
1212	END DO
1213
1214	! integrate the pressure on the deep side
1215	jk1 = jk
1216	DO WHILE ( -zdept(ji,jjd,jk1) < zvijk )
1217	IF( jk1 == 1 ) THEN
1218	zdeps = zdept(ji,jjd,1) + MIN(zvijk, ssh(ji,jjd,Kmm)*znad)
1219	zrhdt1 = zrhh(ji,jjd,1) - interp3(zdept(ji,jjd,1), asp(ji,jjd,1), &
1220	bsp(ji,jjd,1) , csp(ji,jjd,1), &
1221	dsp(ji,jjd,1) ) * zdeps
1222	zpnsd = zpnsd + 0.5_wp * (zrhh(ji,jjd,1) + zrhdt1) * zdeps
1223	EXIT
1224	ENDIF
1225	zdeps = MAX(zdept(ji,jjd,jk1-1), -zvijk)
1226	zpnsd = zpnsd + &
1227	integ_spline(zdeps, zdept(ji,jjd,jk1), &
1228	asp(ji,jjd,jk1-1), bsp(ji,jjd,jk1-1), &
1229	csp(ji,jjd,jk1-1), dsp(ji,jjd,jk1-1) )
1230	jk1 = jk1 - 1
1231	END DO
1232
1233	! update the momentum trends in v direction
1234	zdpdy1 = zcoef0 * r1_e2v(ji,jj) * ( zhpi(ji,jj+1,jk) - zhpi(ji,jj,jk) )
1235	IF( .NOT.ln_linssh ) THEN
1236	zdpdy2 = zcoef0 * r1_e2v(ji,jj) * &
1237	( REAL(jjs-jjd, wp) * (zpnss + zpnsd) + (ssh(ji,jj+1,Kmm)-ssh(ji,jj,Kmm)) )
1238	ELSE
1239	zdpdy2 = zcoef0 * r1_e2v(ji,jj) * REAL(jjs-jjd, wp) * (zpnss + zpnsd )
1240	ENDIF
1241	IF( ln_wd_il ) THEN
1242	zdpdy1 = zdpdy1 * zcpy(ji,jj) * wdrampv(ji,jj)
1243	zdpdy2 = zdpdy2 * zcpy(ji,jj) * wdrampv(ji,jj)
1244	ENDIF
1245
1246	pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + (zdpdy1 + zdpdy2 - zpgv(ji,jj)) * vmask(ji,jj,jk)
1247	ENDIF
1248	!
1249	END_3D
1250	!
1251	IF( ln_wd_il ) DEALLOCATE( zcpx, zcpy )
1252	!
1253	END SUBROUTINE hpg_prj
1254
1255
1256	SUBROUTINE cspline( fsp, xsp, asp, bsp, csp, dsp, polynomial_type )
1257	!!----------------------------------------------------------------------
1258	!! * ROUTINE cspline *
1259	!!
1260	!! ** Purpose : constrained cubic spline interpolation
1261	!!
1262	!! ** Method : f(x) = asp + bspx + cspx^2 + dsp*x^3
1263	!!
1264	!! Reference: CJC Kruger, Constrained Cubic Spline Interpoltation
1265	!!----------------------------------------------------------------------
1266	REAL(wp), DIMENSION(A2D(nn_hls),jpk), INTENT(in ) :: fsp, xsp ! value and coordinate
1267	REAL(wp), DIMENSION(A2D(nn_hls),jpk), INTENT( out) :: asp, bsp, csp, dsp ! coefficients of the interpoated function
1268	INTEGER , INTENT(in ) :: polynomial_type ! 1: cubic spline ; 2: Linear
1269	!
1270	INTEGER :: ji, jj, jk ! dummy loop indices
1271	REAL(wp) :: zdf1, zdf2, zddf1, zddf2, ztmp1, ztmp2, zdxtmp
1272	REAL(wp) :: zdxtmp1, zdxtmp2, zalpha
1273	REAL(wp) :: zdf(jpk)
1274	!!----------------------------------------------------------------------
1275	!
1276	IF (polynomial_type == 1) THEN ! Constrained Cubic Spline
1277	DO_2D( 1, 1, 1, 1 )
1278	!!Fritsch&Butland's method, 1984 (preferred, but more computation)
1279	! DO jk = 2, jpkm1-1
1280	! zdxtmp1 = xsp(ji,jj,jk) - xsp(ji,jj,jk-1)
1281	! zdxtmp2 = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1282	! zdf1 = ( fsp(ji,jj,jk) - fsp(ji,jj,jk-1) ) / zdxtmp1
1283	! zdf2 = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp2
1284	!
1285	! zalpha = ( zdxtmp1 + 2._wp * zdxtmp2 ) / ( zdxtmp1 + zdxtmp2 ) / 3._wp
1286	!
1287	! IF(zdf1 * zdf2 <= 0._wp) THEN
1288	! zdf(jk) = 0._wp
1289	! ELSE
1290	! zdf(jk) = zdf1 * zdf2 / ( ( 1._wp - zalpha ) * zdf1 + zalpha * zdf2 )
1291	! ENDIF
1292	! END DO
1293
1294	!!Simply geometric average
1295	DO jk = 2, jpk-2
1296	zdf1 = (fsp(ji,jj,jk ) - fsp(ji,jj,jk-1)) / (xsp(ji,jj,jk ) - xsp(ji,jj,jk-1))
1297	zdf2 = (fsp(ji,jj,jk+1) - fsp(ji,jj,jk )) / (xsp(ji,jj,jk+1) - xsp(ji,jj,jk ))
1298
1299	IF(zdf1 * zdf2 <= 0._wp) THEN
1300	zdf(jk) = 0._wp
1301	ELSE
1302	zdf(jk) = 2._wp * zdf1 * zdf2 / (zdf1 + zdf2)
1303	ENDIF
1304	END DO
1305
1306	zdf(1) = 1.5_wp * ( fsp(ji,jj,2) - fsp(ji,jj,1) ) / &
1307	& ( xsp(ji,jj,2) - xsp(ji,jj,1) ) - 0.5_wp * zdf(2)
1308	zdf(jpkm1) = 1.5_wp * ( fsp(ji,jj,jpkm1) - fsp(ji,jj,jpkm1-1) ) / &
1309	& ( xsp(ji,jj,jpkm1) - xsp(ji,jj,jpkm1-1) ) - 0.5_wp * zdf(jpk - 2)
1310
1311	DO jk = 1, jpk-2
1312	zdxtmp = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1313	ztmp1 = (zdf(jk+1) + 2._wp * zdf(jk)) / zdxtmp
1314	ztmp2 = 6._wp * (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / zdxtmp / zdxtmp
1315	zddf1 = -2._wp * ztmp1 + ztmp2
1316	ztmp1 = (2._wp * zdf(jk+1) + zdf(jk)) / zdxtmp
1317	zddf2 = 2._wp * ztmp1 - ztmp2
1318
1319	dsp(ji,jj,jk) = (zddf2 - zddf1) / 6._wp / zdxtmp
1320	csp(ji,jj,jk) = ( xsp(ji,jj,jk+1) * zddf1 - xsp(ji,jj,jk)*zddf2 ) / 2._wp / zdxtmp
1321	bsp(ji,jj,jk) = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp - &
1322	& csp(ji,jj,jk) * ( xsp(ji,jj,jk+1) + xsp(ji,jj,jk) ) - &
1323	& dsp(ji,jj,jk) * ((xsp(ji,jj,jk+1) + xsp(ji,jj,jk))**2 - &
1324	& xsp(ji,jj,jk+1) * xsp(ji,jj,jk))
1325	asp(ji,jj,jk) = fsp(ji,jj,jk) - xsp(ji,jj,jk) * (bsp(ji,jj,jk) + &
1326	& (xsp(ji,jj,jk) * (csp(ji,jj,jk) + &
1327	& dsp(ji,jj,jk) * xsp(ji,jj,jk))))
1328	END DO
1329	END_2D
1330
1331	ELSEIF ( polynomial_type == 2 ) THEN ! Linear
1332	DO_3D( 1, 1, 1, 1, 1, jpk-2 )
1333	zdxtmp =xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1334	ztmp1 = fsp(ji,jj,jk+1) - fsp(ji,jj,jk)
1335
1336	dsp(ji,jj,jk) = 0._wp
1337	csp(ji,jj,jk) = 0._wp
1338	bsp(ji,jj,jk) = ztmp1 / zdxtmp
1339	asp(ji,jj,jk) = fsp(ji,jj,jk) - bsp(ji,jj,jk) * xsp(ji,jj,jk)
1340	END_3D
1341	!
1342	ELSE
1343	CALL ctl_stop( 'invalid polynomial type in cspline' )
1344	ENDIF
1345	!
1346	END SUBROUTINE cspline
1347
1348
1349	FUNCTION interp1(x, xl, xr, fl, fr) RESULT(f)
1350	!!----------------------------------------------------------------------
1351	!! * ROUTINE interp1 *
1352	!!
1353	!! ** Purpose : 1-d linear interpolation
1354	!!
1355	!! ** Method : interpolation is straight forward
1356	!! extrapolation is also permitted (no value limit)
1357	!!----------------------------------------------------------------------
1358	REAL(wp), INTENT(in) :: x, xl, xr, fl, fr
1359	REAL(wp) :: f ! result of the interpolation (extrapolation)
1360	REAL(wp) :: zdeltx
1361	!!----------------------------------------------------------------------
1362	!
1363	zdeltx = xr - xl
1364	IF( abs(zdeltx) <= 10._wp * EPSILON(x) ) THEN
1365	f = 0.5_wp * (fl + fr)
1366	ELSE
1367	f = ( (x - xl ) * fr - ( x - xr ) * fl ) / zdeltx
1368	ENDIF
1369	!
1370	END FUNCTION interp1
1371
1372
1373	FUNCTION interp2( x, a, b, c, d ) RESULT(f)
1374	!!----------------------------------------------------------------------
1375	!! * ROUTINE interp1 *
1376	!!
1377	!! ** Purpose : 1-d constrained cubic spline interpolation
1378	!!
1379	!! ** Method : cubic spline interpolation
1380	!!
1381	!!----------------------------------------------------------------------
1382	REAL(wp), INTENT(in) :: x, a, b, c, d
1383	REAL(wp) :: f ! value from the interpolation
1384	!!----------------------------------------------------------------------
1385	!
1386	f = a + x* ( b + x * ( c + d * x ) )
1387	!
1388	END FUNCTION interp2
1389
1390
1391	FUNCTION interp3( x, a, b, c, d ) RESULT(f)
1392	!!----------------------------------------------------------------------
1393	!! * ROUTINE interp1 *
1394	!!
1395	!! ** Purpose : Calculate the first order of derivative of
1396	!! a cubic spline function y=a+bx+cx^2+d*x^3
1397	!!
1398	!! ** Method : f=dy/dx=b+2cx+3dx^2
1399	!!
1400	!!----------------------------------------------------------------------
1401	REAL(wp), INTENT(in) :: x, a, b, c, d
1402	REAL(wp) :: f ! value from the interpolation
1403	!!----------------------------------------------------------------------
1404	!
1405	f = b + x * ( 2._wp * c + 3._wp * d * x)
1406	!
1407	END FUNCTION interp3
1408
1409
1410	FUNCTION integ_spline( xl, xr, a, b, c, d ) RESULT(f)
1411	!!----------------------------------------------------------------------
1412	!! * ROUTINE interp1 *
1413	!!
1414	!! ** Purpose : 1-d constrained cubic spline integration
1415	!!
1416	!! ** Method : integrate polynomial a+bx+cx^2+dx^3 from xl to xr
1417	!!
1418	!!----------------------------------------------------------------------
1419	REAL(wp), INTENT(in) :: xl, xr, a, b, c, d
1420	REAL(wp) :: za1, za2, za3
1421	REAL(wp) :: f ! integration result
1422	!!----------------------------------------------------------------------
1423	!
1424	za1 = 0.5_wp * b
1425	za2 = c / 3.0_wp
1426	za3 = 0.25_wp * d
1427	!
1428	f = xr * ( a + xr * ( za1 + xr * ( za2 + za3 * xr ) ) ) - &
1429	& xl * ( a + xl * ( za1 + xl * ( za2 + za3 * xl ) ) )
1430	!
1431	END FUNCTION integ_spline
1432
1433	!!======================================================================
1434	END MODULE dynhpg

Note: See TracBrowser for help on using the repository browser.

New URL for NEMO forge! http://forge.nemo-ocean.eu

Context Navigation

source: NEMO/trunk/src/OCE/DYN/dynhpg.F90

Download in other formats: