New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
zdfmxl.F90 in NEMO/trunk/src/OCE/ZDF – NEMO

source: NEMO/trunk/src/OCE/ZDF/zdfmxl.F90 @ 15249

Last change on this file since 15249 was 15249, checked in by hadcv, 3 years ago

#2721: Fix SETTE debug failures
  • Property svn:keywords set to Id
File size: 8.1 KB
Line 
1MODULE zdfmxl
2   !!======================================================================
3   !!                       ***  MODULE  zdfmxl  ***
4   !! Ocean physics: mixed layer depth
5   !!======================================================================
6   !! History :  1.0  ! 2003-08  (G. Madec)  original code
7   !!            3.2  ! 2009-07  (S. Masson, G. Madec)  IOM + merge of DO-loop
8   !!            3.7  ! 2012-03  (G. Madec)  make public the density criteria for trdmxl
9   !!             -   ! 2014-02  (F. Roquet)  mixed layer depth calculated using N2 instead of rhop
10   !!----------------------------------------------------------------------
11   !!   zdf_mxl      : Compute the turbocline and mixed layer depths.
12   !!----------------------------------------------------------------------
13   USE oce            ! ocean dynamics and tracers variables
14   USE isf_oce        ! ice shelf
15   USE dom_oce        ! ocean space and time domain variables
16   USE trc_oce  , ONLY: l_offline         ! ocean space and time domain variables
17   USE zdf_oce        ! ocean vertical physics
18   !
19   USE in_out_manager ! I/O manager
20   USE prtctl         ! Print control
21   USE phycst         ! physical constants
22   USE iom            ! I/O library
23   USE lib_mpp        ! MPP library
24
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC   zdf_mxl, zdf_mxl_turb, zdf_mxl_alloc   ! called by zdfphy.F90
29
30   INTEGER , PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) ::   nmln    !: number of level in the mixed layer (used by LDF, ZDF, TRD, TOP)
31   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) ::   hmld    !: mixing layer depth (turbocline)      [m]   (used by TOP)
32   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) ::   hmlp    !: mixed layer depth  (rho=rho0+zdcrit) [m]   (used by LDF)
33   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) ::   hmlpt   !: depth of the last T-point inside the mixed layer [m] (used by LDF)
34
35   REAL(wp), PUBLIC ::   rho_c = 0.01_wp    !: density criterion for mixed layer depth
36   REAL(wp), PUBLIC ::   avt_c = 5.e-4_wp   ! Kz criterion for the turbocline depth
37
38   !! * Substitutions
39#  include "do_loop_substitute.h90"
40#  include "domzgr_substitute.h90"
41   !!----------------------------------------------------------------------
42   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
43   !! $Id$
44   !! Software governed by the CeCILL license (see ./LICENSE)
45   !!----------------------------------------------------------------------
46CONTAINS
47
48   INTEGER FUNCTION zdf_mxl_alloc()
49      !!----------------------------------------------------------------------
50      !!               ***  FUNCTION zdf_mxl_alloc  ***
51      !!----------------------------------------------------------------------
52      zdf_mxl_alloc = 0      ! set to zero if no array to be allocated
53      IF( .NOT. ALLOCATED( nmln ) ) THEN
54         ALLOCATE( nmln(jpi,jpj), hmld(jpi,jpj), hmlp(jpi,jpj), hmlpt(jpi,jpj), STAT= zdf_mxl_alloc )
55         !
56         CALL mpp_sum ( 'zdfmxl', zdf_mxl_alloc )
57         IF( zdf_mxl_alloc /= 0 )   CALL ctl_stop( 'STOP', 'zdf_mxl_alloc: failed to allocate arrays.' )
58         !
59      ENDIF
60   END FUNCTION zdf_mxl_alloc
61
62
63   SUBROUTINE zdf_mxl( kt, Kmm )
64      !!----------------------------------------------------------------------
65      !!                  ***  ROUTINE zdfmxl  ***
66      !!                   
67      !! ** Purpose :   Compute the mixed layer depth with density criteria.
68      !!
69      !! ** Method  :   The mixed layer depth is the shallowest W depth with
70      !!      the density of the corresponding T point (just bellow) bellow a
71      !!      given value defined locally as rho(10m) + rho_c
72      !!
73      !! ** Action  :   nmln, hmlp, hmlpt
74      !!----------------------------------------------------------------------
75      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
76      INTEGER, INTENT(in) ::   Kmm  ! ocean time level index
77      !
78      INTEGER  ::   ji, jj, jk      ! dummy loop indices
79      INTEGER  ::   iik, ikt        ! local integer
80      REAL(wp) ::   zN2_c           ! local scalar
81      !!----------------------------------------------------------------------
82      !
83      IF( .NOT. l_istiled .OR. ntile == 1 )  THEN                       ! Do only on the first tile
84         IF( kt == nit000 ) THEN
85            IF(lwp) WRITE(numout,*)
86            IF(lwp) WRITE(numout,*) 'zdf_mxl : mixed layer depth'
87            IF(lwp) WRITE(numout,*) '~~~~~~~ '
88         ENDIF
89      ENDIF
90      !
91      ! w-level of the mixing and mixed layers
92      DO_2D_OVR( nn_hls, nn_hls, nn_hls, nn_hls )
93         nmln(ji,jj)  = nlb10                  ! Initialization to the number of w ocean point
94         hmlp(ji,jj)  = 0._wp                  ! here hmlp used as a dummy variable, integrating vertically N^2
95      END_2D
96      zN2_c = grav * rho_c * r1_rho0      ! convert density criteria into N^2 criteria
97      DO_3D_OVR( nn_hls, nn_hls, nn_hls, nn_hls, nlb10, jpkm1 )   ! Mixed layer level: w-level
98         ikt = mbkt(ji,jj)
99         hmlp(ji,jj) =   &
100            & hmlp(ji,jj) + MAX( rn2b(ji,jj,jk) , 0._wp ) * e3w(ji,jj,jk,Kmm)
101         IF( hmlp(ji,jj) < zN2_c )   nmln(ji,jj) = MIN( jk , ikt ) + 1   ! Mixed layer level
102      END_3D
103      ! depth of the mixed layer
104      DO_2D_OVR( nn_hls, nn_hls, nn_hls, nn_hls )
105         iik = nmln(ji,jj)
106         hmlp (ji,jj) = gdepw(ji,jj,iik  ,Kmm) * ssmask(ji,jj)    ! Mixed layer depth
107         hmlpt(ji,jj) = gdept(ji,jj,iik-1,Kmm) * ssmask(ji,jj)    ! depth of the last T-point inside the mixed layer
108      END_2D
109      !
110      IF( .NOT.l_offline .AND. iom_use("mldr10_1") ) THEN
111         IF( .NOT. l_istiled .OR. ntile == nijtile ) THEN         ! Do only on the last tile
112            IF( ln_isfcav ) THEN  ;  CALL iom_put( "mldr10_1", hmlp - risfdep)   ! mixed layer thickness
113            ELSE                  ;  CALL iom_put( "mldr10_1", hmlp )            ! mixed layer depth
114            END IF
115         ENDIF
116      ENDIF
117      !
118      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab2d_1=REAL(nmln,wp), clinfo1=' nmln : ', tab2d_2=hmlp, clinfo2=' hmlp : ' )
119      !
120   END SUBROUTINE zdf_mxl
121
122
123   SUBROUTINE zdf_mxl_turb( kt, Kmm )
124      !!----------------------------------------------------------------------
125      !!                  ***  ROUTINE zdf_mxl_turb  ***
126      !!
127      !! ** Purpose :   Compute the turbocline depth.
128      !!
129      !! ** Method  :   The turbocline depth is the depth at which the vertical
130      !!      eddy diffusivity coefficient (resulting from the vertical physics
131      !!      alone, not the isopycnal part, see trazdf.F) fall below a given
132      !!      value defined locally (avt_c here taken equal to 5 cm/s2 by default)
133      !!
134      !! ** Action  :   hmld
135      !!----------------------------------------------------------------------
136      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
137      INTEGER, INTENT(in) ::   Kmm  ! ocean time level index
138      !
139      INTEGER  ::   ji, jj, jk      ! dummy loop indices
140      INTEGER  ::   iik             ! local integer
141      INTEGER, DIMENSION(A2D(nn_hls)) ::   imld   ! 2D workspace
142      !!----------------------------------------------------------------------
143      !
144      ! w-level of the turbocline and mixing layer (iom_use)
145      imld(:,:) = mbkt(A2D(nn_hls)) + 1                ! Initialization to the number of w ocean point
146      DO_3DS( 1, 1, 1, 1, jpkm1, nlb10, -1 )   ! from the bottom to nlb10
147         IF( avt (ji,jj,jk) < avt_c * wmask(ji,jj,jk) )   imld(ji,jj) = jk      ! Turbocline
148      END_3D
149      ! depth of the mixing layer
150      DO_2D_OVR( 1, 1, 1, 1 )
151         iik = imld(ji,jj)
152         hmld (ji,jj) = gdepw(ji,jj,iik  ,Kmm) * ssmask(ji,jj)    ! Turbocline depth
153      END_2D
154      !
155      IF( .NOT.l_offline .AND. iom_use("mldkz5") ) THEN
156         IF( .NOT. l_istiled .OR. ntile == nijtile ) THEN         ! Do only on the last tile
157            IF( ln_isfcav ) THEN  ;  CALL iom_put( "mldkz5"  , hmld - risfdep )   ! turbocline thickness
158            ELSE                  ;  CALL iom_put( "mldkz5"  , hmld )             ! turbocline depth
159            END IF
160         ENDIF
161      ENDIF
162      !
163   END SUBROUTINE zdf_mxl_turb
164   !!======================================================================
165END MODULE zdfmxl
Note: See TracBrowser for help on using the repository browser.