[358] | 1 | MODULE dynspg |
---|
| 2 | !!====================================================================== |
---|
| 3 | !! *** MODULE dynspg *** |
---|
| 4 | !! Ocean dynamics: surface pressure gradient control |
---|
| 5 | !!====================================================================== |
---|
[1566] | 6 | !! History : 1.0 ! 2005-12 (C. Talandier, G. Madec, V. Garnier) Original code |
---|
| 7 | !! 3.2 ! 2009-07 (R. Benshila) Suppression of rigid-lid option |
---|
[14007] | 8 | !! 4.2 ! 2020-12 (G. Madec, E. Clementi) add Bernoulli Head for |
---|
| 9 | !! wave coupling |
---|
[503] | 10 | !!---------------------------------------------------------------------- |
---|
[358] | 11 | |
---|
| 12 | !!---------------------------------------------------------------------- |
---|
[14072] | 13 | !! dyn_spg : update the dynamics trend with surface pressure gradient |
---|
[5930] | 14 | !! dyn_spg_init: initialization, namelist read, and parameters control |
---|
[358] | 15 | !!---------------------------------------------------------------------- |
---|
| 16 | USE oce ! ocean dynamics and tracers variables |
---|
| 17 | USE dom_oce ! ocean space and time domain variables |
---|
[4245] | 18 | USE c1d ! 1D vertical configuration |
---|
[2715] | 19 | USE phycst ! physical constants |
---|
[2528] | 20 | USE sbc_oce ! surface boundary condition: ocean |
---|
[9019] | 21 | USE sbc_ice , ONLY : snwice_mass, snwice_mass_b |
---|
[2528] | 22 | USE sbcapr ! surface boundary condition: atmospheric pressure |
---|
[14007] | 23 | USE sbcwave, ONLY : bhd_wave |
---|
[358] | 24 | USE dynspg_exp ! surface pressure gradient (dyn_spg_exp routine) |
---|
| 25 | USE dynspg_ts ! surface pressure gradient (dyn_spg_ts routine) |
---|
[12377] | 26 | USE tide_mod ! |
---|
[4990] | 27 | USE trd_oce ! trends: ocean variables |
---|
| 28 | USE trddyn ! trend manager: dynamics |
---|
| 29 | ! |
---|
[358] | 30 | USE prtctl ! Print control (prt_ctl routine) |
---|
| 31 | USE in_out_manager ! I/O manager |
---|
[2715] | 32 | USE lib_mpp ! MPP library |
---|
[4990] | 33 | USE timing ! Timing |
---|
[358] | 34 | |
---|
| 35 | IMPLICIT NONE |
---|
| 36 | PRIVATE |
---|
| 37 | |
---|
[2528] | 38 | PUBLIC dyn_spg ! routine called by step module |
---|
| 39 | PUBLIC dyn_spg_init ! routine called by opa module |
---|
[358] | 40 | |
---|
[14072] | 41 | INTEGER :: nspg = 0 ! type of surface pressure gradient scheme defined from lk_dynspg_... |
---|
[358] | 42 | |
---|
[6140] | 43 | ! ! Parameter to control the surface pressure gradient scheme |
---|
| 44 | INTEGER, PARAMETER :: np_TS = 1 ! split-explicit time stepping (Time-Splitting) |
---|
| 45 | INTEGER, PARAMETER :: np_EXP = 0 ! explicit time stepping |
---|
| 46 | INTEGER, PARAMETER :: np_NO =-1 ! no surface pressure gradient, no scheme |
---|
[12377] | 47 | ! |
---|
| 48 | REAL(wp) :: zt0step ! Time of day at the beginning of the time step |
---|
[6140] | 49 | |
---|
[358] | 50 | !! * Substitutions |
---|
[12377] | 51 | # include "do_loop_substitute.h90" |
---|
[358] | 52 | !!---------------------------------------------------------------------- |
---|
[9598] | 53 | !! NEMO/OCE 4.0 , NEMO Consortium (2018) |
---|
[14072] | 54 | !! $Id$ |
---|
[10068] | 55 | !! Software governed by the CeCILL license (see ./LICENSE) |
---|
[358] | 56 | !!---------------------------------------------------------------------- |
---|
| 57 | CONTAINS |
---|
| 58 | |
---|
[14225] | 59 | SUBROUTINE dyn_spg( kt, Kbb, Kmm, Krhs, puu, pvv, pssh, puu_b, pvv_b, Kaa, k_only_ADV ) |
---|
[358] | 60 | !!---------------------------------------------------------------------- |
---|
| 61 | !! *** ROUTINE dyn_spg *** |
---|
| 62 | !! |
---|
[14072] | 63 | !! ** Purpose : compute surface pressure gradient including the |
---|
[6140] | 64 | !! atmospheric pressure forcing (ln_apr_dyn=T). |
---|
[1566] | 65 | !! |
---|
[5930] | 66 | !! ** Method : Two schemes: |
---|
[6140] | 67 | !! - explicit : the spg is evaluated at now |
---|
| 68 | !! - split-explicit : a time splitting technique is used |
---|
[1566] | 69 | !! |
---|
[14072] | 70 | !! ln_apr_dyn=T : the atmospheric pressure forcing is applied |
---|
[2528] | 71 | !! as the gradient of the inverse barometer ssh: |
---|
[12489] | 72 | !! apgu = - 1/rho0 di[apr] = 0.5*grav di[ssh_ib+ssh_ibb] |
---|
| 73 | !! apgv = - 1/rho0 dj[apr] = 0.5*grav dj[ssh_ib+ssh_ibb] |
---|
| 74 | !! Note that as all external forcing a time averaging over a two rn_Dt |
---|
[2528] | 75 | !! period is used to prevent the divergence of odd and even time step. |
---|
[358] | 76 | !!---------------------------------------------------------------------- |
---|
[12377] | 77 | INTEGER , INTENT( in ) :: kt ! ocean time-step index |
---|
| 78 | INTEGER , INTENT( in ) :: Kbb, Kmm, Krhs, Kaa ! ocean time level indices |
---|
| 79 | REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) :: puu, pvv ! ocean velocities and RHS of momentum equation |
---|
| 80 | REAL(wp), DIMENSION(jpi,jpj,jpt) , INTENT(inout) :: pssh, puu_b, pvv_b ! SSH and barotropic velocities at main time levels |
---|
[14225] | 81 | INTEGER , OPTIONAL , INTENT( in ) :: k_only_ADV ! only Advection in the RHS |
---|
[2715] | 82 | ! |
---|
[9019] | 83 | INTEGER :: ji, jj, jk ! dummy loop indices |
---|
[12489] | 84 | REAL(wp) :: z2dt, zg_2, zintp, zgrho0r, zld ! local scalars |
---|
[14064] | 85 | REAL(wp) , DIMENSION(jpi,jpj) :: zpgu, zpgv ! 2D workspace |
---|
| 86 | REAL(wp), ALLOCATABLE, DIMENSION(:,:) :: zpice |
---|
| 87 | REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: ztrdu, ztrdv |
---|
[358] | 88 | !!---------------------------------------------------------------------- |
---|
[3294] | 89 | ! |
---|
[9019] | 90 | IF( ln_timing ) CALL timing_start('dyn_spg') |
---|
[3294] | 91 | ! |
---|
[358] | 92 | IF( l_trddyn ) THEN ! temporary save of ta and sa trends |
---|
[14072] | 93 | ALLOCATE( ztrdu(jpi,jpj,jpk) , ztrdv(jpi,jpj,jpk) ) |
---|
[12377] | 94 | ztrdu(:,:,:) = puu(:,:,:,Krhs) |
---|
| 95 | ztrdv(:,:,:) = pvv(:,:,:,Krhs) |
---|
[358] | 96 | ENDIF |
---|
[6140] | 97 | ! |
---|
[4292] | 98 | IF( ln_apr_dyn & ! atmos. pressure |
---|
[7646] | 99 | .OR. ( .NOT.ln_dynspg_ts .AND. (ln_tide_pot .AND. ln_tide) ) & ! tide potential (no time slitting) |
---|
[14202] | 100 | .OR. ln_ice_embd & ! embedded sea-ice |
---|
| 101 | .OR. ( ln_wave .and. ln_bern_srfc ) ) THEN ! depth-independent Bernoulli head |
---|
[4292] | 102 | ! |
---|
[13295] | 103 | DO_2D( 0, 0, 0, 0 ) |
---|
[14064] | 104 | zpgu(ji,jj) = 0._wp |
---|
| 105 | zpgv(ji,jj) = 0._wp |
---|
[12377] | 106 | END_2D |
---|
[4292] | 107 | ! |
---|
[6140] | 108 | IF( ln_apr_dyn .AND. .NOT.ln_dynspg_ts ) THEN !== Atmospheric pressure gradient (added later in time-split case) ==! |
---|
[4292] | 109 | zg_2 = grav * 0.5 |
---|
[13497] | 110 | DO_2D( 0, 0, 0, 0 ) ! gradient of Patm using inverse barometer ssh |
---|
[14064] | 111 | zpgu(ji,jj) = zpgu(ji,jj) + zg_2 * ( ssh_ib (ji+1,jj) - ssh_ib (ji,jj) & |
---|
[12377] | 112 | & + ssh_ibb(ji+1,jj) - ssh_ibb(ji,jj) ) * r1_e1u(ji,jj) |
---|
[14064] | 113 | zpgv(ji,jj) = zpgv(ji,jj) + zg_2 * ( ssh_ib (ji,jj+1) - ssh_ib (ji,jj) & |
---|
[12377] | 114 | & + ssh_ibb(ji,jj+1) - ssh_ibb(ji,jj) ) * r1_e2v(ji,jj) |
---|
| 115 | END_2D |
---|
[4292] | 116 | ENDIF |
---|
| 117 | ! |
---|
| 118 | ! !== tide potential forcing term ==! |
---|
[7646] | 119 | IF( .NOT.ln_dynspg_ts .AND. ( ln_tide_pot .AND. ln_tide ) ) THEN ! N.B. added directly at sub-time-step in ts-case |
---|
[4292] | 120 | ! |
---|
[12377] | 121 | ! Update tide potential at the beginning of current time step |
---|
[12489] | 122 | zt0step = REAL(nsec_day, wp)-0.5_wp*rn_Dt |
---|
[12377] | 123 | CALL upd_tide(zt0step, Kmm) |
---|
[4292] | 124 | ! |
---|
[13497] | 125 | DO_2D( 0, 0, 0, 0 ) ! add tide potential forcing |
---|
[14064] | 126 | zpgu(ji,jj) = zpgu(ji,jj) + grav * ( pot_astro(ji+1,jj) - pot_astro(ji,jj) ) * r1_e1u(ji,jj) |
---|
| 127 | zpgv(ji,jj) = zpgv(ji,jj) + grav * ( pot_astro(ji,jj+1) - pot_astro(ji,jj) ) * r1_e2v(ji,jj) |
---|
[12377] | 128 | END_2D |
---|
[9023] | 129 | ! |
---|
| 130 | IF (ln_scal_load) THEN |
---|
| 131 | zld = rn_scal_load * grav |
---|
[13497] | 132 | DO_2D( 0, 0, 0, 0 ) ! add scalar approximation for load potential |
---|
[14064] | 133 | zpgu(ji,jj) = zpgu(ji,jj) + zld * ( pssh(ji+1,jj,Kmm) - pssh(ji,jj,Kmm) ) * r1_e1u(ji,jj) |
---|
| 134 | zpgv(ji,jj) = zpgv(ji,jj) + zld * ( pssh(ji,jj+1,Kmm) - pssh(ji,jj,Kmm) ) * r1_e2v(ji,jj) |
---|
[12377] | 135 | END_2D |
---|
[9023] | 136 | ENDIF |
---|
[4292] | 137 | ENDIF |
---|
| 138 | ! |
---|
[9019] | 139 | IF( ln_ice_embd ) THEN !== embedded sea ice: Pressure gradient due to snow-ice mass ==! |
---|
| 140 | ALLOCATE( zpice(jpi,jpj) ) |
---|
[4292] | 141 | zintp = REAL( MOD( kt-1, nn_fsbc ) ) / REAL( nn_fsbc ) |
---|
[12489] | 142 | zgrho0r = - grav * r1_rho0 |
---|
| 143 | zpice(:,:) = ( zintp * snwice_mass(:,:) + ( 1.- zintp ) * snwice_mass_b(:,:) ) * zgrho0r |
---|
[13295] | 144 | DO_2D( 0, 0, 0, 0 ) |
---|
[14064] | 145 | zpgu(ji,jj) = zpgu(ji,jj) + ( zpice(ji+1,jj) - zpice(ji,jj) ) * r1_e1u(ji,jj) |
---|
| 146 | zpgv(ji,jj) = zpgv(ji,jj) + ( zpice(ji,jj+1) - zpice(ji,jj) ) * r1_e2v(ji,jj) |
---|
[12377] | 147 | END_2D |
---|
[14072] | 148 | DEALLOCATE( zpice ) |
---|
[4292] | 149 | ENDIF |
---|
| 150 | ! |
---|
[14007] | 151 | IF( ln_wave .and. ln_bern_srfc ) THEN !== Add J terms: depth-independent Bernoulli head |
---|
| 152 | DO_2D( 0, 0, 0, 0 ) |
---|
[14064] | 153 | zpgu(ji,jj) = zpgu(ji,jj) + ( bhd_wave(ji+1,jj) - bhd_wave(ji,jj) ) / e1u(ji,jj) !++ bhd_wave from wave model in m2/s2 [BHD parameters in WW3] |
---|
| 154 | zpgv(ji,jj) = zpgv(ji,jj) + ( bhd_wave(ji,jj+1) - bhd_wave(ji,jj) ) / e2v(ji,jj) |
---|
[14007] | 155 | END_2D |
---|
| 156 | ENDIF |
---|
| 157 | ! |
---|
[13497] | 158 | DO_3D( 0, 0, 0, 0, 1, jpkm1 ) !== Add all terms to the general trend |
---|
[14064] | 159 | puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + zpgu(ji,jj) |
---|
| 160 | pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + zpgv(ji,jj) |
---|
[12377] | 161 | END_3D |
---|
[6140] | 162 | ! |
---|
[4990] | 163 | !!gm add here a call to dyn_trd for ice pressure gradient, the surf pressure trends ???? |
---|
[14072] | 164 | ! |
---|
[3625] | 165 | ENDIF |
---|
[6140] | 166 | ! |
---|
| 167 | SELECT CASE ( nspg ) !== surface pressure gradient computed and add to the general trend ==! |
---|
[12377] | 168 | CASE ( np_EXP ) ; CALL dyn_spg_exp( kt, Kmm, puu, pvv, Krhs ) ! explicit |
---|
[14225] | 169 | CASE ( np_TS ) ; CALL dyn_spg_ts ( kt, Kbb, Kmm, Krhs, puu, pvv, pssh, puu_b, pvv_b, Kaa, k_only_ADV ) ! time-splitting |
---|
[358] | 170 | END SELECT |
---|
[14072] | 171 | ! |
---|
[6140] | 172 | IF( l_trddyn ) THEN ! save the surface pressure gradient trends for further diagnostics |
---|
[12377] | 173 | ztrdu(:,:,:) = puu(:,:,:,Krhs) - ztrdu(:,:,:) |
---|
| 174 | ztrdv(:,:,:) = pvv(:,:,:,Krhs) - ztrdv(:,:,:) |
---|
| 175 | CALL trd_dyn( ztrdu, ztrdv, jpdyn_spg, kt, Kmm ) |
---|
[14072] | 176 | DEALLOCATE( ztrdu , ztrdv ) |
---|
[358] | 177 | ENDIF |
---|
[6140] | 178 | ! ! print mean trends (used for debugging) |
---|
[12377] | 179 | IF(sn_cfctl%l_prtctl) CALL prt_ctl( tab3d_1=puu(:,:,:,Krhs), clinfo1=' spg - Ua: ', mask1=umask, & |
---|
| 180 | & tab3d_2=pvv(:,:,:,Krhs), clinfo2= ' Va: ', mask2=vmask, clinfo3='dyn' ) |
---|
[503] | 181 | ! |
---|
[9019] | 182 | IF( ln_timing ) CALL timing_stop('dyn_spg') |
---|
[2715] | 183 | ! |
---|
[358] | 184 | END SUBROUTINE dyn_spg |
---|
| 185 | |
---|
| 186 | |
---|
[2528] | 187 | SUBROUTINE dyn_spg_init |
---|
[358] | 188 | !!--------------------------------------------------------------------- |
---|
[2528] | 189 | !! *** ROUTINE dyn_spg_init *** |
---|
[14072] | 190 | !! |
---|
| 191 | !! ** Purpose : Control the consistency between namelist options for |
---|
[1566] | 192 | !! surface pressure gradient schemes |
---|
[358] | 193 | !!---------------------------------------------------------------------- |
---|
[6140] | 194 | INTEGER :: ioptio, ios ! local integers |
---|
[5930] | 195 | ! |
---|
[6140] | 196 | NAMELIST/namdyn_spg/ ln_dynspg_exp , ln_dynspg_ts, & |
---|
| 197 | & ln_bt_fw, ln_bt_av , ln_bt_auto , & |
---|
[12489] | 198 | & nn_e , rn_bt_cmax, nn_bt_flt, rn_bt_alpha |
---|
[358] | 199 | !!---------------------------------------------------------------------- |
---|
[3294] | 200 | ! |
---|
[9169] | 201 | IF(lwp) THEN |
---|
| 202 | WRITE(numout,*) |
---|
| 203 | WRITE(numout,*) 'dyn_spg_init : choice of the surface pressure gradient scheme' |
---|
| 204 | WRITE(numout,*) '~~~~~~~~~~~~' |
---|
| 205 | ENDIF |
---|
| 206 | ! |
---|
[5930] | 207 | READ ( numnam_ref, namdyn_spg, IOSTAT = ios, ERR = 901) |
---|
[11536] | 208 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_spg in reference namelist' ) |
---|
[6140] | 209 | ! |
---|
[5930] | 210 | READ ( numnam_cfg, namdyn_spg, IOSTAT = ios, ERR = 902 ) |
---|
[11536] | 211 | 902 IF( ios > 0 ) CALL ctl_nam ( ios , 'namdyn_spg in configuration namelist' ) |
---|
[5930] | 212 | IF(lwm) WRITE ( numond, namdyn_spg ) |
---|
| 213 | ! |
---|
| 214 | IF(lwp) THEN ! Namelist print |
---|
[9169] | 215 | WRITE(numout,*) ' Namelist : namdyn_spg ' |
---|
| 216 | WRITE(numout,*) ' Explicit free surface ln_dynspg_exp = ', ln_dynspg_exp |
---|
| 217 | WRITE(numout,*) ' Free surface with time splitting ln_dynspg_ts = ', ln_dynspg_ts |
---|
[358] | 218 | ENDIF |
---|
[6140] | 219 | ! ! Control of surface pressure gradient scheme options |
---|
[6981] | 220 | nspg = np_NO ; ioptio = 0 |
---|
[6140] | 221 | IF( ln_dynspg_exp ) THEN ; nspg = np_EXP ; ioptio = ioptio + 1 ; ENDIF |
---|
| 222 | IF( ln_dynspg_ts ) THEN ; nspg = np_TS ; ioptio = ioptio + 1 ; ENDIF |
---|
[1566] | 223 | ! |
---|
[6140] | 224 | IF( ioptio > 1 ) CALL ctl_stop( 'Choose only one surface pressure gradient scheme' ) |
---|
| 225 | IF( ioptio == 0 ) CALL ctl_warn( 'NO surface pressure gradient trend in momentum Eqs.' ) |
---|
| 226 | IF( ln_dynspg_exp .AND. ln_isfcav ) & |
---|
| 227 | & CALL ctl_stop( ' dynspg_exp not tested with ice shelf cavity ' ) |
---|
[1566] | 228 | ! |
---|
| 229 | IF(lwp) THEN |
---|
[358] | 230 | WRITE(numout,*) |
---|
[9190] | 231 | IF( nspg == np_EXP ) WRITE(numout,*) ' ==>>> explicit free surface' |
---|
| 232 | IF( nspg == np_TS ) WRITE(numout,*) ' ==>>> free surface with time splitting scheme' |
---|
| 233 | IF( nspg == np_NO ) WRITE(numout,*) ' ==>>> No surface surface pressure gradient trend in momentum Eqs.' |
---|
[358] | 234 | ENDIF |
---|
[1566] | 235 | ! |
---|
[6140] | 236 | IF( nspg == np_TS ) THEN ! split-explicit scheme initialisation |
---|
[12489] | 237 | CALL dyn_spg_ts_init ! do it first: set nn_e used to allocate some arrays later on |
---|
[6140] | 238 | ENDIF |
---|
| 239 | ! |
---|
[2528] | 240 | END SUBROUTINE dyn_spg_init |
---|
[358] | 241 | |
---|
| 242 | !!====================================================================== |
---|
| 243 | END MODULE dynspg |
---|