New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynldf_lap_blp.F90 in NEMO/trunk/src/OCE/DYN – NEMO

source: NEMO/trunk/src/OCE/DYN/dynldf_lap_blp.F90 @ 10425

Last change on this file since 10425 was 10425, checked in by smasson, 5 years ago

trunk: merge back dev_r10164_HPC09_ESIWACE_PREP_MERGE@10424 into the trunk

  • Property svn:keywords set to Id
File size: 7.8 KB
Line 
1MODULE dynldf_lap_blp
2   !!======================================================================
3   !!                   ***  MODULE  dynldf_lap_blp  ***
4   !! Ocean dynamics:  lateral viscosity trend (laplacian and bilaplacian)
5   !!======================================================================
6   !! History : 3.7  ! 2014-01  (G. Madec, S. Masson)  Original code, re-entrant laplacian
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   !!   dyn_ldf_lap   : update the momentum trend with the lateral viscosity using an iso-level   laplacian operator
11   !!   dyn_ldf_blp   : update the momentum trend with the lateral viscosity using an iso-level bilaplacian operator
12   !!----------------------------------------------------------------------
13   USE oce            ! ocean dynamics and tracers
14   USE dom_oce        ! ocean space and time domain
15   USE ldfdyn         ! lateral diffusion: eddy viscosity coef.
16   USE ldfslp         ! iso-neutral slopes
17   USE zdf_oce        ! ocean vertical physics
18   !
19   USE in_out_manager ! I/O manager
20   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
21
22   IMPLICIT NONE
23   PRIVATE
24
25   PUBLIC dyn_ldf_lap  ! called by dynldf.F90
26   PUBLIC dyn_ldf_blp  ! called by dynldf.F90
27
28   !! * Substitutions
29#  include "vectopt_loop_substitute.h90"
30   !!----------------------------------------------------------------------
31   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
32   !! $Id$
33   !! Software governed by the CeCILL license (see ./LICENSE)
34   !!----------------------------------------------------------------------
35CONTAINS
36
37   SUBROUTINE dyn_ldf_lap( kt, pub, pvb, pua, pva, kpass )
38      !!----------------------------------------------------------------------
39      !!                     ***  ROUTINE dyn_ldf_lap  ***
40      !!                       
41      !! ** Purpose :   Compute the before horizontal momentum diffusive
42      !!      trend and add it to the general trend of momentum equation.
43      !!
44      !! ** Method  :   The Laplacian operator apply on horizontal velocity is
45      !!      writen as :   grad_h( ahmt div_h(U )) - curl_h( ahmf curl_z(U) )
46      !!
47      !! ** Action : - pua, pva increased by the harmonic operator applied on pub, pvb.
48      !!----------------------------------------------------------------------
49      INTEGER                         , INTENT(in   ) ::   kt         ! ocean time-step index
50      INTEGER                         , INTENT(in   ) ::   kpass      ! =1/2 first or second passage
51      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pub, pvb   ! before velocity  [m/s]
52      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pua, pva   ! velocity trend   [m/s2]
53      !
54      INTEGER  ::   ji, jj, jk   ! dummy loop indices
55      REAL(wp) ::   zsign        ! local scalars
56      REAL(wp) ::   zua, zva     ! local scalars
57      REAL(wp), DIMENSION(jpi,jpj) ::   zcur, zdiv
58      !!----------------------------------------------------------------------
59      !
60      IF( kt == nit000 .AND. lwp ) THEN
61         WRITE(numout,*)
62         WRITE(numout,*) 'dyn_ldf : iso-level harmonic (laplacian) operator, pass=', kpass
63         WRITE(numout,*) '~~~~~~~ '
64      ENDIF
65      !
66      IF( kpass == 1 ) THEN   ;   zsign =  1._wp      ! bilaplacian operator require a minus sign
67      ELSE                    ;   zsign = -1._wp      !  (eddy viscosity coef. >0)
68      ENDIF
69      !
70      !                                                ! ===============
71      DO jk = 1, jpkm1                                 ! Horizontal slab
72         !                                             ! ===============
73         DO jj = 2, jpj
74            DO ji = fs_2, jpi   ! vector opt.
75               !                                      ! ahm * e3 * curl  (computed from 1 to jpim1/jpjm1)
76!!gm open question here : e3f  at before or now ?    probably now...
77!!gm note that ahmf has already been multiplied by fmask
78               zcur(ji-1,jj-1) = ahmf(ji-1,jj-1,jk) * e3f_n(ji-1,jj-1,jk) * r1_e1e2f(ji-1,jj-1)       &
79                  &     * (  e2v(ji  ,jj-1) * pvb(ji  ,jj-1,jk) - e2v(ji-1,jj-1) * pvb(ji-1,jj-1,jk)  &
80                  &        - e1u(ji-1,jj  ) * pub(ji-1,jj  ,jk) + e1u(ji-1,jj-1) * pub(ji-1,jj-1,jk)  )
81               !                                      ! ahm * div        (computed from 2 to jpi/jpj)
82!!gm note that ahmt has already been multiplied by tmask
83               zdiv(ji,jj)     = ahmt(ji,jj,jk) * r1_e1e2t(ji,jj) / e3t_b(ji,jj,jk)                                         &
84                  &     * (  e2u(ji,jj)*e3u_b(ji,jj,jk) * pub(ji,jj,jk) - e2u(ji-1,jj)*e3u_b(ji-1,jj,jk) * pub(ji-1,jj,jk)  &
85                  &        + e1v(ji,jj)*e3v_b(ji,jj,jk) * pvb(ji,jj,jk) - e1v(ji,jj-1)*e3v_b(ji,jj-1,jk) * pvb(ji,jj-1,jk)  )
86            END DO 
87         END DO 
88         !
89         DO jj = 2, jpjm1                             ! - curl( curl) + grad( div )
90            DO ji = fs_2, fs_jpim1   ! vector opt.
91               pua(ji,jj,jk) = pua(ji,jj,jk) + zsign * (                                                 &
92                  &              - ( zcur(ji  ,jj) - zcur(ji,jj-1) ) * r1_e2u(ji,jj) / e3u_n(ji,jj,jk)   &
93                  &              + ( zdiv(ji+1,jj) - zdiv(ji,jj  ) ) * r1_e1u(ji,jj)                     )
94                  !
95               pva(ji,jj,jk) = pva(ji,jj,jk) + zsign * (                                                 &
96                  &                ( zcur(ji,jj  ) - zcur(ji-1,jj) ) * r1_e1v(ji,jj) / e3v_n(ji,jj,jk)   &
97                  &              + ( zdiv(ji,jj+1) - zdiv(ji  ,jj) ) * r1_e2v(ji,jj)                     )
98            END DO
99         END DO
100         !                                             ! ===============
101      END DO                                           !   End of slab
102      !                                                ! ===============
103      !
104   END SUBROUTINE dyn_ldf_lap
105
106
107   SUBROUTINE dyn_ldf_blp( kt, pub, pvb, pua, pva )
108      !!----------------------------------------------------------------------
109      !!                 ***  ROUTINE dyn_ldf_blp  ***
110      !!                   
111      !! ** Purpose :   Compute the before lateral momentum viscous trend
112      !!              and add it to the general trend of momentum equation.
113      !!
114      !! ** Method  :   The lateral viscous trends is provided by a bilaplacian
115      !!      operator applied to before field (forward in time).
116      !!      It is computed by two successive calls to dyn_ldf_lap routine
117      !!
118      !! ** Action :   pta   updated with the before rotated bilaplacian diffusion
119      !!----------------------------------------------------------------------
120      INTEGER                         , INTENT(in   ) ::   kt         ! ocean time-step index
121      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pub, pvb   ! before velocity fields
122      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pua, pva   ! momentum trend
123      !
124      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zulap, zvlap   ! laplacian at u- and v-point
125      !!----------------------------------------------------------------------
126      !
127      IF( kt == nit000 )  THEN
128         IF(lwp) WRITE(numout,*)
129         IF(lwp) WRITE(numout,*) 'dyn_ldf_blp : bilaplacian operator momentum '
130         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~'
131      ENDIF
132      !
133      zulap(:,:,:) = 0._wp
134      zvlap(:,:,:) = 0._wp
135      !
136      CALL dyn_ldf_lap( kt, pub, pvb, zulap, zvlap, 1 )   ! rotated laplacian applied to ptb (output in zlap)
137      !
138      CALL lbc_lnk_multi( 'dynldf_lap_blp', zulap, 'U', -1., zvlap, 'V', -1. )             ! Lateral boundary conditions
139      !
140      CALL dyn_ldf_lap( kt, zulap, zvlap, pua, pva, 2 )   ! rotated laplacian applied to zlap (output in pta)
141      !
142   END SUBROUTINE dyn_ldf_blp
143
144   !!======================================================================
145END MODULE dynldf_lap_blp
Note: See TracBrowser for help on using the repository browser.