| 1 | MODULE nemogcm |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE nemogcm *** |
|---|
| 4 | !! Ocean system : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice) |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : OPA ! 1990-10 (C. Levy, G. Madec) Original code |
|---|
| 7 | !! 7.0 ! 1991-11 (M. Imbard, C. Levy, G. Madec) |
|---|
| 8 | !! 7.1 ! 1993-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar, |
|---|
| 9 | !! P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1 |
|---|
| 10 | !! - ! 1992-06 (L.Terray) coupling implementation |
|---|
| 11 | !! - ! 1993-11 (M.A. Filiberti) IGLOO sea-ice |
|---|
| 12 | !! 8.0 ! 1996-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar, |
|---|
| 13 | !! P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0 |
|---|
| 14 | !! 8.1 ! 1997-06 (M. Imbard, G. Madec) |
|---|
| 15 | !! 8.2 ! 1999-11 (M. Imbard, H. Goosse) sea-ice model |
|---|
| 16 | !! ! 1999-12 (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols) OPEN-MP |
|---|
| 17 | !! ! 2000-07 (J-M Molines, M. Imbard) Open Boundary Conditions (CLIPPER) |
|---|
| 18 | !! NEMO 1.0 ! 2002-08 (G. Madec) F90: Free form and modules |
|---|
| 19 | !! - ! 2004-06 (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces |
|---|
| 20 | !! - ! 2004-08 (C. Talandier) New trends organization |
|---|
| 21 | !! - ! 2005-06 (C. Ethe) Add the 1D configuration possibility |
|---|
| 22 | !! - ! 2005-11 (V. Garnier) Surface pressure gradient organization |
|---|
| 23 | !! - ! 2006-03 (L. Debreu, C. Mazauric) Agrif implementation |
|---|
| 24 | !! - ! 2006-04 (G. Madec, R. Benshila) Step reorganization |
|---|
| 25 | !! - ! 2007-07 (J. Chanut, A. Sellar) Unstructured open boundaries (BDY) |
|---|
| 26 | !! 3.2 ! 2009-08 (S. Masson) open/write in the listing file in mpp |
|---|
| 27 | !! 3.3 ! 2010-05 (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface |
|---|
| 28 | !! - ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase |
|---|
| 29 | !! 3.3.1! 2011-01 (A. R. Porter, STFC Daresbury) dynamical allocation |
|---|
| 30 | !! - ! 2011-11 (C. Harris) decomposition changes for running with CICE |
|---|
| 31 | !! 3.6 ! 2012-05 (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening |
|---|
| 32 | !! - ! 2014-12 (G. Madec) remove KPP scheme and cross-land advection (cla) |
|---|
| 33 | !! 4.0 ! 2016-10 (G. Madec, S. Flavoni) domain configuration / user defined interface |
|---|
| 34 | !!---------------------------------------------------------------------- |
|---|
| 35 | |
|---|
| 36 | !!---------------------------------------------------------------------- |
|---|
| 37 | !! nemo_gcm : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice |
|---|
| 38 | !! nemo_init : initialization of the NEMO system |
|---|
| 39 | !! nemo_ctl : initialisation of the contol print |
|---|
| 40 | !! nemo_closefile: close remaining open files |
|---|
| 41 | !! nemo_alloc : dynamical allocation |
|---|
| 42 | !!---------------------------------------------------------------------- |
|---|
| 43 | USE step_oce ! module used in the ocean time stepping module (step.F90) |
|---|
| 44 | ! |
|---|
| 45 | USE phycst ! physical constant (par_cst routine) |
|---|
| 46 | USE domain ! domain initialization (dom_init & dom_cfg routines) |
|---|
| 47 | USE wet_dry ! Wetting and drying setting (wad_init routine) |
|---|
| 48 | USE usrdef_nam ! user defined configuration namelist |
|---|
| 49 | USE tide_mod, ONLY : tide_init ! tidal components initialization (tide_init routine) |
|---|
| 50 | USE bdyini , ONLY : bdy_init ! open boundary cond. setting (bdy_init routine) |
|---|
| 51 | USE istate ! initial state setting (istate_init routine) |
|---|
| 52 | USE trdini ! dyn/tra trends initialization (trd_init routine) |
|---|
| 53 | USE asminc ! assimilation increments |
|---|
| 54 | USE asmbkg ! writing out state trajectory |
|---|
| 55 | USE diadct ! sections transports (dia_dct_init routine) |
|---|
| 56 | USE diaobs ! Observation diagnostics (dia_obs_init routine) |
|---|
| 57 | USE diacfl ! CFL diagnostics (dia_cfl_init routine) |
|---|
| 58 | USE diamlr ! IOM context management for multiple-linear-regression analysis |
|---|
| 59 | #if defined key_qco |
|---|
| 60 | USE stepMLF ! NEMO time-stepping (stp_MLF routine) |
|---|
| 61 | #else |
|---|
| 62 | USE step ! NEMO time-stepping (stp routine) |
|---|
| 63 | #endif |
|---|
| 64 | USE isfstp ! ice shelf (isf_stp_init routine) |
|---|
| 65 | USE icbini ! handle bergs, initialisation |
|---|
| 66 | USE icbstp , ONLY : icb_end ! handle bergs, close iceberg files |
|---|
| 67 | USE cpl_oasis3 ! OASIS3 coupling |
|---|
| 68 | USE dyndmp ! Momentum damping (C1D only) |
|---|
| 69 | USE step_diu ! diurnal bulk SST timestepping (called from here if run offline) |
|---|
| 70 | USE crsini ! initialise grid coarsening utility |
|---|
| 71 | USE dia25h , ONLY : dia_25h_init ! 25h mean output (initialisation) |
|---|
| 72 | USE c1d ! 1D configuration |
|---|
| 73 | USE step_c1d ! Time stepping loop for the 1D configuration |
|---|
| 74 | #if defined key_top |
|---|
| 75 | USE trcini ! passive tracer initialisation |
|---|
| 76 | #endif |
|---|
| 77 | #if defined key_nemocice_decomp |
|---|
| 78 | USE ice_domain_size, only: nx_global, ny_global |
|---|
| 79 | #endif |
|---|
| 80 | #if defined key_qco |
|---|
| 81 | USE stpmlf ! NEMO time-stepping (stp_MLF routine) |
|---|
| 82 | #else |
|---|
| 83 | USE step ! NEMO time-stepping (stp routine) |
|---|
| 84 | #endif |
|---|
| 85 | ! |
|---|
| 86 | USE lib_mpp ! distributed memory computing |
|---|
| 87 | USE mppini ! shared/distributed memory setting (mpp_init routine) |
|---|
| 88 | USE lbcnfd , ONLY : isendto, nsndto ! Setup of north fold exchanges |
|---|
| 89 | USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) |
|---|
| 90 | #if defined key_iomput |
|---|
| 91 | USE xios ! xIOserver |
|---|
| 92 | #endif |
|---|
| 93 | #if defined key_agrif |
|---|
| 94 | USE agrif_all_update ! Master Agrif update |
|---|
| 95 | USE agrif_oce_update |
|---|
| 96 | #endif |
|---|
| 97 | USE halo_mng |
|---|
| 98 | |
|---|
| 99 | IMPLICIT NONE |
|---|
| 100 | PRIVATE |
|---|
| 101 | |
|---|
| 102 | PUBLIC nemo_gcm ! called by model.F90 |
|---|
| 103 | PUBLIC nemo_init ! needed by AGRIF |
|---|
| 104 | PUBLIC nemo_alloc ! needed by TAM |
|---|
| 105 | |
|---|
| 106 | CHARACTER(lc) :: cform_aaa="( /, 'AAAAAAAA', / ) " ! flag for output listing |
|---|
| 107 | |
|---|
| 108 | #if defined key_mpp_mpi |
|---|
| 109 | ! need MPI_Wtime |
|---|
| 110 | INCLUDE 'mpif.h' |
|---|
| 111 | #endif |
|---|
| 112 | |
|---|
| 113 | !!---------------------------------------------------------------------- |
|---|
| 114 | !! NEMO/OCE 4.0 , NEMO Consortium (2018) |
|---|
| 115 | !! $Id$ |
|---|
| 116 | !! Software governed by the CeCILL license (see ./LICENSE) |
|---|
| 117 | !!---------------------------------------------------------------------- |
|---|
| 118 | CONTAINS |
|---|
| 119 | |
|---|
| 120 | SUBROUTINE nemo_gcm |
|---|
| 121 | !!---------------------------------------------------------------------- |
|---|
| 122 | !! *** ROUTINE nemo_gcm *** |
|---|
| 123 | !! |
|---|
| 124 | !! ** Purpose : NEMO solves the primitive equations on an orthogonal |
|---|
| 125 | !! curvilinear mesh on the sphere. |
|---|
| 126 | !! |
|---|
| 127 | !! ** Method : - model general initialization |
|---|
| 128 | !! - launch the time-stepping (stp routine) |
|---|
| 129 | !! - finalize the run by closing files and communications |
|---|
| 130 | !! |
|---|
| 131 | !! References : Madec, Delecluse, Imbard, and Levy, 1997: internal report, IPSL. |
|---|
| 132 | !! Madec, 2008, internal report, IPSL. |
|---|
| 133 | !!---------------------------------------------------------------------- |
|---|
| 134 | INTEGER :: istp ! time step index |
|---|
| 135 | REAL(wp):: zstptiming ! elapsed time for 1 time step |
|---|
| 136 | !!---------------------------------------------------------------------- |
|---|
| 137 | ! |
|---|
| 138 | #if defined key_agrif |
|---|
| 139 | CALL Agrif_Init_Grids() ! AGRIF: set the meshes |
|---|
| 140 | #endif |
|---|
| 141 | ! !-----------------------! |
|---|
| 142 | CALL nemo_init !== Initialisations ==! |
|---|
| 143 | ! !-----------------------! |
|---|
| 144 | #if defined key_agrif |
|---|
| 145 | Kbb_a = Nbb; Kmm_a = Nnn; Krhs_a = Nrhs ! agrif_oce module copies of time level indices |
|---|
| 146 | CALL Agrif_Declare_Var ! " " " " " DYN/TRA |
|---|
| 147 | # if defined key_top |
|---|
| 148 | CALL Agrif_Declare_Var_top ! " " " " " TOP |
|---|
| 149 | # endif |
|---|
| 150 | #endif |
|---|
| 151 | ! check that all process are still there... If some process have an error, |
|---|
| 152 | ! they will never enter in step and other processes will wait until the end of the cpu time! |
|---|
| 153 | CALL mpp_max( 'nemogcm', nstop ) |
|---|
| 154 | |
|---|
| 155 | IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA |
|---|
| 156 | |
|---|
| 157 | ! !-----------------------! |
|---|
| 158 | ! !== time stepping ==! |
|---|
| 159 | ! !-----------------------! |
|---|
| 160 | ! |
|---|
| 161 | ! !== set the model time-step ==! |
|---|
| 162 | ! |
|---|
| 163 | istp = nit000 |
|---|
| 164 | ! |
|---|
| 165 | #if defined key_c1d |
|---|
| 166 | DO WHILE ( istp <= nitend .AND. nstop == 0 ) !== C1D time-stepping ==! |
|---|
| 167 | CALL stp_c1d( istp ) |
|---|
| 168 | istp = istp + 1 |
|---|
| 169 | END DO |
|---|
| 170 | #else |
|---|
| 171 | ! |
|---|
| 172 | # if defined key_agrif |
|---|
| 173 | ! !== AGRIF time-stepping ==! |
|---|
| 174 | CALL Agrif_Regrid() |
|---|
| 175 | ! |
|---|
| 176 | ! Recursive update from highest nested level to lowest: |
|---|
| 177 | Kbb_a = Nbb; Kmm_a = Nnn; Krhs_a = Nrhs ! agrif_oce module copies of time level indices |
|---|
| 178 | CALL Agrif_step_child_adj(Agrif_Update_All) |
|---|
| 179 | CALL Agrif_step_child_adj(Agrif_Check_parent_bat) |
|---|
| 180 | ! |
|---|
| 181 | DO WHILE( istp <= nitend .AND. nstop == 0 ) |
|---|
| 182 | # if defined key_qco |
|---|
| 183 | CALL stp_MLF |
|---|
| 184 | # else |
|---|
| 185 | CALL stp |
|---|
| 186 | # endif |
|---|
| 187 | istp = istp + 1 |
|---|
| 188 | END DO |
|---|
| 189 | ! |
|---|
| 190 | # else |
|---|
| 191 | ! |
|---|
| 192 | IF( .NOT.ln_diurnal_only ) THEN !== Standard time-stepping ==! |
|---|
| 193 | ! |
|---|
| 194 | DO WHILE( istp <= nitend .AND. nstop == 0 ) |
|---|
| 195 | ! |
|---|
| 196 | ncom_stp = istp |
|---|
| 197 | IF( ln_timing ) THEN |
|---|
| 198 | zstptiming = MPI_Wtime() |
|---|
| 199 | IF ( istp == ( nit000 + 1 ) ) elapsed_time = zstptiming |
|---|
| 200 | IF ( istp == nitend ) elapsed_time = zstptiming - elapsed_time |
|---|
| 201 | ENDIF |
|---|
| 202 | ! |
|---|
| 203 | # if defined key_qco |
|---|
| 204 | CALL stp_MLF ( istp ) |
|---|
| 205 | # else |
|---|
| 206 | CALL stp ( istp ) |
|---|
| 207 | # endif |
|---|
| 208 | istp = istp + 1 |
|---|
| 209 | ! |
|---|
| 210 | IF( lwp .AND. ln_timing ) WRITE(numtime,*) 'timing step ', istp-1, ' : ', MPI_Wtime() - zstptiming |
|---|
| 211 | ! |
|---|
| 212 | END DO |
|---|
| 213 | ! |
|---|
| 214 | ELSE !== diurnal SST time-steeping only ==! |
|---|
| 215 | ! |
|---|
| 216 | DO WHILE( istp <= nitend .AND. nstop == 0 ) |
|---|
| 217 | CALL stp_diurnal( istp ) ! time step only the diurnal SST |
|---|
| 218 | istp = istp + 1 |
|---|
| 219 | END DO |
|---|
| 220 | ! |
|---|
| 221 | ENDIF |
|---|
| 222 | ! |
|---|
| 223 | # endif |
|---|
| 224 | ! |
|---|
| 225 | #endif |
|---|
| 226 | ! |
|---|
| 227 | IF( ln_diaobs ) CALL dia_obs_wri |
|---|
| 228 | ! |
|---|
| 229 | IF( ln_icebergs ) CALL icb_end( nitend ) |
|---|
| 230 | |
|---|
| 231 | ! !------------------------! |
|---|
| 232 | ! !== finalize the run ==! |
|---|
| 233 | ! !------------------------! |
|---|
| 234 | IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA |
|---|
| 235 | ! |
|---|
| 236 | IF( nstop /= 0 .AND. lwp ) THEN ! error print |
|---|
| 237 | WRITE(ctmp1,*) ' ==>>> nemo_gcm: a total of ', nstop, ' errors have been found' |
|---|
| 238 | IF( ngrdstop > 0 ) THEN |
|---|
| 239 | WRITE(ctmp9,'(i2)') ngrdstop |
|---|
| 240 | WRITE(ctmp2,*) ' E R R O R detected in Agrif grid '//TRIM(ctmp9) |
|---|
| 241 | WRITE(ctmp3,*) ' Look for "E R R O R" messages in all existing '//TRIM(ctmp9)//'_ocean_output* files' |
|---|
| 242 | CALL ctl_stop( ' ', ctmp1, ' ', ctmp2, ' ', ctmp3 ) |
|---|
| 243 | ELSE |
|---|
| 244 | WRITE(ctmp2,*) ' Look for "E R R O R" messages in all existing ocean_output* files' |
|---|
| 245 | CALL ctl_stop( ' ', ctmp1, ' ', ctmp2 ) |
|---|
| 246 | ENDIF |
|---|
| 247 | ENDIF |
|---|
| 248 | ! |
|---|
| 249 | IF( ln_timing ) CALL timing_finalize |
|---|
| 250 | ! |
|---|
| 251 | CALL nemo_closefile |
|---|
| 252 | ! |
|---|
| 253 | #if defined key_iomput |
|---|
| 254 | CALL xios_finalize ! end mpp communications with xios |
|---|
| 255 | IF( lk_oasis ) CALL cpl_finalize ! end coupling and mpp communications with OASIS |
|---|
| 256 | #else |
|---|
| 257 | IF ( lk_oasis ) THEN ; CALL cpl_finalize ! end coupling and mpp communications with OASIS |
|---|
| 258 | ELSEIF( lk_mpp ) THEN ; CALL mppstop ! end mpp communications |
|---|
| 259 | ENDIF |
|---|
| 260 | #endif |
|---|
| 261 | ! |
|---|
| 262 | IF(lwm) THEN |
|---|
| 263 | IF( nstop == 0 ) THEN ; STOP 0 |
|---|
| 264 | ELSE ; STOP 123 |
|---|
| 265 | ENDIF |
|---|
| 266 | ENDIF |
|---|
| 267 | ! |
|---|
| 268 | END SUBROUTINE nemo_gcm |
|---|
| 269 | |
|---|
| 270 | |
|---|
| 271 | SUBROUTINE nemo_init |
|---|
| 272 | !!---------------------------------------------------------------------- |
|---|
| 273 | !! *** ROUTINE nemo_init *** |
|---|
| 274 | !! |
|---|
| 275 | !! ** Purpose : initialization of the NEMO GCM |
|---|
| 276 | !!---------------------------------------------------------------------- |
|---|
| 277 | INTEGER :: ios, ilocal_comm ! local integers |
|---|
| 278 | !! |
|---|
| 279 | NAMELIST/namctl/ sn_cfctl, ln_timing, ln_diacfl, nn_isplt, nn_jsplt , nn_ictls, & |
|---|
| 280 | & nn_ictle, nn_jctls , nn_jctle |
|---|
| 281 | NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr |
|---|
| 282 | !!---------------------------------------------------------------------- |
|---|
| 283 | ! |
|---|
| 284 | cxios_context = 'nemo' |
|---|
| 285 | ! |
|---|
| 286 | ! !-------------------------------------------------! |
|---|
| 287 | ! ! set communicator & select the local rank ! |
|---|
| 288 | ! ! must be done as soon as possible to get narea ! |
|---|
| 289 | ! !-------------------------------------------------! |
|---|
| 290 | ! |
|---|
| 291 | #if defined key_iomput |
|---|
| 292 | IF( Agrif_Root() ) THEN |
|---|
| 293 | IF( lk_oasis ) THEN |
|---|
| 294 | CALL cpl_init( "oceanx", ilocal_comm ) ! nemo local communicator given by oasis |
|---|
| 295 | CALL xios_initialize( "not used" , local_comm =ilocal_comm ) ! send nemo communicator to xios |
|---|
| 296 | ELSE |
|---|
| 297 | CALL xios_initialize( "for_xios_mpi_id", return_comm=ilocal_comm ) ! nemo local communicator given by xios |
|---|
| 298 | ENDIF |
|---|
| 299 | ENDIF |
|---|
| 300 | CALL mpp_start( ilocal_comm ) |
|---|
| 301 | #else |
|---|
| 302 | IF( lk_oasis ) THEN |
|---|
| 303 | IF( Agrif_Root() ) THEN |
|---|
| 304 | CALL cpl_init( "oceanx", ilocal_comm ) ! nemo local communicator given by oasis |
|---|
| 305 | ENDIF |
|---|
| 306 | CALL mpp_start( ilocal_comm ) |
|---|
| 307 | ELSE |
|---|
| 308 | CALL mpp_start( ) |
|---|
| 309 | ENDIF |
|---|
| 310 | #endif |
|---|
| 311 | ! |
|---|
| 312 | narea = mpprank + 1 ! mpprank: the rank of proc (0 --> mppsize -1 ) |
|---|
| 313 | lwm = (narea == 1) ! control of output namelists |
|---|
| 314 | ! |
|---|
| 315 | ! !---------------------------------------------------------------! |
|---|
| 316 | ! ! Open output files, reference and configuration namelist files ! |
|---|
| 317 | ! !---------------------------------------------------------------! |
|---|
| 318 | ! |
|---|
| 319 | ! open ocean.output as soon as possible to get all output prints (including errors messages) |
|---|
| 320 | IF( lwm ) CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. ) |
|---|
| 321 | ! open reference and configuration namelist files |
|---|
| 322 | CALL load_nml( numnam_ref, 'namelist_ref', -1, lwm ) |
|---|
| 323 | CALL load_nml( numnam_cfg, 'namelist_cfg', -1, lwm ) |
|---|
| 324 | IF( lwm ) CALL ctl_opn( numond, 'output.namelist.dyn', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. ) |
|---|
| 325 | ! open /dev/null file to be able to supress output write easily |
|---|
| 326 | IF( Agrif_Root() ) THEN |
|---|
| 327 | CALL ctl_opn( numnul, '/dev/null', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. ) |
|---|
| 328 | #ifdef key_agrif |
|---|
| 329 | ELSE |
|---|
| 330 | numnul = Agrif_Parent(numnul) |
|---|
| 331 | #endif |
|---|
| 332 | ENDIF |
|---|
| 333 | ! !--------------------! |
|---|
| 334 | ! ! Open listing units ! -> need sn_cfctl from namctl to define lwp |
|---|
| 335 | ! !--------------------! |
|---|
| 336 | ! |
|---|
| 337 | READ ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 ) |
|---|
| 338 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist' ) |
|---|
| 339 | READ ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 ) |
|---|
| 340 | 902 IF( ios > 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist' ) |
|---|
| 341 | ! |
|---|
| 342 | ! finalize the definition of namctl variables |
|---|
| 343 | IF( narea < sn_cfctl%procmin .OR. narea > sn_cfctl%procmax .OR. MOD( narea - sn_cfctl%procmin, sn_cfctl%procincr ) /= 0 ) & |
|---|
| 344 | & CALL nemo_set_cfctl( sn_cfctl, .FALSE. ) |
|---|
| 345 | ! |
|---|
| 346 | lwp = (narea == 1) .OR. sn_cfctl%l_oceout ! control of all listing output print |
|---|
| 347 | ! |
|---|
| 348 | IF(lwp) THEN ! open listing units |
|---|
| 349 | ! |
|---|
| 350 | IF( .NOT.lwm ) & ! alreay opened for narea == 1 |
|---|
| 351 | & CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE., narea ) |
|---|
| 352 | ! |
|---|
| 353 | WRITE(numout,*) |
|---|
| 354 | WRITE(numout,*) ' CNRS - NERC - Met OFFICE - MERCATOR-ocean - CMCC' |
|---|
| 355 | WRITE(numout,*) ' NEMO team' |
|---|
| 356 | WRITE(numout,*) ' Ocean General Circulation Model' |
|---|
| 357 | WRITE(numout,*) ' NEMO version 4.0 (2020) ' |
|---|
| 358 | WRITE(numout,*) |
|---|
| 359 | WRITE(numout,*) " ._ ._ ._ ._ ._ " |
|---|
| 360 | WRITE(numout,*) " _.-._)`\_.-._)`\_.-._)`\_.-._)`\_.-._)`\_ " |
|---|
| 361 | WRITE(numout,*) |
|---|
| 362 | WRITE(numout,*) " o _, _, " |
|---|
| 363 | WRITE(numout,*) " o .' ( .-' / " |
|---|
| 364 | WRITE(numout,*) " o _/..._'. .' / " |
|---|
| 365 | WRITE(numout,*) " ( o .-'` ` '-./ _.' " |
|---|
| 366 | WRITE(numout,*) " ) ( o) ;= <_ ( " |
|---|
| 367 | WRITE(numout,*) " ( '-.,\\__ __.-;`\ '. ) " |
|---|
| 368 | WRITE(numout,*) " ) ) \) |`\ \) '. \ ( ( " |
|---|
| 369 | WRITE(numout,*) " ( ( \_/ '-._\ ) ) " |
|---|
| 370 | WRITE(numout,*) " ) ) jgs ` ( ( " |
|---|
| 371 | WRITE(numout,*) " ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ " |
|---|
| 372 | WRITE(numout,*) |
|---|
| 373 | ! |
|---|
| 374 | WRITE(numout,cform_aaa) ! Flag AAAAAAA |
|---|
| 375 | ! |
|---|
| 376 | ! ! Control print of the working precision |
|---|
| 377 | WRITE(numout,*) |
|---|
| 378 | IF( wp == dp ) THEN ; WRITE(numout,*) "par_kind : wp = Working precision = dp = double-precision" |
|---|
| 379 | ELSE ; WRITE(numout,*) "par_kind : wp = Working precision = sp = single-precision" |
|---|
| 380 | ENDIF |
|---|
| 381 | WRITE(numout,*) "~~~~~~~~ ****************" |
|---|
| 382 | WRITE(numout,*) |
|---|
| 383 | ! |
|---|
| 384 | ENDIF |
|---|
| 385 | ! |
|---|
| 386 | IF(lwm) WRITE( numond, namctl ) |
|---|
| 387 | ! |
|---|
| 388 | ! !------------------------------------! |
|---|
| 389 | ! ! Set global domain size parameters ! |
|---|
| 390 | ! !------------------------------------! |
|---|
| 391 | ! |
|---|
| 392 | READ ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 ) |
|---|
| 393 | 903 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist' ) |
|---|
| 394 | READ ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 ) |
|---|
| 395 | 904 IF( ios > 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist' ) |
|---|
| 396 | ! |
|---|
| 397 | IF( ln_read_cfg ) THEN ! Read sizes in domain configuration file |
|---|
| 398 | CALL domain_cfg ( cn_cfg, nn_cfg, Ni0glo, Nj0glo, jpkglo, jperio ) |
|---|
| 399 | ELSE ! user-defined namelist |
|---|
| 400 | CALL usr_def_nam( cn_cfg, nn_cfg, Ni0glo, Nj0glo, jpkglo, jperio ) |
|---|
| 401 | ENDIF |
|---|
| 402 | ! |
|---|
| 403 | IF(lwm) WRITE( numond, namcfg ) |
|---|
| 404 | ! |
|---|
| 405 | ! !-----------------------------------------! |
|---|
| 406 | ! ! mpp parameters and domain decomposition ! |
|---|
| 407 | ! !-----------------------------------------! |
|---|
| 408 | CALL mpp_init |
|---|
| 409 | |
|---|
| 410 | CALL halo_mng_init() |
|---|
| 411 | ! Now we know the dimensions of the grid and numout has been set: we can allocate arrays |
|---|
| 412 | CALL nemo_alloc() |
|---|
| 413 | |
|---|
| 414 | ! Initialise time level indices |
|---|
| 415 | Nbb = 1 ; Nnn = 2 ; Naa = 3 ; Nrhs = Naa |
|---|
| 416 | #if defined key_agrif |
|---|
| 417 | Kbb_a = Nbb ; Kmm_a = Nnn ; Krhs_a = Nrhs ! agrif_oce module copies of time level indices |
|---|
| 418 | #endif |
|---|
| 419 | ! !-------------------------------! |
|---|
| 420 | ! ! NEMO general initialization ! |
|---|
| 421 | ! !-------------------------------! |
|---|
| 422 | |
|---|
| 423 | CALL nemo_ctl ! Control prints of namctl and namcfg |
|---|
| 424 | ! |
|---|
| 425 | ! ! General initialization |
|---|
| 426 | IF( ln_timing ) CALL timing_init ! timing |
|---|
| 427 | IF( ln_timing ) CALL timing_start( 'nemo_init') |
|---|
| 428 | ! |
|---|
| 429 | CALL phy_cst ! Physical constants |
|---|
| 430 | CALL eos_init ! Equation of state |
|---|
| 431 | IF( lk_c1d ) CALL c1d_init ! 1D column configuration |
|---|
| 432 | CALL wad_init ! Wetting and drying options |
|---|
| 433 | |
|---|
| 434 | #if defined key_agrif |
|---|
| 435 | CALL Agrif_Declare_Var_ini ! " " " " " DOM |
|---|
| 436 | #endif |
|---|
| 437 | CALL dom_init( Nbb, Nnn, Naa ) ! Domain |
|---|
| 438 | IF( ln_crs ) CALL crs_init( Nnn ) ! coarsened grid: domain initialization |
|---|
| 439 | IF( sn_cfctl%l_prtctl ) & |
|---|
| 440 | & CALL prt_ctl_init ! Print control |
|---|
| 441 | |
|---|
| 442 | CALL diurnal_sst_bulk_init ! diurnal sst |
|---|
| 443 | IF( ln_diurnal ) CALL diurnal_sst_coolskin_init ! cool skin |
|---|
| 444 | ! |
|---|
| 445 | IF( ln_diurnal_only ) THEN ! diurnal only: a subset of the initialisation routines |
|---|
| 446 | CALL istate_init( Nbb, Nnn, Naa ) ! ocean initial state (Dynamics and tracers) |
|---|
| 447 | CALL sbc_init( Nbb, Nnn, Naa ) ! Forcings : surface module |
|---|
| 448 | CALL tra_qsr_init ! penetrative solar radiation qsr |
|---|
| 449 | IF( ln_diaobs ) THEN ! Observation & model comparison |
|---|
| 450 | CALL dia_obs_init( Nnn ) ! Initialize observational data |
|---|
| 451 | CALL dia_obs( nit000 - 1, Nnn ) ! Observation operator for restart |
|---|
| 452 | ENDIF |
|---|
| 453 | IF( lk_asminc ) CALL asm_inc_init( Nbb, Nnn, Nrhs ) ! Assimilation increments |
|---|
| 454 | ! |
|---|
| 455 | RETURN ! end of initialization |
|---|
| 456 | ENDIF |
|---|
| 457 | ! |
|---|
| 458 | |
|---|
| 459 | CALL istate_init( Nbb, Nnn, Naa ) ! ocean initial state (Dynamics and tracers) |
|---|
| 460 | |
|---|
| 461 | ! ! external forcing |
|---|
| 462 | CALL tide_init ! tidal harmonics |
|---|
| 463 | CALL sbc_init( Nbb, Nnn, Naa ) ! surface boundary conditions (including sea-ice) |
|---|
| 464 | CALL bdy_init ! Open boundaries initialisation |
|---|
| 465 | |
|---|
| 466 | ! ! Ocean physics |
|---|
| 467 | CALL zdf_phy_init( Nnn ) ! Vertical physics |
|---|
| 468 | |
|---|
| 469 | ! ! Lateral physics |
|---|
| 470 | CALL ldf_tra_init ! Lateral ocean tracer physics |
|---|
| 471 | CALL ldf_eiv_init ! eddy induced velocity param. must be done after ldf_tra_init |
|---|
| 472 | CALL ldf_dyn_init ! Lateral ocean momentum physics |
|---|
| 473 | |
|---|
| 474 | ! ! Active tracers |
|---|
| 475 | IF( ln_traqsr ) CALL tra_qsr_init ! penetrative solar radiation qsr |
|---|
| 476 | CALL tra_bbc_init ! bottom heat flux |
|---|
| 477 | CALL tra_bbl_init ! advective (and/or diffusive) bottom boundary layer scheme |
|---|
| 478 | CALL tra_dmp_init ! internal tracer damping |
|---|
| 479 | CALL tra_adv_init ! horizontal & vertical advection |
|---|
| 480 | CALL tra_ldf_init ! lateral mixing |
|---|
| 481 | |
|---|
| 482 | ! ! Dynamics |
|---|
| 483 | IF( lk_c1d ) CALL dyn_dmp_init ! internal momentum damping |
|---|
| 484 | CALL dyn_adv_init ! advection (vector or flux form) |
|---|
| 485 | CALL dyn_vor_init ! vorticity term including Coriolis |
|---|
| 486 | CALL dyn_ldf_init ! lateral mixing |
|---|
| 487 | CALL dyn_hpg_init( Nnn ) ! horizontal gradient of Hydrostatic pressure |
|---|
| 488 | CALL dyn_spg_init ! surface pressure gradient |
|---|
| 489 | |
|---|
| 490 | ! ! Icebergs |
|---|
| 491 | CALL icb_init( rn_Dt, nit000) ! initialise icebergs instance |
|---|
| 492 | |
|---|
| 493 | ! ice shelf |
|---|
| 494 | CALL isf_init( Nbb, Nnn, Naa ) |
|---|
| 495 | #if defined key_top |
|---|
| 496 | ! ! Passive tracers |
|---|
| 497 | CALL trc_init( Nbb, Nnn, Naa ) |
|---|
| 498 | #endif |
|---|
| 499 | IF( l_ldfslp ) CALL ldf_slp_init ! slope of lateral mixing |
|---|
| 500 | |
|---|
| 501 | ! ! Misc. options |
|---|
| 502 | CALL sto_par_init ! Stochastic parametrization |
|---|
| 503 | IF( ln_sto_eos ) CALL sto_pts_init ! RRandom T/S fluctuations |
|---|
| 504 | |
|---|
| 505 | ! ! Diagnostics |
|---|
| 506 | CALL flo_init( Nnn ) ! drifting Floats |
|---|
| 507 | IF( ln_diacfl ) CALL dia_cfl_init ! Initialise CFL diagnostics |
|---|
| 508 | CALL dia_dct_init ! Sections tranports |
|---|
| 509 | CALL dia_hsb_init( Nnn ) ! heat content, salt content and volume budgets |
|---|
| 510 | CALL trd_init( Nnn ) ! Mixed-layer/Vorticity/Integral constraints trends |
|---|
| 511 | CALL dia_obs_init( Nnn ) ! Initialize observational data |
|---|
| 512 | CALL dia_25h_init( Nbb ) ! 25h mean outputs |
|---|
| 513 | CALL dia_detide_init ! Weights computation for daily detiding of model diagnostics |
|---|
| 514 | IF( ln_diaobs ) CALL dia_obs( nit000-1, Nnn ) ! Observation operator for restart |
|---|
| 515 | CALL dia_mlr_init ! Initialisation of IOM context management for multiple-linear-regression analysis |
|---|
| 516 | |
|---|
| 517 | ! ! Assimilation increments |
|---|
| 518 | IF( lk_asminc ) CALL asm_inc_init( Nbb, Nnn, Nrhs ) ! Initialize assimilation increments |
|---|
| 519 | ! |
|---|
| 520 | IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA |
|---|
| 521 | ! |
|---|
| 522 | IF( ln_timing ) CALL timing_stop( 'nemo_init') |
|---|
| 523 | ! |
|---|
| 524 | END SUBROUTINE nemo_init |
|---|
| 525 | |
|---|
| 526 | |
|---|
| 527 | SUBROUTINE nemo_ctl |
|---|
| 528 | !!---------------------------------------------------------------------- |
|---|
| 529 | !! *** ROUTINE nemo_ctl *** |
|---|
| 530 | !! |
|---|
| 531 | !! ** Purpose : control print setting |
|---|
| 532 | !! |
|---|
| 533 | !! ** Method : - print namctl and namcfg information and check some consistencies |
|---|
| 534 | !!---------------------------------------------------------------------- |
|---|
| 535 | ! |
|---|
| 536 | IF(lwp) THEN ! control print |
|---|
| 537 | WRITE(numout,*) |
|---|
| 538 | WRITE(numout,*) 'nemo_ctl: Control prints' |
|---|
| 539 | WRITE(numout,*) '~~~~~~~~' |
|---|
| 540 | WRITE(numout,*) ' Namelist namctl' |
|---|
| 541 | WRITE(numout,*) ' sn_cfctl%l_runstat = ', sn_cfctl%l_runstat |
|---|
| 542 | WRITE(numout,*) ' sn_cfctl%l_trcstat = ', sn_cfctl%l_trcstat |
|---|
| 543 | WRITE(numout,*) ' sn_cfctl%l_oceout = ', sn_cfctl%l_oceout |
|---|
| 544 | WRITE(numout,*) ' sn_cfctl%l_layout = ', sn_cfctl%l_layout |
|---|
| 545 | WRITE(numout,*) ' sn_cfctl%l_prtctl = ', sn_cfctl%l_prtctl |
|---|
| 546 | WRITE(numout,*) ' sn_cfctl%l_prttrc = ', sn_cfctl%l_prttrc |
|---|
| 547 | WRITE(numout,*) ' sn_cfctl%l_oasout = ', sn_cfctl%l_oasout |
|---|
| 548 | WRITE(numout,*) ' sn_cfctl%procmin = ', sn_cfctl%procmin |
|---|
| 549 | WRITE(numout,*) ' sn_cfctl%procmax = ', sn_cfctl%procmax |
|---|
| 550 | WRITE(numout,*) ' sn_cfctl%procincr = ', sn_cfctl%procincr |
|---|
| 551 | WRITE(numout,*) ' sn_cfctl%ptimincr = ', sn_cfctl%ptimincr |
|---|
| 552 | WRITE(numout,*) ' timing by routine ln_timing = ', ln_timing |
|---|
| 553 | WRITE(numout,*) ' CFL diagnostics ln_diacfl = ', ln_diacfl |
|---|
| 554 | ENDIF |
|---|
| 555 | ! |
|---|
| 556 | IF( .NOT.ln_read_cfg ) ln_closea = .false. ! dealing possible only with a domcfg file |
|---|
| 557 | IF(lwp) THEN ! control print |
|---|
| 558 | WRITE(numout,*) |
|---|
| 559 | WRITE(numout,*) ' Namelist namcfg' |
|---|
| 560 | WRITE(numout,*) ' read domain configuration file ln_read_cfg = ', ln_read_cfg |
|---|
| 561 | WRITE(numout,*) ' filename to be read cn_domcfg = ', TRIM(cn_domcfg) |
|---|
| 562 | WRITE(numout,*) ' keep closed seas in the domain (if exist) ln_closea = ', ln_closea |
|---|
| 563 | WRITE(numout,*) ' create a configuration definition file ln_write_cfg = ', ln_write_cfg |
|---|
| 564 | WRITE(numout,*) ' filename to be written cn_domcfg_out = ', TRIM(cn_domcfg_out) |
|---|
| 565 | WRITE(numout,*) ' use file attribute if exists as i/p j-start ln_use_jattr = ', ln_use_jattr |
|---|
| 566 | ENDIF |
|---|
| 567 | ! |
|---|
| 568 | IF( 1._wp /= SIGN(1._wp,-0._wp) ) CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.', & |
|---|
| 569 | & 'Compile with key_nosignedzero enabled:', & |
|---|
| 570 | & '--> add -Dkey_nosignedzero to the definition of %CPP in your arch file' ) |
|---|
| 571 | ! |
|---|
| 572 | #if defined key_agrif |
|---|
| 573 | IF( ln_timing ) CALL ctl_stop( 'AGRIF not implemented with ln_timing = true') |
|---|
| 574 | #endif |
|---|
| 575 | ! |
|---|
| 576 | END SUBROUTINE nemo_ctl |
|---|
| 577 | |
|---|
| 578 | |
|---|
| 579 | SUBROUTINE nemo_closefile |
|---|
| 580 | !!---------------------------------------------------------------------- |
|---|
| 581 | !! *** ROUTINE nemo_closefile *** |
|---|
| 582 | !! |
|---|
| 583 | !! ** Purpose : Close the files |
|---|
| 584 | !!---------------------------------------------------------------------- |
|---|
| 585 | ! |
|---|
| 586 | IF( lk_mpp ) CALL mppsync |
|---|
| 587 | ! |
|---|
| 588 | CALL iom_close ! close all input/output files managed by iom_* |
|---|
| 589 | ! |
|---|
| 590 | IF( numstp /= -1 ) CLOSE( numstp ) ! time-step file |
|---|
| 591 | IF( numrun /= -1 ) CLOSE( numrun ) ! run statistics file |
|---|
| 592 | IF( lwm.AND.numond /= -1 ) CLOSE( numond ) ! oce output namelist |
|---|
| 593 | IF( lwm.AND.numoni /= -1 ) CLOSE( numoni ) ! ice output namelist |
|---|
| 594 | IF( numevo_ice /= -1 ) CLOSE( numevo_ice ) ! ice variables (temp. evolution) |
|---|
| 595 | IF( numout /= 6 ) CLOSE( numout ) ! standard model output file |
|---|
| 596 | IF( numdct_vol /= -1 ) CLOSE( numdct_vol ) ! volume transports |
|---|
| 597 | IF( numdct_heat /= -1 ) CLOSE( numdct_heat ) ! heat transports |
|---|
| 598 | IF( numdct_salt /= -1 ) CLOSE( numdct_salt ) ! salt transports |
|---|
| 599 | ! |
|---|
| 600 | numout = 6 ! redefine numout in case it is used after this point... |
|---|
| 601 | ! |
|---|
| 602 | END SUBROUTINE nemo_closefile |
|---|
| 603 | |
|---|
| 604 | |
|---|
| 605 | SUBROUTINE nemo_alloc |
|---|
| 606 | !!---------------------------------------------------------------------- |
|---|
| 607 | !! *** ROUTINE nemo_alloc *** |
|---|
| 608 | !! |
|---|
| 609 | !! ** Purpose : Allocate all the dynamic arrays of the OPA modules |
|---|
| 610 | !! |
|---|
| 611 | !! ** Method : |
|---|
| 612 | !!---------------------------------------------------------------------- |
|---|
| 613 | USE diawri , ONLY : dia_wri_alloc |
|---|
| 614 | USE dom_oce , ONLY : dom_oce_alloc |
|---|
| 615 | USE trc_oce , ONLY : trc_oce_alloc |
|---|
| 616 | USE bdy_oce , ONLY : bdy_oce_alloc |
|---|
| 617 | ! |
|---|
| 618 | INTEGER :: ierr |
|---|
| 619 | !!---------------------------------------------------------------------- |
|---|
| 620 | ! |
|---|
| 621 | ierr = oce_alloc () ! ocean |
|---|
| 622 | ierr = ierr + dia_wri_alloc() |
|---|
| 623 | ierr = ierr + dom_oce_alloc() ! ocean domain |
|---|
| 624 | ierr = ierr + zdf_oce_alloc() ! ocean vertical physics |
|---|
| 625 | ierr = ierr + trc_oce_alloc() ! shared TRC / TRA arrays |
|---|
| 626 | ierr = ierr + bdy_oce_alloc() ! bdy masks (incl. initialization) |
|---|
| 627 | ! |
|---|
| 628 | CALL mpp_sum( 'nemogcm', ierr ) |
|---|
| 629 | IF( ierr /= 0 ) CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' ) |
|---|
| 630 | ! |
|---|
| 631 | END SUBROUTINE nemo_alloc |
|---|
| 632 | |
|---|
| 633 | |
|---|
| 634 | SUBROUTINE nemo_set_cfctl(sn_cfctl, setto ) |
|---|
| 635 | !!---------------------------------------------------------------------- |
|---|
| 636 | !! *** ROUTINE nemo_set_cfctl *** |
|---|
| 637 | !! |
|---|
| 638 | !! ** Purpose : Set elements of the output control structure to setto. |
|---|
| 639 | !! |
|---|
| 640 | !! ** Method : Note this routine can be used to switch on/off some |
|---|
| 641 | !! types of output for selected areas. |
|---|
| 642 | !!---------------------------------------------------------------------- |
|---|
| 643 | TYPE(sn_ctl), INTENT(inout) :: sn_cfctl |
|---|
| 644 | LOGICAL , INTENT(in ) :: setto |
|---|
| 645 | !!---------------------------------------------------------------------- |
|---|
| 646 | sn_cfctl%l_runstat = setto |
|---|
| 647 | sn_cfctl%l_trcstat = setto |
|---|
| 648 | sn_cfctl%l_oceout = setto |
|---|
| 649 | sn_cfctl%l_layout = setto |
|---|
| 650 | sn_cfctl%l_prtctl = setto |
|---|
| 651 | sn_cfctl%l_prttrc = setto |
|---|
| 652 | sn_cfctl%l_oasout = setto |
|---|
| 653 | END SUBROUTINE nemo_set_cfctl |
|---|
| 654 | |
|---|
| 655 | !!====================================================================== |
|---|
| 656 | END MODULE nemogcm |
|---|
