New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
restart.F90 in NEMO/trunk/src/OCE/IOM – NEMO

source: NEMO/trunk/src/OCE/IOM/restart.F90 @ 14072

Last change on this file since 14072 was 14072, checked in by laurent, 3 years ago

Merging branch "2020/dev_r13648_ASINTER-04_laurent_bulk_ice", ticket #2369
  • Property svn:keywords set to Id
File size: 14.7 KB
Line 
1MODULE restart
2   !!======================================================================
3   !!                     ***  MODULE  restart  ***
4   !! Ocean restart :  write the ocean restart file
5   !!======================================================================
6   !! History :  OPA  !  1999-11  (M. Imbard)  Original code
7   !!   NEMO     1.0  !  2002-08  (G. Madec)  F90: Free form
8   !!            2.0  !  2006-07  (S. Masson)  use IOM for restart
9   !!            3.3  !  2010-04  (M. Leclair, G. Madec)  modified LF-RA
10   !!            - -  !  2010-10  (C. Ethe, G. Madec) TRC-TRA merge (T-S in 4D)
11   !!            3.7  !  2014-01  (G. Madec) suppression of curl and hdiv from the restart
12   !!             -   !  2014-12  (G. Madec) remove KPP scheme
13   !!            4.1  !  2020-11  (S. Techene, G. Madec)  move ssh initiatlisation in DYN/sshwzv:ssh_init_rst
14   !!----------------------------------------------------------------------
15
16   !!----------------------------------------------------------------------
17   !!   rst_opn    : open the ocean restart file
18   !!   rst_write  : write the ocean restart file
19   !!   rst_read   : read the ocean restart file
20   !!----------------------------------------------------------------------
21   USE oce             ! ocean dynamics and tracers
22   USE dom_oce         ! ocean space and time domain
23   USE sbc_ice         ! only lk_si3
24   USE phycst          ! physical constants
25   USE eosbn2          ! equation of state            (eos bn2 routine)
26   USE trdmxl_oce      ! ocean active mixed layer tracers trends variables
27   !
28   USE in_out_manager  ! I/O manager
29   USE iom             ! I/O module
30   USE diu_bulk
31   USE lib_mpp         ! distribued memory computing library
32
33   IMPLICIT NONE
34   PRIVATE
35
36   PUBLIC   rst_opn         ! routine called by step module
37   PUBLIC   rst_write       ! routine called by step module
38   PUBLIC   rst_read        ! routine called by istate module
39   PUBLIC   rst_read_open   ! routine called in rst_read and (possibly) in dom_vvl_init
40
41   !!----------------------------------------------------------------------
42   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
43   !! $Id$
44   !! Software governed by the CeCILL license (see ./LICENSE)
45   !!----------------------------------------------------------------------
46CONTAINS
47
48   SUBROUTINE rst_opn( kt )
49      !!---------------------------------------------------------------------
50      !!                   ***  ROUTINE rst_opn  ***
51      !!
52      !! ** Purpose : + initialization (should be read in the namelist) of nitrst
53      !!              + open the restart when we are one time step before nitrst
54      !!                   - restart header is defined when kt = nitrst-1
55      !!                   - restart data  are written when kt = nitrst
56      !!              + define lrst_oce to .TRUE. when we need to define or write the restart
57      !!----------------------------------------------------------------------
58      INTEGER, INTENT(in) ::   kt     ! ocean time-step
59      !!
60      CHARACTER(LEN=20)   ::   clkt     ! ocean time-step deine as a character
61      CHARACTER(LEN=50)   ::   clname   ! ocean output restart file name
62      CHARACTER(lc)       ::   clpath   ! full path to ocean output restart file
63      CHARACTER(LEN=52)   ::   clpname   ! ocean output restart file name including prefix for AGRIF
64      CHARACTER(LEN=256)  ::   clinfo    ! info character
65      !!----------------------------------------------------------------------
66      !
67      IF( kt == nit000 ) THEN   ! default definitions
68         lrst_oce = .FALSE.
69         IF( ln_rst_list ) THEN
70            nrst_lst = 1
71            nitrst = nn_stocklist( nrst_lst )
72         ELSE
73            nitrst = nitend
74         ENDIF
75      ENDIF
76
77      IF( .NOT. ln_rst_list .AND. nn_stock == -1 )   RETURN   ! we will never do any restart
78
79      ! frequency-based restart dumping (nn_stock)
80      IF( .NOT. ln_rst_list .AND. MOD( kt - 1, nn_stock ) == 0 ) THEN
81         ! we use kt - 1 and not kt - nit000 to keep the same periodicity from the beginning of the experiment
82         nitrst = kt + nn_stock - 1                  ! define the next value of nitrst for restart writing
83         IF( nitrst > nitend )   nitrst = nitend   ! make sure we write a restart at the end of the run
84      ENDIF
85      ! to get better performances with NetCDF format:
86      ! we open and define the ocean restart file one time step before writing the data (-> at nitrst - 1)
87      ! except if we write ocean restart files every time step or if an ocean restart file was writen at nitend - 1
88      IF( kt == nitrst - 1 .OR. nn_stock == 1 .OR. ( kt == nitend .AND. .NOT. lrst_oce ) ) THEN
89         IF( nitrst <= nitend .AND. nitrst > 0 ) THEN
90            ! beware of the format used to write kt (default is i8.8, that should be large enough...)
91            IF( nitrst > 999999999 ) THEN   ;   WRITE(clkt, *       ) nitrst
92            ELSE                            ;   WRITE(clkt, '(i8.8)') nitrst
93            ENDIF
94            ! create the file
95            clname = TRIM(cexper)//"_"//TRIM(ADJUSTL(clkt))//"_"//TRIM(cn_ocerst_out)
96            clpath = TRIM(cn_ocerst_outdir)
97            IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
98            IF(lwp) THEN
99               WRITE(numout,*)
100               IF(.NOT.lwxios) THEN
101                  WRITE(numout,*) '             open ocean restart NetCDF file: ',TRIM(clpath)//TRIM(clname)
102                  IF ( snc4set%luse )      WRITE(numout,*) '             opened for NetCDF4 chunking and compression'
103                  IF( kt == nitrst - 1 ) THEN   ;   WRITE(numout,*) '             kt = nitrst - 1 = ', kt
104                  ELSE                          ;   WRITE(numout,*) '             kt = '             , kt
105                  ENDIF
106               ENDIF
107            ENDIF
108            !
109            IF(.NOT.lwxios) THEN
110               CALL iom_open( TRIM(clpath)//TRIM(clname), numrow, ldwrt = .TRUE. )
111            ELSE
112#if defined key_iomput
113               cw_ocerst_cxt = "rstw_"//TRIM(ADJUSTL(clkt))
114               IF( TRIM(Agrif_CFixed()) == '0' ) THEN
115                  clpname = clname
116               ELSE
117                  clpname = TRIM(Agrif_CFixed())//"_"//clname
118               ENDIF
119               numrow = iom_xios_setid(TRIM(clpath)//TRIM(clpname))
120               CALL iom_init( cw_ocerst_cxt, kdid = numrow, ld_closedef = .false. )
121               CALL iom_swap(      cxios_context          )
122#else
123               clinfo = 'Can not use XIOS in rst_opn'
124               CALL ctl_stop(TRIM(clinfo))
125#endif
126            ENDIF
127            lrst_oce = .TRUE.
128         ENDIF
129      ENDIF
130      !
131   END SUBROUTINE rst_opn
132
133
134   SUBROUTINE rst_write( kt, Kbb, Kmm )
135      !!---------------------------------------------------------------------
136      !!                   ***  ROUTINE rstwrite  ***
137      !!
138      !! ** Purpose :   Write restart fields in NetCDF format
139      !!
140      !! ** Method  :   Write in numrow when kt == nitrst in NetCDF
141      !!              file, save fields which are necessary for restart
142      !!
143      !!                NB: ssh is written here (rst_write)
144      !!                    but is read or set in DYN/sshwzv:shh_init_rst
145      !!----------------------------------------------------------------------
146      INTEGER, INTENT(in) ::   kt         ! ocean time-step
147      INTEGER, INTENT(in) ::   Kbb, Kmm   ! ocean time level indices
148      !!----------------------------------------------------------------------
149                     CALL iom_rstput( kt, nitrst, numrow, 'rdt'    , rn_Dt       )   ! dynamics time step
150                     IF(.NOT.lwxios) CALL iom_delay_rst( 'WRITE', 'OCE', numrow )   ! save only ocean delayed global communication variables
151
152      IF ( .NOT. ln_diurnal_only ) THEN
153                     CALL iom_rstput( kt, nitrst, numrow, 'ub'     , uu(:,:,:       ,Kbb) )     ! before fields
154                     CALL iom_rstput( kt, nitrst, numrow, 'vb'     , vv(:,:,:       ,Kbb) )
155                     CALL iom_rstput( kt, nitrst, numrow, 'tb'     , ts(:,:,:,jp_tem,Kbb) )
156                     CALL iom_rstput( kt, nitrst, numrow, 'sb'     , ts(:,:,:,jp_sal,Kbb) )
157                     CALL iom_rstput( kt, nitrst, numrow, 'sshb'   , ssh(:,:         ,Kbb))
158                     !
159                     CALL iom_rstput( kt, nitrst, numrow, 'un'     , uu(:,:,:       ,Kmm) )     ! now fields
160                     CALL iom_rstput( kt, nitrst, numrow, 'vn'     , vv(:,:,:       ,Kmm) )
161                     CALL iom_rstput( kt, nitrst, numrow, 'tn'     , ts(:,:,:,jp_tem,Kmm) )
162                     CALL iom_rstput( kt, nitrst, numrow, 'sn'     , ts(:,:,:,jp_sal,Kmm) )
163                     CALL iom_rstput( kt, nitrst, numrow, 'sshn'   , ssh(:,:         ,Kmm))
164                     CALL iom_rstput( kt, nitrst, numrow, 'rhop'   , rhop      )
165      ENDIF
166
167      IF (ln_diurnal) CALL iom_rstput( kt, nitrst, numrow, 'Dsst', x_dsst )
168      IF( kt == nitrst ) THEN
169         IF(.NOT.lwxios) THEN
170            CALL iom_close( numrow )     ! close the restart file (only at last time step)
171         ELSE
172            CALL iom_context_finalize(      cw_ocerst_cxt          )
173            iom_file(numrow)%nfid       = 0
174            numrow = 0
175         ENDIF
176!!gm         IF( .NOT. lk_trdmld )   lrst_oce = .FALSE.
177!!gm  not sure what to do here   ===>>>  ask to Sebastian
178         lrst_oce = .FALSE.
179            IF( ln_rst_list ) THEN
180               nrst_lst = MIN(nrst_lst + 1, SIZE(nn_stocklist,1))
181               nitrst = nn_stocklist( nrst_lst )
182            ENDIF
183      ENDIF
184      !
185   END SUBROUTINE rst_write
186
187
188   SUBROUTINE rst_read_open
189      !!----------------------------------------------------------------------
190      !!                   ***  ROUTINE rst_read_open  ***
191      !!
192      !! ** Purpose :   Open read files for NetCDF restart
193      !!
194      !! ** Method  :   Use a non-zero, positive value of numror to assess whether or not
195      !!                the file has already been opened
196      !!----------------------------------------------------------------------
197      LOGICAL             ::   llok
198      CHARACTER(len=lc)   ::   clpath   ! full path to ocean output restart file
199      CHARACTER(len=lc+2) ::   clpname  ! file name including agrif prefix
200      !!----------------------------------------------------------------------
201      !
202      IF( numror <= 0 ) THEN
203         IF(lwp) THEN                                             ! Contol prints
204            WRITE(numout,*)
205            WRITE(numout,*) 'rst_read : read oce NetCDF restart file'
206            IF ( snc4set%luse )      WRITE(numout,*) 'rst_read : configured with NetCDF4 support'
207            WRITE(numout,*) '~~~~~~~~'
208         ENDIF
209         lxios_sini = .FALSE.
210         clpath = TRIM(cn_ocerst_indir)
211         IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
212         CALL iom_open( TRIM(clpath)//cn_ocerst_in, numror )
213! are we using XIOS to read the data? Part above will have to modified once XIOS
214! can handle checking if variable is in the restart file (there will be no need to open
215! restart)
216         lrxios = lrxios.AND.lxios_sini
217
218         IF( lrxios) THEN
219             cr_ocerst_cxt = 'oce_rst'
220             IF(lwp) WRITE(numout,*) 'Enable restart reading by XIOS'
221!            IF( TRIM(Agrif_CFixed()) == '0' ) THEN
222!               clpname = cn_ocerst_in
223!            ELSE
224!               clpname = TRIM(Agrif_CFixed())//"_"//cn_ocerst_in
225!            ENDIF
226             CALL iom_init( cr_ocerst_cxt, kdid = numror, ld_closedef = .TRUE. )
227             CALL iom_swap(      cxios_context          )
228         ENDIF
229
230      ENDIF
231
232   END SUBROUTINE rst_read_open
233
234
235   SUBROUTINE rst_read( Kbb, Kmm )
236      !!----------------------------------------------------------------------
237      !!                   ***  ROUTINE rst_read  ***
238      !!
239      !! ** Purpose :   Read velocity and T-S fields in the restart file
240      !!
241      !! ** Method  :   Read in restart.nc fields which are necessary for restart
242      !!
243      !!                NB: restart file openned           in DOM/domain.F90:dom_init
244      !!                    before field in restart tested in DOM/domain.F90:dom_init
245      !!                    (sshb)
246      !!
247      !!                NB: ssh is read or set in DYN/sshwzv:shh_init_rst
248      !!                    but is written     in IOM/restart:rst_write
249      !!----------------------------------------------------------------------
250      INTEGER, INTENT(in) ::   Kbb, Kmm   ! ocean time level indices
251      INTEGER  ::   jk
252      REAL(wp), DIMENSION(jpi, jpj, jpk) :: w3d
253      !!----------------------------------------------------------------------
254      !
255      IF(.NOT.lrxios ) CALL iom_delay_rst( 'READ', 'OCE', numror )   ! read only ocean delayed global communication variables
256      !
257      !                             !*  Diurnal DSST
258      IF( ln_diurnal )   CALL iom_get( numror, jpdom_auto, 'Dsst' , x_dsst )
259      IF ( ln_diurnal_only ) THEN
260         IF(lwp) WRITE( numout, * ) &
261         &   "rst_read:- ln_diurnal_only set, setting rhop=rho0"
262         rhop = rho0
263         CALL iom_get( numror, jpdom_auto, 'tn'     , w3d )
264         ts(:,:,1,jp_tem,Kmm) = w3d(:,:,1)
265         RETURN
266      ENDIF
267      !
268      !                             !*  Read Kmm fields
269      IF(lwp) WRITE(numout,*)    '           Kmm u, v and T-S fields read in the restart file'
270      CALL iom_get( numror, jpdom_auto, 'un'     , uu(:,:,:       ,Kmm), cd_type = 'U', psgn = -1._wp )
271      CALL iom_get( numror, jpdom_auto, 'vn'     , vv(:,:,:       ,Kmm), cd_type = 'V', psgn = -1._wp )
272      CALL iom_get( numror, jpdom_auto, 'tn'     , ts(:,:,:,jp_tem,Kmm) )
273      CALL iom_get( numror, jpdom_auto, 'sn'     , ts(:,:,:,jp_sal,Kmm) )
274      !
275      IF( l_1st_euler ) THEN        !*  Euler restart
276         IF(lwp) WRITE(numout,*) '           Kbb u, v and T-S fields set to Kmm values'
277         ts(:,:,:,:,Kbb) = ts(:,:,:,:,Kmm)         ! all before fields set to now values
278         uu(:,:,:  ,Kbb) = uu(:,:,:  ,Kmm)
279         vv(:,:,:  ,Kbb) = vv(:,:,:  ,Kmm)
280      ELSE                          !* Leap frog restart
281         IF(lwp) WRITE(numout,*) '           Kbb u, v and T-S fields read in the restart file'
282         CALL iom_get( numror, jpdom_auto, 'ub'     , uu(:,:,:       ,Kbb), cd_type = 'U', psgn = -1._wp )
283         CALL iom_get( numror, jpdom_auto, 'vb'     , vv(:,:,:       ,Kbb), cd_type = 'V', psgn = -1._wp )
284         CALL iom_get( numror, jpdom_auto, 'tb'     , ts(:,:,:,jp_tem,Kbb) )
285         CALL iom_get( numror, jpdom_auto, 'sb'     , ts(:,:,:,jp_sal,Kbb) )
286      ENDIF
287      !
288      IF( iom_varid( numror, 'rhop', ldstop = .FALSE. ) > 0 ) THEN
289         CALL iom_get( numror, jpdom_auto, 'rhop'   , rhop )   ! now    potential density
290      ELSE
291         CALL eos( ts(:,:,:,:,Kmm), rhd, rhop, gdept(:,:,:,Kmm) )
292      ENDIF
293      !
294   END SUBROUTINE rst_read
295
296   !!=====================================================================
297END MODULE restart
Note: See TracBrowser for help on using the repository browser.