| 1 | MODULE stpmlf |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE stpMLF *** |
|---|
| 4 | !! Time-stepping : manager of the ocean, tracer and ice time stepping |
|---|
| 5 | !! using Modified Leap Frog for OCE |
|---|
| 6 | !!====================================================================== |
|---|
| 7 | !! History : OPA ! 1991-03 (G. Madec) Original code |
|---|
| 8 | !! - ! 1991-11 (G. Madec) |
|---|
| 9 | !! - ! 1992-06 (M. Imbard) add a first output record |
|---|
| 10 | !! - ! 1996-04 (G. Madec) introduction of dynspg |
|---|
| 11 | !! - ! 1996-04 (M.A. Foujols) introduction of passive tracer |
|---|
| 12 | !! 8.0 ! 1997-06 (G. Madec) new architecture of call |
|---|
| 13 | !! 8.2 ! 1997-06 (G. Madec, M. Imbard, G. Roullet) free surface |
|---|
| 14 | !! - ! 1999-02 (G. Madec, N. Grima) hpg implicit |
|---|
| 15 | !! - ! 2000-07 (J-M Molines, M. Imbard) Open Bondary Conditions |
|---|
| 16 | !! NEMO 1.0 ! 2002-06 (G. Madec) free form, suppress macro-tasking |
|---|
| 17 | !! - ! 2004-08 (C. Talandier) New trends organization |
|---|
| 18 | !! - ! 2005-01 (C. Ethe) Add the KPP closure scheme |
|---|
| 19 | !! - ! 2005-11 (G. Madec) Reorganisation of tra and dyn calls |
|---|
| 20 | !! - ! 2006-01 (L. Debreu, C. Mazauric) Agrif implementation |
|---|
| 21 | !! - ! 2006-07 (S. Masson) restart using iom |
|---|
| 22 | !! 3.2 ! 2009-02 (G. Madec, R. Benshila) reintroduicing z*-coordinate |
|---|
| 23 | !! - ! 2009-06 (S. Masson, G. Madec) TKE restart compatible with key_cpl |
|---|
| 24 | !! 3.3 ! 2010-05 (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface |
|---|
| 25 | !! - ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase + merge TRC-TRA |
|---|
| 26 | !! 3.4 ! 2011-04 (G. Madec, C. Ethe) Merge of dtatem and dtasal |
|---|
| 27 | !! 3.6 ! 2012-07 (J. Simeon, G. Madec. C. Ethe) Online coarsening of outputs |
|---|
| 28 | !! 3.6 ! 2014-04 (F. Roquet, G. Madec) New equations of state |
|---|
| 29 | !! 3.6 ! 2014-10 (E. Clementi, P. Oddo) Add Qiao vertical mixing in case of waves |
|---|
| 30 | !! 3.7 ! 2014-10 (G. Madec) LDF simplication |
|---|
| 31 | !! - ! 2014-12 (G. Madec) remove KPP scheme |
|---|
| 32 | !! - ! 2015-11 (J. Chanut) free surface simplification (remove filtered free surface) |
|---|
| 33 | !! 4.0 ! 2017-05 (G. Madec) introduction of the vertical physics manager (zdfphy) |
|---|
| 34 | !! 4.1 ! 2019-08 (A. Coward, D. Storkey) rewrite in preparation for new timestepping scheme |
|---|
| 35 | !! 4.x ! 2020-08 (S. Techene, G. Madec) quasi eulerian coordinate time stepping |
|---|
| 36 | !!---------------------------------------------------------------------- |
|---|
| 37 | |
|---|
| 38 | #if defined key_qco || defined key_linssh |
|---|
| 39 | !!---------------------------------------------------------------------- |
|---|
| 40 | !! 'key_qco' Quasi-Eulerian vertical coordinate |
|---|
| 41 | !! OR |
|---|
| 42 | !! 'key_linssh Fixed in time vertical coordinate |
|---|
| 43 | !!---------------------------------------------------------------------- |
|---|
| 44 | |
|---|
| 45 | !!---------------------------------------------------------------------- |
|---|
| 46 | !! stp_MLF : NEMO modified Leap Frog time-stepping with qco or linssh |
|---|
| 47 | !!---------------------------------------------------------------------- |
|---|
| 48 | USE step_oce ! time stepping definition modules |
|---|
| 49 | ! |
|---|
| 50 | USE domqco ! quasi-eulerian coordinate |
|---|
| 51 | USE traatf_qco ! time filtering (tra_atf_qco routine) |
|---|
| 52 | USE dynatf_qco ! time filtering (dyn_atf_qco routine) |
|---|
| 53 | |
|---|
| 54 | USE bdydyn ! ocean open boundary conditions (define bdy_dyn) |
|---|
| 55 | |
|---|
| 56 | #if defined key_agrif |
|---|
| 57 | USE agrif_oce_interp |
|---|
| 58 | #endif |
|---|
| 59 | |
|---|
| 60 | IMPLICIT NONE |
|---|
| 61 | PRIVATE |
|---|
| 62 | |
|---|
| 63 | PUBLIC stp_MLF ! called by nemogcm.F90 |
|---|
| 64 | |
|---|
| 65 | ! !** time level indices **! |
|---|
| 66 | INTEGER, PUBLIC :: Nbb, Nnn, Naa, Nrhs !: used by nemo_init |
|---|
| 67 | |
|---|
| 68 | !! * Substitutions |
|---|
| 69 | # include "domzgr_substitute.h90" |
|---|
| 70 | !!---------------------------------------------------------------------- |
|---|
| 71 | !! NEMO/OCE 4.0 , NEMO Consortium (2018) |
|---|
| 72 | !! $Id: step.F90 12377 2020-02-12 14:39:06Z acc $ |
|---|
| 73 | !! Software governed by the CeCILL license (see ./LICENSE) |
|---|
| 74 | !!---------------------------------------------------------------------- |
|---|
| 75 | CONTAINS |
|---|
| 76 | |
|---|
| 77 | #if defined key_agrif |
|---|
| 78 | RECURSIVE SUBROUTINE stp_MLF( ) |
|---|
| 79 | INTEGER :: kstp ! ocean time-step index |
|---|
| 80 | #else |
|---|
| 81 | SUBROUTINE stp_MLF( kstp ) |
|---|
| 82 | INTEGER, INTENT(in) :: kstp ! ocean time-step index |
|---|
| 83 | #endif |
|---|
| 84 | !!---------------------------------------------------------------------- |
|---|
| 85 | !! *** ROUTINE stp_MLF *** |
|---|
| 86 | !! |
|---|
| 87 | !! ** Purpose : - Time stepping of OPA (momentum and active tracer eqs.) |
|---|
| 88 | !! - Time stepping of SI3 (dynamic and thermodynamic eqs.) |
|---|
| 89 | !! - Time stepping of TRC (passive tracer eqs.) |
|---|
| 90 | !! |
|---|
| 91 | !! ** Method : -1- Update forcings and data |
|---|
| 92 | !! -2- Update ocean physics |
|---|
| 93 | !! -3- Compute the t and s trends |
|---|
| 94 | !! -4- Update t and s |
|---|
| 95 | !! -5- Compute the momentum trends |
|---|
| 96 | !! -6- Update the horizontal velocity |
|---|
| 97 | !! -7- Compute the diagnostics variables (rd,N2, hdiv,w) |
|---|
| 98 | !! -8- Outputs and diagnostics |
|---|
| 99 | !!---------------------------------------------------------------------- |
|---|
| 100 | INTEGER :: ji, jj, jk ! dummy loop indice |
|---|
| 101 | INTEGER :: indic ! error indicator if < 0 |
|---|
| 102 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: zgdept |
|---|
| 103 | REAL(wp), ALLOCATABLE, DIMENSION(:,:) :: zssh_f |
|---|
| 104 | !! --------------------------------------------------------------------- |
|---|
| 105 | #if defined key_agrif |
|---|
| 106 | kstp = nit000 + Agrif_Nb_Step() |
|---|
| 107 | Kbb_a = Nbb; Kmm_a = Nnn; Krhs_a = Nrhs ! agrif_oce module copies of time level indices |
|---|
| 108 | IF( lk_agrif_debug ) THEN |
|---|
| 109 | IF( Agrif_Root() .and. lwp) WRITE(*,*) '---' |
|---|
| 110 | IF(lwp) WRITE(*,*) 'Grid Number', Agrif_Fixed(),' time step ', kstp, 'int tstep', Agrif_NbStepint() |
|---|
| 111 | ENDIF |
|---|
| 112 | IF( kstp == nit000 + 1 ) lk_agrif_fstep = .FALSE. |
|---|
| 113 | # if defined key_iomput |
|---|
| 114 | IF( Agrif_Nbstepint() == 0 ) CALL iom_swap( cxios_context ) |
|---|
| 115 | # endif |
|---|
| 116 | #endif |
|---|
| 117 | ! |
|---|
| 118 | IF( ln_timing ) CALL timing_start('stp_MLF') |
|---|
| 119 | ! |
|---|
| 120 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 121 | ! model timestep |
|---|
| 122 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 123 | ! |
|---|
| 124 | IF( l_1st_euler ) THEN ! start or restart with Euler 1st time-step |
|---|
| 125 | rDt = rn_Dt |
|---|
| 126 | r1_Dt = 1._wp / rDt |
|---|
| 127 | ENDIF |
|---|
| 128 | ! |
|---|
| 129 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 130 | ! update I/O and calendar |
|---|
| 131 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 132 | indic = 0 ! reset to no error condition |
|---|
| 133 | |
|---|
| 134 | IF( kstp == nit000 ) THEN ! initialize IOM context (must be done after nemo_init for AGRIF+XIOS+OASIS) |
|---|
| 135 | CALL iom_init( cxios_context, ld_closedef=.FALSE. ) ! for model grid (including passible AGRIF zoom) |
|---|
| 136 | IF( lk_diamlr ) CALL dia_mlr_iom_init ! with additional setup for multiple-linear-regression analysis |
|---|
| 137 | CALL iom_init_closedef |
|---|
| 138 | IF( ln_crs ) CALL iom_init( TRIM(cxios_context)//"_crs" ) ! for coarse grid |
|---|
| 139 | ENDIF |
|---|
| 140 | IF( kstp /= nit000 ) CALL day( kstp ) ! Calendar (day was already called at nit000 in day_init) |
|---|
| 141 | CALL iom_setkt( kstp - nit000 + 1, cxios_context ) ! tell IOM we are at time step kstp |
|---|
| 142 | IF( ln_crs ) CALL iom_setkt( kstp - nit000 + 1, TRIM(cxios_context)//"_crs" ) ! tell IOM we are at time step kstp |
|---|
| 143 | |
|---|
| 144 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 145 | ! Update external forcing (tides, open boundaries, ice shelf interaction and surface boundary condition (including sea-ice) |
|---|
| 146 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 147 | IF( ln_tide ) CALL tide_update( kstp ) ! update tide potential |
|---|
| 148 | IF( ln_apr_dyn ) CALL sbc_apr ( kstp ) ! atmospheric pressure (NB: call before bdy_dta which needs ssh_ib) |
|---|
| 149 | IF( ln_bdy ) CALL bdy_dta ( kstp, Nnn ) ! update dynamic & tracer data at open boundaries |
|---|
| 150 | IF( ln_isf ) CALL isf_stp ( kstp, Nnn ) |
|---|
| 151 | CALL sbc ( kstp, Nbb, Nnn ) ! Sea Boundary Condition (including sea-ice) |
|---|
| 152 | |
|---|
| 153 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 154 | ! Update stochastic parameters and random T/S fluctuations |
|---|
| 155 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 156 | IF( ln_sto_eos ) CALL sto_par( kstp ) ! Stochastic parameters |
|---|
| 157 | IF( ln_sto_eos ) CALL sto_pts( ts(:,:,:,:,Nnn) ) ! Random T/S fluctuations |
|---|
| 158 | |
|---|
| 159 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 160 | ! Ocean physics update |
|---|
| 161 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 162 | ! THERMODYNAMICS |
|---|
| 163 | CALL eos_rab( ts(:,:,:,:,Nbb), rab_b, Nnn ) ! before local thermal/haline expension ratio at T-points |
|---|
| 164 | CALL eos_rab( ts(:,:,:,:,Nnn), rab_n, Nnn ) ! now local thermal/haline expension ratio at T-points |
|---|
| 165 | CALL bn2 ( ts(:,:,:,:,Nbb), rab_b, rn2b, Nnn ) ! before Brunt-Vaisala frequency |
|---|
| 166 | CALL bn2 ( ts(:,:,:,:,Nnn), rab_n, rn2, Nnn ) ! now Brunt-Vaisala frequency |
|---|
| 167 | |
|---|
| 168 | ! VERTICAL PHYSICS |
|---|
| 169 | CALL zdf_phy( kstp, Nbb, Nnn, Nrhs ) ! vertical physics update (top/bot drag, avt, avs, avm + MLD) |
|---|
| 170 | |
|---|
| 171 | ! LATERAL PHYSICS |
|---|
| 172 | ! |
|---|
| 173 | IF( l_ldfslp ) THEN ! slope of lateral mixing |
|---|
| 174 | CALL eos( ts(:,:,:,:,Nbb), rhd, gdept_0(:,:,:) ) ! before in situ density |
|---|
| 175 | |
|---|
| 176 | IF( ln_zps .AND. .NOT. ln_isfcav) & |
|---|
| 177 | & CALL zps_hde ( kstp, Nnn, jpts, ts(:,:,:,:,Nbb), gtsu, gtsv, & ! Partial steps: before horizontal gradient |
|---|
| 178 | & rhd, gru , grv ) ! of t, s, rd at the last ocean level |
|---|
| 179 | |
|---|
| 180 | IF( ln_zps .AND. ln_isfcav) & |
|---|
| 181 | & CALL zps_hde_isf( kstp, Nnn, jpts, ts(:,:,:,:,Nbb), gtsu, gtsv, gtui, gtvi, & ! Partial steps for top cell (ISF) |
|---|
| 182 | & rhd, gru , grv , grui, grvi ) ! of t, s, rd at the first ocean level |
|---|
| 183 | IF( ln_traldf_triad ) THEN |
|---|
| 184 | CALL ldf_slp_triad( kstp, Nbb, Nnn ) ! before slope for triad operator |
|---|
| 185 | ELSE |
|---|
| 186 | CALL ldf_slp ( kstp, rhd, rn2b, Nbb, Nnn ) ! before slope for standard operator |
|---|
| 187 | ENDIF |
|---|
| 188 | ENDIF |
|---|
| 189 | ! ! eddy diffusivity coeff. |
|---|
| 190 | IF( l_ldftra_time .OR. l_ldfeiv_time ) CALL ldf_tra( kstp, Nbb, Nnn ) ! and/or eiv coeff. |
|---|
| 191 | IF( l_ldfdyn_time ) CALL ldf_dyn( kstp, Nbb ) ! eddy viscosity coeff. |
|---|
| 192 | |
|---|
| 193 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 194 | ! Ocean dynamics : hdiv, ssh, e3, u, v, w |
|---|
| 195 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 196 | DO jk = 1, jpk |
|---|
| 197 | zgdept(:,:,jk) = gdept(:,:,jk,Nnn) |
|---|
| 198 | END DO |
|---|
| 199 | CALL ssh_nxt ( kstp, Nbb, Nnn, ssh, Naa ) ! after ssh (includes call to div_hor) |
|---|
| 200 | IF( .NOT.lk_linssh ) THEN |
|---|
| 201 | CALL dom_qco_r3c( ssh(:,:,Naa), r3t(:,:,Naa), r3u(:,:,Naa), r3v(:,:,Naa) ) ! "after" ssh/h_0 ratio at t,u,v pts |
|---|
| 202 | IF( ln_dynspg_exp ) CALL dom_qco_r3c( ssh(:,:,Nnn), r3t(:,:,Nnn), r3u(:,:,Nnn), r3v(:,:,Nnn), r3f(:,:) ) ! spg_exp : needed only for "now" ssh/h_0 ratio at f point |
|---|
| 203 | ENDIF |
|---|
| 204 | CALL wzv ( kstp, Nbb, Nnn, Naa, ww ) ! Nnn cross-level velocity |
|---|
| 205 | IF( ln_zad_Aimp ) CALL wAimp ( kstp, Nnn ) ! Adaptive-implicit vertical advection partitioning |
|---|
| 206 | CALL eos ( ts(:,:,:,:,Nnn), rhd, rhop, zgdept ) ! now in situ density for hpg computation |
|---|
| 207 | |
|---|
| 208 | |
|---|
| 209 | uu(:,:,:,Nrhs) = 0._wp ! set dynamics trends to zero |
|---|
| 210 | vv(:,:,:,Nrhs) = 0._wp |
|---|
| 211 | |
|---|
| 212 | IF( lk_asminc .AND. ln_asmiau .AND. ln_dyninc ) & |
|---|
| 213 | & CALL dyn_asm_inc ( kstp, Nbb, Nnn, uu, vv, Nrhs ) ! apply dynamics assimilation increment |
|---|
| 214 | IF( ln_bdy ) CALL bdy_dyn3d_dmp ( kstp, Nbb, uu, vv, Nrhs ) ! bdy damping trends |
|---|
| 215 | #if defined key_agrif |
|---|
| 216 | IF(.NOT. Agrif_Root()) & |
|---|
| 217 | & CALL Agrif_Sponge_dyn ! momentum sponge |
|---|
| 218 | #endif |
|---|
| 219 | CALL dyn_adv( kstp, Nbb, Nnn , uu, vv, Nrhs ) ! advection (VF or FF) ==> RHS |
|---|
| 220 | CALL dyn_vor( kstp, Nnn , uu, vv, Nrhs ) ! vorticity ==> RHS |
|---|
| 221 | CALL dyn_ldf( kstp, Nbb, Nnn , uu, vv, Nrhs ) ! lateral mixing |
|---|
| 222 | IF( ln_zdfosm ) CALL dyn_osm( kstp, Nnn , uu, vv, Nrhs ) ! OSMOSIS non-local velocity fluxes ==> RHS |
|---|
| 223 | CALL dyn_hpg( kstp, Nnn , uu, vv, Nrhs ) ! horizontal gradient of Hydrostatic pressure |
|---|
| 224 | CALL dyn_spg( kstp, Nbb, Nnn, Nrhs, uu, vv, ssh, uu_b, vv_b, Naa ) ! surface pressure gradient |
|---|
| 225 | ! With split-explicit free surface, since now transports have been updated and ssh(:,:,Nrhs) as well |
|---|
| 226 | |
|---|
| 227 | IF( ln_dynspg_ts ) THEN ! vertical scale factors and vertical velocity need to be updated |
|---|
| 228 | CALL div_hor ( kstp, Nbb, Nnn ) ! Horizontal divergence (2nd call in time-split case) |
|---|
| 229 | IF(.NOT.lk_linssh) CALL dom_qco_r3c ( ssh(:,:,Naa), r3t(:,:,Naa), r3u(:,:,Naa), r3v(:,:,Naa), r3f(:,:) ) ! update ssh/h_0 ratio at t,u,v,f pts |
|---|
| 230 | ENDIF |
|---|
| 231 | CALL dyn_zdf ( kstp, Nbb, Nnn, Nrhs, uu, vv, Naa ) ! vertical diffusion |
|---|
| 232 | IF( ln_dynspg_ts ) THEN ! vertical scale factors and vertical velocity need to be updated |
|---|
| 233 | CALL wzv ( kstp, Nbb, Nnn, Naa, ww ) ! Nnn cross-level velocity |
|---|
| 234 | IF( ln_zad_Aimp ) CALL wAimp ( kstp, Nnn ) ! Adaptive-implicit vertical advection partitioning |
|---|
| 235 | ENDIF |
|---|
| 236 | |
|---|
| 237 | |
|---|
| 238 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 239 | ! cool skin |
|---|
| 240 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 241 | IF ( ln_diurnal ) CALL diurnal_layers( kstp ) |
|---|
| 242 | |
|---|
| 243 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 244 | ! diagnostics and outputs |
|---|
| 245 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 246 | IF( ln_floats ) CALL flo_stp ( kstp, Nbb, Nnn ) ! drifting Floats |
|---|
| 247 | IF( ln_diacfl ) CALL dia_cfl ( kstp, Nnn ) ! Courant number diagnostics |
|---|
| 248 | CALL dia_hth ( kstp, Nnn ) ! Thermocline depth (20 degres isotherm depth) |
|---|
| 249 | IF( ln_diadct ) CALL dia_dct ( kstp, Nnn ) ! Transports |
|---|
| 250 | CALL dia_ar5 ( kstp, Nnn ) ! ar5 diag |
|---|
| 251 | CALL dia_ptr ( kstp, Nnn ) ! Poleward adv/ldf TRansports diagnostics |
|---|
| 252 | CALL dia_wri ( kstp, Nnn ) ! ocean model: outputs |
|---|
| 253 | IF( ln_crs ) CALL crs_fld ( kstp, Nnn ) ! ocean model: online field coarsening & output |
|---|
| 254 | IF( lk_diadetide ) CALL dia_detide( kstp ) ! Weights computation for daily detiding of model diagnostics |
|---|
| 255 | IF( lk_diamlr ) CALL dia_mlr ! Update time used in multiple-linear-regression analysis |
|---|
| 256 | |
|---|
| 257 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 258 | ! Now ssh filtering |
|---|
| 259 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 260 | CALL ssh_atf ( kstp, Nbb, Nnn, Naa, ssh ) ! time filtering of "now" sea surface height |
|---|
| 261 | IF(.NOT.lk_linssh) CALL dom_qco_r3c( ssh(:,:,Nnn), r3t_f, r3u_f, r3v_f ) ! "now" ssh/h_0 ratio from filtrered ssh |
|---|
| 262 | #if defined key_top |
|---|
| 263 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 264 | ! Passive Tracer Model |
|---|
| 265 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 266 | CALL trc_stp ( kstp, Nbb, Nnn, Nrhs, Naa ) ! time-stepping |
|---|
| 267 | #endif |
|---|
| 268 | |
|---|
| 269 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 270 | ! Active tracers |
|---|
| 271 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 272 | ts(:,:,:,:,Nrhs) = 0._wp ! set tracer trends to zero |
|---|
| 273 | |
|---|
| 274 | IF( lk_asminc .AND. ln_asmiau .AND. & |
|---|
| 275 | & ln_trainc ) CALL tra_asm_inc( kstp, Nbb, Nnn, ts, Nrhs ) ! apply tracer assimilation increment |
|---|
| 276 | CALL tra_sbc ( kstp, Nnn, ts, Nrhs ) ! surface boundary condition |
|---|
| 277 | IF( ln_traqsr ) CALL tra_qsr ( kstp, Nnn, ts, Nrhs ) ! penetrative solar radiation qsr |
|---|
| 278 | IF( ln_isf ) CALL tra_isf ( kstp, Nnn, ts, Nrhs ) ! ice shelf heat flux |
|---|
| 279 | IF( ln_trabbc ) CALL tra_bbc ( kstp, Nnn, ts, Nrhs ) ! bottom heat flux |
|---|
| 280 | IF( ln_trabbl ) CALL tra_bbl ( kstp, Nbb, Nnn, ts, Nrhs ) ! advective (and/or diffusive) bottom boundary layer scheme |
|---|
| 281 | IF( ln_tradmp ) CALL tra_dmp ( kstp, Nbb, Nnn, ts, Nrhs ) ! internal damping trends |
|---|
| 282 | IF( ln_bdy ) CALL bdy_tra_dmp( kstp, Nbb, ts, Nrhs ) ! bdy damping trends |
|---|
| 283 | #if defined key_agrif |
|---|
| 284 | IF(.NOT. Agrif_Root()) & |
|---|
| 285 | & CALL Agrif_Sponge_tra ! tracers sponge |
|---|
| 286 | #endif |
|---|
| 287 | CALL tra_adv ( kstp, Nbb, Nnn, ts, Nrhs ) ! hor. + vert. advection ==> RHS |
|---|
| 288 | IF( ln_zdfosm ) CALL tra_osm ( kstp, Nnn, ts, Nrhs ) ! OSMOSIS non-local tracer fluxes ==> RHS |
|---|
| 289 | IF( lrst_oce .AND. ln_zdfosm ) & |
|---|
| 290 | & CALL osm_rst ( kstp, Nnn, 'WRITE' ) ! write OSMOSIS outputs + ww (so must do here) to restarts |
|---|
| 291 | CALL tra_ldf ( kstp, Nbb, Nnn, ts, Nrhs ) ! lateral mixing |
|---|
| 292 | |
|---|
| 293 | CALL tra_zdf ( kstp, Nbb, Nnn, Nrhs, ts, Naa ) ! vertical mixing and after tracer fields |
|---|
| 294 | IF( ln_zdfnpc ) CALL tra_npc ( kstp, Nnn, Nrhs, ts, Naa ) ! update after fields by non-penetrative convection |
|---|
| 295 | |
|---|
| 296 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 297 | ! Set boundary conditions, time filter and swap time levels |
|---|
| 298 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 299 | !!jc1: For agrif, it would be much better to finalize tracers/momentum here (e.g. bdy conditions) and move the swap |
|---|
| 300 | !! (and time filtering) after Agrif update. Then restart would be done after and would contain updated fields. |
|---|
| 301 | !! If so: |
|---|
| 302 | !! (i) no need to call agrif update at initialization time |
|---|
| 303 | !! (ii) no need to update "before" fields |
|---|
| 304 | !! |
|---|
| 305 | !! Apart from creating new tra_swp/dyn_swp routines, this however: |
|---|
| 306 | !! (i) makes boundary conditions at initialization time computed from updated fields which is not the case between |
|---|
| 307 | !! two restarts => restartability issue. One can circumvent this, maybe, by assuming "interface separation", |
|---|
| 308 | !! e.g. a shift of the feedback interface inside child domain. |
|---|
| 309 | !! (ii) requires that all restart outputs of updated variables by agrif (e.g. passive tracers/tke/barotropic arrays) are done at the same |
|---|
| 310 | !! place. |
|---|
| 311 | !! |
|---|
| 312 | IF( ln_dynspg_ts ) CALL mlf_baro_corr ( Nnn, Naa, uu, vv ) ! barotrope adjustment |
|---|
| 313 | CALL finalize_lbc ( kstp, Nbb , Naa, uu, vv, ts ) ! boundary conditions |
|---|
| 314 | CALL tra_atf_qco ( kstp, Nbb, Nnn, Naa , ts ) ! time filtering of "now" tracer arrays |
|---|
| 315 | CALL dyn_atf_qco ( kstp, Nbb, Nnn, Naa, uu, vv ) ! time filtering of "now" velocities |
|---|
| 316 | IF(.NOT.lk_linssh) THEN |
|---|
| 317 | r3t(:,:,Nnn) = r3t_f(:,:) ! update now ssh/h_0 with time filtered values |
|---|
| 318 | r3u(:,:,Nnn) = r3u_f(:,:) |
|---|
| 319 | r3v(:,:,Nnn) = r3v_f(:,:) |
|---|
| 320 | ENDIF |
|---|
| 321 | |
|---|
| 322 | ! |
|---|
| 323 | ! Swap time levels |
|---|
| 324 | Nrhs = Nbb |
|---|
| 325 | Nbb = Nnn |
|---|
| 326 | Nnn = Naa |
|---|
| 327 | Naa = Nrhs |
|---|
| 328 | ! |
|---|
| 329 | ! |
|---|
| 330 | IF( ln_diahsb ) CALL dia_hsb ( kstp, Nbb, Nnn ) ! - ML - global conservation diagnostics |
|---|
| 331 | |
|---|
| 332 | !!gm : This does not only concern the dynamics ==>>> add a new title |
|---|
| 333 | !!gm2: why ouput restart before AGRIF update? |
|---|
| 334 | !! |
|---|
| 335 | !!jc: That would be better, but see comment above |
|---|
| 336 | !! |
|---|
| 337 | IF( lrst_oce ) CALL rst_write ( kstp, Nbb, Nnn ) ! write output ocean restart file |
|---|
| 338 | IF( ln_sto_eos ) CALL sto_rst_write( kstp ) ! write restart file for stochastic parameters |
|---|
| 339 | |
|---|
| 340 | #if defined key_agrif |
|---|
| 341 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 342 | ! AGRIF |
|---|
| 343 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 344 | Kbb_a = Nbb; Kmm_a = Nnn; Krhs_a = Nrhs ! agrif_oce module copies of time level indices |
|---|
| 345 | CALL Agrif_Integrate_ChildGrids( stp_MLF ) ! allows to finish all the Child Grids before updating |
|---|
| 346 | |
|---|
| 347 | IF( Agrif_NbStepint() == 0 ) THEN |
|---|
| 348 | CALL Agrif_update_all( ) ! Update all components |
|---|
| 349 | ENDIF |
|---|
| 350 | #endif |
|---|
| 351 | IF( ln_diaobs ) CALL dia_obs ( kstp, Nnn ) ! obs-minus-model (assimilation) diagnostics (call after dynamics update) |
|---|
| 352 | |
|---|
| 353 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 354 | ! Control |
|---|
| 355 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 356 | CALL stp_ctl ( kstp, Nnn ) |
|---|
| 357 | |
|---|
| 358 | IF( kstp == nit000 ) THEN ! 1st time step only |
|---|
| 359 | CALL iom_close( numror ) ! close input ocean restart file |
|---|
| 360 | IF(lwm) CALL FLUSH ( numond ) ! flush output namelist oce |
|---|
| 361 | IF(lwm .AND. numoni /= -1 ) CALL FLUSH ( numoni ) ! flush output namelist ice (if exist) |
|---|
| 362 | ENDIF |
|---|
| 363 | |
|---|
| 364 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 365 | ! Coupled mode |
|---|
| 366 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 367 | !!gm why lk_oasis and not lk_cpl ???? |
|---|
| 368 | IF( lk_oasis ) CALL sbc_cpl_snd( kstp, Nbb, Nnn ) ! coupled mode : field exchanges |
|---|
| 369 | ! |
|---|
| 370 | #if defined key_iomput |
|---|
| 371 | IF( kstp == nitend .OR. indic < 0 ) THEN |
|---|
| 372 | CALL iom_context_finalize( cxios_context ) ! needed for XIOS+AGRIF |
|---|
| 373 | IF( ln_crs ) CALL iom_context_finalize( trim(cxios_context)//"_crs" ) ! |
|---|
| 374 | ENDIF |
|---|
| 375 | #endif |
|---|
| 376 | ! |
|---|
| 377 | IF( l_1st_euler ) THEN ! recover Leap-frog timestep |
|---|
| 378 | rDt = 2._wp * rn_Dt |
|---|
| 379 | r1_Dt = 1._wp / rDt |
|---|
| 380 | l_1st_euler = .FALSE. |
|---|
| 381 | ENDIF |
|---|
| 382 | ! |
|---|
| 383 | IF( ln_timing ) CALL timing_stop('stp_MLF') |
|---|
| 384 | ! |
|---|
| 385 | END SUBROUTINE stp_MLF |
|---|
| 386 | |
|---|
| 387 | |
|---|
| 388 | SUBROUTINE mlf_baro_corr( Kmm, Kaa, puu, pvv ) |
|---|
| 389 | !!---------------------------------------------------------------------- |
|---|
| 390 | !! *** ROUTINE mlf_baro_corr *** |
|---|
| 391 | !! |
|---|
| 392 | !! ** Purpose : Finalize after horizontal velocity. |
|---|
| 393 | !! |
|---|
| 394 | !! ** Method : * Ensure after velocities transport matches time splitting |
|---|
| 395 | !! estimate (ln_dynspg_ts=T) |
|---|
| 396 | !! |
|---|
| 397 | !! ** Action : puu(Kmm),pvv(Kmm) updated now horizontal velocity (ln_bt_fw=F) |
|---|
| 398 | !! puu(Kaa),pvv(Kaa) after horizontal velocity |
|---|
| 399 | !!---------------------------------------------------------------------- |
|---|
| 400 | USE dynspg_ts, ONLY : un_adv, vn_adv ! updated Kmm barotropic transport |
|---|
| 401 | !! |
|---|
| 402 | INTEGER , INTENT(in ) :: Kmm, Kaa ! before and after time level indices |
|---|
| 403 | REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) :: puu, pvv ! velocities |
|---|
| 404 | ! |
|---|
| 405 | INTEGER :: jk ! dummy loop indices |
|---|
| 406 | REAL(wp), DIMENSION(jpi,jpj) :: zue, zve |
|---|
| 407 | !!---------------------------------------------------------------------- |
|---|
| 408 | |
|---|
| 409 | ! Ensure below that barotropic velocities match time splitting estimate |
|---|
| 410 | ! Compute actual transport and replace it with ts estimate at "after" time step |
|---|
| 411 | zue(:,:) = e3u(:,:,1,Kaa) * puu(:,:,1,Kaa) * umask(:,:,1) |
|---|
| 412 | zve(:,:) = e3v(:,:,1,Kaa) * pvv(:,:,1,Kaa) * vmask(:,:,1) |
|---|
| 413 | DO jk = 2, jpkm1 |
|---|
| 414 | zue(:,:) = zue(:,:) + e3u(:,:,jk,Kaa) * puu(:,:,jk,Kaa) * umask(:,:,jk) |
|---|
| 415 | zve(:,:) = zve(:,:) + e3v(:,:,jk,Kaa) * pvv(:,:,jk,Kaa) * vmask(:,:,jk) |
|---|
| 416 | END DO |
|---|
| 417 | DO jk = 1, jpkm1 |
|---|
| 418 | puu(:,:,jk,Kaa) = ( puu(:,:,jk,Kaa) - zue(:,:) * r1_hu(:,:,Kaa) + uu_b(:,:,Kaa) ) * umask(:,:,jk) |
|---|
| 419 | pvv(:,:,jk,Kaa) = ( pvv(:,:,jk,Kaa) - zve(:,:) * r1_hv(:,:,Kaa) + vv_b(:,:,Kaa) ) * vmask(:,:,jk) |
|---|
| 420 | END DO |
|---|
| 421 | ! |
|---|
| 422 | IF( .NOT.ln_bt_fw ) THEN |
|---|
| 423 | ! Remove advective velocity from "now velocities" |
|---|
| 424 | ! prior to asselin filtering |
|---|
| 425 | ! In the forward case, this is done below after asselin filtering |
|---|
| 426 | ! so that asselin contribution is removed at the same time |
|---|
| 427 | DO jk = 1, jpkm1 |
|---|
| 428 | puu(:,:,jk,Kmm) = ( puu(:,:,jk,Kmm) - un_adv(:,:)*r1_hu(:,:,Kmm) + uu_b(:,:,Kmm) )*umask(:,:,jk) |
|---|
| 429 | pvv(:,:,jk,Kmm) = ( pvv(:,:,jk,Kmm) - vn_adv(:,:)*r1_hv(:,:,Kmm) + vv_b(:,:,Kmm) )*vmask(:,:,jk) |
|---|
| 430 | END DO |
|---|
| 431 | ENDIF |
|---|
| 432 | ! |
|---|
| 433 | END SUBROUTINE mlf_baro_corr |
|---|
| 434 | |
|---|
| 435 | |
|---|
| 436 | SUBROUTINE finalize_lbc( kt, Kbb, Kaa, puu, pvv, pts ) |
|---|
| 437 | !!---------------------------------------------------------------------- |
|---|
| 438 | !! *** ROUTINE finalize_lbc *** |
|---|
| 439 | !! |
|---|
| 440 | !! ** Purpose : Apply the boundary condition on the after velocity |
|---|
| 441 | !! |
|---|
| 442 | !! ** Method : * Apply lateral boundary conditions on after velocity |
|---|
| 443 | !! at the local domain boundaries through lbc_lnk call, |
|---|
| 444 | !! at the one-way open boundaries (ln_bdy=T), |
|---|
| 445 | !! at the AGRIF zoom boundaries (lk_agrif=T) |
|---|
| 446 | !! |
|---|
| 447 | !! ** Action : puu(Kaa),pvv(Kaa) after horizontal velocity and tracers |
|---|
| 448 | !!---------------------------------------------------------------------- |
|---|
| 449 | INTEGER , INTENT(in ) :: kt ! ocean time-step index |
|---|
| 450 | INTEGER , INTENT(in ) :: Kbb, Kaa ! before and after time level indices |
|---|
| 451 | REAL(wp), DIMENSION(jpi,jpj,jpk,jpt) , INTENT(inout) :: puu, pvv ! velocities to be time filtered |
|---|
| 452 | REAL(wp), DIMENSION(jpi,jpj,jpk,jpts,jpt), INTENT(inout) :: pts ! active tracers |
|---|
| 453 | !!---------------------------------------------------------------------- |
|---|
| 454 | ! |
|---|
| 455 | ! Update after tracer and velocity on domain lateral boundaries |
|---|
| 456 | ! |
|---|
| 457 | # if defined key_agrif |
|---|
| 458 | CALL Agrif_tra !* AGRIF zoom boundaries |
|---|
| 459 | CALL Agrif_dyn( kt ) |
|---|
| 460 | # endif |
|---|
| 461 | ! ! local domain boundaries (T-point, unchanged sign) |
|---|
| 462 | CALL lbc_lnk_multi( 'finalize_lbc', puu(:,:,:, Kaa), 'U', -1., pvv(:,:,: ,Kaa), 'V', -1. & |
|---|
| 463 | & , pts(:,:,:,jp_tem,Kaa), 'T', 1., pts(:,:,:,jp_sal,Kaa), 'T', 1. ) |
|---|
| 464 | ! |
|---|
| 465 | ! !* BDY open boundaries |
|---|
| 466 | IF( ln_bdy ) THEN |
|---|
| 467 | CALL bdy_tra( kt, Kbb, pts, Kaa ) |
|---|
| 468 | IF( ln_dynspg_exp ) CALL bdy_dyn( kt, Kbb, puu, pvv, Kaa ) |
|---|
| 469 | IF( ln_dynspg_ts ) CALL bdy_dyn( kt, Kbb, puu, pvv, Kaa, dyn3d_only=.true. ) |
|---|
| 470 | ENDIF |
|---|
| 471 | ! |
|---|
| 472 | END SUBROUTINE finalize_lbc |
|---|
| 473 | |
|---|
| 474 | #else |
|---|
| 475 | !!---------------------------------------------------------------------- |
|---|
| 476 | !! default option EMPTY MODULE qco not activated |
|---|
| 477 | !!---------------------------------------------------------------------- |
|---|
| 478 | #endif |
|---|
| 479 | |
|---|
| 480 | !!====================================================================== |
|---|
| 481 | END MODULE stpmlf |
|---|
