New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trazdf.F90 in NEMO/trunk/src/OCE/TRA – NEMO

source: NEMO/trunk/src/OCE/TRA/trazdf.F90

Last change on this file was 14834, checked in by hadcv, 3 years ago

#2600: Merge in dev_r14273_HPC-02_Daley_Tiling
  • Property svn:keywords set to Id
File size: 13.9 KB
Line 
1MODULE trazdf
2   !!==============================================================================
3   !!                 ***  MODULE  trazdf  ***
4   !! Ocean active tracers:  vertical component of the tracer mixing trend
5   !!==============================================================================
6   !! History :  1.0  !  2005-11  (G. Madec)  Original code
7   !!            3.0  !  2008-01  (C. Ethe, G. Madec)  merge TRC-TRA
8   !!            4.0  !  2017-06  (G. Madec)  remove explict time-stepping option
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   tra_zdf       : Update the tracer trend with the vertical diffusion
13   !!----------------------------------------------------------------------
14   USE oce            ! ocean dynamics and tracers variables
15   USE dom_oce        ! ocean space and time domain variables
16   USE domvvl         ! variable volume
17   USE phycst         ! physical constant
18   USE zdf_oce        ! ocean vertical physics variables
19   USE zdfmfc         ! Mass FLux Convection
20   USE sbc_oce        ! surface boundary condition: ocean
21   USE ldftra         ! lateral diffusion: eddy diffusivity
22   USE ldfslp         ! lateral diffusion: iso-neutral slope
23   USE trd_oce        ! trends: ocean variables
24   USE trdtra         ! trends: tracer trend manager
25   USE eosbn2, ONLY: ln_SEOS, rn_b0
26   !
27   USE in_out_manager ! I/O manager
28   USE prtctl         ! Print control
29   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
30   USE lib_mpp        ! MPP library
31   USE timing         ! Timing
32
33   IMPLICIT NONE
34   PRIVATE
35
36   PUBLIC   tra_zdf       ! called by step.F90
37   PUBLIC   tra_zdf_imp   ! called by trczdf.F90
38
39   !! * Substitutions
40#  include "do_loop_substitute.h90"
41#  include "domzgr_substitute.h90"
42   !!----------------------------------------------------------------------
43   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
44   !! $Id$
45   !! Software governed by the CeCILL license (see ./LICENSE)
46   !!----------------------------------------------------------------------
47CONTAINS
48
49   SUBROUTINE tra_zdf( kt, Kbb, Kmm, Krhs, pts, Kaa )
50      !!----------------------------------------------------------------------
51      !!                  ***  ROUTINE tra_zdf  ***
52      !!
53      !! ** Purpose :   compute the vertical ocean tracer physics.
54      !!---------------------------------------------------------------------
55      INTEGER                                  , INTENT(in)    :: kt                  ! ocean time-step index
56      INTEGER                                  , INTENT(in)    :: Kbb, Kmm, Krhs, Kaa ! time level indices
57      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts,jpt), INTENT(inout) :: pts                 ! active tracers and RHS of tracer equation
58      !
59      INTEGER  ::   ji, jj, jk   ! Dummy loop indices
60      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrdt, ztrds   ! 3D workspace
61      !!---------------------------------------------------------------------
62      !
63      IF( ln_timing )   CALL timing_start('tra_zdf')
64      !
65      IF( kt == nit000 )  THEN
66         IF( .NOT. l_istiled .OR. ntile == 1 )  THEN                   ! Do only on the first tile
67            IF(lwp)WRITE(numout,*)
68            IF(lwp)WRITE(numout,*) 'tra_zdf : implicit vertical mixing on T & S'
69            IF(lwp)WRITE(numout,*) '~~~~~~~ '
70         ENDIF
71      ENDIF
72      !
73      IF( l_trdtra )   THEN                  !* Save ta and sa trends
74         ALLOCATE( ztrdt(jpi,jpj,jpk), ztrds(jpi,jpj,jpk) )
75         ztrdt(:,:,:) = pts(:,:,:,jp_tem,Kaa)
76         ztrds(:,:,:) = pts(:,:,:,jp_sal,Kaa)
77      ENDIF
78      !
79      !                                      !* compute lateral mixing trend and add it to the general trend
80      CALL tra_zdf_imp( kt, nit000, 'TRA', rDt, Kbb, Kmm, Krhs, pts, Kaa, jpts )
81
82!!gm WHY here !   and I don't like that !
83      ! DRAKKAR SSS control {
84      ! JMM avoid negative salinities near river outlet ! Ugly fix
85      ! JMM : restore negative salinities to small salinities:
86!!jc: discard this correction in case salinity is not used in eos
87      IF ( .NOT.(ln_SEOS.AND.(rn_b0==0._wp)) ) THEN
88         WHERE( pts(A2D(0),:,jp_sal,Kaa) < 0._wp )   pts(A2D(0),:,jp_sal,Kaa) = 0.1_wp
89      ENDIF
90!!gm
91
92      IF( l_trdtra )   THEN                      ! save the vertical diffusive trends for further diagnostics
93         DO jk = 1, jpk
94            ztrdt(:,:,jk) = (   (  pts(:,:,jk,jp_tem,Kaa)*e3t(:,:,jk,Kaa)     &
95               &                 - pts(:,:,jk,jp_tem,Kbb)*e3t(:,:,jk,Kbb)  )  &
96               &              / (  e3t(:,:,jk,Kmm)*rDt  )   )                 &
97               &          - ztrdt(:,:,jk)
98            ztrds(:,:,jk) = (   (  pts(:,:,jk,jp_sal,Kaa)*e3t(:,:,jk,Kaa)     &
99               &                 - pts(:,:,jk,jp_sal,Kbb)*e3t(:,:,jk,Kbb)  )  &
100               &             / (   e3t(:,:,jk,Kmm)*rDt  )   )                 &
101               &          - ztrds(:,:,jk)
102         END DO
103!!gm this should be moved in trdtra.F90 and done on all trends
104         CALL lbc_lnk( 'trazdf', ztrdt, 'T', 1.0_wp , ztrds, 'T', 1.0_wp )
105!!gm
106         CALL trd_tra( kt, Kmm, Krhs, 'TRA', jp_tem, jptra_zdf, ztrdt )
107         CALL trd_tra( kt, Kmm, Krhs, 'TRA', jp_sal, jptra_zdf, ztrds )
108         DEALLOCATE( ztrdt , ztrds )
109      ENDIF
110      !                                          ! print mean trends (used for debugging)
111      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab3d_1=pts(:,:,:,jp_tem,Kaa), clinfo1=' zdf  - Ta: ', mask1=tmask,               &
112         &                                  tab3d_2=pts(:,:,:,jp_sal,Kaa), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
113      !
114      IF( ln_timing )   CALL timing_stop('tra_zdf')
115      !
116   END SUBROUTINE tra_zdf
117
118
119   SUBROUTINE tra_zdf_imp( kt, kit000, cdtype, p2dt, Kbb, Kmm, Krhs, pt, Kaa, kjpt )
120      !!----------------------------------------------------------------------
121      !!                  ***  ROUTINE tra_zdf_imp  ***
122      !!
123      !! ** Purpose :   Compute the after tracer through a implicit computation
124      !!     of the vertical tracer diffusion (including the vertical component
125      !!     of lateral mixing (only for 2nd order operator, for fourth order
126      !!     it is already computed and add to the general trend in traldf)
127      !!
128      !! ** Method  :  The vertical diffusion of a tracer ,t , is given by:
129      !!          difft = dz( avt dz(t) ) = 1/e3t dk+1( avt/e3w dk(t) )
130      !!      It is computed using a backward time scheme (t=after field)
131      !!      which provide directly the after tracer field.
132      !!      If ln_zdfddm=T, use avs for salinity or for passive tracers
133      !!      Surface and bottom boundary conditions: no diffusive flux on
134      !!      both tracers (bottom, applied through the masked field avt).
135      !!      If iso-neutral mixing, add to avt the contribution due to lateral mixing.
136      !!
137      !! ** Action  : - pt(:,:,:,:,Kaa)  becomes the after tracer
138      !!---------------------------------------------------------------------
139      INTEGER                                  , INTENT(in   ) ::   kt       ! ocean time-step index
140      INTEGER                                  , INTENT(in   ) ::   Kbb, Kmm, Krhs, Kaa  ! ocean time level indices
141      INTEGER                                  , INTENT(in   ) ::   kit000   ! first time step index
142      CHARACTER(len=3)                         , INTENT(in   ) ::   cdtype   ! =TRA or TRC (tracer indicator)
143      INTEGER                                  , INTENT(in   ) ::   kjpt     ! number of tracers
144      REAL(wp)                                 , INTENT(in   ) ::   p2dt     ! tracer time-step
145      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt,jpt), INTENT(inout) ::   pt       ! tracers and RHS of tracer equation
146      !
147      INTEGER  ::  ji, jj, jk, jn   ! dummy loop indices
148      REAL(wp) ::  zrhs, zzwi, zzws ! local scalars
149      REAL(wp), DIMENSION(A2D(nn_hls),jpk) ::  zwi, zwt, zwd, zws
150      !!---------------------------------------------------------------------
151      !
152      !                                               ! ============= !
153      DO jn = 1, kjpt                                 !  tracer loop  !
154         !                                            ! ============= !
155         !  Matrix construction
156         ! --------------------
157         ! Build matrix if temperature or salinity (only in double diffusion case) or first passive tracer
158         !
159         IF(  ( cdtype == 'TRA' .AND. ( jn == jp_tem .OR. ( jn == jp_sal .AND. ln_zdfddm ) ) ) .OR.   &
160            & ( cdtype == 'TRC' .AND. jn == 1 )  )  THEN
161            !
162            ! vertical mixing coef.: avt for temperature, avs for salinity and passive tracers
163            IF( cdtype == 'TRA' .AND. jn == jp_tem ) THEN
164               DO_3D( 1, 1, 1, 1, 2, jpk )
165                  zwt(ji,jj,jk) = avt(ji,jj,jk)
166               END_3D
167            ELSE
168               DO_3D( 1, 1, 1, 1, 2, jpk )
169                  zwt(ji,jj,jk) = avs(ji,jj,jk)
170               END_3D
171            ENDIF
172            zwt(:,:,1) = 0._wp
173            !
174            IF( l_ldfslp ) THEN            ! isoneutral diffusion: add the contribution
175               IF( ln_traldf_msc  ) THEN     ! MSC iso-neutral operator
176                  DO_3D( 0, 0, 0, 0, 2, jpkm1 )
177                     zwt(ji,jj,jk) = zwt(ji,jj,jk) + akz(ji,jj,jk)
178                  END_3D
179               ELSE                          ! standard or triad iso-neutral operator
180                  DO_3D( 0, 0, 0, 0, 2, jpkm1 )
181                     zwt(ji,jj,jk) = zwt(ji,jj,jk) + ah_wslp2(ji,jj,jk)
182                  END_3D
183               ENDIF
184            ENDIF
185            !
186            ! Diagonal, lower (i), upper (s)  (including the bottom boundary condition since avt is masked)
187            IF( ln_zad_Aimp ) THEN         ! Adaptive implicit vertical advection
188               DO_3D( 0, 0, 0, 0, 1, jpkm1 )
189                  zzwi = - p2dt * zwt(ji,jj,jk  ) / e3w(ji,jj,jk  ,Kmm)
190                  zzws = - p2dt * zwt(ji,jj,jk+1) / e3w(ji,jj,jk+1,Kmm)
191                  zwd(ji,jj,jk) = e3t(ji,jj,jk,Kaa) - zzwi - zzws   &
192                     &                 + p2dt * ( MAX( wi(ji,jj,jk  ) , 0._wp ) - MIN( wi(ji,jj,jk+1) , 0._wp ) )
193                  zwi(ji,jj,jk) = zzwi + p2dt *   MIN( wi(ji,jj,jk  ) , 0._wp )
194                  zws(ji,jj,jk) = zzws - p2dt *   MAX( wi(ji,jj,jk+1) , 0._wp )
195               END_3D
196            ELSE
197               DO_3D( 0, 0, 0, 0, 1, jpkm1 )
198                  zwi(ji,jj,jk) = - p2dt * zwt(ji,jj,jk  ) / e3w(ji,jj,jk,Kmm)
199                  zws(ji,jj,jk) = - p2dt * zwt(ji,jj,jk+1) / e3w(ji,jj,jk+1,Kmm)
200                  zwd(ji,jj,jk) = e3t(ji,jj,jk,Kaa) - zwi(ji,jj,jk) - zws(ji,jj,jk)
201               END_3D
202            ENDIF
203            !
204            ! Modification of diagonal to add MF scheme
205            IF ( ln_zdfmfc ) THEN
206               CALL diag_mfc( zwi, zwd, zws, p2dt, Kaa )
207            END IF
208            !
209            !! Matrix inversion from the first level
210            !!----------------------------------------------------------------------
211            !   solve m.x = y  where m is a tri diagonal matrix ( jpk*jpk )
212            !
213            !        ( zwd1 zws1   0    0    0  )( zwx1 ) ( zwy1 )
214            !        ( zwi2 zwd2 zws2   0    0  )( zwx2 ) ( zwy2 )
215            !        (  0   zwi3 zwd3 zws3   0  )( zwx3 )=( zwy3 )
216            !        (        ...               )( ...  ) ( ...  )
217            !        (  0    0    0   zwik zwdk )( zwxk ) ( zwyk )
218            !
219            !   m is decomposed in the product of an upper and lower triangular matrix.
220            !   The 3 diagonal terms are in 3d arrays: zwd, zws, zwi.
221            !   Suffices i,s and d indicate "inferior" (below diagonal), diagonal
222            !   and "superior" (above diagonal) components of the tridiagonal system.
223            !   The solution will be in the 4d array pta.
224            !   The 3d array zwt is used as a work space array.
225            !   En route to the solution pt(:,:,:,:,Kaa) is used a to evaluate the rhs and then
226            !   used as a work space array: its value is modified.
227            !
228            DO_2D( 0, 0, 0, 0 )      !* 1st recurrence:   Tk = Dk - Ik Sk-1 / Tk-1   (increasing k) ! done one for all passive tracers (so included in the IF instruction)
229               zwt(ji,jj,1) = zwd(ji,jj,1)
230            END_2D
231            DO_3D( 0, 0, 0, 0, 2, jpkm1 )
232               zwt(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) / zwt(ji,jj,jk-1)
233            END_3D
234            !
235         ENDIF
236         !
237         ! Modification of rhs to add MF scheme
238         IF ( ln_zdfmfc ) THEN
239            CALL rhs_mfc( pt(:,:,:,jn,Krhs), jn )
240         END IF
241         !
242         DO_2D( 0, 0, 0, 0 )         !* 2nd recurrence:    Zk = Yk - Ik / Tk-1  Zk-1
243            pt(ji,jj,1,jn,Kaa) =        e3t(ji,jj,1,Kbb) * pt(ji,jj,1,jn,Kbb)    &
244               &               + p2dt * e3t(ji,jj,1,Kmm) * pt(ji,jj,1,jn,Krhs)
245         END_2D
246         DO_3D( 0, 0, 0, 0, 2, jpkm1 )
247            zrhs =        e3t(ji,jj,jk,Kbb) * pt(ji,jj,jk,jn,Kbb)    &
248               & + p2dt * e3t(ji,jj,jk,Kmm) * pt(ji,jj,jk,jn,Krhs)   ! zrhs=right hand side
249            pt(ji,jj,jk,jn,Kaa) = zrhs - zwi(ji,jj,jk) / zwt(ji,jj,jk-1) * pt(ji,jj,jk-1,jn,Kaa)
250         END_3D
251         !
252         DO_2D( 0, 0, 0, 0 )         !* 3d recurrence:    Xk = (Zk - Sk Xk+1 ) / Tk   (result is the after tracer)
253            pt(ji,jj,jpkm1,jn,Kaa) = pt(ji,jj,jpkm1,jn,Kaa) / zwt(ji,jj,jpkm1) * tmask(ji,jj,jpkm1)
254         END_2D
255         DO_3DS( 0, 0, 0, 0, jpk-2, 1, -1 )
256            pt(ji,jj,jk,jn,Kaa) = ( pt(ji,jj,jk,jn,Kaa) - zws(ji,jj,jk) * pt(ji,jj,jk+1,jn,Kaa) )   &
257               &             / zwt(ji,jj,jk) * tmask(ji,jj,jk)
258         END_3D
259         !                                            ! ================= !
260      END DO                                          !  end tracer loop  !
261      !                                               ! ================= !
262   END SUBROUTINE tra_zdf_imp
263
264   !!==============================================================================
265END MODULE trazdf
Note: See TracBrowser for help on using the repository browser.