| 1 | MODULE nemogcm |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE nemogcm *** |
|---|
| 4 | !! Ocean system : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice) |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : OPA ! 1990-10 (C. Levy, G. Madec) Original code |
|---|
| 7 | !! 7.0 ! 1991-11 (M. Imbard, C. Levy, G. Madec) |
|---|
| 8 | !! 7.1 ! 1993-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar, |
|---|
| 9 | !! P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1 |
|---|
| 10 | !! - ! 1992-06 (L.Terray) coupling implementation |
|---|
| 11 | !! - ! 1993-11 (M.A. Filiberti) IGLOO sea-ice |
|---|
| 12 | !! 8.0 ! 1996-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar, |
|---|
| 13 | !! P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0 |
|---|
| 14 | !! 8.1 ! 1997-06 (M. Imbard, G. Madec) |
|---|
| 15 | !! 8.2 ! 1999-11 (M. Imbard, H. Goosse) sea-ice model |
|---|
| 16 | !! ! 1999-12 (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols) OPEN-MP |
|---|
| 17 | !! ! 2000-07 (J-M Molines, M. Imbard) Open Boundary Conditions (CLIPPER) |
|---|
| 18 | !! NEMO 1.0 ! 2002-08 (G. Madec) F90: Free form and modules |
|---|
| 19 | !! - ! 2004-06 (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces |
|---|
| 20 | !! - ! 2004-08 (C. Talandier) New trends organization |
|---|
| 21 | !! - ! 2005-06 (C. Ethe) Add the 1D configuration possibility |
|---|
| 22 | !! - ! 2005-11 (V. Garnier) Surface pressure gradient organization |
|---|
| 23 | !! - ! 2006-03 (L. Debreu, C. Mazauric) Agrif implementation |
|---|
| 24 | !! - ! 2006-04 (G. Madec, R. Benshila) Step reorganization |
|---|
| 25 | !! - ! 2007-07 (J. Chanut, A. Sellar) Unstructured open boundaries (BDY) |
|---|
| 26 | !! 3.2 ! 2009-08 (S. Masson) open/write in the listing file in mpp |
|---|
| 27 | !! 3.3 ! 2010-05 (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface |
|---|
| 28 | !! - ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase |
|---|
| 29 | !! 3.3.1! 2011-01 (A. R. Porter, STFC Daresbury) dynamical allocation |
|---|
| 30 | !! - ! 2011-11 (C. Harris) decomposition changes for running with CICE |
|---|
| 31 | !! 3.6 ! 2012-05 (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening |
|---|
| 32 | !! - ! 2014-12 (G. Madec) remove KPP scheme and cross-land advection (cla) |
|---|
| 33 | !! 4.0 ! 2016-10 (G. Madec, S. Flavoni) domain configuration / user defined interface |
|---|
| 34 | !!---------------------------------------------------------------------- |
|---|
| 35 | |
|---|
| 36 | !!---------------------------------------------------------------------- |
|---|
| 37 | !! nemo_gcm : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice |
|---|
| 38 | !! nemo_init : initialization of the NEMO system |
|---|
| 39 | !! nemo_ctl : initialisation of the contol print |
|---|
| 40 | !! nemo_closefile: close remaining open files |
|---|
| 41 | !! nemo_alloc : dynamical allocation |
|---|
| 42 | !!---------------------------------------------------------------------- |
|---|
| 43 | USE step_oce ! module used in the ocean time stepping module (step.F90) |
|---|
| 44 | ! |
|---|
| 45 | USE phycst ! physical constant (par_cst routine) |
|---|
| 46 | USE domain ! domain initialization (dom_init & dom_cfg routines) |
|---|
| 47 | USE wet_dry ! Wetting and drying setting (wad_init routine) |
|---|
| 48 | USE usrdef_nam ! user defined configuration namelist |
|---|
| 49 | USE tide_mod, ONLY : tide_init ! tidal components initialization (tide_init routine) |
|---|
| 50 | USE bdyini , ONLY : bdy_init ! open boundary cond. setting (bdy_init routine) |
|---|
| 51 | USE istate ! initial state setting (istate_init routine) |
|---|
| 52 | USE trdini ! dyn/tra trends initialization (trd_init routine) |
|---|
| 53 | USE icbini ! handle bergs, initialisation |
|---|
| 54 | USE icbstp , ONLY : icb_end ! handle bergs, close iceberg files |
|---|
| 55 | USE cpl_oasis3 ! OASIS3 coupling |
|---|
| 56 | USE dyndmp ! Momentum damping (C1D only) |
|---|
| 57 | USE step_diu ! diurnal bulk SST timestepping (called from here if run offline) |
|---|
| 58 | USE crsini ! initialise grid coarsening utility |
|---|
| 59 | USE dia25h , ONLY : dia_25h_init ! 25h mean output (initialisation) |
|---|
| 60 | USE c1d ! 1D configuration |
|---|
| 61 | #if defined key_top |
|---|
| 62 | USE trcini ! passive tracer initialisation |
|---|
| 63 | #endif |
|---|
| 64 | #if defined key_nemocice_decomp |
|---|
| 65 | USE ice_domain_size, only: nx_global, ny_global |
|---|
| 66 | #endif |
|---|
| 67 | #if defined key_qco || defined key_linssh |
|---|
| 68 | USE stpmlf ! NEMO time-stepping (stp_MLF routine) |
|---|
| 69 | #else |
|---|
| 70 | USE step ! NEMO time-stepping (stp routine) |
|---|
| 71 | #endif |
|---|
| 72 | ! |
|---|
| 73 | USE lib_mpp ! distributed memory computing |
|---|
| 74 | USE mppini ! shared/distributed memory setting (mpp_init routine) |
|---|
| 75 | USE lbcnfd , ONLY : isendto, nsndto ! Setup of north fold exchanges |
|---|
| 76 | USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) |
|---|
| 77 | USE halo_mng ! halo manager |
|---|
| 78 | |
|---|
| 79 | IMPLICIT NONE |
|---|
| 80 | PRIVATE |
|---|
| 81 | |
|---|
| 82 | PUBLIC nemo_gcm ! called by model.F90 |
|---|
| 83 | PUBLIC nemo_init ! needed by AGRIF |
|---|
| 84 | PUBLIC nemo_alloc ! needed by TAM |
|---|
| 85 | |
|---|
| 86 | CHARACTER(lc) :: cform_aaa="( /, 'AAAAAAAA', / ) " ! flag for output listing |
|---|
| 87 | |
|---|
| 88 | #if ! defined key_mpi_off |
|---|
| 89 | ! need MPI_Wtime |
|---|
| 90 | INCLUDE 'mpif.h' |
|---|
| 91 | #endif |
|---|
| 92 | |
|---|
| 93 | !!---------------------------------------------------------------------- |
|---|
| 94 | !! NEMO/OCE 4.0 , NEMO Consortium (2018) |
|---|
| 95 | !! $Id$ |
|---|
| 96 | !! Software governed by the CeCILL license (see ./LICENSE) |
|---|
| 97 | !!---------------------------------------------------------------------- |
|---|
| 98 | CONTAINS |
|---|
| 99 | |
|---|
| 100 | SUBROUTINE nemo_gcm |
|---|
| 101 | !!---------------------------------------------------------------------- |
|---|
| 102 | !! *** ROUTINE nemo_gcm *** |
|---|
| 103 | !! |
|---|
| 104 | !! ** Purpose : NEMO solves the primitive equations on an orthogonal |
|---|
| 105 | !! curvilinear mesh on the sphere. |
|---|
| 106 | !! |
|---|
| 107 | !! ** Method : - model general initialization |
|---|
| 108 | !! - launch the time-stepping (stp routine) |
|---|
| 109 | !! - finalize the run by closing files and communications |
|---|
| 110 | !! |
|---|
| 111 | !! References : Madec, Delecluse, Imbard, and Levy, 1997: internal report, IPSL. |
|---|
| 112 | !! Madec, 2008, internal report, IPSL. |
|---|
| 113 | !!---------------------------------------------------------------------- |
|---|
| 114 | INTEGER :: istp ! time step index |
|---|
| 115 | REAL(wp):: zstptiming ! elapsed time for 1 time step |
|---|
| 116 | !!---------------------------------------------------------------------- |
|---|
| 117 | ! |
|---|
| 118 | #if defined key_agrif |
|---|
| 119 | CALL Agrif_Init_Grids() ! AGRIF: set the meshes |
|---|
| 120 | #endif |
|---|
| 121 | ! !-----------------------! |
|---|
| 122 | CALL nemo_init !== Initialisations ==! |
|---|
| 123 | ! !-----------------------! |
|---|
| 124 | #if defined key_agrif |
|---|
| 125 | Kbb_a = Nbb; Kmm_a = Nnn; Krhs_a = Nrhs ! agrif_oce module copies of time level indices |
|---|
| 126 | CALL Agrif_Declare_Var ! " " " " " DYN/TRA |
|---|
| 127 | # if defined key_top |
|---|
| 128 | CALL Agrif_Declare_Var_top ! " " " " " TOP |
|---|
| 129 | # endif |
|---|
| 130 | #endif |
|---|
| 131 | ! check that all process are still there... If some process have an error, |
|---|
| 132 | ! they will never enter in step and other processes will wait until the end of the cpu time! |
|---|
| 133 | CALL mpp_max( 'nemogcm', nstop ) |
|---|
| 134 | |
|---|
| 135 | IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA |
|---|
| 136 | |
|---|
| 137 | ! !-----------------------! |
|---|
| 138 | ! !== time stepping ==! |
|---|
| 139 | ! !-----------------------! |
|---|
| 140 | ! |
|---|
| 141 | ! !== set the model time-step ==! |
|---|
| 142 | ! |
|---|
| 143 | istp = nit000 |
|---|
| 144 | ! |
|---|
| 145 | # if defined key_agrif |
|---|
| 146 | ! !== AGRIF time-stepping ==! |
|---|
| 147 | CALL Agrif_Regrid() |
|---|
| 148 | ! |
|---|
| 149 | ! Recursive update from highest nested level to lowest: |
|---|
| 150 | Kbb_a = Nbb; Kmm_a = Nnn; Krhs_a = Nrhs ! agrif_oce module copies of time level indices |
|---|
| 151 | CALL Agrif_step_child_adj(Agrif_Update_All) |
|---|
| 152 | CALL Agrif_step_child_adj(Agrif_Check_parent_bat) |
|---|
| 153 | ! |
|---|
| 154 | DO WHILE( istp <= nitend .AND. nstop == 0 ) |
|---|
| 155 | ! |
|---|
| 156 | # if defined key_qco || defined key_linssh |
|---|
| 157 | CALL stp_MLF |
|---|
| 158 | # else |
|---|
| 159 | CALL stp |
|---|
| 160 | # endif |
|---|
| 161 | istp = istp + 1 |
|---|
| 162 | END DO |
|---|
| 163 | ! |
|---|
| 164 | # else |
|---|
| 165 | ! |
|---|
| 166 | IF( .NOT.ln_diurnal_only ) THEN !== Standard time-stepping ==! |
|---|
| 167 | ! |
|---|
| 168 | DO WHILE( istp <= nitend .AND. nstop == 0 ) |
|---|
| 169 | ! |
|---|
| 170 | ncom_stp = istp |
|---|
| 171 | IF( ln_timing ) THEN |
|---|
| 172 | zstptiming = MPI_Wtime() |
|---|
| 173 | IF ( istp == ( nit000 + 1 ) ) elapsed_time = zstptiming |
|---|
| 174 | IF ( istp == nitend ) elapsed_time = zstptiming - elapsed_time |
|---|
| 175 | ENDIF |
|---|
| 176 | ! |
|---|
| 177 | # if defined key_qco || defined key_linssh |
|---|
| 178 | CALL stp_MLF( istp ) |
|---|
| 179 | # else |
|---|
| 180 | CALL stp ( istp ) |
|---|
| 181 | # endif |
|---|
| 182 | istp = istp + 1 |
|---|
| 183 | ! |
|---|
| 184 | IF( lwp .AND. ln_timing ) WRITE(numtime,*) 'timing step ', istp-1, ' : ', MPI_Wtime() - zstptiming |
|---|
| 185 | ! |
|---|
| 186 | END DO |
|---|
| 187 | ! |
|---|
| 188 | ELSE !== diurnal SST time-steeping only ==! |
|---|
| 189 | ! |
|---|
| 190 | DO WHILE( istp <= nitend .AND. nstop == 0 ) |
|---|
| 191 | CALL stp_diurnal( istp ) ! time step only the diurnal SST |
|---|
| 192 | istp = istp + 1 |
|---|
| 193 | END DO |
|---|
| 194 | ! |
|---|
| 195 | ENDIF |
|---|
| 196 | ! |
|---|
| 197 | # endif |
|---|
| 198 | ! |
|---|
| 199 | IF( ln_diaobs ) CALL dia_obs_wri |
|---|
| 200 | ! |
|---|
| 201 | IF( ln_icebergs ) CALL icb_end( nitend ) |
|---|
| 202 | |
|---|
| 203 | ! !------------------------! |
|---|
| 204 | ! !== finalize the run ==! |
|---|
| 205 | ! !------------------------! |
|---|
| 206 | IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA |
|---|
| 207 | ! |
|---|
| 208 | IF( nstop /= 0 .AND. lwp ) THEN ! error print |
|---|
| 209 | WRITE(ctmp1,*) ' ==>>> nemo_gcm: a total of ', nstop, ' errors have been found' |
|---|
| 210 | IF( ngrdstop > 0 ) THEN |
|---|
| 211 | WRITE(ctmp9,'(i2)') ngrdstop |
|---|
| 212 | WRITE(ctmp2,*) ' E R R O R detected in Agrif grid '//TRIM(ctmp9) |
|---|
| 213 | WRITE(ctmp3,*) ' Look for "E R R O R" messages in all existing '//TRIM(ctmp9)//'_ocean_output* files' |
|---|
| 214 | CALL ctl_stop( ' ', ctmp1, ' ', ctmp2, ' ', ctmp3 ) |
|---|
| 215 | ELSE |
|---|
| 216 | WRITE(ctmp2,*) ' Look for "E R R O R" messages in all existing ocean_output* files' |
|---|
| 217 | CALL ctl_stop( ' ', ctmp1, ' ', ctmp2 ) |
|---|
| 218 | ENDIF |
|---|
| 219 | ENDIF |
|---|
| 220 | ! |
|---|
| 221 | IF( ln_timing ) CALL timing_finalize |
|---|
| 222 | ! |
|---|
| 223 | CALL nemo_closefile |
|---|
| 224 | ! |
|---|
| 225 | #if defined key_xios |
|---|
| 226 | CALL xios_finalize ! end mpp communications with xios |
|---|
| 227 | IF( lk_oasis ) CALL cpl_finalize ! end coupling and mpp communications with OASIS |
|---|
| 228 | #else |
|---|
| 229 | IF ( lk_oasis ) THEN ; CALL cpl_finalize ! end coupling and mpp communications with OASIS |
|---|
| 230 | ELSEIF( lk_mpp ) THEN ; CALL mppstop ! end mpp communications |
|---|
| 231 | ENDIF |
|---|
| 232 | #endif |
|---|
| 233 | ! |
|---|
| 234 | IF(lwm) THEN |
|---|
| 235 | IF( nstop == 0 ) THEN ; STOP 0 |
|---|
| 236 | ELSE ; STOP 123 |
|---|
| 237 | ENDIF |
|---|
| 238 | ENDIF |
|---|
| 239 | ! |
|---|
| 240 | END SUBROUTINE nemo_gcm |
|---|
| 241 | |
|---|
| 242 | |
|---|
| 243 | SUBROUTINE nemo_init |
|---|
| 244 | !!---------------------------------------------------------------------- |
|---|
| 245 | !! *** ROUTINE nemo_init *** |
|---|
| 246 | !! |
|---|
| 247 | !! ** Purpose : initialization of the NEMO GCM |
|---|
| 248 | !!---------------------------------------------------------------------- |
|---|
| 249 | INTEGER :: ios, ilocal_comm ! local integers |
|---|
| 250 | !! |
|---|
| 251 | NAMELIST/namctl/ sn_cfctl, ln_timing, ln_diacfl, nn_isplt, nn_jsplt , nn_ictls, & |
|---|
| 252 | & nn_ictle, nn_jctls , nn_jctle |
|---|
| 253 | NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr |
|---|
| 254 | !!---------------------------------------------------------------------- |
|---|
| 255 | ! |
|---|
| 256 | cxios_context = 'nemo' |
|---|
| 257 | ! |
|---|
| 258 | ! !-------------------------------------------------! |
|---|
| 259 | ! ! set communicator & select the local rank ! |
|---|
| 260 | ! ! must be done as soon as possible to get narea ! |
|---|
| 261 | ! !-------------------------------------------------! |
|---|
| 262 | ! |
|---|
| 263 | #if defined key_xios |
|---|
| 264 | IF( Agrif_Root() ) THEN |
|---|
| 265 | IF( lk_oasis ) THEN |
|---|
| 266 | CALL cpl_init( "oceanx", ilocal_comm ) ! nemo local communicator given by oasis |
|---|
| 267 | CALL xios_initialize( "not used" , local_comm =ilocal_comm ) ! send nemo communicator to xios |
|---|
| 268 | ELSE |
|---|
| 269 | CALL xios_initialize( "for_xios_mpi_id", return_comm=ilocal_comm ) ! nemo local communicator given by xios |
|---|
| 270 | ENDIF |
|---|
| 271 | ENDIF |
|---|
| 272 | CALL mpp_start( ilocal_comm ) |
|---|
| 273 | #else |
|---|
| 274 | IF( lk_oasis ) THEN |
|---|
| 275 | IF( Agrif_Root() ) THEN |
|---|
| 276 | CALL cpl_init( "oceanx", ilocal_comm ) ! nemo local communicator given by oasis |
|---|
| 277 | ENDIF |
|---|
| 278 | CALL mpp_start( ilocal_comm ) |
|---|
| 279 | ELSE |
|---|
| 280 | CALL mpp_start( ) |
|---|
| 281 | ENDIF |
|---|
| 282 | #endif |
|---|
| 283 | ! |
|---|
| 284 | narea = mpprank + 1 ! mpprank: the rank of proc (0 --> mppsize -1 ) |
|---|
| 285 | lwm = (narea == 1) ! control of output namelists |
|---|
| 286 | ! |
|---|
| 287 | ! !---------------------------------------------------------------! |
|---|
| 288 | ! ! Open output files, reference and configuration namelist files ! |
|---|
| 289 | ! !---------------------------------------------------------------! |
|---|
| 290 | ! |
|---|
| 291 | ! open ocean.output as soon as possible to get all output prints (including errors messages) |
|---|
| 292 | IF( lwm ) CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. ) |
|---|
| 293 | ! open reference and configuration namelist files |
|---|
| 294 | CALL load_nml( numnam_ref, 'namelist_ref', -1, lwm ) |
|---|
| 295 | CALL load_nml( numnam_cfg, 'namelist_cfg', -1, lwm ) |
|---|
| 296 | IF( lwm ) CALL ctl_opn( numond, 'output.namelist.dyn', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. ) |
|---|
| 297 | ! open /dev/null file to be able to supress output write easily |
|---|
| 298 | IF( Agrif_Root() ) THEN |
|---|
| 299 | CALL ctl_opn( numnul, '/dev/null', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. ) |
|---|
| 300 | #ifdef key_agrif |
|---|
| 301 | ELSE |
|---|
| 302 | numnul = Agrif_Parent(numnul) |
|---|
| 303 | #endif |
|---|
| 304 | ENDIF |
|---|
| 305 | ! !--------------------! |
|---|
| 306 | ! ! Open listing units ! -> need sn_cfctl from namctl to define lwp |
|---|
| 307 | ! !--------------------! |
|---|
| 308 | ! |
|---|
| 309 | READ ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 ) |
|---|
| 310 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist' ) |
|---|
| 311 | READ ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 ) |
|---|
| 312 | 902 IF( ios > 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist' ) |
|---|
| 313 | ! |
|---|
| 314 | ! finalize the definition of namctl variables |
|---|
| 315 | IF( narea < sn_cfctl%procmin .OR. narea > sn_cfctl%procmax .OR. MOD( narea - sn_cfctl%procmin, sn_cfctl%procincr ) /= 0 ) & |
|---|
| 316 | & CALL nemo_set_cfctl( sn_cfctl, .FALSE. ) |
|---|
| 317 | ! |
|---|
| 318 | lwp = (narea == 1) .OR. sn_cfctl%l_oceout ! control of all listing output print |
|---|
| 319 | ! |
|---|
| 320 | IF(lwp) THEN ! open listing units |
|---|
| 321 | ! |
|---|
| 322 | IF( .NOT. lwm ) & ! alreay opened for narea == 1 |
|---|
| 323 | & CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE., narea ) |
|---|
| 324 | ! |
|---|
| 325 | WRITE(numout,*) |
|---|
| 326 | WRITE(numout,*) ' CNRS - NERC - Met OFFICE - MERCATOR-ocean - CMCC' |
|---|
| 327 | WRITE(numout,*) ' NEMO team' |
|---|
| 328 | WRITE(numout,*) ' Ocean General Circulation Model' |
|---|
| 329 | WRITE(numout,*) ' NEMO version 4.0 (2020) ' |
|---|
| 330 | WRITE(numout,*) |
|---|
| 331 | WRITE(numout,*) " ._ ._ ._ ._ ._ " |
|---|
| 332 | WRITE(numout,*) " _.-._)`\_.-._)`\_.-._)`\_.-._)`\_.-._)`\_ " |
|---|
| 333 | WRITE(numout,*) |
|---|
| 334 | WRITE(numout,*) " o _, _, " |
|---|
| 335 | WRITE(numout,*) " o .' ( .-' / " |
|---|
| 336 | WRITE(numout,*) " o _/..._'. .' / " |
|---|
| 337 | WRITE(numout,*) " ( o .-'` ` '-./ _.' " |
|---|
| 338 | WRITE(numout,*) " ) ( o) ;= <_ ( " |
|---|
| 339 | WRITE(numout,*) " ( '-.,\\__ __.-;`\ '. ) " |
|---|
| 340 | WRITE(numout,*) " ) ) \) |`\ \) '. \ ( ( " |
|---|
| 341 | WRITE(numout,*) " ( ( \_/ '-._\ ) ) " |
|---|
| 342 | WRITE(numout,*) " ) ) jgs ` ( ( " |
|---|
| 343 | WRITE(numout,*) " ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ " |
|---|
| 344 | WRITE(numout,*) |
|---|
| 345 | ! |
|---|
| 346 | WRITE(numout,cform_aaa) ! Flag AAAAAAA |
|---|
| 347 | ! |
|---|
| 348 | ! ! Control print of the working precision |
|---|
| 349 | WRITE(numout,*) |
|---|
| 350 | IF( wp == dp ) THEN ; WRITE(numout,*) "par_kind : wp = Working precision = dp = double-precision" |
|---|
| 351 | ELSE ; WRITE(numout,*) "par_kind : wp = Working precision = sp = single-precision" |
|---|
| 352 | ENDIF |
|---|
| 353 | WRITE(numout,*) "~~~~~~~~ ****************" |
|---|
| 354 | WRITE(numout,*) |
|---|
| 355 | ! |
|---|
| 356 | ENDIF |
|---|
| 357 | ! |
|---|
| 358 | IF(lwm) WRITE( numond, namctl ) |
|---|
| 359 | ! |
|---|
| 360 | ! !------------------------------------! |
|---|
| 361 | ! ! Set global domain size parameters ! |
|---|
| 362 | ! !------------------------------------! |
|---|
| 363 | ! |
|---|
| 364 | READ ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 ) |
|---|
| 365 | 903 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist' ) |
|---|
| 366 | READ ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 ) |
|---|
| 367 | 904 IF( ios > 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist' ) |
|---|
| 368 | ! |
|---|
| 369 | IF( ln_read_cfg ) THEN ! Read sizes in domain configuration file |
|---|
| 370 | CALL domain_cfg ( cn_cfg, nn_cfg, Ni0glo, Nj0glo, jpkglo, l_Iperio, l_Jperio, l_NFold, c_NFtype ) |
|---|
| 371 | ELSE ! user-defined namelist |
|---|
| 372 | CALL usr_def_nam( cn_cfg, nn_cfg, Ni0glo, Nj0glo, jpkglo, l_Iperio, l_Jperio, l_NFold, c_NFtype ) |
|---|
| 373 | ENDIF |
|---|
| 374 | ! |
|---|
| 375 | IF(lwm) WRITE( numond, namcfg ) |
|---|
| 376 | ! |
|---|
| 377 | ! !-----------------------------------------! |
|---|
| 378 | ! ! mpp parameters and domain decomposition ! |
|---|
| 379 | ! !-----------------------------------------! |
|---|
| 380 | CALL mpp_init |
|---|
| 381 | |
|---|
| 382 | #if defined key_loop_fusion |
|---|
| 383 | IF( nn_hls == 1 ) THEN |
|---|
| 384 | CALL ctl_stop( 'STOP', 'nemogcm : Loop fusion can be used only with extra-halo' ) |
|---|
| 385 | ENDIF |
|---|
| 386 | #endif |
|---|
| 387 | |
|---|
| 388 | CALL halo_mng_init() |
|---|
| 389 | ! Now we know the dimensions of the grid and numout has been set: we can allocate arrays |
|---|
| 390 | CALL nemo_alloc() |
|---|
| 391 | |
|---|
| 392 | ! Initialise time level indices |
|---|
| 393 | Nbb = 1 ; Nnn = 2 ; Naa = 3 ; Nrhs = Naa |
|---|
| 394 | #if defined key_agrif |
|---|
| 395 | Kbb_a = Nbb ; Kmm_a = Nnn ; Krhs_a = Nrhs ! agrif_oce module copies of time level indices |
|---|
| 396 | #endif |
|---|
| 397 | ! !-------------------------------! |
|---|
| 398 | ! ! NEMO general initialization ! |
|---|
| 399 | ! !-------------------------------! |
|---|
| 400 | |
|---|
| 401 | CALL nemo_ctl ! Control prints of namctl and namcfg |
|---|
| 402 | ! |
|---|
| 403 | ! ! General initialization |
|---|
| 404 | IF( ln_timing ) CALL timing_init ! timing |
|---|
| 405 | IF( ln_timing ) CALL timing_start( 'nemo_init') |
|---|
| 406 | ! |
|---|
| 407 | CALL phy_cst ! Physical constants |
|---|
| 408 | CALL eos_init ! Equation of state |
|---|
| 409 | CALL wad_init ! Wetting and drying options |
|---|
| 410 | |
|---|
| 411 | #if defined key_agrif |
|---|
| 412 | CALL Agrif_Declare_Var_ini ! " " " " " DOM |
|---|
| 413 | #endif |
|---|
| 414 | CALL dom_init( Nbb, Nnn, Naa ) ! Domain |
|---|
| 415 | IF( ln_crs ) CALL crs_init( Nnn ) ! coarsened grid: domain initialization |
|---|
| 416 | IF( sn_cfctl%l_prtctl ) & |
|---|
| 417 | & CALL prt_ctl_init ! Print control |
|---|
| 418 | |
|---|
| 419 | CALL diurnal_sst_bulk_init ! diurnal sst |
|---|
| 420 | IF( ln_diurnal ) CALL diurnal_sst_coolskin_init ! cool skin |
|---|
| 421 | ! |
|---|
| 422 | IF( ln_diurnal_only ) THEN ! diurnal only: a subset of the initialisation routines |
|---|
| 423 | CALL istate_init( Nbb, Nnn, Naa ) ! ocean initial state (Dynamics and tracers) |
|---|
| 424 | CALL sbc_init( Nbb, Nnn, Naa ) ! Forcings : surface module |
|---|
| 425 | CALL tra_qsr_init ! penetrative solar radiation qsr |
|---|
| 426 | IF( ln_diaobs ) THEN ! Observation & model comparison |
|---|
| 427 | CALL dia_obs_init( Nnn ) ! Initialize observational data |
|---|
| 428 | CALL dia_obs( nit000 - 1, Nnn ) ! Observation operator for restart |
|---|
| 429 | ENDIF |
|---|
| 430 | IF( lk_asminc ) CALL asm_inc_init( Nbb, Nnn, Nrhs ) ! Assimilation increments |
|---|
| 431 | ! |
|---|
| 432 | RETURN ! end of initialization |
|---|
| 433 | ENDIF |
|---|
| 434 | ! |
|---|
| 435 | |
|---|
| 436 | CALL istate_init( Nbb, Nnn, Naa ) ! ocean initial state (Dynamics and tracers) |
|---|
| 437 | |
|---|
| 438 | ! ! external forcing |
|---|
| 439 | CALL tide_init ! tidal harmonics |
|---|
| 440 | CALL sbc_init( Nbb, Nnn, Naa ) ! surface boundary conditions (including sea-ice) |
|---|
| 441 | CALL bdy_init ! Open boundaries initialisation |
|---|
| 442 | |
|---|
| 443 | ! ! Ocean physics |
|---|
| 444 | CALL zdf_phy_init( Nnn ) ! Vertical physics |
|---|
| 445 | |
|---|
| 446 | ! ! Lateral physics |
|---|
| 447 | CALL ldf_tra_init ! Lateral ocean tracer physics |
|---|
| 448 | CALL ldf_eiv_init ! eddy induced velocity param. must be done after ldf_tra_init |
|---|
| 449 | CALL ldf_dyn_init ! Lateral ocean momentum physics |
|---|
| 450 | |
|---|
| 451 | ! ! Active tracers |
|---|
| 452 | IF( ln_traqsr ) CALL tra_qsr_init ! penetrative solar radiation qsr |
|---|
| 453 | CALL tra_bbc_init ! bottom heat flux |
|---|
| 454 | CALL tra_bbl_init ! advective (and/or diffusive) bottom boundary layer scheme |
|---|
| 455 | CALL tra_dmp_init ! internal tracer damping |
|---|
| 456 | CALL tra_adv_init ! horizontal & vertical advection |
|---|
| 457 | CALL tra_ldf_init ! lateral mixing |
|---|
| 458 | |
|---|
| 459 | ! ! Dynamics |
|---|
| 460 | IF( ln_c1d ) CALL dyn_dmp_init ! internal momentum damping |
|---|
| 461 | CALL dyn_adv_init ! advection (vector or flux form) |
|---|
| 462 | CALL dyn_vor_init ! vorticity term including Coriolis |
|---|
| 463 | CALL dyn_ldf_init ! lateral mixing |
|---|
| 464 | CALL dyn_hpg_init( Nnn ) ! horizontal gradient of Hydrostatic pressure |
|---|
| 465 | CALL dyn_spg_init ! surface pressure gradient |
|---|
| 466 | |
|---|
| 467 | ! ! Icebergs |
|---|
| 468 | CALL icb_init( rn_Dt, nit000) ! initialise icebergs instance |
|---|
| 469 | |
|---|
| 470 | ! ice shelf |
|---|
| 471 | CALL isf_init( Nbb, Nnn, Naa ) |
|---|
| 472 | #if defined key_top |
|---|
| 473 | ! ! Passive tracers |
|---|
| 474 | CALL trc_init( Nbb, Nnn, Naa ) |
|---|
| 475 | #endif |
|---|
| 476 | IF( l_ldfslp ) CALL ldf_slp_init ! slope of lateral mixing |
|---|
| 477 | |
|---|
| 478 | ! ! Misc. options |
|---|
| 479 | CALL sto_par_init ! Stochastic parametrization |
|---|
| 480 | IF( ln_sto_eos ) CALL sto_pts_init ! RRandom T/S fluctuations |
|---|
| 481 | |
|---|
| 482 | ! ! Diagnostics |
|---|
| 483 | CALL flo_init( Nnn ) ! drifting Floats |
|---|
| 484 | IF( ln_diacfl ) CALL dia_cfl_init ! Initialise CFL diagnostics |
|---|
| 485 | CALL dia_dct_init ! Sections tranports |
|---|
| 486 | CALL dia_hsb_init( Nnn ) ! heat content, salt content and volume budgets |
|---|
| 487 | CALL trd_init( Nnn ) ! Mixed-layer/Vorticity/Integral constraints trends |
|---|
| 488 | CALL dia_obs_init( Nnn ) ! Initialize observational data |
|---|
| 489 | CALL dia_25h_init( Nbb ) ! 25h mean outputs |
|---|
| 490 | CALL dia_detide_init ! Weights computation for daily detiding of model diagnostics |
|---|
| 491 | IF( ln_diaobs ) CALL dia_obs( nit000-1, Nnn ) ! Observation operator for restart |
|---|
| 492 | CALL dia_mlr_init ! Initialisation of IOM context management for multiple-linear-regression analysis |
|---|
| 493 | |
|---|
| 494 | ! ! Assimilation increments |
|---|
| 495 | IF( lk_asminc ) CALL asm_inc_init( Nbb, Nnn, Nrhs ) ! Initialize assimilation increments |
|---|
| 496 | ! |
|---|
| 497 | IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA |
|---|
| 498 | ! |
|---|
| 499 | IF( ln_timing ) CALL timing_stop( 'nemo_init') |
|---|
| 500 | ! |
|---|
| 501 | END SUBROUTINE nemo_init |
|---|
| 502 | |
|---|
| 503 | |
|---|
| 504 | SUBROUTINE nemo_ctl |
|---|
| 505 | !!---------------------------------------------------------------------- |
|---|
| 506 | !! *** ROUTINE nemo_ctl *** |
|---|
| 507 | !! |
|---|
| 508 | !! ** Purpose : control print setting |
|---|
| 509 | !! |
|---|
| 510 | !! ** Method : - print namctl and namcfg information and check some consistencies |
|---|
| 511 | !!---------------------------------------------------------------------- |
|---|
| 512 | ! |
|---|
| 513 | IF(lwp) THEN ! control print |
|---|
| 514 | WRITE(numout,*) |
|---|
| 515 | WRITE(numout,*) 'nemo_ctl: Control prints' |
|---|
| 516 | WRITE(numout,*) '~~~~~~~~' |
|---|
| 517 | WRITE(numout,*) ' Namelist namctl' |
|---|
| 518 | WRITE(numout,*) ' sn_cfctl%l_runstat = ', sn_cfctl%l_runstat |
|---|
| 519 | WRITE(numout,*) ' sn_cfctl%l_trcstat = ', sn_cfctl%l_trcstat |
|---|
| 520 | WRITE(numout,*) ' sn_cfctl%l_oceout = ', sn_cfctl%l_oceout |
|---|
| 521 | WRITE(numout,*) ' sn_cfctl%l_layout = ', sn_cfctl%l_layout |
|---|
| 522 | WRITE(numout,*) ' sn_cfctl%l_prtctl = ', sn_cfctl%l_prtctl |
|---|
| 523 | WRITE(numout,*) ' sn_cfctl%l_prttrc = ', sn_cfctl%l_prttrc |
|---|
| 524 | WRITE(numout,*) ' sn_cfctl%l_oasout = ', sn_cfctl%l_oasout |
|---|
| 525 | WRITE(numout,*) ' sn_cfctl%procmin = ', sn_cfctl%procmin |
|---|
| 526 | WRITE(numout,*) ' sn_cfctl%procmax = ', sn_cfctl%procmax |
|---|
| 527 | WRITE(numout,*) ' sn_cfctl%procincr = ', sn_cfctl%procincr |
|---|
| 528 | WRITE(numout,*) ' sn_cfctl%ptimincr = ', sn_cfctl%ptimincr |
|---|
| 529 | WRITE(numout,*) ' timing by routine ln_timing = ', ln_timing |
|---|
| 530 | WRITE(numout,*) ' CFL diagnostics ln_diacfl = ', ln_diacfl |
|---|
| 531 | ENDIF |
|---|
| 532 | ! |
|---|
| 533 | IF( .NOT.ln_read_cfg ) ln_closea = .false. ! dealing possible only with a domcfg file |
|---|
| 534 | IF(lwp) THEN ! control print |
|---|
| 535 | WRITE(numout,*) |
|---|
| 536 | WRITE(numout,*) ' Namelist namcfg' |
|---|
| 537 | WRITE(numout,*) ' read domain configuration file ln_read_cfg = ', ln_read_cfg |
|---|
| 538 | WRITE(numout,*) ' filename to be read cn_domcfg = ', TRIM(cn_domcfg) |
|---|
| 539 | WRITE(numout,*) ' keep closed seas in the domain (if exist) ln_closea = ', ln_closea |
|---|
| 540 | WRITE(numout,*) ' create a configuration definition file ln_write_cfg = ', ln_write_cfg |
|---|
| 541 | WRITE(numout,*) ' filename to be written cn_domcfg_out = ', TRIM(cn_domcfg_out) |
|---|
| 542 | WRITE(numout,*) ' use file attribute if exists as i/p j-start ln_use_jattr = ', ln_use_jattr |
|---|
| 543 | ENDIF |
|---|
| 544 | ! |
|---|
| 545 | IF( 1._wp /= SIGN(1._wp,-0._wp) ) CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.', & |
|---|
| 546 | & 'Compile with key_nosignedzero enabled:', & |
|---|
| 547 | & '--> add -Dkey_nosignedzero to the definition of %CPP in your arch file' ) |
|---|
| 548 | ! |
|---|
| 549 | #if defined key_agrif |
|---|
| 550 | IF( ln_timing ) CALL ctl_stop( 'AGRIF not implemented with ln_timing = true') |
|---|
| 551 | #endif |
|---|
| 552 | ! |
|---|
| 553 | END SUBROUTINE nemo_ctl |
|---|
| 554 | |
|---|
| 555 | |
|---|
| 556 | SUBROUTINE nemo_closefile |
|---|
| 557 | !!---------------------------------------------------------------------- |
|---|
| 558 | !! *** ROUTINE nemo_closefile *** |
|---|
| 559 | !! |
|---|
| 560 | !! ** Purpose : Close the files |
|---|
| 561 | !!---------------------------------------------------------------------- |
|---|
| 562 | ! |
|---|
| 563 | IF( lk_mpp ) CALL mppsync |
|---|
| 564 | ! |
|---|
| 565 | CALL iom_close ! close all input/output files managed by iom_* |
|---|
| 566 | ! |
|---|
| 567 | IF( numstp /= -1 ) CLOSE( numstp ) ! time-step file |
|---|
| 568 | IF( numrun /= -1 ) CLOSE( numrun ) ! run statistics file |
|---|
| 569 | IF( lwm.AND.numond /= -1 ) CLOSE( numond ) ! oce output namelist |
|---|
| 570 | IF( lwm.AND.numoni /= -1 ) CLOSE( numoni ) ! ice output namelist |
|---|
| 571 | IF( numevo_ice /= -1 ) CLOSE( numevo_ice ) ! ice variables (temp. evolution) |
|---|
| 572 | IF( numout /= 6 ) CLOSE( numout ) ! standard model output file |
|---|
| 573 | IF( numdct_vol /= -1 ) CLOSE( numdct_vol ) ! volume transports |
|---|
| 574 | IF( numdct_heat /= -1 ) CLOSE( numdct_heat ) ! heat transports |
|---|
| 575 | IF( numdct_salt /= -1 ) CLOSE( numdct_salt ) ! salt transports |
|---|
| 576 | ! |
|---|
| 577 | numout = 6 ! redefine numout in case it is used after this point... |
|---|
| 578 | ! |
|---|
| 579 | END SUBROUTINE nemo_closefile |
|---|
| 580 | |
|---|
| 581 | |
|---|
| 582 | SUBROUTINE nemo_alloc |
|---|
| 583 | !!---------------------------------------------------------------------- |
|---|
| 584 | !! *** ROUTINE nemo_alloc *** |
|---|
| 585 | !! |
|---|
| 586 | !! ** Purpose : Allocate all the dynamic arrays of the OCE modules |
|---|
| 587 | !! |
|---|
| 588 | !! ** Method : |
|---|
| 589 | !!---------------------------------------------------------------------- |
|---|
| 590 | USE diawri , ONLY : dia_wri_alloc |
|---|
| 591 | USE dom_oce , ONLY : dom_oce_alloc |
|---|
| 592 | USE trc_oce , ONLY : trc_oce_alloc |
|---|
| 593 | USE bdy_oce , ONLY : bdy_oce_alloc |
|---|
| 594 | ! |
|---|
| 595 | INTEGER :: ierr |
|---|
| 596 | !!---------------------------------------------------------------------- |
|---|
| 597 | ! |
|---|
| 598 | ierr = oce_alloc () ! ocean |
|---|
| 599 | ierr = ierr + dia_wri_alloc() |
|---|
| 600 | ierr = ierr + dom_oce_alloc() ! ocean domain |
|---|
| 601 | ierr = ierr + zdf_oce_alloc() ! ocean vertical physics |
|---|
| 602 | ierr = ierr + trc_oce_alloc() ! shared TRC / TRA arrays |
|---|
| 603 | ierr = ierr + bdy_oce_alloc() ! bdy masks (incl. initialization) |
|---|
| 604 | ! |
|---|
| 605 | CALL mpp_sum( 'nemogcm', ierr ) |
|---|
| 606 | IF( ierr /= 0 ) CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' ) |
|---|
| 607 | ! |
|---|
| 608 | END SUBROUTINE nemo_alloc |
|---|
| 609 | |
|---|
| 610 | |
|---|
| 611 | SUBROUTINE nemo_set_cfctl(sn_cfctl, setto ) |
|---|
| 612 | !!---------------------------------------------------------------------- |
|---|
| 613 | !! *** ROUTINE nemo_set_cfctl *** |
|---|
| 614 | !! |
|---|
| 615 | !! ** Purpose : Set elements of the output control structure to setto. |
|---|
| 616 | !! |
|---|
| 617 | !! ** Method : Note this routine can be used to switch on/off some |
|---|
| 618 | !! types of output for selected areas. |
|---|
| 619 | !!---------------------------------------------------------------------- |
|---|
| 620 | TYPE(sn_ctl), INTENT(inout) :: sn_cfctl |
|---|
| 621 | LOGICAL , INTENT(in ) :: setto |
|---|
| 622 | !!---------------------------------------------------------------------- |
|---|
| 623 | sn_cfctl%l_runstat = setto |
|---|
| 624 | sn_cfctl%l_trcstat = setto |
|---|
| 625 | sn_cfctl%l_oceout = setto |
|---|
| 626 | sn_cfctl%l_layout = setto |
|---|
| 627 | sn_cfctl%l_prtctl = setto |
|---|
| 628 | sn_cfctl%l_prttrc = setto |
|---|
| 629 | sn_cfctl%l_oasout = setto |
|---|
| 630 | END SUBROUTINE nemo_set_cfctl |
|---|
| 631 | |
|---|
| 632 | !!====================================================================== |
|---|
| 633 | END MODULE nemogcm |
|---|
