source: NEMO/trunk/src/OCE/nemogcm.F90 @ 12206

Last change on this file since 12206 was 12206, checked in by smasson, 15 months ago

trunk: supress diatmb as it was bugged and already coded in diawri, see #1759

  • Property svn:keywords set to Id
File size: 35.1 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Ocean system   : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5   !!======================================================================
6   !! History :  OPA  ! 1990-10  (C. Levy, G. Madec)  Original code
7   !!            7.0  ! 1991-11  (M. Imbard, C. Levy, G. Madec)
8   !!            7.1  ! 1993-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9   !!                             P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10   !!             -   ! 1992-06  (L.Terray)  coupling implementation
11   !!             -   ! 1993-11  (M.A. Filiberti) IGLOO sea-ice
12   !!            8.0  ! 1996-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13   !!                             P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14   !!            8.1  ! 1997-06  (M. Imbard, G. Madec)
15   !!            8.2  ! 1999-11  (M. Imbard, H. Goosse)  sea-ice model
16   !!                 ! 1999-12  (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols)  OPEN-MP
17   !!                 ! 2000-07  (J-M Molines, M. Imbard)  Open Boundary Conditions  (CLIPPER)
18   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and modules
19   !!             -   ! 2004-06  (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20   !!             -   ! 2004-08  (C. Talandier) New trends organization
21   !!             -   ! 2005-06  (C. Ethe) Add the 1D configuration possibility
22   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
23   !!             -   ! 2006-03  (L. Debreu, C. Mazauric)  Agrif implementation
24   !!             -   ! 2006-04  (G. Madec, R. Benshila)  Step reorganization
25   !!             -   ! 2007-07  (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26   !!            3.2  ! 2009-08  (S. Masson)  open/write in the listing file in mpp
27   !!            3.3  ! 2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28   !!             -   ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
29   !!            3.3.1! 2011-01  (A. R. Porter, STFC Daresbury) dynamical allocation
30   !!             -   ! 2011-11  (C. Harris) decomposition changes for running with CICE
31   !!            3.6  ! 2012-05  (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
32   !!             -   ! 2014-12  (G. Madec) remove KPP scheme and cross-land advection (cla)
33   !!            4.0  ! 2016-10  (G. Madec, S. Flavoni)  domain configuration / user defined interface
34   !!----------------------------------------------------------------------
35
36   !!----------------------------------------------------------------------
37   !!   nemo_gcm      : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
38   !!   nemo_init     : initialization of the NEMO system
39   !!   nemo_ctl      : initialisation of the contol print
40   !!   nemo_closefile: close remaining open files
41   !!   nemo_alloc    : dynamical allocation
42   !!----------------------------------------------------------------------
43   USE step_oce       ! module used in the ocean time stepping module (step.F90)
44   USE phycst         ! physical constant                  (par_cst routine)
45   USE domain         ! domain initialization   (dom_init & dom_cfg routines)
46   USE closea         ! treatment of closed seas (for ln_closea)
47   USE usrdef_nam     ! user defined configuration
48   USE tideini        ! tidal components initialization   (tide_ini routine)
49   USE bdy_oce,  ONLY : ln_bdy
50   USE bdyini         ! open boundary cond. setting       (bdy_init routine)
51   USE istate         ! initial state setting          (istate_init routine)
52   USE ldfdyn         ! lateral viscosity setting      (ldfdyn_init routine)
53   USE ldftra         ! lateral diffusivity setting    (ldftra_init routine)
54   USE trdini         ! dyn/tra trends initialization     (trd_init routine)
55   USE asminc         ! assimilation increments     
56   USE asmbkg         ! writing out state trajectory
57   USE diaptr         ! poleward transports           (dia_ptr_init routine)
58   USE diadct         ! sections transports           (dia_dct_init routine)
59   USE diaobs         ! Observation diagnostics       (dia_obs_init routine)
60   USE diacfl         ! CFL diagnostics               (dia_cfl_init routine)
61   USE diaharm        ! tidal harmonics diagnostics  (dia_harm_init routine)
62   USE step           ! NEMO time-stepping                 (stp     routine)
63   USE icbini         ! handle bergs, initialisation
64   USE icbstp         ! handle bergs, calving, themodynamics and transport
65   USE cpl_oasis3     ! OASIS3 coupling
66   USE c1d            ! 1D configuration
67   USE step_c1d       ! Time stepping loop for the 1D configuration
68   USE dyndmp         ! Momentum damping
69   USE stopar         ! Stochastic param.: ???
70   USE stopts         ! Stochastic param.: ???
71   USE diurnal_bulk   ! diurnal bulk SST
72   USE step_diu       ! diurnal bulk SST timestepping (called from here if run offline)
73   USE crsini         ! initialise grid coarsening utility
74   USE sbc_oce , ONLY : lk_oasis
75   USE wet_dry        ! Wetting and drying setting   (wad_init routine)
76#if defined key_top
77   USE trcini         ! passive tracer initialisation
78#endif
79#if defined key_nemocice_decomp
80   USE ice_domain_size, only: nx_global, ny_global
81#endif
82   !
83   USE lib_mpp        ! distributed memory computing
84   USE mppini         ! shared/distributed memory setting (mpp_init routine)
85   USE lbcnfd  , ONLY : isendto, nsndto, nfsloop, nfeloop   ! Setup of north fold exchanges
86   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
87#if defined key_iomput
88   USE xios           ! xIOserver
89#endif
90#if defined key_agrif
91   USE agrif_all_update   ! Master Agrif update
92#endif
93
94   IMPLICIT NONE
95   PRIVATE
96
97   PUBLIC   nemo_gcm    ! called by model.F90
98   PUBLIC   nemo_init   ! needed by AGRIF
99   PUBLIC   nemo_alloc  ! needed by TAM
100
101   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
102
103#if defined key_mpp_mpi
104   ! need MPI_Wtime
105   INCLUDE 'mpif.h'
106#endif
107
108   !!----------------------------------------------------------------------
109   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
110   !! $Id$
111   !! Software governed by the CeCILL license (see ./LICENSE)
112   !!----------------------------------------------------------------------
113CONTAINS
114
115   SUBROUTINE nemo_gcm
116      !!----------------------------------------------------------------------
117      !!                     ***  ROUTINE nemo_gcm  ***
118      !!
119      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
120      !!              curvilinear mesh on the sphere.
121      !!
122      !! ** Method  : - model general initialization
123      !!              - launch the time-stepping (stp routine)
124      !!              - finalize the run by closing files and communications
125      !!
126      !! References : Madec, Delecluse, Imbard, and Levy, 1997:  internal report, IPSL.
127      !!              Madec, 2008, internal report, IPSL.
128      !!----------------------------------------------------------------------
129      INTEGER ::   istp   ! time step index
130      REAL(wp)::   zstptiming   ! elapsed time for 1 time step
131      !!----------------------------------------------------------------------
132      !
133#if defined key_agrif
134      CALL Agrif_Init_Grids()      ! AGRIF: set the meshes
135#endif
136      !                            !-----------------------!
137      CALL nemo_init               !==  Initialisations  ==!
138      !                            !-----------------------!
139#if defined key_agrif
140      CALL Agrif_Declare_Var_dom   ! AGRIF: set the meshes for DOM
141      CALL Agrif_Declare_Var       !  "      "   "   "      "  DYN/TRA
142# if defined key_top
143      CALL Agrif_Declare_Var_top   !  "      "   "   "      "  TOP
144# endif
145# if defined key_si3
146      CALL Agrif_Declare_Var_ice   !  "      "   "   "      "  Sea ice
147# endif
148#endif
149      ! check that all process are still there... If some process have an error,
150      ! they will never enter in step and other processes will wait until the end of the cpu time!
151      CALL mpp_max( 'nemogcm', nstop )
152
153      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
154
155      !                            !-----------------------!
156      !                            !==   time stepping   ==!
157      !                            !-----------------------!
158      istp = nit000
159      !
160#if defined key_c1d
161      DO WHILE ( istp <= nitend .AND. nstop == 0 )    !==  C1D time-stepping  ==!
162         CALL stp_c1d( istp )
163         istp = istp + 1
164      END DO
165#else
166      !
167# if defined key_agrif
168      !                                               !==  AGRIF time-stepping  ==!
169      CALL Agrif_Regrid()
170      !
171      ! Recursive update from highest nested level to lowest:
172      CALL Agrif_step_child_adj(Agrif_Update_All)
173      !
174      DO WHILE( istp <= nitend .AND. nstop == 0 )
175         CALL stp
176         istp = istp + 1
177      END DO
178      !
179      IF( .NOT. Agrif_Root() ) THEN
180         CALL Agrif_ParentGrid_To_ChildGrid()
181         IF( ln_diaobs )   CALL dia_obs_wri
182         IF( ln_timing )   CALL timing_finalize
183         CALL Agrif_ChildGrid_To_ParentGrid()
184      ENDIF
185      !
186# else
187      !
188      IF( .NOT.ln_diurnal_only ) THEN                 !==  Standard time-stepping  ==!
189         !
190         DO WHILE( istp <= nitend .AND. nstop == 0 )
191
192            ncom_stp = istp
193            IF( ln_timing ) THEN
194               zstptiming = MPI_Wtime()
195               IF ( istp == ( nit000 + 1 ) ) elapsed_time = zstptiming
196               IF ( istp ==         nitend ) elapsed_time = zstptiming - elapsed_time
197            ENDIF
198           
199            CALL stp        ( istp ) 
200            istp = istp + 1
201
202            IF( lwp .AND. ln_timing )   WRITE(numtime,*) 'timing step ', istp-1, ' : ', MPI_Wtime() - zstptiming
203
204         END DO
205         !
206      ELSE                                            !==  diurnal SST time-steeping only  ==!
207         !
208         DO WHILE( istp <= nitend .AND. nstop == 0 )
209            CALL stp_diurnal( istp )   ! time step only the diurnal SST
210            istp = istp + 1
211         END DO
212         !
213      ENDIF
214      !
215# endif
216      !
217#endif
218      !
219      IF( ln_diaobs   )   CALL dia_obs_wri
220      !
221      IF( ln_icebergs )   CALL icb_end( nitend )
222
223      !                            !------------------------!
224      !                            !==  finalize the run  ==!
225      !                            !------------------------!
226      IF(lwp) WRITE(numout,cform_aaa)        ! Flag AAAAAAA
227      !
228      IF( nstop /= 0 .AND. lwp ) THEN        ! error print
229         WRITE(ctmp1,*) '   ==>>>   nemo_gcm: a total of ', nstop, ' errors have been found'
230         CALL ctl_stop( ctmp1 )
231      ENDIF
232      !
233      IF( ln_timing )   CALL timing_finalize
234      !
235      CALL nemo_closefile
236      !
237#if defined key_iomput
238                                    CALL xios_finalize  ! end mpp communications with xios
239      IF( lk_oasis     )            CALL cpl_finalize   ! end coupling and mpp communications with OASIS
240#else
241      IF    ( lk_oasis ) THEN   ;   CALL cpl_finalize   ! end coupling and mpp communications with OASIS
242      ELSEIF( lk_mpp   ) THEN   ;   CALL mppstop      ! end mpp communications
243      ENDIF
244#endif
245      !
246      IF(lwm) THEN
247         IF( nstop == 0 ) THEN   ;   STOP 0
248         ELSE                    ;   STOP 123
249         ENDIF
250      ENDIF
251      !
252   END SUBROUTINE nemo_gcm
253
254
255   SUBROUTINE nemo_init
256      !!----------------------------------------------------------------------
257      !!                     ***  ROUTINE nemo_init  ***
258      !!
259      !! ** Purpose :   initialization of the NEMO GCM
260      !!----------------------------------------------------------------------
261      INTEGER ::   ios, ilocal_comm   ! local integers
262      !!
263      NAMELIST/namctl/ ln_ctl   , sn_cfctl, nn_print, nn_ictls, nn_ictle,   &
264         &             nn_isplt , nn_jsplt, nn_jctls, nn_jctle,             &
265         &             ln_timing, ln_diacfl
266      NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr
267      !!----------------------------------------------------------------------
268      !
269      cxios_context = 'nemo'
270      !
271      !                             !-------------------------------------------------!
272      !                             !     set communicator & select the local rank    !
273      !                             !  must be done as soon as possible to get narea  !
274      !                             !-------------------------------------------------!
275      !
276#if defined key_iomput
277      IF( Agrif_Root() ) THEN
278         IF( lk_oasis ) THEN
279            CALL cpl_init( "oceanx", ilocal_comm )                               ! nemo local communicator given by oasis
280            CALL xios_initialize( "not used"       , local_comm =ilocal_comm )   ! send nemo communicator to xios
281         ELSE
282            CALL xios_initialize( "for_xios_mpi_id", return_comm=ilocal_comm )   ! nemo local communicator given by xios
283         ENDIF
284      ENDIF
285      CALL mpp_start( ilocal_comm )
286#else
287      IF( lk_oasis ) THEN
288         IF( Agrif_Root() ) THEN
289            CALL cpl_init( "oceanx", ilocal_comm )          ! nemo local communicator given by oasis
290         ENDIF
291         CALL mpp_start( ilocal_comm )
292      ELSE
293         CALL mpp_start( )
294      ENDIF
295#endif
296      !
297      narea = mpprank + 1               ! mpprank: the rank of proc (0 --> mppsize -1 )
298      lwm = (narea == 1)                ! control of output namelists
299      !
300      !                             !---------------------------------------------------------------!
301      !                             ! Open output files, reference and configuration namelist files !
302      !                             !---------------------------------------------------------------!
303      !
304      ! open ocean.output as soon as possible to get all output prints (including errors messages)
305      IF( lwm )   CALL ctl_opn(     numout,        'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
306      ! open reference and configuration namelist files
307                  CALL ctl_opn( numnam_ref,        'namelist_ref',     'OLD', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
308                  CALL ctl_opn( numnam_cfg,        'namelist_cfg',     'OLD', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
309      IF( lwm )   CALL ctl_opn(     numond, 'output.namelist.dyn', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
310      ! open /dev/null file to be able to supress output write easily
311                  CALL ctl_opn(     numnul,           '/dev/null', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
312      !
313      !                             !--------------------!
314      !                             ! Open listing units !  -> need ln_ctl from namctl to define lwp
315      !                             !--------------------!
316      !
317      REWIND( numnam_ref )              ! Namelist namctl in reference namelist
318      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
319901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namctl in reference namelist' )
320      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist
321      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
322902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namctl in configuration namelist' )
323      !
324      lwp = (narea == 1) .OR. ln_ctl    ! control of all listing output print
325      !
326      IF(lwp) THEN                      ! open listing units
327         !
328         IF( .NOT. lwm )   &            ! alreay opened for narea == 1
329            &            CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE., narea )
330         !
331         WRITE(numout,*)
332         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - CMCC'
333         WRITE(numout,*) '                       NEMO team'
334         WRITE(numout,*) '            Ocean General Circulation Model'
335         WRITE(numout,*) '                NEMO version 4.0  (2019) '
336         WRITE(numout,*)
337         WRITE(numout,*) "           ._      ._      ._      ._      ._    "
338         WRITE(numout,*) "       _.-._)`\_.-._)`\_.-._)`\_.-._)`\_.-._)`\_ "
339         WRITE(numout,*)
340         WRITE(numout,*) "           o         _,           _,             "
341         WRITE(numout,*) "            o      .' (        .-' /             "
342         WRITE(numout,*) "           o     _/..._'.    .'   /              "
343         WRITE(numout,*) "      (    o .-'`      ` '-./  _.'               "
344         WRITE(numout,*) "       )    ( o)           ;= <_         (       "
345         WRITE(numout,*) "      (      '-.,\\__ __.-;`\   '.        )      "
346         WRITE(numout,*) "       )  )       \) |`\ \)  '.   \      (   (   "
347         WRITE(numout,*) "      (  (           \_/       '-._\      )   )  "
348         WRITE(numout,*) "       )  ) jgs                     `    (   (   "
349         WRITE(numout,*) "     ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ "
350         WRITE(numout,*)
351         !
352         WRITE(numout,cform_aaa)                                        ! Flag AAAAAAA
353         !
354      ENDIF
355      !
356      ! finalize the definition of namctl variables
357      IF( sn_cfctl%l_config ) THEN
358         ! Activate finer control of report outputs
359         ! optionally switch off output from selected areas (note this only
360         ! applies to output which does not involve global communications)
361         IF( ( narea < sn_cfctl%procmin .OR. narea > sn_cfctl%procmax  ) .OR. &
362           & ( MOD( narea - sn_cfctl%procmin, sn_cfctl%procincr ) /= 0 ) )    &
363           &   CALL nemo_set_cfctl( sn_cfctl, .FALSE., .FALSE. )
364      ELSE
365         ! Use ln_ctl to turn on or off all options.
366         CALL nemo_set_cfctl( sn_cfctl, ln_ctl, .TRUE. )
367      ENDIF
368      !
369      IF(lwm) WRITE( numond, namctl )
370      !
371      !                             !------------------------------------!
372      !                             !  Set global domain size parameters !
373      !                             !------------------------------------!
374      !
375      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist
376      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
377903   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namcfg in reference namelist' )
378      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist
379      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
380904   IF( ios >  0 )   CALL ctl_nam ( ios , 'namcfg in configuration namelist' )   
381      !
382      IF( ln_read_cfg ) THEN            ! Read sizes in domain configuration file
383         CALL domain_cfg ( cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
384      ELSE                              ! user-defined namelist
385         CALL usr_def_nam( cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
386      ENDIF
387      !
388      IF(lwm)   WRITE( numond, namcfg )
389      !
390      !                             !-----------------------------------------!
391      !                             ! mpp parameters and domain decomposition !
392      !                             !-----------------------------------------!
393      CALL mpp_init
394
395      ! Now we know the dimensions of the grid and numout has been set: we can allocate arrays
396      CALL nemo_alloc()
397
398      !                             !-------------------------------!
399      !                             !  NEMO general initialization  !
400      !                             !-------------------------------!
401
402      CALL nemo_ctl                          ! Control prints
403      !
404      !                                      ! General initialization
405      IF( ln_timing    )   CALL timing_init     ! timing
406      IF( ln_timing    )   CALL timing_start( 'nemo_init')
407      !
408                           CALL     phy_cst         ! Physical constants
409                           CALL     eos_init        ! Equation of state
410      IF( lk_c1d       )   CALL     c1d_init        ! 1D column configuration
411                           CALL     wad_init        ! Wetting and drying options
412                           CALL     dom_init("OPA") ! Domain
413      IF( ln_crs       )   CALL     crs_init        ! coarsened grid: domain initialization
414      IF( ln_ctl       )   CALL prt_ctl_init        ! Print control
415     
416      CALL diurnal_sst_bulk_init                ! diurnal sst
417      IF( ln_diurnal   )   CALL diurnal_sst_coolskin_init   ! cool skin   
418      !                           
419      IF( ln_diurnal_only ) THEN                   ! diurnal only: a subset of the initialisation routines
420         CALL  istate_init                            ! ocean initial state (Dynamics and tracers)
421         CALL     sbc_init                            ! Forcings : surface module
422         CALL tra_qsr_init                            ! penetrative solar radiation qsr
423         IF( ln_diaobs ) THEN                         ! Observation & model comparison
424            CALL dia_obs_init                            ! Initialize observational data
425            CALL dia_obs( nit000 - 1 )                   ! Observation operator for restart
426         ENDIF     
427         IF( lk_asminc )   CALL asm_inc_init          ! Assimilation increments
428         !
429         RETURN                                       ! end of initialization
430      ENDIF
431     
432                           CALL  istate_init    ! ocean initial state (Dynamics and tracers)
433
434      !                                      ! external forcing
435                           CALL    tide_init    ! tidal harmonics
436                           CALL     sbc_init    ! surface boundary conditions (including sea-ice)
437                           CALL     bdy_init    ! Open boundaries initialisation
438
439      !                                      ! Ocean physics
440                           CALL zdf_phy_init    ! Vertical physics
441                                     
442      !                                         ! Lateral physics
443                           CALL ldf_tra_init      ! Lateral ocean tracer physics
444                           CALL ldf_eiv_init      ! eddy induced velocity param.
445                           CALL ldf_dyn_init      ! Lateral ocean momentum physics
446
447      !                                      ! Active tracers
448      IF( ln_traqsr    )   CALL tra_qsr_init      ! penetrative solar radiation qsr
449                           CALL tra_bbc_init      ! bottom heat flux
450                           CALL tra_bbl_init      ! advective (and/or diffusive) bottom boundary layer scheme
451                           CALL tra_dmp_init      ! internal tracer damping
452                           CALL tra_adv_init      ! horizontal & vertical advection
453                           CALL tra_ldf_init      ! lateral mixing
454
455      !                                      ! Dynamics
456      IF( lk_c1d       )   CALL dyn_dmp_init      ! internal momentum damping
457                           CALL dyn_adv_init      ! advection (vector or flux form)
458                           CALL dyn_vor_init      ! vorticity term including Coriolis
459                           CALL dyn_ldf_init      ! lateral mixing
460                           CALL dyn_hpg_init      ! horizontal gradient of Hydrostatic pressure
461                           CALL dyn_spg_init      ! surface pressure gradient
462
463#if defined key_top
464      !                                      ! Passive tracers
465                           CALL     trc_init
466#endif
467      IF( l_ldfslp     )   CALL ldf_slp_init    ! slope of lateral mixing
468
469      !                                      ! Icebergs
470                           CALL icb_init( rdt, nit000)   ! initialise icebergs instance
471
472      !                                      ! Misc. options
473                           CALL sto_par_init    ! Stochastic parametrization
474      IF( ln_sto_eos   )   CALL sto_pts_init    ! RRandom T/S fluctuations
475     
476      !                                      ! Diagnostics
477                           CALL     flo_init    ! drifting Floats
478      IF( ln_diacfl    )   CALL dia_cfl_init    ! Initialise CFL diagnostics
479                           CALL dia_ptr_init    ! Poleward TRansports initialization
480                           CALL dia_dct_init    ! Sections tranports
481                           CALL dia_hsb_init    ! heat content, salt content and volume budgets
482                           CALL     trd_init    ! Mixed-layer/Vorticity/Integral constraints trends
483                           CALL dia_obs_init    ! Initialize observational data
484                           CALL dia_25h_init    ! 25h mean  outputs
485                           CALL dia_harm_init   ! tidal harmonics outputs
486     IF( ln_diaobs    )    CALL dia_obs( nit000-1 )   ! Observation operator for restart
487
488      !                                      ! Assimilation increments
489      IF( lk_asminc    )   CALL asm_inc_init    ! Initialize assimilation increments
490      !
491      IF(lwp) WRITE(numout,cform_aaa)           ! Flag AAAAAAA
492      !
493      IF( ln_timing    )   CALL timing_stop( 'nemo_init')
494      !
495   END SUBROUTINE nemo_init
496
497
498   SUBROUTINE nemo_ctl
499      !!----------------------------------------------------------------------
500      !!                     ***  ROUTINE nemo_ctl  ***
501      !!
502      !! ** Purpose :   control print setting
503      !!
504      !! ** Method  : - print namctl and namcfg information and check some consistencies
505      !!----------------------------------------------------------------------
506      !
507      IF(lwp) THEN                  ! control print
508         WRITE(numout,*)
509         WRITE(numout,*) 'nemo_ctl: Control prints'
510         WRITE(numout,*) '~~~~~~~~'
511         WRITE(numout,*) '   Namelist namctl'
512         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
513         WRITE(numout,*) '       finer control over o/p sn_cfctl%l_config  = ', sn_cfctl%l_config
514         WRITE(numout,*) '                              sn_cfctl%l_runstat = ', sn_cfctl%l_runstat
515         WRITE(numout,*) '                              sn_cfctl%l_trcstat = ', sn_cfctl%l_trcstat
516         WRITE(numout,*) '                              sn_cfctl%l_oceout  = ', sn_cfctl%l_oceout
517         WRITE(numout,*) '                              sn_cfctl%l_layout  = ', sn_cfctl%l_layout
518         WRITE(numout,*) '                              sn_cfctl%l_mppout  = ', sn_cfctl%l_mppout
519         WRITE(numout,*) '                              sn_cfctl%l_mpptop  = ', sn_cfctl%l_mpptop
520         WRITE(numout,*) '                              sn_cfctl%procmin   = ', sn_cfctl%procmin 
521         WRITE(numout,*) '                              sn_cfctl%procmax   = ', sn_cfctl%procmax 
522         WRITE(numout,*) '                              sn_cfctl%procincr  = ', sn_cfctl%procincr 
523         WRITE(numout,*) '                              sn_cfctl%ptimincr  = ', sn_cfctl%ptimincr 
524         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
525         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
526         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
527         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
528         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
529         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
530         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
531         WRITE(numout,*) '      timing by routine               ln_timing  = ', ln_timing
532         WRITE(numout,*) '      CFL diagnostics                 ln_diacfl  = ', ln_diacfl
533      ENDIF
534      !
535      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
536      nictls    = nn_ictls
537      nictle    = nn_ictle
538      njctls    = nn_jctls
539      njctle    = nn_jctle
540      isplt     = nn_isplt
541      jsplt     = nn_jsplt
542
543      IF(lwp) THEN                  ! control print
544         WRITE(numout,*)
545         WRITE(numout,*) '   Namelist namcfg'
546         WRITE(numout,*) '      read domain configuration file                ln_read_cfg      = ', ln_read_cfg
547         WRITE(numout,*) '         filename to be read                           cn_domcfg     = ', TRIM(cn_domcfg)
548         WRITE(numout,*) '         keep closed seas in the domain (if exist)     ln_closea     = ', ln_closea
549         WRITE(numout,*) '      create a configuration definition file        ln_write_cfg     = ', ln_write_cfg
550         WRITE(numout,*) '         filename to be written                        cn_domcfg_out = ', TRIM(cn_domcfg_out)
551         WRITE(numout,*) '      use file attribute if exists as i/p j-start   ln_use_jattr     = ', ln_use_jattr
552      ENDIF
553      IF( .NOT.ln_read_cfg )   ln_closea = .false.   ! dealing possible only with a domcfg file
554      !
555      !                             ! Parameter control
556      !
557      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
558         IF( lk_mpp .AND. jpnij > 1 ) THEN
559            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
560         ELSE
561            IF( isplt == 1 .AND. jsplt == 1  ) THEN
562               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
563                  &           ' - the print control will be done over the whole domain' )
564            ENDIF
565            ijsplt = isplt * jsplt            ! total number of processors ijsplt
566         ENDIF
567         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
568         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
569         !
570         !                              ! indices used for the SUM control
571         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
572            lsp_area = .FALSE.
573         ELSE                                             ! print control done over a specific  area
574            lsp_area = .TRUE.
575            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
576               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
577               nictls = 1
578            ENDIF
579            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
580               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
581               nictle = jpiglo
582            ENDIF
583            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
584               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
585               njctls = 1
586            ENDIF
587            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
588               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
589               njctle = jpjglo
590            ENDIF
591         ENDIF
592      ENDIF
593      !
594      IF( 1._wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.',  &
595         &                                                'Compile with key_nosignedzero enabled:',   &
596         &                                                '--> add -Dkey_nosignedzero to the definition of %CPP in your arch file' )
597      !
598#if defined key_agrif
599      IF( ln_timing )   CALL ctl_stop( 'AGRIF not implemented with ln_timing = true')
600#endif
601      !
602   END SUBROUTINE nemo_ctl
603
604
605   SUBROUTINE nemo_closefile
606      !!----------------------------------------------------------------------
607      !!                     ***  ROUTINE nemo_closefile  ***
608      !!
609      !! ** Purpose :   Close the files
610      !!----------------------------------------------------------------------
611      !
612      IF( lk_mpp )   CALL mppsync
613      !
614      CALL iom_close                                 ! close all input/output files managed by iom_*
615      !
616      IF( numstp          /= -1 )   CLOSE( numstp          )   ! time-step file
617      IF( numrun          /= -1 )   CLOSE( numrun          )   ! run statistics file
618      IF( numnam_ref      /= -1 )   CLOSE( numnam_ref      )   ! oce reference namelist
619      IF( numnam_cfg      /= -1 )   CLOSE( numnam_cfg      )   ! oce configuration namelist
620      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
621      IF( numnam_ice_ref  /= -1 )   CLOSE( numnam_ice_ref  )   ! ice reference namelist
622      IF( numnam_ice_cfg  /= -1 )   CLOSE( numnam_ice_cfg  )   ! ice configuration namelist
623      IF( lwm.AND.numoni  /= -1 )   CLOSE( numoni          )   ! ice output namelist
624      IF( numevo_ice      /= -1 )   CLOSE( numevo_ice      )   ! ice variables (temp. evolution)
625      IF( numout          /=  6 )   CLOSE( numout          )   ! standard model output file
626      IF( numdct_vol      /= -1 )   CLOSE( numdct_vol      )   ! volume transports
627      IF( numdct_heat     /= -1 )   CLOSE( numdct_heat     )   ! heat transports
628      IF( numdct_salt     /= -1 )   CLOSE( numdct_salt     )   ! salt transports
629      !
630      numout = 6                                     ! redefine numout in case it is used after this point...
631      !
632   END SUBROUTINE nemo_closefile
633
634
635   SUBROUTINE nemo_alloc
636      !!----------------------------------------------------------------------
637      !!                     ***  ROUTINE nemo_alloc  ***
638      !!
639      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
640      !!
641      !! ** Method  :
642      !!----------------------------------------------------------------------
643      USE diawri    , ONLY : dia_wri_alloc
644      USE dom_oce   , ONLY : dom_oce_alloc
645      USE trc_oce   , ONLY : trc_oce_alloc
646      USE bdy_oce   , ONLY : bdy_oce_alloc
647      !
648      INTEGER :: ierr
649      !!----------------------------------------------------------------------
650      !
651      ierr =        oce_alloc    ()    ! ocean
652      ierr = ierr + dia_wri_alloc()
653      ierr = ierr + dom_oce_alloc()    ! ocean domain
654      ierr = ierr + zdf_oce_alloc()    ! ocean vertical physics
655      ierr = ierr + trc_oce_alloc()    ! shared TRC / TRA arrays
656      ierr = ierr + bdy_oce_alloc()    ! bdy masks (incl. initialization)
657      !
658      CALL mpp_sum( 'nemogcm', ierr )
659      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' )
660      !
661   END SUBROUTINE nemo_alloc
662
663   
664   SUBROUTINE nemo_set_cfctl(sn_cfctl, setto, for_all )
665      !!----------------------------------------------------------------------
666      !!                     ***  ROUTINE nemo_set_cfctl  ***
667      !!
668      !! ** Purpose :   Set elements of the output control structure to setto.
669      !!                for_all should be .false. unless all areas are to be
670      !!                treated identically.
671      !!
672      !! ** Method  :   Note this routine can be used to switch on/off some
673      !!                types of output for selected areas but any output types
674      !!                that involve global communications (e.g. mpp_max, glob_sum)
675      !!                should be protected from selective switching by the
676      !!                for_all argument
677      !!----------------------------------------------------------------------
678      LOGICAL :: setto, for_all
679      TYPE(sn_ctl) :: sn_cfctl
680      !!----------------------------------------------------------------------
681      IF( for_all ) THEN
682         sn_cfctl%l_runstat = setto
683         sn_cfctl%l_trcstat = setto
684      ENDIF
685      sn_cfctl%l_oceout  = setto
686      sn_cfctl%l_layout  = setto
687      sn_cfctl%l_mppout  = setto
688      sn_cfctl%l_mpptop  = setto
689   END SUBROUTINE nemo_set_cfctl
690
691   !!======================================================================
692END MODULE nemogcm
693
Note: See TracBrowser for help on using the repository browser.