source: NEMO/trunk/src/OCE/ICB/icbrst.F90 @ 9598

Last change on this file since 9598 was 9598, checked in by nicolasmartin, 3 years ago

Reorganisation plan for NEMO repository: changes to make compilation succeed with new structure
Juste one issue left with AGRIF_NORDIC with AGRIF preprocessing
Standardisation of routines header with version 4.0 and year 2018
Fix for some broken symlinks

  • Property svn:keywords set to Id
File size: 18.7 KB
Line 
1MODULE icbrst
2   !!======================================================================
3   !!                       ***  MODULE  icbrst  ***
4   !! Ocean physics:  read and write iceberg restart files
5   !!======================================================================
6   !! History : 3.3.1 !  2010-01  (Martin&Adcroft) Original code
7   !!            -    !  2011-03  (Madec)          Part conversion to NEMO form
8   !!            -    !                            Removal of mapping from another grid
9   !!            -    !  2011-04  (Alderson)       Split into separate modules
10   !!            -    !  2011-04  (Alderson)       Restore restart routine
11   !!            -    !                            Currently needs a fixed processor
12   !!            -    !                            layout between restarts
13   !!            -    !  2015-11  Dave Storkey     Convert icb_rst_read to use IOM so can
14   !!                                              read single restart files
15   !!----------------------------------------------------------------------
16
17   !!----------------------------------------------------------------------
18   !!   icb_rst_read    : read restart file
19   !!   icb_rst_write   : write restart file
20   !!----------------------------------------------------------------------
21   USE par_oce        ! NEMO parameters
22   USE dom_oce        ! NEMO domain
23   USE in_out_manager ! NEMO IO routines
24   USE lib_mpp        ! NEMO MPI library, lk_mpp in particular
25   USE netcdf         ! netcdf routines for IO
26   USE iom
27   USE icb_oce        ! define iceberg arrays
28   USE icbutl         ! iceberg utility routines
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC   icb_rst_read    ! routine called in icbini.F90 module
34   PUBLIC   icb_rst_write   ! routine called in icbstp.F90 module
35   
36   INTEGER ::   nlonid, nlatid, nxid, nyid, nuvelid, nvvelid
37   INTEGER ::   nmassid, nthicknessid, nwidthid, nlengthid
38   INTEGER ::   nyearid, ndayid
39   INTEGER ::   nscaling_id, nmass_of_bits_id, nheat_density_id, numberid
40   INTEGER ::   nsiceid, nsheatid, ncalvid, ncalvhid, nkountid
41   INTEGER ::   nret, ncid, nc_dim
42   
43   INTEGER,  DIMENSION(3)                  :: nstrt3, nlngth3
44
45   !!----------------------------------------------------------------------
46   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
47   !! $Id$
48   !! Software governed by the CeCILL licence     (./LICENSE)
49   !!----------------------------------------------------------------------
50CONTAINS
51
52   SUBROUTINE icb_rst_read()
53      !!----------------------------------------------------------------------
54      !!                 ***  SUBROUTINE icb_rst_read  ***
55      !!
56      !! ** Purpose :   read a iceberg restart file
57      !!      NB: for this version, we just read back in the restart for this processor
58      !!      so we cannot change the processor layout currently with iceberg code
59      !!----------------------------------------------------------------------
60      INTEGER                      ::   idim, ivar, iatt
61      INTEGER                      ::   jn, iunlim_dim, ibergs_in_file
62      INTEGER                      ::   ii,ij,iclass
63      REAL(wp), DIMENSION(nkounts) ::   zdata     
64      LOGICAL                      ::   ll_found_restart
65      CHARACTER(len=256)           ::   cl_path
66      CHARACTER(len=256)           ::   cl_filename
67      CHARACTER(len=NF90_MAX_NAME) ::   cl_dname
68      TYPE(iceberg)                ::   localberg ! NOT a pointer but an actual local variable
69      TYPE(point)                  ::   localpt   ! NOT a pointer but an actual local variable
70      !!----------------------------------------------------------------------
71
72      ! Find a restart file. Assume iceberg restarts in same directory as ocean restarts
73      ! and are called TRIM(cn_ocerst)//'_icebergs'
74      cl_path = TRIM(cn_ocerst_indir)
75      IF( cl_path(LEN_TRIM(cl_path):) /= '/' ) cl_path = TRIM(cl_path) // '/'
76      cl_filename = TRIM(cn_ocerst_in)//'_icebergs'
77      CALL iom_open( TRIM(cl_path)//cl_filename, ncid )
78
79      IF( iom_file(ncid)%iduld .GE. 0) THEN
80
81         ibergs_in_file = iom_file(ncid)%lenuld
82         DO jn = 1,ibergs_in_file
83
84            ! iom_get treats the unlimited dimension as time. Here the unlimited dimension
85            ! is the iceberg index, but we can still use the ktime keyword to get the iceberg we want.
86
87            CALL iom_get( ncid, 'xi'     ,localpt%xi  , ktime=jn )
88            CALL iom_get( ncid, 'yj'     ,localpt%yj  , ktime=jn )
89
90            ii = INT( localpt%xi + 0.5 )
91            ij = INT( localpt%yj + 0.5 )
92            ! Only proceed if this iceberg is on the local processor (excluding halos).
93            IF ( ii .GE. nldi+nimpp-1 .AND. ii .LE. nlei+nimpp-1 .AND. &
94           &     ij .GE. nldj+njmpp-1 .AND. ij .LE. nlej+njmpp-1 ) THEN           
95
96               CALL iom_get( ncid, jpdom_unknown, 'number'       , zdata(:) , ktime=jn, kstart=(/1/), kcount=(/nkounts/) )
97               localberg%number(:) = INT(zdata(:))
98               CALL iom_get( ncid, 'mass_scaling' , localberg%mass_scaling, ktime=jn )
99               CALL iom_get( ncid, 'lon'          , localpt%lon           , ktime=jn )
100               CALL iom_get( ncid, 'lat'          , localpt%lat           , ktime=jn )
101               CALL iom_get( ncid, 'uvel'         , localpt%uvel          , ktime=jn )
102               CALL iom_get( ncid, 'vvel'         , localpt%vvel          , ktime=jn )
103               CALL iom_get( ncid, 'mass'         , localpt%mass          , ktime=jn )
104               CALL iom_get( ncid, 'thickness'    , localpt%thickness     , ktime=jn )
105               CALL iom_get( ncid, 'width'        , localpt%width         , ktime=jn )
106               CALL iom_get( ncid, 'length'       , localpt%length        , ktime=jn )
107               CALL iom_get( ncid, 'year'         , zdata(1)              , ktime=jn )
108               localpt%year = INT(zdata(1))
109               CALL iom_get( ncid, 'day'          , localpt%day           , ktime=jn )
110               CALL iom_get( ncid, 'mass_of_bits' , localpt%mass_of_bits  , ktime=jn )
111               CALL iom_get( ncid, 'heat_density' , localpt%heat_density  , ktime=jn )
112               !
113               CALL icb_utl_add( localberg, localpt )
114               !
115            ENDIF
116            !
117         END DO
118         !
119      ENDIF 
120
121      ! Gridded variables
122      CALL iom_get( ncid, jpdom_autoglo,    'calving'     , src_calving  )
123      CALL iom_get( ncid, jpdom_autoglo,    'calving_hflx', src_calving_hflx  )
124      CALL iom_get( ncid, jpdom_autoglo,    'stored_heat' , berg_grid%stored_heat  )
125      CALL iom_get( ncid, jpdom_autoglo_xy, 'stored_ice'  , berg_grid%stored_ice, kstart=(/1,1,1/), kcount=(/1,1,nclasses/) )
126     
127      CALL iom_get( ncid, jpdom_unknown, 'kount' , zdata(:) )
128      num_bergs(:) = INT(zdata(:))
129
130      ! Sanity check
131      jn = icb_utl_count()
132      IF (nn_verbose_level >= 0)   &
133         WRITE(numout,'(2(a,i5))') 'icebergs, read_restart_bergs: # bergs =',jn,' on PE',narea-1
134      IF( lk_mpp ) THEN
135         ! Only mpp_sum ibergs_in_file if we are reading from multiple restart files.
136         IF( INDEX(iom_file(ncid)%name,'icebergs.nc' ) .EQ. 0 ) CALL mpp_sum(ibergs_in_file)
137         CALL mpp_sum(jn)
138      ENDIF
139      IF(lwp)   WRITE(numout,'(a,i5,a,i5,a)') 'icebergs, read_restart_bergs: there were',ibergs_in_file,   &
140         &                                    ' bergs in the restart file and', jn,' bergs have been read'
141      !
142      ! Finish up
143      CALL iom_close( ncid )
144      !
145      IF( lwp .AND. nn_verbose_level >= 0)  WRITE(numout,'(a)') 'icebergs, read_restart_bergs: completed'
146      !
147   END SUBROUTINE icb_rst_read
148
149
150   SUBROUTINE icb_rst_write( kt )
151      !!----------------------------------------------------------------------
152      !!                 ***  SUBROUTINE icb_rst_write  ***
153      !!
154      !!----------------------------------------------------------------------
155      INTEGER, INTENT( in ) :: kt
156      !
157      INTEGER ::   jn   ! dummy loop index
158      INTEGER ::   ix_dim, iy_dim, ik_dim, in_dim
159      CHARACTER(len=256)     :: cl_path
160      CHARACTER(len=256)     :: cl_filename
161      TYPE(iceberg), POINTER :: this
162      TYPE(point)  , POINTER :: pt
163      !!----------------------------------------------------------------------
164
165      ! Assume we write iceberg restarts to same directory as ocean restarts.
166      cl_path = TRIM(cn_ocerst_outdir)
167      IF( cl_path(LEN_TRIM(cl_path):) /= '/' ) cl_path = TRIM(cl_path) // '/'
168      IF( lk_mpp ) THEN
169         WRITE(cl_filename,'(A,"_icebergs_",I8.8,"_restart_",I4.4,".nc")') TRIM(cexper), kt, narea-1
170      ELSE
171         WRITE(cl_filename,'(A,"_icebergs_",I8.8,"_restart.nc")') TRIM(cexper), kt
172      ENDIF
173      IF (nn_verbose_level >= 0) WRITE(numout,'(2a)') 'icebergs, write_restart: creating ',TRIM(cl_path)//TRIM(cl_filename)
174
175      nret = NF90_CREATE(TRIM(cl_path)//TRIM(cl_filename), NF90_CLOBBER, ncid)
176      IF (nret .ne. NF90_NOERR) CALL ctl_stop('icebergs, write_restart: nf_create failed')
177
178      ! Dimensions
179      nret = NF90_DEF_DIM(ncid, 'x', jpi, ix_dim)
180      IF (nret .ne. NF90_NOERR) CALL ctl_stop('icebergs, write_restart: nf_def_dim x failed')
181
182      nret = NF90_DEF_DIM(ncid, 'y', jpj, iy_dim)
183      IF (nret .ne. NF90_NOERR) CALL ctl_stop('icebergs, write_restart: nf_def_dim y failed')
184
185      nret = NF90_DEF_DIM(ncid, 'c', nclasses, nc_dim)
186      IF (nret .ne. NF90_NOERR) CALL ctl_stop('icebergs, write_restart: nf_def_dim c failed')
187
188      nret = NF90_DEF_DIM(ncid, 'k', nkounts, ik_dim)
189      IF (nret .ne. NF90_NOERR) CALL ctl_stop('icebergs, write_restart: nf_def_dim k failed')
190
191      ! global attributes
192      IF( lk_mpp ) THEN
193         ! Set domain parameters (assume jpdom_local_full)
194         nret = NF90_PUT_ATT( ncid, NF90_GLOBAL, 'DOMAIN_number_total'   , jpnij              )
195         nret = NF90_PUT_ATT( ncid, NF90_GLOBAL, 'DOMAIN_number'         , narea-1            )
196         nret = NF90_PUT_ATT( ncid, NF90_GLOBAL, 'DOMAIN_dimensions_ids' , (/1     , 2     /) )
197         nret = NF90_PUT_ATT( ncid, NF90_GLOBAL, 'DOMAIN_size_global'    , (/jpiglo, jpjglo/) )
198         nret = NF90_PUT_ATT( ncid, NF90_GLOBAL, 'DOMAIN_size_local'     , (/jpi   , jpj   /) )
199         nret = NF90_PUT_ATT( ncid, NF90_GLOBAL, 'DOMAIN_position_first' , (/nimpp , njmpp /) )
200         nret = NF90_PUT_ATT( ncid, NF90_GLOBAL, 'DOMAIN_position_last'  , (/nimpp + jpi - 1 , njmpp + jpj - 1  /) )
201         nret = NF90_PUT_ATT( ncid, NF90_GLOBAL, 'DOMAIN_halo_size_start', (/nldi - 1        , nldj - 1         /) )
202         nret = NF90_PUT_ATT( ncid, NF90_GLOBAL, 'DOMAIN_halo_size_end'  , (/jpi - nlei      , jpj - nlej       /) )
203         nret = NF90_PUT_ATT( ncid, NF90_GLOBAL, 'DOMAIN_type'           , 'BOX'              )
204      ENDIF
205     
206      IF (associated(first_berg)) then
207         nret = NF90_DEF_DIM(ncid, 'n', NF90_UNLIMITED, in_dim)
208         IF (nret .ne. NF90_NOERR) CALL ctl_stop('icebergs, write_restart: nf_def_dim n failed')
209      ENDIF
210
211      ! Variables
212      nret = NF90_DEF_VAR(ncid, 'kount'       , NF90_INT   , (/ ik_dim /), nkountid)
213      nret = NF90_DEF_VAR(ncid, 'calving'     , NF90_DOUBLE, (/ ix_dim, iy_dim /), ncalvid)
214      nret = NF90_DEF_VAR(ncid, 'calving_hflx', NF90_DOUBLE, (/ ix_dim, iy_dim /), ncalvhid)
215      nret = NF90_DEF_VAR(ncid, 'stored_ice'  , NF90_DOUBLE, (/ ix_dim, iy_dim, nc_dim /), nsiceid)
216      nret = NF90_DEF_VAR(ncid, 'stored_heat' , NF90_DOUBLE, (/ ix_dim, iy_dim /), nsheatid)
217
218      ! Attributes
219      nret = NF90_PUT_ATT(ncid, ncalvid , 'long_name', 'iceberg calving')
220      nret = NF90_PUT_ATT(ncid, ncalvid , 'units', 'some')
221      nret = NF90_PUT_ATT(ncid, ncalvhid, 'long_name', 'heat flux associated with iceberg calving')
222      nret = NF90_PUT_ATT(ncid, ncalvhid, 'units', 'some')
223      nret = NF90_PUT_ATT(ncid, nsiceid , 'long_name', 'stored ice used to calve icebergs')
224      nret = NF90_PUT_ATT(ncid, nsiceid , 'units', 'kg/s')
225      nret = NF90_PUT_ATT(ncid, nsheatid, 'long_name', 'heat in stored ice used to calve icebergs')
226      nret = NF90_PUT_ATT(ncid, nsheatid, 'units', 'J/kg/s')
227
228      IF ( ASSOCIATED(first_berg) ) THEN
229
230         ! Only add berg variables for this PE if we have anything to say
231
232         ! Variables
233         nret = NF90_DEF_VAR(ncid, 'lon', NF90_DOUBLE, in_dim, nlonid)
234         nret = NF90_DEF_VAR(ncid, 'lat', NF90_DOUBLE, in_dim, nlatid)
235         nret = NF90_DEF_VAR(ncid, 'xi', NF90_DOUBLE, in_dim, nxid)
236         nret = NF90_DEF_VAR(ncid, 'yj', NF90_DOUBLE, in_dim, nyid)
237         nret = NF90_DEF_VAR(ncid, 'uvel', NF90_DOUBLE, in_dim, nuvelid)
238         nret = NF90_DEF_VAR(ncid, 'vvel', NF90_DOUBLE, in_dim, nvvelid)
239         nret = NF90_DEF_VAR(ncid, 'mass', NF90_DOUBLE, in_dim, nmassid)
240         nret = NF90_DEF_VAR(ncid, 'thickness', NF90_DOUBLE, in_dim, nthicknessid)
241         nret = NF90_DEF_VAR(ncid, 'width', NF90_DOUBLE, in_dim, nwidthid)
242         nret = NF90_DEF_VAR(ncid, 'length', NF90_DOUBLE, in_dim, nlengthid)
243         nret = NF90_DEF_VAR(ncid, 'number', NF90_INT, (/ik_dim,in_dim/), numberid)
244         nret = NF90_DEF_VAR(ncid, 'year', NF90_INT, in_dim, nyearid)
245         nret = NF90_DEF_VAR(ncid, 'day', NF90_DOUBLE, in_dim, ndayid)
246         nret = NF90_DEF_VAR(ncid, 'mass_scaling', NF90_DOUBLE, in_dim, nscaling_id)
247         nret = NF90_DEF_VAR(ncid, 'mass_of_bits', NF90_DOUBLE, in_dim, nmass_of_bits_id)
248         nret = NF90_DEF_VAR(ncid, 'heat_density', NF90_DOUBLE, in_dim, nheat_density_id)
249
250         ! Attributes
251         nret = NF90_PUT_ATT(ncid, nlonid, 'long_name', 'longitude')
252         nret = NF90_PUT_ATT(ncid, nlonid, 'units', 'degrees_E')
253         nret = NF90_PUT_ATT(ncid, nlatid, 'long_name', 'latitude')
254         nret = NF90_PUT_ATT(ncid, nlatid, 'units', 'degrees_N')
255         nret = NF90_PUT_ATT(ncid, nxid, 'long_name', 'x grid box position')
256         nret = NF90_PUT_ATT(ncid, nxid, 'units', 'fractional')
257         nret = NF90_PUT_ATT(ncid, nyid, 'long_name', 'y grid box position')
258         nret = NF90_PUT_ATT(ncid, nyid, 'units', 'fractional')
259         nret = NF90_PUT_ATT(ncid, nuvelid, 'long_name', 'zonal velocity')
260         nret = NF90_PUT_ATT(ncid, nuvelid, 'units', 'm/s')
261         nret = NF90_PUT_ATT(ncid, nvvelid, 'long_name', 'meridional velocity')
262         nret = NF90_PUT_ATT(ncid, nvvelid, 'units', 'm/s')
263         nret = NF90_PUT_ATT(ncid, nmassid, 'long_name', 'mass')
264         nret = NF90_PUT_ATT(ncid, nmassid, 'units', 'kg')
265         nret = NF90_PUT_ATT(ncid, nthicknessid, 'long_name', 'thickness')
266         nret = NF90_PUT_ATT(ncid, nthicknessid, 'units', 'm')
267         nret = NF90_PUT_ATT(ncid, nwidthid, 'long_name', 'width')
268         nret = NF90_PUT_ATT(ncid, nwidthid, 'units', 'm')
269         nret = NF90_PUT_ATT(ncid, nlengthid, 'long_name', 'length')
270         nret = NF90_PUT_ATT(ncid, nlengthid, 'units', 'm')
271         nret = NF90_PUT_ATT(ncid, numberid, 'long_name', 'iceberg number on this processor')
272         nret = NF90_PUT_ATT(ncid, numberid, 'units', 'count')
273         nret = NF90_PUT_ATT(ncid, nyearid, 'long_name', 'calendar year of calving event')
274         nret = NF90_PUT_ATT(ncid, nyearid, 'units', 'years')
275         nret = NF90_PUT_ATT(ncid, ndayid, 'long_name', 'year day of calving event')
276         nret = NF90_PUT_ATT(ncid, ndayid, 'units', 'days')
277         nret = NF90_PUT_ATT(ncid, nscaling_id, 'long_name', 'scaling factor for mass of calving berg')
278         nret = NF90_PUT_ATT(ncid, nscaling_id, 'units', 'none')
279         nret = NF90_PUT_ATT(ncid, nmass_of_bits_id, 'long_name', 'mass of bergy bits')
280         nret = NF90_PUT_ATT(ncid, nmass_of_bits_id, 'units', 'kg')
281         nret = NF90_PUT_ATT(ncid, nheat_density_id, 'long_name', 'heat density')
282         nret = NF90_PUT_ATT(ncid, nheat_density_id, 'units', 'J/kg')
283
284      ENDIF ! associated(first_berg)
285
286      ! End define mode
287      nret = NF90_ENDDEF(ncid)
288
289      ! --------------------------------
290      ! now write some data
291
292      nstrt3(1) = 1
293      nstrt3(2) = 1
294      nlngth3(1) = jpi
295      nlngth3(2) = jpj
296      nlngth3(3) = 1
297
298      DO jn=1,nclasses
299         griddata(:,:,1) = berg_grid%stored_ice(:,:,jn)
300         nstrt3(3) = jn
301         nret = NF90_PUT_VAR( ncid, nsiceid, griddata, nstrt3, nlngth3 )
302         IF (nret .ne. NF90_NOERR) THEN
303            IF( lwp ) WRITE(numout,*) TRIM(NF90_STRERROR( nret ))
304            CALL ctl_stop('icebergs, write_restart: nf_put_var stored_ice failed')
305         ENDIF
306      ENDDO
307      IF( lwp ) WRITE(numout,*) 'file: ',TRIM(cl_path)//TRIM(cl_filename),' var: stored_ice  written'
308
309      nret = NF90_PUT_VAR( ncid, nkountid, num_bergs(:) )
310      IF (nret .ne. NF90_NOERR) CALL ctl_stop('icebergs, write_restart: nf_put_var kount failed')
311
312      nret = NF90_PUT_VAR( ncid, nsheatid, berg_grid%stored_heat(:,:) )
313      IF (nret .ne. NF90_NOERR) CALL ctl_stop('icebergs, write_restart: nf_put_var stored_heat failed')
314      IF( lwp ) WRITE(numout,*) 'file: ',TRIM(cl_path)//TRIM(cl_filename),' var: stored_heat written'
315
316      nret = NF90_PUT_VAR( ncid, ncalvid , src_calving(:,:) )
317      IF (nret .ne. NF90_NOERR) CALL ctl_stop('icebergs, write_restart: nf_put_var calving failed')
318      nret = NF90_PUT_VAR( ncid, ncalvhid, src_calving_hflx(:,:) )
319      IF (nret .ne. NF90_NOERR) CALL ctl_stop('icebergs, write_restart: nf_put_var calving_hflx failed')
320      IF( lwp ) WRITE(numout,*) 'file: ',TRIM(cl_path)//TRIM(cl_filename),' var: calving written'
321
322      IF ( ASSOCIATED(first_berg) ) THEN
323
324         ! Write variables
325         ! just write out the current point of the trajectory
326
327         this => first_berg
328         jn = 0
329         DO WHILE (ASSOCIATED(this))
330            pt => this%current_point
331            jn=jn+1
332
333            nret = NF90_PUT_VAR(ncid, numberid, this%number, (/1,jn/), (/nkounts,1/) )
334            nret = NF90_PUT_VAR(ncid, nscaling_id, this%mass_scaling, (/ jn /) )
335
336            nret = NF90_PUT_VAR(ncid, nlonid, pt%lon, (/ jn /) )
337            nret = NF90_PUT_VAR(ncid, nlatid, pt%lat, (/ jn /) )
338            nret = NF90_PUT_VAR(ncid, nxid, pt%xi, (/ jn /) )
339            nret = NF90_PUT_VAR(ncid, nyid, pt%yj, (/ jn /) )
340            nret = NF90_PUT_VAR(ncid, nuvelid, pt%uvel, (/ jn /) )
341            nret = NF90_PUT_VAR(ncid, nvvelid, pt%vvel, (/ jn /) )
342            nret = NF90_PUT_VAR(ncid, nmassid, pt%mass, (/ jn /) )
343            nret = NF90_PUT_VAR(ncid, nthicknessid, pt%thickness, (/ jn /) )
344            nret = NF90_PUT_VAR(ncid, nwidthid, pt%width, (/ jn /) )
345            nret = NF90_PUT_VAR(ncid, nlengthid, pt%length, (/ jn /) )
346            nret = NF90_PUT_VAR(ncid, nyearid, pt%year, (/ jn /) )
347            nret = NF90_PUT_VAR(ncid, ndayid, pt%day, (/ jn /) )
348            nret = NF90_PUT_VAR(ncid, nmass_of_bits_id, pt%mass_of_bits, (/ jn /) )
349            nret = NF90_PUT_VAR(ncid, nheat_density_id, pt%heat_density, (/ jn /) )
350
351            this=>this%next
352         END DO
353         !
354      ENDIF ! associated(first_berg)
355
356      ! Finish up
357      nret = NF90_CLOSE(ncid)
358      IF (nret /= NF90_NOERR) CALL ctl_stop('icebergs, write_restart: nf_close failed')
359      !
360   END SUBROUTINE icb_rst_write
361   !
362   !!======================================================================
363END MODULE icbrst
Note: See TracBrowser for help on using the repository browser.