New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
zdfevd.F90 in NEMO/trunk/src/OCE/ZDF – NEMO

source: NEMO/trunk/src/OCE/ZDF/zdfevd.F90

Last change on this file was 15298, checked in by cetlod, 3 years ago

minor bugfix in zdfevd
  • Property svn:keywords set to Id
File size: 6.8 KB
Line 
1MODULE zdfevd
2   !!======================================================================
3   !!                       ***  MODULE  zdfevd  ***
4   !! Ocean physics: parameterization of convection through an enhancement
5   !!                of vertical eddy mixing coefficient
6   !!======================================================================
7   !! History :  OPA  !  1997-06  (G. Madec, A. Lazar)  Original code
8   !!   NEMO     1.0  !  2002-06  (G. Madec)  F90: Free form and module
9   !!            3.2  !  2009-03  (M. Leclair, G. Madec, R. Benshila) test on both before & after
10   !!            4.0  !  2017-04  (G. Madec)  evd applied on avm (at t-point)
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   zdf_evd       : increase the momentum and tracer Kz at the location of
15   !!                   statically unstable portion of the water column (ln_zdfevd=T)
16   !!----------------------------------------------------------------------
17   USE oce             ! ocean dynamics and tracers variables
18   USE dom_oce         ! ocean space and time domain variables
19   USE zdf_oce         ! ocean vertical physics variables
20   USE trd_oce         ! trends: ocean variables
21   USE trdtra          ! trends manager: tracers
22   !
23   USE in_out_manager  ! I/O manager
24   USE iom             ! for iom_put
25   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
26   USE timing          ! Timing
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC   zdf_evd    ! called by step.F90
32
33   !! * Substitutions
34#  include "do_loop_substitute.h90"
35   !!----------------------------------------------------------------------
36   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
37   !! $Id$
38   !! Software governed by the CeCILL license (see ./LICENSE)
39   !!----------------------------------------------------------------------
40CONTAINS
41
42   SUBROUTINE zdf_evd( kt, Kmm, Krhs, p_avm, p_avt )
43      !!----------------------------------------------------------------------
44      !!                  ***  ROUTINE zdf_evd  ***
45      !!                   
46      !! ** Purpose :   Local increased the vertical eddy viscosity and diffu-
47      !!      sivity coefficients when a static instability is encountered.
48      !!
49      !! ** Method  :   tracer (and momentum if nn_evdm=1) vertical mixing
50      !!              coefficients are set to rn_evd (namelist parameter)
51      !!              if the water column is statically unstable.
52      !!                The test of static instability is performed using
53      !!              Brunt-Vaisala frequency (rn2 < -1.e-12) of to successive
54      !!              time-step (Leap-Frog environnement): before and
55      !!              now time-step.
56      !!
57      !! ** Action  :   avt, avm   enhanced where static instability occurs
58      !!----------------------------------------------------------------------
59      INTEGER                    , INTENT(in   ) ::   kt             ! ocean time-step indexocean time step
60      INTEGER                    , INTENT(in   ) ::   Kmm, Krhs      ! time level indices
61      REAL(wp), DIMENSION(:,:,:) , INTENT(inout) ::   p_avm, p_avt   !  momentum and tracer Kz (w-points)
62      !
63      INTEGER ::   ji, jj, jk   ! dummy loop indices
64      ! NOTE: [tiling] use a SAVE array to store diagnostics, then send after all tiles are finished. This is necessary because p_avt/p_avm are modified on adjacent tiles when using nn_hls > 1. zavt_evd/zavm_evd are then zero on some points when subsequently calculated for these tiles.
65      REAL(wp), SAVE, ALLOCATABLE, DIMENSION(:,:,:) ::   zavt_evd, zavm_evd
66      !!----------------------------------------------------------------------
67      !
68      IF( .NOT. l_istiled .OR. ntile == 1 )  THEN                       ! Do only on the first tile
69         IF( kt == nit000 ) THEN
70            IF(lwp) WRITE(numout,*)
71            IF(lwp) WRITE(numout,*) 'zdf_evd : Enhanced Vertical Diffusion (evd)'
72            IF(lwp) WRITE(numout,*) '~~~~~~~ '
73            IF(lwp) WRITE(numout,*)
74         ENDIF
75
76         ALLOCATE( zavt_evd(jpi,jpj,jpk) )
77         IF( nn_evdm == 1 ) ALLOCATE( zavm_evd(jpi,jpj,jpk) )
78      ENDIF
79      !
80      !
81      DO_3D_OVR( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpk )
82         zavt_evd(ji,jj,jk) = p_avt(ji,jj,jk)         ! set avt prior to evd application
83      END_3D
84      !
85      SELECT CASE ( nn_evdm )
86      !
87      CASE ( 1 )           !==  enhance tracer & momentum Kz  ==!   (if rn2<-1.e-12)
88         !
89         DO_3D_OVR( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpk )
90            zavm_evd(ji,jj,jk) = p_avm(ji,jj,jk)      ! set avm prior to evd application
91         END_3D
92         !
93!! change last digits results
94!         WHERE( MAX( rn2(2:jpi,2:jpj,2:jpkm1), rn2b(2:jpi,2:jpj,2:jpkm1) )  <= -1.e-12 ) THEN
95!            p_avt(2:jpi,2:jpj,2:jpkm1) = rn_evd * wmask(2:jpi,2:jpj,2:jpkm1)
96!            p_avm(2:jpi,2:jpj,2:jpkm1) = rn_evd * wmask(2:jpi,2:jpj,2:jpkm1)
97!         END WHERE
98         !
99         DO_3D_OVR( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpkm1 )
100            IF(  MIN( rn2(ji,jj,jk), rn2b(ji,jj,jk) ) <= -1.e-12 ) THEN
101               p_avt(ji,jj,jk) = rn_evd * wmask(ji,jj,jk)
102               p_avm(ji,jj,jk) = rn_evd * wmask(ji,jj,jk)
103            ENDIF
104         END_3D
105         !
106         DO_3D_OVR( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpk )
107            zavm_evd(ji,jj,jk) = p_avm(ji,jj,jk) - zavm_evd(ji,jj,jk)   ! change in avm due to evd
108         END_3D
109         IF( .NOT. l_istiled .OR. ntile == nijtile ) THEN                       ! Do only on the last tile
110            CALL iom_put( "avm_evd", zavm_evd )                ! output this change
111            DEALLOCATE( zavm_evd )
112         ENDIF
113         !
114      CASE DEFAULT         !==  enhance tracer Kz  ==!   (if rn2<-1.e-12)
115!! change last digits results
116!         WHERE( MAX( rn2(2:jpi,2:jpj,2:jpkm1), rn2b(2:jpi,2:jpj,2:jpkm1) )  <= -1.e-12 )
117!            p_avt(2:jpi,2:jpj,2:jpkm1) = rn_evd * wmask(2:jpi,2:jpj,2:jpkm1)
118!         END WHERE
119
120         DO_3D_OVR( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpkm1 )
121            IF(  MIN( rn2(ji,jj,jk), rn2b(ji,jj,jk) ) <= -1.e-12 )   &
122               p_avt(ji,jj,jk) = rn_evd * wmask(ji,jj,jk)
123         END_3D
124         !
125      END SELECT 
126      !
127      DO_3D_OVR( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpk )
128         zavt_evd(ji,jj,jk) = p_avt(ji,jj,jk) - zavt_evd(ji,jj,jk)   ! change in avt due to evd
129      END_3D
130      !
131      IF( l_trdtra ) CALL trd_tra( kt, Kmm, Krhs, 'TRA', jp_tem, jptra_evd, zavt_evd )
132      !
133      IF( .NOT. l_istiled .OR. ntile == nijtile ) THEN                       ! Do only on the last tile
134         CALL iom_put( "avt_evd", zavt_evd )              ! output this change
135         DEALLOCATE( zavt_evd )
136      ENDIF
137      !
138   END SUBROUTINE zdf_evd
139
140   !!======================================================================
141END MODULE zdfevd
Note: See TracBrowser for help on using the repository browser.