source: NEMO/trunk/src/OCE/SBC/sbcssr.F90 @ 12276

Last change on this file since 12276 was 12276, checked in by cetlod, 10 months ago

trunk : merge in some cmip6 diagnostics into the trunk before copying it to release-4.0.2(-head). SETTE tests are OK and the is no difference with the revision 12248

  • Property svn:keywords set to Id
File size: 13.9 KB
Line 
1MODULE sbcssr
2   !!======================================================================
3   !!                       ***  MODULE  sbcssr  ***
4   !! Surface module :  heat and fresh water fluxes a restoring term toward observed SST/SSS
5   !!======================================================================
6   !! History :  3.0  !  2006-06  (G. Madec)  Original code
7   !!            3.2  !  2009-04  (B. Lemaire)  Introduce iom_put
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   sbc_ssr       : add to sbc a restoring term toward SST/SSS climatology
12   !!   sbc_ssr_init  : initialisation of surface restoring
13   !!----------------------------------------------------------------------
14   USE oce            ! ocean dynamics and tracers
15   USE dom_oce        ! ocean space and time domain
16   USE sbc_oce        ! surface boundary condition
17   USE phycst         ! physical constants
18   USE sbcrnf         ! surface boundary condition : runoffs
19   !
20   USE fldread        ! read input fields
21   USE in_out_manager ! I/O manager
22   USE iom            ! I/O manager
23   USE lib_mpp        ! distribued memory computing library
24   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
25   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
26
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC   sbc_ssr        ! routine called in sbcmod
31   PUBLIC   sbc_ssr_init   ! routine called in sbcmod
32   PUBLIC   sbc_ssr_alloc  ! routine called in sbcmod
33
34   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) ::   erp   !: evaporation damping   [kg/m2/s]
35   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) ::   qrp   !: heat flux damping        [w/m2]
36   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) ::   coefice   !: under ice relaxation coefficient
37
38   !                                   !!* Namelist namsbc_ssr *
39   INTEGER, PUBLIC ::   nn_sstr         ! SST/SSS restoring indicator
40   INTEGER, PUBLIC ::   nn_sssr         ! SST/SSS restoring indicator
41   REAL(wp)        ::   rn_dqdt         ! restoring factor on SST and SSS
42   REAL(wp)        ::   rn_deds         ! restoring factor on SST and SSS
43   LOGICAL         ::   ln_sssr_bnd     ! flag to bound erp term
44   REAL(wp)        ::   rn_sssr_bnd     ! ABS(Max./Min.) value of erp term [mm/day]
45   INTEGER         ::   nn_sssr_ice     ! Control of restoring under ice
46
47   REAL(wp) , ALLOCATABLE, DIMENSION(:) ::   buffer   ! Temporary buffer for exchange
48   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_sst   ! structure of input SST (file informations, fields read)
49   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_sss   ! structure of input SSS (file informations, fields read)
50
51   !!----------------------------------------------------------------------
52   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
53   !! $Id$
54   !! Software governed by the CeCILL license (see ./LICENSE)
55   !!----------------------------------------------------------------------
56CONTAINS
57
58   SUBROUTINE sbc_ssr( kt )
59      !!---------------------------------------------------------------------
60      !!                     ***  ROUTINE sbc_ssr  ***
61      !!
62      !! ** Purpose :   Add to heat and/or freshwater fluxes a damping term
63      !!                toward observed SST and/or SSS.
64      !!
65      !! ** Method  : - Read namelist namsbc_ssr
66      !!              - Read observed SST and/or SSS
67      !!              - at each nscb time step
68      !!                   add a retroaction term on qns    (nn_sstr = 1)
69      !!                   add a damping term on sfx        (nn_sssr = 1)
70      !!                   add a damping term on emp        (nn_sssr = 2)
71      !!---------------------------------------------------------------------
72      INTEGER, INTENT(in   ) ::   kt   ! ocean time step
73      !!
74      INTEGER  ::   ji, jj   ! dummy loop indices
75      REAL(wp) ::   zerp     ! local scalar for evaporation damping
76      REAL(wp) ::   zqrp     ! local scalar for heat flux damping
77      REAL(wp) ::   zsrp     ! local scalar for unit conversion of rn_deds factor
78      REAL(wp) ::   zerp_bnd ! local scalar for unit conversion of rn_epr_max factor
79      INTEGER  ::   ierror   ! return error code
80      !!
81      CHARACTER(len=100) ::  cn_dir          ! Root directory for location of ssr files
82      TYPE(FLD_N) ::   sn_sst, sn_sss        ! informations about the fields to be read
83      !!----------------------------------------------------------------------
84      !
85      IF( nn_sstr + nn_sssr /= 0 ) THEN
86         !
87         IF( nn_sstr == 1)   CALL fld_read( kt, nn_fsbc, sf_sst )   ! Read SST data and provides it at kt
88         IF( nn_sssr >= 1)   CALL fld_read( kt, nn_fsbc, sf_sss )   ! Read SSS data and provides it at kt
89         !
90         !                                         ! ========================= !
91         IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN      !    Add restoring term     !
92            !                                      ! ========================= !
93            !
94            IF( nn_sstr == 1 ) THEN                                   !* Temperature restoring term
95               DO jj = 1, jpj
96                  DO ji = 1, jpi
97                     zqrp = rn_dqdt * ( sst_m(ji,jj) - sf_sst(1)%fnow(ji,jj,1) ) * tmask(ji,jj,1)
98                     qns(ji,jj) = qns(ji,jj) + zqrp
99                     qrp(ji,jj) = zqrp
100                  END DO
101               END DO
102            ENDIF
103            !
104            IF( nn_sssr /= 0 .AND. nn_sssr_ice /= 1 ) THEN
105              ! use fraction of ice ( fr_i ) to adjust relaxation under ice if nn_sssr_ice .ne. 1
106              ! n.b. coefice is initialised and fixed to 1._wp if nn_sssr_ice = 1
107               DO jj = 1, jpj
108                  DO ji = 1, jpi
109                     SELECT CASE ( nn_sssr_ice )
110                       CASE ( 0 )    ;  coefice(ji,jj) = 1._wp - fr_i(ji,jj)              ! no/reduced damping under ice
111                       CASE  DEFAULT ;  coefice(ji,jj) = 1._wp + ( nn_sssr_ice - 1 ) * fr_i(ji,jj) ! reinforced damping (x nn_sssr_ice) under ice )
112                     END SELECT
113                  END DO
114               END DO
115            ENDIF
116            !
117            IF( nn_sssr == 1 ) THEN                                   !* Salinity damping term (salt flux only (sfx))
118               zsrp = rn_deds / rday                                  ! from [mm/day] to [kg/m2/s]
119               DO jj = 1, jpj
120                  DO ji = 1, jpi
121                     zerp = zsrp * ( 1. - 2.*rnfmsk(ji,jj) )   &      ! No damping in vicinity of river mouths
122                        &        *   coefice(ji,jj)            &      ! Optional control of damping under sea-ice
123                        &        * ( sss_m(ji,jj) - sf_sss(1)%fnow(ji,jj,1) ) * tmask(ji,jj,1)
124                     sfx(ji,jj) = sfx(ji,jj) + zerp                 ! salt flux
125                     erp(ji,jj) = zerp / MAX( sss_m(ji,jj), 1.e-20 ) ! converted into an equivalent volume flux (diagnostic only)
126                  END DO
127               END DO
128               !
129            ELSEIF( nn_sssr == 2 ) THEN                               !* Salinity damping term (volume flux (emp) and associated heat flux (qns)
130               zsrp = rn_deds / rday                                  ! from [mm/day] to [kg/m2/s]
131               zerp_bnd = rn_sssr_bnd / rday                          !       -              -   
132               DO jj = 1, jpj
133                  DO ji = 1, jpi                           
134                     zerp = zsrp * ( 1. - 2.*rnfmsk(ji,jj) )   &      ! No damping in vicinity of river mouths
135                        &        *   coefice(ji,jj)            &      ! Optional control of damping under sea-ice
136                        &        * ( sss_m(ji,jj) - sf_sss(1)%fnow(ji,jj,1) )   &
137                        &        / MAX(  sss_m(ji,jj), 1.e-20   ) * tmask(ji,jj,1)
138                     IF( ln_sssr_bnd )   zerp = SIGN( 1., zerp ) * MIN( zerp_bnd, ABS(zerp) )
139                     emp(ji,jj) = emp (ji,jj) + zerp
140                     qns(ji,jj) = qns(ji,jj) - zerp * rcp * sst_m(ji,jj)
141                     erp(ji,jj) = zerp
142                  END DO
143               END DO
144            ENDIF
145            !
146         ENDIF
147         !
148      ENDIF
149      !
150   END SUBROUTINE sbc_ssr
151
152 
153   SUBROUTINE sbc_ssr_init
154      !!---------------------------------------------------------------------
155      !!                  ***  ROUTINE sbc_ssr_init  ***
156      !!
157      !! ** Purpose :   initialisation of surface damping term
158      !!
159      !! ** Method  : - Read namelist namsbc_ssr
160      !!              - Read observed SST and/or SSS if required
161      !!---------------------------------------------------------------------
162      INTEGER  ::   ji, jj   ! dummy loop indices
163      REAL(wp) ::   zerp     ! local scalar for evaporation damping
164      REAL(wp) ::   zqrp     ! local scalar for heat flux damping
165      REAL(wp) ::   zsrp     ! local scalar for unit conversion of rn_deds factor
166      REAL(wp) ::   zerp_bnd ! local scalar for unit conversion of rn_epr_max factor
167      INTEGER  ::   ierror   ! return error code
168      !!
169      CHARACTER(len=100) ::  cn_dir          ! Root directory for location of ssr files
170      TYPE(FLD_N) ::   sn_sst, sn_sss        ! informations about the fields to be read
171      NAMELIST/namsbc_ssr/ cn_dir, nn_sstr, nn_sssr, rn_dqdt, rn_deds, sn_sst, &
172              & sn_sss, ln_sssr_bnd, rn_sssr_bnd, nn_sssr_ice
173      INTEGER     ::  ios
174      !!----------------------------------------------------------------------
175      !
176      IF(lwp) THEN
177         WRITE(numout,*)
178         WRITE(numout,*) 'sbc_ssr : SST and/or SSS damping term '
179         WRITE(numout,*) '~~~~~~~ '
180      ENDIF
181      !
182      REWIND( numnam_ref )              ! Namelist namsbc_ssr in reference namelist :
183      READ  ( numnam_ref, namsbc_ssr, IOSTAT = ios, ERR = 901)
184901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namsbc_ssr in reference namelist' )
185
186      REWIND( numnam_cfg )              ! Namelist namsbc_ssr in configuration namelist :
187      READ  ( numnam_cfg, namsbc_ssr, IOSTAT = ios, ERR = 902 )
188902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namsbc_ssr in configuration namelist' )
189      IF(lwm) WRITE ( numond, namsbc_ssr )
190
191      IF(lwp) THEN                 !* control print
192         WRITE(numout,*) '   Namelist namsbc_ssr :'
193         WRITE(numout,*) '      SST restoring term (Yes=1)             nn_sstr        = ', nn_sstr
194         WRITE(numout,*) '         dQ/dT (restoring magnitude on SST)     rn_dqdt     = ', rn_dqdt, ' W/m2/K'
195         WRITE(numout,*) '      SSS damping term (Yes=1, salt   flux)  nn_sssr        = ', nn_sssr
196         WRITE(numout,*) '                       (Yes=2, volume flux) '
197         WRITE(numout,*) '         dE/dS (restoring magnitude on SST)     rn_deds     = ', rn_deds, ' mm/day'
198         WRITE(numout,*) '         flag to bound erp term                 ln_sssr_bnd = ', ln_sssr_bnd
199         WRITE(numout,*) '         ABS(Max./Min.) erp threshold           rn_sssr_bnd = ', rn_sssr_bnd, ' mm/day'
200         WRITE(numout,*) '      Cntrl of surface restoration under ice nn_sssr_ice    = ', nn_sssr_ice
201         WRITE(numout,*) '          ( 0 = no restoration under ice)'
202         WRITE(numout,*) '          ( 1 = restoration everywhere  )'
203         WRITE(numout,*) '          (>1 = enhanced restoration under ice  )'
204      ENDIF
205      !
206      IF( nn_sstr == 1 ) THEN      !* set sf_sst structure & allocate arrays
207         !
208         ALLOCATE( sf_sst(1), STAT=ierror )
209         IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_ssr: unable to allocate sf_sst structure' )
210         ALLOCATE( sf_sst(1)%fnow(jpi,jpj,1), STAT=ierror )
211         IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_ssr: unable to allocate sf_sst now array' )
212         !
213         ! fill sf_sst with sn_sst and control print
214         CALL fld_fill( sf_sst, (/ sn_sst /), cn_dir, 'sbc_ssr', 'SST restoring term toward SST data', 'namsbc_ssr', no_print )
215         IF( sf_sst(1)%ln_tint )   ALLOCATE( sf_sst(1)%fdta(jpi,jpj,1,2), STAT=ierror )
216         IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_ssr: unable to allocate sf_sst data array' )
217         !
218      ENDIF
219      !
220      IF( nn_sssr >= 1 ) THEN      !* set sf_sss structure & allocate arrays
221         !
222         ALLOCATE( sf_sss(1), STAT=ierror )
223         IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_ssr: unable to allocate sf_sss structure' )
224         ALLOCATE( sf_sss(1)%fnow(jpi,jpj,1), STAT=ierror )
225         IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_ssr: unable to allocate sf_sss now array' )
226         !
227         ! fill sf_sss with sn_sss and control print
228         CALL fld_fill( sf_sss, (/ sn_sss /), cn_dir, 'sbc_ssr', 'SSS restoring term toward SSS data', 'namsbc_ssr', no_print )
229         IF( sf_sss(1)%ln_tint )   ALLOCATE( sf_sss(1)%fdta(jpi,jpj,1,2), STAT=ierror )
230         IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_ssr: unable to allocate sf_sss data array' )
231         !
232      ENDIF
233      !
234      coefice(:,:) = 1._wp         !  Initialise coefice to 1._wp ; will not need to be changed if nn_sssr_ice=1
235      !                            !* Initialize qrp and erp if no restoring
236      IF( nn_sstr /= 1                   )   qrp(:,:) = 0._wp
237      IF( nn_sssr /= 1 .OR. nn_sssr /= 2 )   erp(:,:) = 0._wp
238      !
239   END SUBROUTINE sbc_ssr_init
240         
241   INTEGER FUNCTION sbc_ssr_alloc()
242      !!----------------------------------------------------------------------
243      !!               ***  FUNCTION sbc_ssr_alloc  ***
244      !!----------------------------------------------------------------------
245      sbc_ssr_alloc = 0       ! set to zero if no array to be allocated
246      IF( .NOT. ALLOCATED( erp ) ) THEN
247         ALLOCATE( qrp(jpi,jpj), erp(jpi,jpj), coefice(jpi,jpj), STAT= sbc_ssr_alloc )
248         !
249         IF( lk_mpp                  )   CALL mpp_sum ( 'sbcssr', sbc_ssr_alloc )
250         IF( sbc_ssr_alloc /= 0 )   CALL ctl_warn('sbc_ssr_alloc: failed to allocate arrays.')
251         !
252      ENDIF
253   END FUNCTION
254     
255   !!======================================================================
256END MODULE sbcssr
Note: See TracBrowser for help on using the repository browser.