New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_cen_lf.F90 in NEMO/trunk/src/OCE/TRA – NEMO

source: NEMO/trunk/src/OCE/TRA/traadv_cen_lf.F90 @ 14834

Last change on this file since 14834 was 14834, checked in by hadcv, 3 years ago

#2600: Merge in dev_r14273_HPC-02_Daley_Tiling
File size: 10.1 KB
Line 
1MODULE traadv_cen_lf
2   !!======================================================================
3   !!                     ***  MODULE  traadv_cen  ***
4   !! Ocean  tracers:   advective trend (2nd/4th order centered)
5   !!======================================================================
6   !! History :  3.7  ! 2014-05  (G. Madec)  original code
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   !!   tra_adv_cen   : update the tracer trend with the advection trends using a centered or scheme (2nd or 4th order)
11   !!                   NB: on the vertical it is actually a 4th order COMPACT scheme which is used
12   !!----------------------------------------------------------------------
13   USE dom_oce        ! ocean space and time domain
14   USE eosbn2         ! equation of state
15   USE traadv_fct     ! acces to routine interp_4th_cpt
16   USE trd_oce        ! trends: ocean variables
17   USE trdtra         ! trends manager: tracers
18   USE diaptr         ! poleward transport diagnostics
19   USE diaar5         ! AR5 diagnostics
20   !
21   USE in_out_manager ! I/O manager
22   USE iom            ! IOM library
23   USE trc_oce        ! share passive tracers/Ocean variables
24   USE lib_mpp        ! MPP library
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   tra_adv_cen_lf   ! called by traadv.F90
30
31   REAL(wp) ::   r1_6 = 1._wp / 6._wp   ! =1/6
32
33   LOGICAL ::   l_trd   ! flag to compute trends
34   LOGICAL ::   l_ptr   ! flag to compute poleward transport
35   LOGICAL ::   l_hst   ! flag to compute heat/salt transport
36
37   !! * Substitutions
38#  include "do_loop_substitute.h90"
39#  include "domzgr_substitute.h90"
40   !!----------------------------------------------------------------------
41   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
42   !! $Id: traadv_cen.F90 14776 2021-04-30 12:33:41Z mocavero $
43   !! Software governed by the CeCILL license (see ./LICENSE)
44   !!----------------------------------------------------------------------
45CONTAINS
46
47   SUBROUTINE tra_adv_cen_lf( kt, kit000, cdtype, pU, pV, pW,     &
48      &                    Kmm, pt, kjpt, Krhs, kn_cen_h, kn_cen_v )
49      !!----------------------------------------------------------------------
50      !!                  ***  ROUTINE tra_adv_cen  ***
51      !!
52      !! ** Purpose :   Compute the now trend due to the advection of tracers
53      !!      and add it to the general trend of passive tracer equations.
54      !!
55      !! ** Method  :   The advection is evaluated by a 2nd or 4th order scheme
56      !!               using now fields (leap-frog scheme).
57      !!       kn_cen_h = 2  ==>> 2nd order centered scheme on the horizontal
58      !!                = 4  ==>> 4th order    -        -       -      -
59      !!       kn_cen_v = 2  ==>> 2nd order centered scheme on the vertical
60      !!                = 4  ==>> 4th order COMPACT  scheme     -      -
61      !!
62      !! ** Action : - update pt(:,:,:,:,Krhs)  with the now advective tracer trends
63      !!             - send trends to trdtra module for further diagnostcs (l_trdtra=T)
64      !!             - poleward advective heat and salt transport (l_diaptr=T)
65      !!----------------------------------------------------------------------
66      INTEGER                                  , INTENT(in   ) ::   kt              ! ocean time-step index
67      INTEGER                                  , INTENT(in   ) ::   Kmm, Krhs       ! ocean time level indices
68      INTEGER                                  , INTENT(in   ) ::   kit000          ! first time step index
69      CHARACTER(len=3)                         , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
70      INTEGER                                  , INTENT(in   ) ::   kjpt            ! number of tracers
71      INTEGER                                  , INTENT(in   ) ::   kn_cen_h        ! =2/4 (2nd or 4th order scheme)
72      INTEGER                                  , INTENT(in   ) ::   kn_cen_v        ! =2/4 (2nd or 4th order scheme)
73      ! TEMP: [tiling] This can be A2D(nn_hls) if using XIOS (subdomain support)
74      REAL(wp), DIMENSION(jpi,jpj,jpk         ), INTENT(in   ) ::   pU, pV, pW      ! 3 ocean volume flux components
75      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt,jpt), INTENT(inout) ::   pt              ! tracers and RHS of tracer equation
76      !
77      INTEGER  ::   ji, jj, jk, jn   ! dummy loop indices
78      INTEGER  ::   ierr             ! local integer
79      REAL(wp) ::   zC2t_u, zC4t_u   ! local scalars
80      REAL(wp) ::   zC2t_v, zC4t_v   !   -      -
81      REAL(wp) ::   ztu_im1, ztu_ip1 !   -      -
82      REAL(wp) ::   ztv_jm1, ztv_jp1 !   -      -
83      REAL(wp), DIMENSION(A2D(nn_hls),jpk) ::   zwx, zwy, zwz, ztw
84      !!----------------------------------------------------------------------
85      !
86      IF( ntile == 0 .OR. ntile == 1 )  THEN                       ! Do only on the first tile
87         IF( kt == kit000 )  THEN
88            IF(lwp) WRITE(numout,*)
89            IF(lwp) WRITE(numout,*) 'tra_adv_cen : centered advection scheme on ', cdtype, ' order h/v =', kn_cen_h,'/', kn_cen_v
90            IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~ '
91         ENDIF
92         !                          ! set local switches
93         l_trd = .FALSE.
94         l_hst = .FALSE.
95         l_ptr = .FALSE.
96         IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) )       l_trd = .TRUE.
97         IF(   cdtype == 'TRA' .AND. ( iom_use( 'sophtadv' ) .OR. iom_use( 'sophtadv' ) )  )    l_ptr = .TRUE.
98         IF(   cdtype == 'TRA' .AND. ( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR. &
99            &                          iom_use("uadv_salttr") .OR. iom_use("vadv_salttr")  ) )  l_hst = .TRUE.
100      ENDIF
101      !
102      !
103      zwz(:,:, 1 ) = 0._wp       ! surface & bottom vertical flux set to zero for all tracers
104      zwz(:,:,jpk) = 0._wp
105      !
106      DO jn = 1, kjpt            !==  loop over the tracers  ==!
107         !
108         SELECT CASE( kn_cen_h )       !--  Horizontal fluxes  --!
109         !
110         CASE(  2  )                         !* 2nd order centered
111            DO_3D( 1, 0, 1, 0, 1, jpkm1 )
112               zwx(ji,jj,jk) = 0.5_wp * pU(ji,jj,jk) * ( pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj  ,jk,jn,Kmm) )
113               zwy(ji,jj,jk) = 0.5_wp * pV(ji,jj,jk) * ( pt(ji,jj,jk,jn,Kmm) + pt(ji  ,jj+1,jk,jn,Kmm) )
114            END_3D
115            !
116         CASE(  4  )                         !* 4th order centered
117            DO_3D( 1, 0, 1, 0, 1, jpkm1 )           ! Horizontal advective fluxes
118               ztu_im1 = ( pt(ji,jj  ,jk,jn,Kmm) - pt(ji-1,jj,jk,jn,Kmm) ) * umask(ji-1,jj,jk)
119               ztu_ip1 = ( pt(ji+2,jj  ,jk,jn,Kmm) - pt(ji+1,jj,jk,jn,Kmm) ) * umask(ji+1,jj,jk)
120               ztv_jm1 = ( pt(ji,jj,jk,jn,Kmm) - pt(ji,jj-1,jk,jn,Kmm) ) * vmask(ji,jj-1,jk)
121               ztv_jp1 = ( pt(ji,jj+2,jk,jn,Kmm) - pt(ji,jj+1,jk,jn,Kmm) ) * vmask(ji,jj+1,jk)
122               !
123               zC2t_u = pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj  ,jk,jn,Kmm)   ! C2 interpolation of T at u- & v-points (x2)
124               zC2t_v = pt(ji,jj,jk,jn,Kmm) + pt(ji  ,jj+1,jk,jn,Kmm)
125               !                                                  ! C4 interpolation of T at u- & v-points (x2)
126               zC4t_u =  zC2t_u + r1_6 * ( ztu_im1 - ztu_ip1 )
127               zC4t_v =  zC2t_v + r1_6 * ( ztv_jm1 - ztv_jp1 )
128               !                                                  ! C4 fluxes
129               zwx(ji,jj,jk) =  0.5_wp * pU(ji,jj,jk) * zC4t_u
130               zwy(ji,jj,jk) =  0.5_wp * pV(ji,jj,jk) * zC4t_v
131            END_3D
132            !
133         CASE DEFAULT
134            CALL ctl_stop( 'traadv_cen: wrong value for nn_cen' )
135         END SELECT
136         !
137         SELECT CASE( kn_cen_v )       !--  Vertical fluxes  --!   (interior)
138         !
139         CASE(  2  )                         !* 2nd order centered
140            DO_3D( 0, 0, 0, 0, 2, jpk )
141               zwz(ji,jj,jk) = 0.5 * pW(ji,jj,jk) * ( pt(ji,jj,jk,jn,Kmm) + pt(ji,jj,jk-1,jn,Kmm) ) * wmask(ji,jj,jk)
142            END_3D
143            !
144         CASE(  4  )                         !* 4th order compact
145            CALL interp_4th_cpt( pt(:,:,:,jn,Kmm) , ztw )      ! ztw = interpolated value of T at w-point
146            DO_3D( 0, 0, 0, 0, 2, jpkm1 )
147               zwz(ji,jj,jk) = pW(ji,jj,jk) * ztw(ji,jj,jk) * wmask(ji,jj,jk)
148            END_3D
149            !
150         END SELECT
151         !
152         IF( ln_linssh ) THEN                !* top value   (linear free surf. only as zwz is multiplied by wmask)
153            IF( ln_isfcav ) THEN                  ! ice-shelf cavities (top of the ocean)
154               DO_2D( 1, 1, 1, 1 )
155                  zwz(ji,jj, mikt(ji,jj) ) = pW(ji,jj,mikt(ji,jj)) * pt(ji,jj,mikt(ji,jj),jn,Kmm)
156               END_2D
157            ELSE                                   ! no ice-shelf cavities (only ocean surface)
158               DO_2D( 1, 1, 1, 1 )
159                  zwz(ji,jj,1) = pW(ji,jj,1) * pt(ji,jj,1,jn,Kmm)
160               END_2D
161            ENDIF
162         ENDIF
163         !
164         DO_3D( 0, 0, 0, 0, 1, jpkm1 )   !--  Divergence of advective fluxes  --!
165            pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs)    &
166               &             - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )    &
167               &                + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )    &
168               &                + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1)  ) &
169               &                * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
170         END_3D
171         !                               ! trend diagnostics
172         IF( l_trd ) THEN
173            CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_xad, zwx, pU, pt(:,:,:,jn,Kmm) )
174            CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_yad, zwy, pV, pt(:,:,:,jn,Kmm) )
175            CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_zad, zwz, pW, pt(:,:,:,jn,Kmm) )
176         ENDIF
177         !                                 ! "Poleward" heat and salt transports
178         IF( l_ptr )   CALL dia_ptr_hst( jn, 'adv', zwy(:,:,:) )
179         !                                 !  heat and salt transport
180         IF( l_hst )   CALL dia_ar5_hst( jn, 'adv', zwx(:,:,:), zwy(:,:,:) )
181         !
182      END DO
183      !
184   END SUBROUTINE tra_adv_cen_lf
185
186   !!======================================================================
187END MODULE traadv_cen_lf
Note: See TracBrowser for help on using the repository browser.