source: NEMO/trunk/src/OFF/nemogcm.F90

Last change on this file was 13558, checked in by smasson, 2 months ago

trunk: pass sette tests with debugging option -init=arrays,snan,huge, see #2535

  • Property svn:keywords set to Id
File size: 26.4 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Off-line Ocean   : passive tracer evolution, dynamics read in files
5   !!======================================================================
6   !! History :  3.3  ! 2010-05  (C. Ethe)  Full reorganization of the off-line: phasing with the on-line
7   !!            3.4  ! 2011-01  (C. Ethe, A. R. Porter, STFC Daresbury) dynamical allocation
8   !!            4.0  ! 2016-10  (C. Ethe, G. Madec, S. Flavoni)  domain configuration / user defined interface
9   !!            4.1  ! 2019-08  (A. Coward, D. Storkey) rewrite in preparation for new timestepping scheme
10   !!----------------------------------------------------------------------
11
12   !!----------------------------------------------------------------------
13   !!   nemo_gcm      : off-line: solve ocean tracer only
14   !!   nemo_gcm      : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
15   !!   nemo_init     : initialization of the NEMO system
16   !!   nemo_ctl      : initialisation of the contol print
17   !!   nemo_closefile: close remaining open files
18   !!   nemo_alloc    : dynamical allocation
19   !!   istate_init   : simple initialization to zero of ocean fields
20   !!   stp_ctl       : reduced step control (no dynamics in off-line)
21   !!----------------------------------------------------------------------
22   USE dom_oce        ! ocean space domain variables
23   USE oce            ! dynamics and tracers variables
24   USE trc_oce        ! Shared ocean/passive tracers variables
25   USE c1d            ! 1D configuration
26   USE domain         ! domain initialization from coordinate & bathymetry (dom_init routine)
27   USE closea         ! treatment of closed seas (for ln_closea)
28   USE usrdef_nam     ! user defined configuration
29   USE eosbn2         ! equation of state            (eos bn2 routine)
30#if defined key_qco
31   USE domqco         ! tools for scale factor         (dom_qco_r3c  routine)
32#endif
33   USE bdyini         ! open boundary cond. setting        (bdy_init routine)
34   !              ! ocean physics
35   USE ldftra         ! lateral diffusivity setting    (ldf_tra_init routine)
36   USE ldfslp         ! slopes of neutral surfaces     (ldf_slp_init routine)
37   USE traqsr         ! solar radiation penetration    (tra_qsr_init routine)
38   USE trabbl         ! bottom boundary layer          (tra_bbl_init routine)
39   USE traldf         ! lateral physics                (tra_ldf_init routine)
40   USE sbcmod         ! surface boundary condition     (sbc_init     routine)
41   USE phycst         ! physical constant                   (par_cst routine)
42   USE zdfphy         ! vertical physics manager       (zdf_phy_init routine)
43   USE dtadyn         ! Lecture and Interpolation of the dynamical fields
44   USE trcini         ! Initilization of the passive tracers
45   USE daymod         ! calendar                            (day     routine)
46   USE trcstp         ! passive tracer time-stepping        (trc_stp routine)
47   USE dtadyn         ! Lecture and interpolation of the dynamical fields
48   !              ! Passive tracers needs
49   USE trc            ! passive tracer : variables
50   USE trcnam         ! passive tracer : namelist
51   USE trcrst         ! passive tracer restart
52   USE sbc_oce , ONLY : ln_rnf
53   USE sbcrnf         ! surface boundary condition : runoffs
54   !              ! I/O & MPP
55   USE iom            ! I/O library
56   USE in_out_manager ! I/O manager
57   USE mppini         ! shared/distributed memory setting (mpp_init routine)
58   USE lib_mpp        ! distributed memory computing
59#if defined key_iomput
60   USE xios           ! xIOserver
61#endif
62   USE prtctl         ! Print control                    (prt_ctl_init routine)
63   USE timing         ! Timing
64   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
65   USE lbcnfd  , ONLY : isendto, nsndto   ! Setup of north fold exchanges
66   USE step, ONLY : Nbb, Nnn, Naa, Nrhs   ! time level indices
67   USE halo_mng
68
69   IMPLICIT NONE
70   PRIVATE
71   
72   PUBLIC   nemo_gcm   ! called by nemo.F90
73
74   CHARACTER (len=64) ::   cform_aaa="( /, 'AAAAAAAA', / ) "   ! flag for output listing
75#if defined key_mpp_mpi
76   ! need MPI_Wtime
77   INCLUDE 'mpif.h'
78#endif
79
80   !!----------------------------------------------------------------------
81   !! NEMO/OFF 4.0 , NEMO Consortium (2018)
82   !! $Id$
83   !! Software governed by the CeCILL license (see ./LICENSE)
84   !!----------------------------------------------------------------------
85CONTAINS
86
87   SUBROUTINE nemo_gcm
88      !!----------------------------------------------------------------------
89      !!                     ***  ROUTINE nemo_gcm  ***
90      !!
91      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
92      !!              curvilinear mesh on the sphere.
93      !!
94      !! ** Method  : - model general initialization
95      !!              - launch the time-stepping (dta_dyn and trc_stp)
96      !!              - finalize the run by closing files and communications
97      !!
98      !! References : Madec, Delecluse,Imbard, and Levy, 1997:  internal report, IPSL.
99      !!              Madec, 2008, internal report, IPSL.
100      !!----------------------------------------------------------------------
101      INTEGER :: istp       ! time step index
102      REAL(wp)::   zstptiming   ! elapsed time for 1 time step
103      !!----------------------------------------------------------------------
104
105      CALL nemo_init  ! Initializations
106
107      ! check that all process are still there... If some process have an error,
108      ! they will never enter in step and other processes will wait until the end of the cpu time!
109      CALL mpp_max( 'nemogcm', nstop )
110
111      !                            !-----------------------!
112      !                            !==   time stepping   ==!
113      !                            !-----------------------!
114      istp = nit000
115      !
116      IF( ln_rnf )   CALL sbc_rnf(istp)   ! runoffs initialization
117      !
118      CALL iom_init( cxios_context )      ! iom_put initialization (must be done after nemo_init for AGRIF+XIOS+OASIS)
119      !
120      DO WHILE ( istp <= nitend .AND. nstop == 0 )    !==  OFF time-stepping  ==!
121
122         IF( ln_timing ) THEN
123            zstptiming = MPI_Wtime()
124            IF ( istp == ( nit000 + 1 ) ) elapsed_time = zstptiming
125            IF ( istp ==         nitend ) elapsed_time = zstptiming - elapsed_time
126         ENDIF
127         !
128         IF( istp /= nit000 )   CALL day        ( istp )         ! Calendar (day was already called at nit000 in day_init)
129                                CALL iom_setkt  ( istp - nit000 + 1, cxios_context )   ! say to iom that we are at time step kstp
130#if defined key_sed_off
131                                CALL dta_dyn_sed( istp,      Nnn      )       ! Interpolation of the dynamical fields
132#else
133                                CALL dta_dyn    ( istp, Nbb, Nnn, Naa )       ! Interpolation of the dynamical fields
134#endif
135#if ! defined key_sed_off
136         IF( .NOT.ln_linssh ) THEN
137                                CALL dta_dyn_atf( istp, Nbb, Nnn, Naa )       ! time filter of sea  surface height and vertical scale factors
138# if defined key_qco
139                                CALL dom_qco_r3c( ssh(:,:,Kmm), r3t_f, r3u_f, r3v_f )
140# endif
141         ENDIF
142                                CALL trc_stp    ( istp, Nbb, Nnn, Nrhs, Naa ) ! time-stepping
143# if defined key_qco
144                                !r3t(:,:,Kmm) = r3t_f(:,:)                     ! update ssh to h0 ratio
145                                !r3u(:,:,Kmm) = r3u_f(:,:)
146                                !r3v(:,:,Kmm) = r3v_f(:,:)
147# endif
148#endif
149         ! Swap time levels
150         Nrhs = Nbb
151         Nbb = Nnn
152         Nnn = Naa
153         Naa = Nrhs
154         !
155#if ! defined key_qco
156#if ! defined key_sed_off
157         IF( .NOT.ln_linssh )   CALL dta_dyn_sf_interp( istp, Nnn )  ! calculate now grid parameters
158#endif
159#endif         
160         CALL stp_ctl    ( istp )             ! Time loop: control and print
161         istp = istp + 1
162
163         IF( lwp .AND. ln_timing )   WRITE(numtime,*) 'timing step ', istp-1, ' : ', MPI_Wtime() - zstptiming
164
165      END DO
166      !
167#if defined key_iomput
168      CALL iom_context_finalize( cxios_context ) ! needed for XIOS+AGRIF
169#endif
170
171      !                            !------------------------!
172      !                            !==  finalize the run  ==!
173      !                            !------------------------!
174      IF(lwp) WRITE(numout,cform_aaa)                 ! Flag AAAAAAA
175
176      IF( nstop /= 0 .AND. lwp ) THEN                 ! error print
177         WRITE(ctmp1,*) '   ==>>>   nemo_gcm: a total of ', nstop, ' errors have been found'
178         WRITE(ctmp2,*) '           Look for "E R R O R" messages in all existing ocean_output* files'
179         CALL ctl_stop( ' ', ctmp1, ' ', ctmp2 )
180      ENDIF
181      !
182      IF( ln_timing )   CALL timing_finalize
183      !
184      CALL nemo_closefile
185      !
186#if defined key_iomput
187                     CALL xios_finalize   ! end mpp communications with xios
188#else
189      IF( lk_mpp )   CALL mppstop         ! end mpp communications
190#endif
191      !
192      IF(lwm) THEN
193         IF( nstop == 0 ) THEN   ;   STOP 0
194         ELSE                    ;   STOP 123
195         ENDIF
196      ENDIF
197      !
198   END SUBROUTINE nemo_gcm
199
200
201   SUBROUTINE nemo_init
202      !!----------------------------------------------------------------------
203      !!                     ***  ROUTINE nemo_init  ***
204      !!
205      !! ** Purpose :   initialization of the nemo model in off-line mode
206      !!----------------------------------------------------------------------
207      INTEGER ::   ios, ilocal_comm   ! local integers
208      !!
209      NAMELIST/namctl/ sn_cfctl, ln_timing, ln_diacfl,                                &
210         &             nn_isplt,  nn_jsplt,  nn_ictls, nn_ictle, nn_jctls, nn_jctle
211      NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr
212      !!----------------------------------------------------------------------
213      !
214      cxios_context = 'nemo'
215      nn_hls = 1
216      !
217      !                             !-------------------------------------------------!
218      !                             !     set communicator & select the local rank    !
219      !                             !  must be done as soon as possible to get narea  !
220      !                             !-------------------------------------------------!
221      !
222#if defined key_iomput
223      CALL xios_initialize( "for_xios_mpi_id", return_comm=ilocal_comm )   ! nemo local communicator given by xios
224      CALL mpp_start( ilocal_comm )
225#else
226      CALL mpp_start( )
227#endif
228      !
229      narea = mpprank + 1               ! mpprank: the rank of proc (0 --> mppsize -1 )
230      lwm = (narea == 1)                ! control of output namelists
231      !
232      !                             !---------------------------------------------------------------!
233      !                             ! Open output files, reference and configuration namelist files !
234      !                             !---------------------------------------------------------------!
235      !
236      ! open ocean.output as soon as possible to get all output prints (including errors messages)
237      IF( lwm )   CALL ctl_opn(     numout,        'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
238      ! open reference and configuration namelist files
239                  CALL load_nml( numnam_ref,        'namelist_ref',                                           -1, lwm )
240                  CALL load_nml( numnam_cfg,        'namelist_cfg',                                           -1, lwm )
241      IF( lwm )   CALL ctl_opn(     numond, 'output.namelist.dyn', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
242      ! open /dev/null file to be able to supress output write easily
243      IF( Agrif_Root() ) THEN
244                  CALL ctl_opn(     numnul,           '/dev/null', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
245#ifdef key_agrif
246      ELSE
247                  numnul = Agrif_Parent(numnul)   
248#endif
249      ENDIF
250      !
251      !                             !--------------------!
252      !                             ! Open listing units !  -> need sn_cfctl from namctl to define lwp
253      !                             !--------------------!
254      !
255      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
256901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namctl in reference namelist' )
257      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
258902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namctl in configuration namelist' )
259      !
260      ! finalize the definition of namctl variables
261      IF( narea < sn_cfctl%procmin .OR. narea > sn_cfctl%procmax .OR. MOD( narea - sn_cfctl%procmin, sn_cfctl%procincr ) /= 0 )   &
262         &   CALL nemo_set_cfctl( sn_cfctl, .FALSE. )
263      !
264      lwp = (narea == 1) .OR. sn_cfctl%l_oceout    ! control of all listing output print
265      !
266      IF(lwp) THEN                            ! open listing units
267         !
268         IF( .NOT. lwm )   &           ! alreay opened for narea == 1
269            &     CALL ctl_opn(     numout,        'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE., narea )
270         !
271         WRITE(numout,*)
272         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - CMCC'
273         WRITE(numout,*) '                       NEMO team'
274         WRITE(numout,*) '                   Off-line TOP Model'
275         WRITE(numout,*) '                NEMO version 4.0  (2019) '
276         WRITE(numout,*)
277         WRITE(numout,*) "           ._      ._      ._      ._      ._    "
278         WRITE(numout,*) "       _.-._)`\_.-._)`\_.-._)`\_.-._)`\_.-._)`\_ "
279         WRITE(numout,*)
280         WRITE(numout,*) "           o         _,           _,             "
281         WRITE(numout,*) "            o      .' (        .-' /             "
282         WRITE(numout,*) "           o     _/..._'.    .'   /              "
283         WRITE(numout,*) "      (    o .-'`      ` '-./  _.'               "
284         WRITE(numout,*) "       )    ( o)           ;= <_         (       "
285         WRITE(numout,*) "      (      '-.,\\__ __.-;`\   '.        )      "
286         WRITE(numout,*) "       )  )       \) |`\ \)  '.   \      (   (   "
287         WRITE(numout,*) "      (  (           \_/       '-._\      )   )  "
288         WRITE(numout,*) "       )  )                        `     (   (   "
289         WRITE(numout,*) "     ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ "
290         WRITE(numout,*)
291         !
292         WRITE(numout,cform_aaa)                                        ! Flag AAAAAAA
293         !
294      ENDIF
295      !
296      IF(lwm) WRITE( numond, namctl )
297      !
298      !                             !------------------------------------!
299      !                             !  Set global domain size parameters !
300      !                             !------------------------------------!
301      !     
302      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
303903   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namcfg in reference namelist' )
304      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
305904   IF( ios >  0 )   CALL ctl_nam ( ios , 'namcfg in configuration namelist' )   
306      !
307      IF( ln_read_cfg ) THEN              ! Read sizes in domain configuration file
308         CALL domain_cfg ( cn_cfg, nn_cfg, Ni0glo, Nj0glo, jpkglo, jperio )
309      ELSE                                ! user-defined namelist
310         CALL usr_def_nam( cn_cfg, nn_cfg, Ni0glo, Nj0glo, jpkglo, jperio )
311      ENDIF
312      !
313      IF(lwm)   WRITE( numond, namcfg )
314      l_offline = .true.                  ! passive tracers are run offline
315      !
316      !                             !-----------------------------------------!
317      !                             ! mpp parameters and domain decomposition !
318      !                             !-----------------------------------------!
319      !
320      CALL mpp_init
321
322      CALL halo_mng_init()
323      ! Now we know the dimensions of the grid and numout has been set: we can allocate arrays
324      CALL nemo_alloc()
325
326      ! Initialise time level indices
327      Nbb = 1; Nnn = 2; Naa = 3; Nrhs = Naa
328
329      !                             !-------------------------------!
330      !                             !  NEMO general initialization  !
331      !                             !-------------------------------!
332
333      CALL nemo_ctl                          ! Control prints
334      !
335      !                                      ! General initialization
336      IF( ln_timing    )   CALL timing_init
337      IF( ln_timing    )   CALL timing_start( 'nemo_init')
338      !
339                           CALL     phy_cst         ! Physical constants
340                           CALL     eos_init        ! Equation of state
341      IF( lk_c1d       )   CALL     c1d_init        ! 1D column configuration
342                           CALL     dom_init( Nbb, Nnn, Naa, "OPA") ! Domain
343      IF( sn_cfctl%l_prtctl )   &
344         &                 CALL prt_ctl_init        ! Print control
345
346                           CALL  istate_init( Nnn, Naa )    ! ocean initial state (Dynamics and tracers)
347
348                           CALL     sbc_init( Nbb, Nnn, Naa )    ! Forcings : surface module
349                           CALL     bdy_init    ! Open boundaries initialisation
350                           
351                           CALL zdf_phy_init( Nnn )    ! Vertical physics
352
353      !                                      ! Tracer physics
354                           CALL ldf_tra_init    ! Lateral ocean tracer physics
355                           CALL ldf_eiv_init    ! Eddy induced velocity param. must be done after ldf_tra_init
356                           CALL tra_ldf_init    ! lateral mixing
357      IF( l_ldfslp     )   CALL ldf_slp_init    ! slope of lateral mixing
358      IF( ln_traqsr    )   CALL tra_qsr_init    ! penetrative solar radiation
359      IF( ln_trabbl    )   CALL tra_bbl_init    ! advective (and/or diffusive) bottom boundary layer scheme
360
361      !                                      ! Passive tracers
362                           CALL trc_nam_run    ! Needed to get restart parameters for passive tracers
363                           CALL trc_rst_cal( nit000, 'READ' )   ! calendar
364#if defined key_sed_off
365                           CALL dta_dyn_sed_init(  Nnn      )        ! Initialization for the dynamics
366#else
367                           CALL dta_dyn_init( Nbb, Nnn, Naa )        ! Initialization for the dynamics
368#endif
369                           CALL     trc_init( Nbb, Nnn, Naa )        ! Passive tracers initialization
370                           
371      IF(lwp) WRITE(numout,cform_aaa)           ! Flag AAAAAAA
372      !
373      IF( ln_timing    )   CALL timing_stop( 'nemo_init')
374      !
375   END SUBROUTINE nemo_init
376
377
378   SUBROUTINE nemo_ctl
379      !!----------------------------------------------------------------------
380      !!                     ***  ROUTINE nemo_ctl  ***
381      !!
382      !! ** Purpose :   control print setting
383      !!
384      !! ** Method  : - print namctl and namcfg information and check some consistencies
385      !!----------------------------------------------------------------------
386      !
387      IF(lwp) THEN                  ! control print
388         WRITE(numout,*)
389         WRITE(numout,*) 'nemo_ctl: Control prints'
390         WRITE(numout,*) '~~~~~~~~'
391         WRITE(numout,*) '   Namelist namctl'
392         WRITE(numout,*) '                              sn_cfctl%l_runstat = ', sn_cfctl%l_runstat
393         WRITE(numout,*) '                              sn_cfctl%l_trcstat = ', sn_cfctl%l_trcstat
394         WRITE(numout,*) '                              sn_cfctl%l_oceout  = ', sn_cfctl%l_oceout
395         WRITE(numout,*) '                              sn_cfctl%l_layout  = ', sn_cfctl%l_layout
396         WRITE(numout,*) '                              sn_cfctl%l_prtctl  = ', sn_cfctl%l_prtctl
397         WRITE(numout,*) '                              sn_cfctl%l_prttrc  = ', sn_cfctl%l_prttrc
398         WRITE(numout,*) '                              sn_cfctl%l_oasout  = ', sn_cfctl%l_oasout
399         WRITE(numout,*) '                              sn_cfctl%procmin   = ', sn_cfctl%procmin 
400         WRITE(numout,*) '                              sn_cfctl%procmax   = ', sn_cfctl%procmax 
401         WRITE(numout,*) '                              sn_cfctl%procincr  = ', sn_cfctl%procincr 
402         WRITE(numout,*) '                              sn_cfctl%ptimincr  = ', sn_cfctl%ptimincr 
403         WRITE(numout,*) '      timing by routine               ln_timing  = ', ln_timing
404         WRITE(numout,*) '      CFL diagnostics                 ln_diacfl  = ', ln_diacfl
405      ENDIF
406
407      IF( .NOT.ln_read_cfg )   ln_closea = .false.   ! dealing possible only with a domcfg file
408      IF(lwp) THEN                  ! control print
409         WRITE(numout,*)
410         WRITE(numout,*) '   Namelist namcfg'
411         WRITE(numout,*) '      read domain configuration file              ln_read_cfg      = ', ln_read_cfg
412         WRITE(numout,*) '         filename to be read                         cn_domcfg     = ', TRIM(cn_domcfg)
413         WRITE(numout,*) '         keep closed seas in the domain (if exist)   ln_closea     = ', ln_closea
414         WRITE(numout,*) '      create a configuration definition file      ln_write_cfg     = ', ln_write_cfg
415         WRITE(numout,*) '         filename to be written                      cn_domcfg_out = ', TRIM(cn_domcfg_out)
416         WRITE(numout,*) '      use file attribute if exists as i/p j-start ln_use_jattr     = ', ln_use_jattr
417      ENDIF
418      !
419      IF( 1._wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.',  &
420         &                                                'Compile with key_nosignedzero enabled' )
421      !
422   END SUBROUTINE nemo_ctl
423
424
425   SUBROUTINE nemo_closefile
426      !!----------------------------------------------------------------------
427      !!                     ***  ROUTINE nemo_closefile  ***
428      !!
429      !! ** Purpose :   Close the files
430      !!----------------------------------------------------------------------
431      !
432      IF( lk_mpp )   CALL mppsync
433      !
434      CALL iom_close                                 ! close all input/output files managed by iom_*
435      !
436      IF( numstp     /= -1 )   CLOSE( numstp     )   ! time-step file
437      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
438      !
439      numout = 6                                     ! redefine numout in case it is used after this point...
440      !
441   END SUBROUTINE nemo_closefile
442
443
444   SUBROUTINE nemo_alloc
445      !!----------------------------------------------------------------------
446      !!                     ***  ROUTINE nemo_alloc  ***
447      !!
448      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
449      !!
450      !! ** Method  :
451      !!----------------------------------------------------------------------
452      USE diawri ,   ONLY : dia_wri_alloc
453      USE dom_oce,   ONLY : dom_oce_alloc
454      USE zdf_oce,   ONLY : zdf_oce_alloc
455      USE trc_oce,   ONLY : trc_oce_alloc
456      USE bdy_oce,   ONLY : bdy_oce_alloc
457      !
458      INTEGER :: ierr
459      !!----------------------------------------------------------------------
460      !
461      ierr =        oce_alloc    ()          ! ocean
462      ierr = ierr + dia_wri_alloc()
463      ierr = ierr + dom_oce_alloc()          ! ocean domain
464      ierr = ierr + zdf_oce_alloc()          ! ocean vertical physics
465      ierr = ierr + trc_oce_alloc()          ! shared TRC / TRA arrays
466      ierr = ierr + bdy_oce_alloc()    ! bdy masks (incl. initialization)     
467      !
468      CALL mpp_sum( 'nemogcm', ierr )
469      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' )
470      !
471   END SUBROUTINE nemo_alloc
472
473   SUBROUTINE nemo_set_cfctl(sn_cfctl, setto )
474      !!----------------------------------------------------------------------
475      !!                     ***  ROUTINE nemo_set_cfctl  ***
476      !!
477      !! ** Purpose :   Set elements of the output control structure to setto.
478     !!
479      !! ** Method  :   Note this routine can be used to switch on/off some
480      !!                types of output for selected areas.
481      !!----------------------------------------------------------------------
482      TYPE(sn_ctl), INTENT(inout) :: sn_cfctl
483      LOGICAL     , INTENT(in   ) :: setto
484      !!----------------------------------------------------------------------
485      sn_cfctl%l_runstat = setto
486      sn_cfctl%l_trcstat = setto
487      sn_cfctl%l_oceout  = setto
488      sn_cfctl%l_layout  = setto
489      sn_cfctl%l_prtctl  = setto
490      sn_cfctl%l_prttrc  = setto
491      sn_cfctl%l_oasout  = setto
492   END SUBROUTINE nemo_set_cfctl
493
494   SUBROUTINE istate_init( Kmm, Kaa )
495      !!----------------------------------------------------------------------
496      !!                   ***  ROUTINE istate_init  ***
497      !!
498      !! ** Purpose :   Initialization to zero of the dynamics and tracers.
499      !!----------------------------------------------------------------------
500      INTEGER, INTENT(in) ::   Kmm, Kaa  ! ocean time level indices
501      !
502      !     now fields         !     after fields      !
503      uu   (:,:,:,Kmm)   = 0._wp   ;   uu(:,:,:,Kaa) = 0._wp   !
504      vv   (:,:,:,Kmm)   = 0._wp   ;   vv(:,:,:,Kaa) = 0._wp   !
505      ww   (:,:,:)   = 0._wp   !                       !
506      hdiv (:,:,:)   = 0._wp   !                       !
507      ts  (:,:,:,:,Kmm) = 0._wp   !                       !
508      !
509      rhd  (:,:,:) = 0.e0
510      rhop (:,:,:) = 0.e0
511      rn2  (:,:,:) = 0.e0
512      !
513   END SUBROUTINE istate_init
514
515
516   SUBROUTINE stp_ctl( kt )
517      !!----------------------------------------------------------------------
518      !!                    ***  ROUTINE stp_ctl  ***
519      !!
520      !! ** Purpose :   Control the run
521      !!
522      !! ** Method  : - Save the time step in numstp
523      !!
524      !! ** Actions :   'time.step' file containing the last ocean time-step
525      !!----------------------------------------------------------------------
526      INTEGER, INTENT(in   ) ::   kt      ! ocean time-step index
527      !!----------------------------------------------------------------------
528      !
529      IF( kt == nit000 .AND. lwm ) THEN
530         WRITE(numout,*)
531         WRITE(numout,*) 'stp_ctl : time-stepping control'
532         WRITE(numout,*) '~~~~~~~'
533         ! open time.step file
534         CALL ctl_opn( numstp, 'time.step', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea )
535      ENDIF
536      !
537      IF(lwm) WRITE ( numstp, '(1x, i8)' )   kt      !* save the current time step in numstp
538      IF(lwm) REWIND( numstp )                       ! --------------------------
539      !
540   END SUBROUTINE stp_ctl
541   !!======================================================================
542END MODULE nemogcm
Note: See TracBrowser for help on using the repository browser.