1 | MODULE dynkeg |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE dynkeg *** |
---|
4 | !! Ocean dynamics: kinetic energy gradient trend |
---|
5 | !!====================================================================== |
---|
6 | !! History : 1.0 ! 1987-09 (P. Andrich, M.-A. Foujols) Original code |
---|
7 | !! 7.0 ! 1997-05 (G. Madec) Split dynber into dynkeg and dynhpg |
---|
8 | !! NEMO 1.0 ! 2002-07 (G. Madec) F90: Free form and module |
---|
9 | !! 3.6 ! 2015-05 (N. Ducousso, G. Madec) add Hollingsworth scheme as an option |
---|
10 | !!---------------------------------------------------------------------- |
---|
11 | |
---|
12 | !!---------------------------------------------------------------------- |
---|
13 | !! dyn_keg : update the momentum trend with the horizontal tke |
---|
14 | !!---------------------------------------------------------------------- |
---|
15 | USE oce ! ocean dynamics and tracers |
---|
16 | USE dom_oce ! ocean space and time domain |
---|
17 | USE trd_oce ! trends: ocean variables |
---|
18 | USE trddyn ! trend manager: dynamics |
---|
19 | ! |
---|
20 | USE in_out_manager ! I/O manager |
---|
21 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
---|
22 | USE lib_mpp ! MPP library |
---|
23 | USE prtctl ! Print control |
---|
24 | USE timing ! Timing |
---|
25 | USE bdy_oce ! ocean open boundary conditions |
---|
26 | |
---|
27 | IMPLICIT NONE |
---|
28 | PRIVATE |
---|
29 | |
---|
30 | PUBLIC dyn_keg ! routine called by step module |
---|
31 | |
---|
32 | INTEGER, PARAMETER, PUBLIC :: nkeg_C2 = 0 !: 2nd order centered scheme (standard scheme) |
---|
33 | INTEGER, PARAMETER, PUBLIC :: nkeg_HW = 1 !: Hollingsworth et al., QJRMS, 1983 |
---|
34 | ! |
---|
35 | REAL(wp) :: r1_48 = 1._wp / 48._wp !: =1/(4*2*6) |
---|
36 | |
---|
37 | !! * Substitutions |
---|
38 | # include "do_loop_substitute.h90" |
---|
39 | !!---------------------------------------------------------------------- |
---|
40 | !! NEMO/OCE 4.0 , NEMO Consortium (2018) |
---|
41 | !! $Id$ |
---|
42 | !! Software governed by the CeCILL license (see ./LICENSE) |
---|
43 | !!---------------------------------------------------------------------- |
---|
44 | CONTAINS |
---|
45 | |
---|
46 | SUBROUTINE dyn_keg( kt, kscheme, Kmm, puu, pvv, Krhs ) |
---|
47 | !!---------------------------------------------------------------------- |
---|
48 | !! *** ROUTINE dyn_keg *** |
---|
49 | !! |
---|
50 | !! ** Purpose : Compute the now momentum trend due to the horizontal |
---|
51 | !! gradient of the horizontal kinetic energy and add it to the |
---|
52 | !! general momentum trend. |
---|
53 | !! |
---|
54 | !! ** Method : * kscheme = nkeg_C2 : 2nd order centered scheme that |
---|
55 | !! conserve kinetic energy. Compute the now horizontal kinetic energy |
---|
56 | !! zhke = 1/2 [ mi-1( un^2 ) + mj-1( vn^2 ) ] |
---|
57 | !! * kscheme = nkeg_HW : Hollingsworth correction following |
---|
58 | !! Arakawa (2001). The now horizontal kinetic energy is given by: |
---|
59 | !! zhke = 1/6 [ mi-1( 2 * un^2 + ((u(j+1)+u(j-1))/2)^2 ) |
---|
60 | !! + mj-1( 2 * vn^2 + ((v(i+1)+v(i-1))/2)^2 ) ] |
---|
61 | !! |
---|
62 | !! Take its horizontal gradient and add it to the general momentum |
---|
63 | !! trend. |
---|
64 | !! u(rhs) = u(rhs) - 1/e1u di[ zhke ] |
---|
65 | !! v(rhs) = v(rhs) - 1/e2v dj[ zhke ] |
---|
66 | !! |
---|
67 | !! ** Action : - Update the (puu(:,:,:,Krhs), pvv(:,:,:,Krhs)) with the hor. ke gradient trend |
---|
68 | !! - send this trends to trd_dyn (l_trddyn=T) for post-processing |
---|
69 | !! |
---|
70 | !! ** References : Arakawa, A., International Geophysics 2001. |
---|
71 | !! Hollingsworth et al., Quart. J. Roy. Meteor. Soc., 1983. |
---|
72 | !!---------------------------------------------------------------------- |
---|
73 | INTEGER , INTENT( in ) :: kt ! ocean time-step index |
---|
74 | INTEGER , INTENT( in ) :: kscheme ! =0/1 type of KEG scheme |
---|
75 | INTEGER , INTENT( in ) :: Kmm, Krhs ! ocean time level indices |
---|
76 | REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) :: puu, pvv ! ocean velocities and RHS of momentum equation |
---|
77 | ! |
---|
78 | INTEGER :: ji, jj, jk ! dummy loop indices |
---|
79 | REAL(wp) :: zu, zv ! local scalars |
---|
80 | REAL(wp), DIMENSION(A2D(nn_hls),jpk) :: zhke |
---|
81 | REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: ztrdu, ztrdv |
---|
82 | !!---------------------------------------------------------------------- |
---|
83 | ! |
---|
84 | IF( ln_timing ) CALL timing_start('dyn_keg') |
---|
85 | ! |
---|
86 | IF( .NOT. l_istiled .OR. ntile == 1 ) THEN ! Do only on the first tile |
---|
87 | IF( kt == nit000 ) THEN |
---|
88 | IF(lwp) WRITE(numout,*) |
---|
89 | IF(lwp) WRITE(numout,*) 'dyn_keg : kinetic energy gradient trend, scheme number=', kscheme |
---|
90 | IF(lwp) WRITE(numout,*) '~~~~~~~' |
---|
91 | ENDIF |
---|
92 | ENDIF |
---|
93 | |
---|
94 | IF( l_trddyn ) THEN ! Save the input trends |
---|
95 | ALLOCATE( ztrdu(jpi,jpj,jpk) , ztrdv(jpi,jpj,jpk) ) |
---|
96 | ztrdu(:,:,:) = puu(:,:,:,Krhs) |
---|
97 | ztrdv(:,:,:) = pvv(:,:,:,Krhs) |
---|
98 | ENDIF |
---|
99 | |
---|
100 | zhke(:,:,jpk) = 0._wp |
---|
101 | |
---|
102 | SELECT CASE ( kscheme ) !== Horizontal kinetic energy at T-point ==! |
---|
103 | ! |
---|
104 | CASE ( nkeg_C2 ) !-- Standard scheme --! |
---|
105 | DO_3D( 0, 1, 0, 1, 1, jpkm1 ) |
---|
106 | zu = puu(ji-1,jj ,jk,Kmm) * puu(ji-1,jj ,jk,Kmm) & |
---|
107 | & + puu(ji ,jj ,jk,Kmm) * puu(ji ,jj ,jk,Kmm) |
---|
108 | zv = pvv(ji ,jj-1,jk,Kmm) * pvv(ji ,jj-1,jk,Kmm) & |
---|
109 | & + pvv(ji ,jj ,jk,Kmm) * pvv(ji ,jj ,jk,Kmm) |
---|
110 | zhke(ji,jj,jk) = 0.25_wp * ( zv + zu ) |
---|
111 | END_3D |
---|
112 | CASE ( nkeg_HW ) !-- Hollingsworth scheme --! |
---|
113 | DO_3D( 0, nn_hls-1, 0, nn_hls-1, 1, jpkm1 ) |
---|
114 | ! round brackets added to fix the order of floating point operations |
---|
115 | ! needed to ensure halo 1 - halo 2 compatibility |
---|
116 | zu = 8._wp * ( puu(ji-1,jj ,jk,Kmm) * puu(ji-1,jj ,jk,Kmm) & |
---|
117 | & + puu(ji ,jj ,jk,Kmm) * puu(ji ,jj ,jk,Kmm) ) & |
---|
118 | & + ( ( puu(ji-1,jj-1,jk,Kmm) + puu(ji-1,jj+1,jk,Kmm) ) * ( puu(ji-1,jj-1,jk,Kmm) + puu(ji-1,jj+1,jk,Kmm) ) & |
---|
119 | & + ( puu(ji ,jj-1,jk,Kmm) + puu(ji ,jj+1,jk,Kmm) ) * ( puu(ji ,jj-1,jk,Kmm) + puu(ji ,jj+1,jk,Kmm) ) & |
---|
120 | & ) ! bracket for halo 1 - halo 2 compatibility |
---|
121 | ! |
---|
122 | zv = 8._wp * ( pvv(ji ,jj-1,jk,Kmm) * pvv(ji ,jj-1,jk,Kmm) & |
---|
123 | & + pvv(ji ,jj ,jk,Kmm) * pvv(ji ,jj ,jk,Kmm) ) & |
---|
124 | & + ( ( pvv(ji-1,jj-1,jk,Kmm) + pvv(ji+1,jj-1,jk,Kmm) ) * ( pvv(ji-1,jj-1,jk,Kmm) + pvv(ji+1,jj-1,jk,Kmm) ) & |
---|
125 | & + ( pvv(ji-1,jj ,jk,Kmm) + pvv(ji+1,jj ,jk,Kmm) ) * ( pvv(ji-1,jj ,jk,Kmm) + pvv(ji+1,jj ,jk,Kmm) ) & |
---|
126 | & ) ! bracket for halo 1 - halo 2 compatibility |
---|
127 | zhke(ji,jj,jk) = r1_48 * ( zv + zu ) |
---|
128 | END_3D |
---|
129 | IF (nn_hls==1) CALL lbc_lnk( 'dynkeg', zhke, 'T', 1.0_wp ) |
---|
130 | ! |
---|
131 | END SELECT |
---|
132 | ! |
---|
133 | DO_3D( 0, 0, 0, 0, 1, jpkm1 ) !== grad( KE ) added to the general momentum trends ==! |
---|
134 | puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) - ( zhke(ji+1,jj ,jk) - zhke(ji,jj,jk) ) / e1u(ji,jj) |
---|
135 | pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) - ( zhke(ji ,jj+1,jk) - zhke(ji,jj,jk) ) / e2v(ji,jj) |
---|
136 | END_3D |
---|
137 | ! |
---|
138 | IF( l_trddyn ) THEN ! save the Kinetic Energy trends for diagnostic |
---|
139 | ztrdu(:,:,:) = puu(:,:,:,Krhs) - ztrdu(:,:,:) |
---|
140 | ztrdv(:,:,:) = pvv(:,:,:,Krhs) - ztrdv(:,:,:) |
---|
141 | CALL trd_dyn( ztrdu, ztrdv, jpdyn_keg, kt, Kmm ) |
---|
142 | DEALLOCATE( ztrdu , ztrdv ) |
---|
143 | ENDIF |
---|
144 | ! |
---|
145 | IF(sn_cfctl%l_prtctl) CALL prt_ctl( tab3d_1=puu(:,:,:,Krhs), clinfo1=' keg - Ua: ', mask1=umask, & |
---|
146 | & tab3d_2=pvv(:,:,:,Krhs), clinfo2= ' Va: ', mask2=vmask, clinfo3='dyn' ) |
---|
147 | ! |
---|
148 | IF( ln_timing ) CALL timing_stop('dyn_keg') |
---|
149 | ! |
---|
150 | END SUBROUTINE dyn_keg |
---|
151 | |
---|
152 | !!====================================================================== |
---|
153 | END MODULE dynkeg |
---|