New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
stpctl.F90 in NEMO/trunk/src/OCE – NEMO

source: NEMO/trunk/src/OCE/stpctl.F90 @ 14053

Last change on this file since 14053 was 14053, checked in by techene, 3 years ago

#2385 added to the trunk
  • Property svn:keywords set to Id
File size: 19.5 KB
Line 
1MODULE stpctl
2   !!======================================================================
3   !!                       ***  MODULE  stpctl  ***
4   !! Ocean run control :  gross check of the ocean time stepping
5   !!======================================================================
6   !! History :  OPA  ! 1991-03  (G. Madec) Original code
7   !!            6.0  ! 1992-06  (M. Imbard)
8   !!            8.0  ! 1997-06  (A.M. Treguier)
9   !!   NEMO     1.0  ! 2002-06  (G. Madec)  F90: Free form and module
10   !!            2.0  ! 2009-07  (G. Madec)  Add statistic for time-spliting
11   !!            3.7  ! 2016-09  (G. Madec)  Remove solver
12   !!            4.0  ! 2017-04  (G. Madec)  regroup global communications
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   stp_ctl      : Control the run
17   !!----------------------------------------------------------------------
18   USE oce             ! ocean dynamics and tracers variables
19   USE dom_oce         ! ocean space and time domain variables
20   USE c1d             ! 1D vertical configuration
21   USE zdf_oce ,  ONLY : ln_zad_Aimp       ! ocean vertical physics variables
22   USE wet_dry,   ONLY : ll_wd, ssh_ref    ! reference depth for negative bathy
23   ! 
24   USE diawri          ! Standard run outputs       (dia_wri_state routine)
25   USE in_out_manager  ! I/O manager
26   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
27   USE lib_mpp         ! distributed memory computing
28   USE netcdf          ! NetCDF library
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC stp_ctl           ! routine called by step.F90
34
35   INTEGER                ::   nrunid   ! netcdf file id
36   INTEGER, DIMENSION(8)  ::   nvarid   ! netcdf variable id
37   !!----------------------------------------------------------------------
38   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
39   !! $Id$
40   !! Software governed by the CeCILL license (see ./LICENSE)
41   !!----------------------------------------------------------------------
42CONTAINS
43
44   SUBROUTINE stp_ctl( kt, Kmm )
45      !!----------------------------------------------------------------------
46      !!                    ***  ROUTINE stp_ctl  ***
47      !!                     
48      !! ** Purpose :   Control the run
49      !!
50      !! ** Method  : - Save the time step in numstp
51      !!              - Stop the run IF problem encountered by setting nstop > 0
52      !!                Problems checked: |ssh| maximum larger than 10 m
53      !!                                  |U|   maximum larger than 10 m/s
54      !!                                  negative sea surface salinity
55      !!
56      !! ** Actions :   "time.step" file = last ocean time-step
57      !!                "run.stat"  file = run statistics
58      !!                 nstop indicator sheared among all local domain
59      !!----------------------------------------------------------------------
60      INTEGER, INTENT(in   ) ::   kt       ! ocean time-step index
61      INTEGER, INTENT(in   ) ::   Kmm      ! ocean time level index
62      !!
63      INTEGER                         ::   ji                                    ! dummy loop indices
64      INTEGER                         ::   idtime, istatus
65      INTEGER , DIMENSION(9)          ::   iareasum, iareamin, iareamax
66      INTEGER , DIMENSION(3,4)        ::   iloc                                  ! min/max loc indices
67      REAL(wp)                        ::   zzz                                   ! local real
68      REAL(wp), DIMENSION(9)          ::   zmax, zmaxlocal
69      LOGICAL                         ::   ll_wrtstp, ll_colruns, ll_wrtruns, ll_0oce
70      LOGICAL, DIMENSION(jpi,jpj,jpk) ::   llmsk
71      CHARACTER(len=20)               ::   clname
72      !!----------------------------------------------------------------------
73      !
74      IF( nstop > 0 .AND. ngrdstop > -1 )   RETURN   !   stpctl was already called by a child grid
75      !
76      ll_wrtstp  = ( MOD( kt-nit000, sn_cfctl%ptimincr ) == 0 ) .OR. ( kt == nitend )
77      ll_colruns = ll_wrtstp .AND. sn_cfctl%l_runstat .AND. jpnij > 1 
78      ll_wrtruns = ( ll_colruns .OR. jpnij == 1 ) .AND. lwm
79      !
80      IF( kt == nit000 ) THEN
81         !
82         IF( lwp ) THEN
83            WRITE(numout,*)
84            WRITE(numout,*) 'stp_ctl : time-stepping control'
85            WRITE(numout,*) '~~~~~~~'
86         ENDIF
87         !                                ! open time.step    ascii file, done only by 1st subdomain
88         IF( lwm )   CALL ctl_opn( numstp, 'time.step', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea )
89         !
90         IF( ll_wrtruns ) THEN
91            !                             ! open run.stat     ascii file, done only by 1st subdomain
92            CALL ctl_opn( numrun, 'run.stat', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea )
93            !                             ! open run.stat.nc netcdf file, done only by 1st subdomain
94            clname = 'run.stat.nc'
95            IF( .NOT. Agrif_Root() )   clname = TRIM(Agrif_CFixed())//"_"//TRIM(clname)
96            istatus = NF90_CREATE( TRIM(clname), NF90_CLOBBER, nrunid )
97            istatus = NF90_DEF_DIM( nrunid, 'time', NF90_UNLIMITED, idtime )
98            istatus = NF90_DEF_VAR( nrunid, 'abs_ssh_max', NF90_DOUBLE, (/ idtime /), nvarid(1) )
99            istatus = NF90_DEF_VAR( nrunid,   'abs_u_max', NF90_DOUBLE, (/ idtime /), nvarid(2) )
100            istatus = NF90_DEF_VAR( nrunid,       's_min', NF90_DOUBLE, (/ idtime /), nvarid(3) )
101            istatus = NF90_DEF_VAR( nrunid,       's_max', NF90_DOUBLE, (/ idtime /), nvarid(4) )
102            istatus = NF90_DEF_VAR( nrunid,       't_min', NF90_DOUBLE, (/ idtime /), nvarid(5) )
103            istatus = NF90_DEF_VAR( nrunid,       't_max', NF90_DOUBLE, (/ idtime /), nvarid(6) )
104            IF( ln_zad_Aimp ) THEN
105               istatus = NF90_DEF_VAR( nrunid,   'Cf_max', NF90_DOUBLE, (/ idtime /), nvarid(7) )
106               istatus = NF90_DEF_VAR( nrunid,'abs_wi_max',NF90_DOUBLE, (/ idtime /), nvarid(8) )
107            ENDIF
108            istatus = NF90_ENDDEF(nrunid)
109         ENDIF
110         !   
111      ENDIF
112      !
113      !                                   !==              write current time step              ==!
114      !                                   !==  done only by 1st subdomain at writting timestep  ==!
115      IF( lwm .AND. ll_wrtstp ) THEN
116         WRITE ( numstp, '(1x, i8)' )   kt
117         REWIND( numstp )
118      ENDIF
119      !                                   !==            test of local extrema           ==!
120      !                                   !==  done by all processes at every time step  ==!
121      !
122      llmsk(   1:Nis1,:,:) = .FALSE.                                              ! exclude halos from the checked region
123      llmsk(Nie1: jpi,:,:) = .FALSE.
124      llmsk(:,   1:Njs1,:) = .FALSE.
125      llmsk(:,Nje1: jpj,:) = .FALSE.
126      !
127      llmsk(Nis0:Nie0,Njs0:Nje0,1) = ssmask(Nis0:Nie0,Njs0:Nje0) == 1._wp         ! define only the inner domain
128      !
129      ll_0oce = .NOT. ANY( llmsk(:,:,1) )                                         ! no ocean point in the inner domain?
130      !
131      IF( ll_wd ) THEN
132         zmax(1) = MAXVAL( ABS( ssh(:,:,Kmm) + ssh_ref ), mask = llmsk(:,:,1) )   ! ssh max
133      ELSE
134         zmax(1) = MAXVAL( ABS( ssh(:,:,Kmm)           ), mask = llmsk(:,:,1) )   ! ssh max
135      ENDIF
136      llmsk(Nis0:Nie0,Njs0:Nje0,:) = umask(Nis0:Nie0,Njs0:Nje0,:) == 1._wp        ! define only the inner domain
137      zmax(2) = MAXVAL(  ABS( uu(:,:,:,Kmm) ), mask = llmsk )                     ! velocity max (zonal only)
138      llmsk(Nis0:Nie0,Njs0:Nje0,:) = tmask(Nis0:Nie0,Njs0:Nje0,:) == 1._wp        ! define only the inner domain
139      zmax(3) = MAXVAL( -ts(:,:,:,jp_sal,Kmm), mask = llmsk )                     ! minus salinity max
140      zmax(4) = MAXVAL(  ts(:,:,:,jp_sal,Kmm), mask = llmsk )                     !       salinity max
141      IF( ll_colruns .OR. jpnij == 1 ) THEN     ! following variables are used only in the netcdf file
142         zmax(5) = MAXVAL( -ts(:,:,:,jp_tem,Kmm), mask = llmsk )                  ! minus temperature max
143         zmax(6) = MAXVAL(  ts(:,:,:,jp_tem,Kmm), mask = llmsk )                  !       temperature max
144         IF( ln_zad_Aimp ) THEN
145            zmax(7) = MAXVAL(   Cu_adv(:,:,:)   , mask = llmsk )                  ! partitioning coeff. max
146            llmsk(:,:,:) = wmask(:,:,:) == 1._wp
147            zmax(8) = MAXVAL(  ABS( wi(:,:,:) ) , mask = llmsk )                  ! implicit vertical vel. max
148         ELSE
149            zmax(7:8) = 0._wp
150         ENDIF
151      ELSE
152         zmax(5:8) = 0._wp
153      ENDIF
154      zmax(9) = REAL( nstop, wp )                                                 ! stop indicator
155      !
156      !                                   !==               get global extrema             ==!
157      !                                   !==  done by all processes if writting run.stat  ==!
158      IF( ll_colruns ) THEN
159         zmaxlocal(:) = zmax(:)
160         CALL mpp_max( "stpctl", zmax )          ! max over the global domain: ok even of ll_0oce = .true.
161         nstop = NINT( zmax(9) )                 ! update nstop indicator (now sheared among all local domains)
162      ELSE
163         ! if no ocean point: MAXVAL returns -HUGE => we must overwrite this value to avoid error handling bellow.
164         IF( ll_0oce )   zmax(1:4) = (/ 0._wp, 0._wp, -1._wp, 1._wp /)   ! default "valid" values...
165      ENDIF
166      !
167      zmax(3) = -zmax(3)                         ! move back from max(-zz) to min(zz) : easier to manage!
168      zmax(5) = -zmax(5)                         ! move back from max(-zz) to min(zz) : easier to manage!
169      IF( ll_colruns ) THEN
170         zmaxlocal(3) = -zmaxlocal(3)            ! move back from max(-zz) to min(zz) : easier to manage!
171         zmaxlocal(5) = -zmaxlocal(5)            ! move back from max(-zz) to min(zz) : easier to manage!
172      ENDIF
173      !
174      !                                   !==              write "run.stat" files              ==!
175      !                                   !==  done only by 1st subdomain at writting timestep  ==!
176      IF( ll_wrtruns ) THEN
177         WRITE(numrun,9500) kt, zmax(1), zmax(2), zmax(3), zmax(4)
178         DO ji = 1, 6 + 2 * COUNT( (/ln_zad_Aimp/) )
179            istatus = NF90_PUT_VAR( nrunid, nvarid(ji), (/zmax(ji)/), (/kt/), (/1/) )
180         END DO
181         IF( kt == nitend )   istatus = NF90_CLOSE(nrunid)
182      ENDIF
183      !                                   !==               error handling               ==!
184      !                                   !==  done by all processes at every time step  ==!
185      !
186      IF(  zmax(1) >   20._wp .OR.   &                   ! too large sea surface height ( > 20 m )
187         & zmax(2) >   10._wp .OR.   &                   ! too large velocity ( > 10 m/s)
188         & zmax(3) <=   0._wp .OR.   &                   ! negative or zero sea surface salinity
189         & zmax(4) >= 100._wp .OR.   &                   ! too large sea surface salinity ( > 100 )
190         & zmax(4) <    0._wp .OR.   &                   ! too large sea surface salinity (keep this line for sea-ice)
191         & ISNAN( zmax(1) + zmax(2) + zmax(3) ) .OR.   &               ! NaN encounter in the tests
192         & ABS(   zmax(1) + zmax(2) + zmax(3) ) > HUGE(1._wp) ) THEN   ! Infinity encounter in the tests
193         !
194         iloc(:,:) = 0
195         IF( ll_colruns ) THEN   ! zmax is global, so it is the same on all subdomains -> no dead lock with mpp_maxloc
196            ! first: close the netcdf file, so we can read it
197            IF( lwm .AND. kt /= nitend )   istatus = NF90_CLOSE(nrunid)
198            ! get global loc on the min/max
199            llmsk(Nis0:Nie0,Njs0:Nje0,1) = ssmask(Nis0:Nie0,Njs0:Nje0 ) == 1._wp         ! define only the inner domain
200            CALL mpp_maxloc( 'stpctl', ABS(ssh(:,:,         Kmm)), llmsk(:,:,1), zzz, iloc(1:2,1) )   ! mpp_maxloc ok if mask = F
201            llmsk(Nis0:Nie0,Njs0:Nje0,:) = umask(Nis0:Nie0,Njs0:Nje0,:) == 1._wp        ! define only the inner domain
202            CALL mpp_maxloc( 'stpctl', ABS( uu(:,:,:,       Kmm)), llmsk(:,:,:), zzz, iloc(1:3,2) )
203            llmsk(Nis0:Nie0,Njs0:Nje0,:) = tmask(Nis0:Nie0,Njs0:Nje0,:) == 1._wp        ! define only the inner domain
204            CALL mpp_minloc( 'stpctl',      ts(:,:,:,jp_sal,Kmm) , llmsk(:,:,:), zzz, iloc(1:3,3) )
205            CALL mpp_maxloc( 'stpctl',      ts(:,:,:,jp_sal,Kmm) , llmsk(:,:,:), zzz, iloc(1:3,4) )
206            ! find which subdomain has the max.
207            iareamin(:) = jpnij+1   ;   iareamax(:) = 0   ;   iareasum(:) = 0
208            DO ji = 1, 9
209               IF( zmaxlocal(ji) == zmax(ji) ) THEN
210                  iareamin(ji) = narea   ;   iareamax(ji) = narea   ;   iareasum(ji) = 1
211               ENDIF
212            END DO
213            CALL mpp_min( "stpctl", iareamin )         ! min over the global domain
214            CALL mpp_max( "stpctl", iareamax )         ! max over the global domain
215            CALL mpp_sum( "stpctl", iareasum )         ! sum over the global domain
216         ELSE                    ! find local min and max locations:
217            ! if we are here, this means that the subdomain contains some oce points -> no need to test the mask used in maxloc
218            llmsk(Nis0:Nie0,Njs0:Nje0,1) = ssmask(Nis0:Nie0,Njs0:Nje0 ) == 1._wp        ! define only the inner domain
219            iloc(1:2,1) = MAXLOC( ABS( ssh(:,:,         Kmm)), mask = llmsk(:,:,1) )
220            llmsk(Nis0:Nie0,Njs0:Nje0,:) = umask(Nis0:Nie0,Njs0:Nje0,:) == 1._wp        ! define only the inner domain
221            iloc(1:3,2) = MAXLOC( ABS(  uu(:,:,:,       Kmm)), mask = llmsk(:,:,:) )
222            llmsk(Nis0:Nie0,Njs0:Nje0,:) = tmask(Nis0:Nie0,Njs0:Nje0,:) == 1._wp        ! define only the inner domain
223            iloc(1:3,3) = MINLOC(       ts(:,:,:,jp_sal,Kmm) , mask = llmsk(:,:,:) )
224            iloc(1:3,4) = MAXLOC(       ts(:,:,:,jp_sal,Kmm) , mask = llmsk(:,:,:) )
225            DO ji = 1, 4   ! local domain indices ==> global domain indices, excluding halos
226               iloc(1:2,ji) = (/ mig0(iloc(1,ji)), mjg0(iloc(2,ji)) /)
227            END DO
228            iareamin(:) = narea   ;   iareamax(:) = narea   ;   iareasum(:) = 1         ! this is local information
229         ENDIF
230         !
231         WRITE(ctmp1,*) ' stp_ctl: |ssh| > 20 m  or  |U| > 10 m/s  or  S <= 0  or  S >= 100  or  NaN encounter in the tests'
232         CALL wrt_line( ctmp2, kt, '|ssh| max', zmax(1), iloc(:,1), iareasum(1), iareamin(1), iareamax(1) )
233         CALL wrt_line( ctmp3, kt, '|U|   max', zmax(2), iloc(:,2), iareasum(2), iareamin(2), iareamax(2) )
234         CALL wrt_line( ctmp4, kt, 'Sal   min', zmax(3), iloc(:,3), iareasum(3), iareamin(3), iareamax(3) )
235         CALL wrt_line( ctmp5, kt, 'Sal   max', zmax(4), iloc(:,4), iareasum(4), iareamin(4), iareamax(4) )
236         IF( Agrif_Root() ) THEN
237            WRITE(ctmp6,*) '      ===> output of last computed fields in output.abort* files'
238         ELSE
239            WRITE(ctmp6,*) '      ===> output of last computed fields in '//TRIM(Agrif_CFixed())//'_output.abort* files'
240         ENDIF
241         !
242         CALL dia_wri_state( Kmm, 'output.abort' )     ! create an output.abort file
243         !
244         IF( ll_colruns .or. jpnij == 1 ) THEN   ! all processes synchronized -> use lwp to print in opened ocean.output files
245            IF(lwp) THEN   ;   CALL ctl_stop( ctmp1, ' ', ctmp2, ctmp3, ctmp4, ctmp5, ' ', ctmp6 )
246            ELSE           ;   nstop = MAX(1, nstop)   ! make sure nstop > 0 (automatically done when calling ctl_stop)
247            ENDIF
248         ELSE                                    ! only mpi subdomains with errors are here -> STOP now
249            CALL ctl_stop( 'STOP', ctmp1, ' ', ctmp2, ctmp3, ctmp4, ctmp5, ' ', ctmp6 )
250         ENDIF
251         !
252      ENDIF
253      !
254      IF( nstop > 0 ) THEN                                                  ! an error was detected and we did not abort yet...
255         ngrdstop = Agrif_Fixed()                                           ! store which grid got this error
256         IF( .NOT. ll_colruns .AND. jpnij > 1 )   CALL ctl_stop( 'STOP' )   ! we must abort here to avoid MPI deadlock
257      ENDIF
258      !
2599500  FORMAT(' it :', i8, '    |ssh|_max: ', D23.16, ' |U|_max: ', D23.16,' S_min: ', D23.16,' S_max: ', D23.16)
260      !
261   END SUBROUTINE stp_ctl
262
263
264   SUBROUTINE wrt_line( cdline, kt, cdprefix, pval, kloc, ksum, kmin, kmax )
265      !!----------------------------------------------------------------------
266      !!                     ***  ROUTINE wrt_line  ***
267      !!
268      !! ** Purpose :   write information line
269      !!
270      !!----------------------------------------------------------------------
271      CHARACTER(len=*),      INTENT(  out) ::   cdline
272      CHARACTER(len=*),      INTENT(in   ) ::   cdprefix
273      REAL(wp),              INTENT(in   ) ::   pval
274      INTEGER, DIMENSION(3), INTENT(in   ) ::   kloc
275      INTEGER,               INTENT(in   ) ::   kt, ksum, kmin, kmax
276      !
277      CHARACTER(len=80) ::   clsuff
278      CHARACTER(len=9 ) ::   clkt, clsum, clmin, clmax
279      CHARACTER(len=9 ) ::   cli, clj, clk
280      CHARACTER(len=1 ) ::   clfmt
281      CHARACTER(len=4 ) ::   cl4   ! needed to be able to compile with Agrif, I don't know why
282      INTEGER           ::   ifmtk
283      !!----------------------------------------------------------------------
284      WRITE(clkt , '(i9)') kt
285     
286      WRITE(clfmt, '(i1)') INT(LOG10(REAL(jpnij  ,wp))) + 1     ! how many digits to we need to write ? (we decide max = 9)
287      !!! WRITE(clsum, '(i'//clfmt//')') ksum                   ! this is creating a compilation error with AGRIF
288      cl4 = '(i'//clfmt//')'   ;   WRITE(clsum, cl4) ksum
289      WRITE(clfmt, '(i1)') INT(LOG10(REAL(MAX(1,jpnij-1),wp))) + 1    ! how many digits to we need to write ? (we decide max = 9)
290      cl4 = '(i'//clfmt//')'   ;   WRITE(clmin, cl4) kmin-1
291                                   WRITE(clmax, cl4) kmax-1
292      !
293      WRITE(clfmt, '(i1)') INT(LOG10(REAL(jpiglo,wp))) + 1      ! how many digits to we need to write jpiglo? (we decide max = 9)
294      cl4 = '(i'//clfmt//')'   ;   WRITE(cli, cl4) kloc(1)      ! this is ok with AGRIF
295      WRITE(clfmt, '(i1)') INT(LOG10(REAL(jpjglo,wp))) + 1      ! how many digits to we need to write jpjglo? (we decide max = 9)
296      cl4 = '(i'//clfmt//')'   ;   WRITE(clj, cl4) kloc(2)      ! this is ok with AGRIF
297      !
298      IF( ksum == 1 ) THEN   ;   WRITE(clsuff,9100) TRIM(clmin)
299      ELSE                   ;   WRITE(clsuff,9200) TRIM(clsum), TRIM(clmin), TRIM(clmax)
300      ENDIF
301      IF(kloc(3) == 0) THEN
302         ifmtk = INT(LOG10(REAL(jpk,wp))) + 1                   ! how many digits to we need to write jpk? (we decide max = 9)
303         clk = REPEAT(' ', ifmtk)                               ! create the equivalent in blank string
304         WRITE(cdline,9300) TRIM(ADJUSTL(clkt)), TRIM(ADJUSTL(cdprefix)), pval, TRIM(cli), TRIM(clj), clk(1:ifmtk), TRIM(clsuff)
305      ELSE
306         WRITE(clfmt, '(i1)') INT(LOG10(REAL(jpk,wp))) + 1      ! how many digits to we need to write jpk? (we decide max = 9)
307         !!! WRITE(clk, '(i'//clfmt//')') kloc(3)               ! this is creating a compilation error with AGRIF
308         cl4 = '(i'//clfmt//')'   ;   WRITE(clk, cl4) kloc(3)   ! this is ok with AGRIF
309         WRITE(cdline,9400) TRIM(ADJUSTL(clkt)), TRIM(ADJUSTL(cdprefix)), pval, TRIM(cli), TRIM(clj),    TRIM(clk), TRIM(clsuff)
310      ENDIF
311      !
3129100  FORMAT('MPI rank ', a)
3139200  FORMAT('found in ', a, ' MPI tasks, spread out among ranks ', a, ' to ', a)
3149300  FORMAT('kt ', a, ' ', a, ' ', 1pg11.4, ' at i j   ', a, ' ', a, ' ', a, ' ', a)
3159400  FORMAT('kt ', a, ' ', a, ' ', 1pg11.4, ' at i j k ', a, ' ', a, ' ', a, ' ', a)
316      !
317   END SUBROUTINE wrt_line
318
319
320   !!======================================================================
321END MODULE stpctl
Note: See TracBrowser for help on using the repository browser.