1 | MODULE p4zmicro |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE p4zmicro *** |
---|
4 | !! TOP : PISCES Compute the sources/sinks for microzooplankton |
---|
5 | !!====================================================================== |
---|
6 | !! History : 1.0 ! 2004 (O. Aumont) Original code |
---|
7 | !! 2.0 ! 2007-12 (C. Ethe, G. Madec) F90 |
---|
8 | !! 3.4 ! 2011-06 (O. Aumont, C. Ethe) Quota model for iron |
---|
9 | !!---------------------------------------------------------------------- |
---|
10 | !! p4z_micro : Compute the sources/sinks for microzooplankton |
---|
11 | !! p4z_micro_init : Initialize and read the appropriate namelist |
---|
12 | !!---------------------------------------------------------------------- |
---|
13 | USE oce_trc ! shared variables between ocean and passive tracers |
---|
14 | USE trc ! passive tracers common variables |
---|
15 | USE sms_pisces ! PISCES Source Minus Sink variables |
---|
16 | USE p4zlim ! Co-limitations |
---|
17 | USE p4zprod ! production |
---|
18 | USE iom ! I/O manager |
---|
19 | USE prtctl ! print control for debugging |
---|
20 | |
---|
21 | IMPLICIT NONE |
---|
22 | PRIVATE |
---|
23 | |
---|
24 | PUBLIC p4z_micro ! called in p4zbio.F90 |
---|
25 | PUBLIC p4z_micro_init ! called in trcsms_pisces.F90 |
---|
26 | |
---|
27 | REAL(wp), PUBLIC :: part !: part of calcite not dissolved in microzoo guts |
---|
28 | REAL(wp), PUBLIC :: xprefc !: microzoo preference for POC |
---|
29 | REAL(wp), PUBLIC :: xprefn !: microzoo preference for nanophyto |
---|
30 | REAL(wp), PUBLIC :: xprefd !: microzoo preference for diatoms |
---|
31 | REAL(wp), PUBLIC :: xthreshdia !: diatoms feeding threshold for microzooplankton |
---|
32 | REAL(wp), PUBLIC :: xthreshphy !: nanophyto threshold for microzooplankton |
---|
33 | REAL(wp), PUBLIC :: xthreshpoc !: poc threshold for microzooplankton |
---|
34 | REAL(wp), PUBLIC :: xthresh !: feeding threshold for microzooplankton |
---|
35 | REAL(wp), PUBLIC :: resrat !: exsudation rate of microzooplankton |
---|
36 | REAL(wp), PUBLIC :: mzrat !: microzooplankton mortality rate |
---|
37 | REAL(wp), PUBLIC :: grazrat !: maximal microzoo grazing rate |
---|
38 | REAL(wp), PUBLIC :: xkgraz !: Half-saturation constant of assimilation |
---|
39 | REAL(wp), PUBLIC :: unass !: Non-assimilated part of food |
---|
40 | REAL(wp), PUBLIC :: sigma1 !: Fraction of microzoo excretion as DOM |
---|
41 | REAL(wp), PUBLIC :: epsher !: growth efficiency for grazing 1 |
---|
42 | REAL(wp), PUBLIC :: epshermin !: minimum growth efficiency for grazing 1 |
---|
43 | |
---|
44 | !! * Substitutions |
---|
45 | # include "do_loop_substitute.h90" |
---|
46 | !!---------------------------------------------------------------------- |
---|
47 | !! NEMO/TOP 4.0 , NEMO Consortium (2018) |
---|
48 | !! $Id$ |
---|
49 | !! Software governed by the CeCILL license (see ./LICENSE) |
---|
50 | !!---------------------------------------------------------------------- |
---|
51 | CONTAINS |
---|
52 | |
---|
53 | SUBROUTINE p4z_micro( kt, knt, Kbb, Krhs ) |
---|
54 | !!--------------------------------------------------------------------- |
---|
55 | !! *** ROUTINE p4z_micro *** |
---|
56 | !! |
---|
57 | !! ** Purpose : Compute the sources/sinks for microzooplankton |
---|
58 | !! |
---|
59 | !! ** Method : - ??? |
---|
60 | !!--------------------------------------------------------------------- |
---|
61 | INTEGER, INTENT(in) :: kt ! ocean time step |
---|
62 | INTEGER, INTENT(in) :: knt ! ??? |
---|
63 | INTEGER, INTENT(in) :: Kbb, Krhs ! time level indices |
---|
64 | ! |
---|
65 | INTEGER :: ji, jj, jk |
---|
66 | REAL(wp) :: zcompadi, zcompaz , zcompaph, zcompapoc |
---|
67 | REAL(wp) :: zgraze , zdenom, zdenom2 |
---|
68 | REAL(wp) :: zfact , zfood, zfoodlim, zbeta |
---|
69 | REAL(wp) :: zepsherf, zepshert, zepsherv, zepsherq |
---|
70 | REAL(wp) :: zgrarsig, zgraztotc, zgraztotn, zgraztotf |
---|
71 | REAL(wp) :: zgrarem, zgrafer, zgrapoc, zprcaca, zmortz |
---|
72 | REAL(wp) :: zrespz, ztortz, zgrasrat, zgrasratn |
---|
73 | REAL(wp) :: zgrazp, zgrazm, zgrazsd |
---|
74 | REAL(wp) :: zgrazmf, zgrazsf, zgrazpf |
---|
75 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: zgrazing, zfezoo, zzligprod |
---|
76 | CHARACTER (len=25) :: charout |
---|
77 | !!--------------------------------------------------------------------- |
---|
78 | ! |
---|
79 | IF( ln_timing ) CALL timing_start('p4z_micro') |
---|
80 | ! |
---|
81 | DO_3D( nn_hls, nn_hls, nn_hls, nn_hls, 1, jpkm1) |
---|
82 | zcompaz = MAX( ( tr(ji,jj,jk,jpzoo,Kbb) - 1.e-9 ), 0.e0 ) |
---|
83 | zfact = xstep * tgfunc2(ji,jj,jk) * zcompaz |
---|
84 | |
---|
85 | ! Respiration rates of both zooplankton |
---|
86 | ! ------------------------------------- |
---|
87 | zrespz = resrat * zfact * tr(ji,jj,jk,jpzoo,Kbb) / ( xkmort + tr(ji,jj,jk,jpzoo,Kbb) ) & |
---|
88 | & + resrat * zfact * 3. * nitrfac(ji,jj,jk) |
---|
89 | |
---|
90 | ! Zooplankton mortality. A square function has been selected with |
---|
91 | ! no real reason except that it seems to be more stable and may mimic predation. |
---|
92 | ! --------------------------------------------------------------- |
---|
93 | ztortz = mzrat * 1.e6 * zfact * tr(ji,jj,jk,jpzoo,Kbb) * (1. - nitrfac(ji,jj,jk)) |
---|
94 | |
---|
95 | zcompadi = MIN( MAX( ( tr(ji,jj,jk,jpdia,Kbb) - xthreshdia ), 0.e0 ), xsizedia ) |
---|
96 | zcompaph = MAX( ( tr(ji,jj,jk,jpphy,Kbb) - xthreshphy ), 0.e0 ) |
---|
97 | zcompapoc = MAX( ( tr(ji,jj,jk,jppoc,Kbb) - xthreshpoc ), 0.e0 ) |
---|
98 | |
---|
99 | ! Microzooplankton grazing |
---|
100 | ! ------------------------ |
---|
101 | zfood = xprefn * zcompaph + xprefc * zcompapoc + xprefd * zcompadi |
---|
102 | zfoodlim = MAX( 0. , zfood - min(xthresh,0.5*zfood) ) |
---|
103 | zdenom = zfoodlim / ( xkgraz + zfoodlim ) |
---|
104 | zdenom2 = zdenom / ( zfood + rtrn ) |
---|
105 | zgraze = grazrat * xstep * tgfunc2(ji,jj,jk) * tr(ji,jj,jk,jpzoo,Kbb) * (1. - nitrfac(ji,jj,jk)) |
---|
106 | |
---|
107 | zgrazp = zgraze * xprefn * zcompaph * zdenom2 |
---|
108 | zgrazm = zgraze * xprefc * zcompapoc * zdenom2 |
---|
109 | zgrazsd = zgraze * xprefd * zcompadi * zdenom2 |
---|
110 | |
---|
111 | zgrazpf = zgrazp * tr(ji,jj,jk,jpnfe,Kbb) / (tr(ji,jj,jk,jpphy,Kbb) + rtrn) |
---|
112 | zgrazmf = zgrazm * tr(ji,jj,jk,jpsfe,Kbb) / (tr(ji,jj,jk,jppoc,Kbb) + rtrn) |
---|
113 | zgrazsf = zgrazsd * tr(ji,jj,jk,jpdfe,Kbb) / (tr(ji,jj,jk,jpdia,Kbb) + rtrn) |
---|
114 | ! |
---|
115 | zgraztotc = zgrazp + zgrazm + zgrazsd |
---|
116 | zgraztotf = zgrazpf + zgrazsf + zgrazmf |
---|
117 | zgraztotn = zgrazp * quotan(ji,jj,jk) + zgrazm + zgrazsd * quotad(ji,jj,jk) |
---|
118 | |
---|
119 | ! Grazing by microzooplankton |
---|
120 | zgrazing(ji,jj,jk) = zgraztotc |
---|
121 | |
---|
122 | |
---|
123 | ! Microzooplankton efficiency. |
---|
124 | ! We adopt a formulation proposed by Mitra et al. (2007) |
---|
125 | ! The gross growth efficiency is controled by the most limiting nutrient. |
---|
126 | ! Growth is also further decreased when the food quality is poor. This is currently |
---|
127 | ! hard coded : it can be decreased by up to 50% (zepsherq) |
---|
128 | ! GGE can also be decreased when food quantity is high, zepsherf (Montagnes and |
---|
129 | ! Fulton, 2012) |
---|
130 | ! ----------------------------------------------------------------------------- |
---|
131 | zgrasrat = ( zgraztotf + rtrn ) / ( zgraztotc + rtrn ) |
---|
132 | zgrasratn = ( zgraztotn + rtrn ) / ( zgraztotc + rtrn ) |
---|
133 | zepshert = MIN( 1., zgrasratn, zgrasrat / ferat3) |
---|
134 | zbeta = MAX(0., (epsher - epshermin) ) |
---|
135 | zepsherf = epshermin + zbeta / ( 1.0 + 0.04E6 * 12. * zfood * zbeta ) |
---|
136 | zepsherq = 0.5 + (1.0 - 0.5) * zepshert * ( 1.0 + 1.0 ) / ( zepshert + 1.0 ) |
---|
137 | zepsherv = zepsherf * zepshert * zepsherq |
---|
138 | |
---|
139 | zgrafer = zgraztotc * MAX( 0. , ( 1. - unass ) * zgrasrat - ferat3 * zepsherv ) |
---|
140 | zgrarem = zgraztotc * ( 1. - zepsherv - unass ) |
---|
141 | zgrapoc = zgraztotc * unass |
---|
142 | |
---|
143 | ! Update of the TRA arrays |
---|
144 | ! ------------------------ |
---|
145 | zgrarsig = zgrarem * sigma1 |
---|
146 | tr(ji,jj,jk,jppo4,Krhs) = tr(ji,jj,jk,jppo4,Krhs) + zgrarsig |
---|
147 | tr(ji,jj,jk,jpnh4,Krhs) = tr(ji,jj,jk,jpnh4,Krhs) + zgrarsig |
---|
148 | tr(ji,jj,jk,jpdoc,Krhs) = tr(ji,jj,jk,jpdoc,Krhs) + zgrarem - zgrarsig |
---|
149 | ! |
---|
150 | IF( ln_ligand ) THEN |
---|
151 | tr(ji,jj,jk,jplgw,Krhs) = tr(ji,jj,jk,jplgw,Krhs) + (zgrarem - zgrarsig) * ldocz |
---|
152 | zzligprod(ji,jj,jk) = (zgrarem - zgrarsig) * ldocz |
---|
153 | ENDIF |
---|
154 | ! |
---|
155 | tr(ji,jj,jk,jpoxy,Krhs) = tr(ji,jj,jk,jpoxy,Krhs) - o2ut * zgrarsig |
---|
156 | tr(ji,jj,jk,jpfer,Krhs) = tr(ji,jj,jk,jpfer,Krhs) + zgrafer |
---|
157 | zfezoo(ji,jj,jk) = zgrafer |
---|
158 | tr(ji,jj,jk,jppoc,Krhs) = tr(ji,jj,jk,jppoc,Krhs) + zgrapoc |
---|
159 | prodpoc(ji,jj,jk) = prodpoc(ji,jj,jk) + zgrapoc |
---|
160 | tr(ji,jj,jk,jpsfe,Krhs) = tr(ji,jj,jk,jpsfe,Krhs) + zgraztotf * unass |
---|
161 | tr(ji,jj,jk,jpdic,Krhs) = tr(ji,jj,jk,jpdic,Krhs) + zgrarsig |
---|
162 | tr(ji,jj,jk,jptal,Krhs) = tr(ji,jj,jk,jptal,Krhs) + rno3 * zgrarsig |
---|
163 | ! Update the arrays TRA which contain the biological sources and sinks |
---|
164 | ! -------------------------------------------------------------------- |
---|
165 | zmortz = ztortz + zrespz |
---|
166 | tr(ji,jj,jk,jpzoo,Krhs) = tr(ji,jj,jk,jpzoo,Krhs) - zmortz + zepsherv * zgraztotc |
---|
167 | tr(ji,jj,jk,jpphy,Krhs) = tr(ji,jj,jk,jpphy,Krhs) - zgrazp |
---|
168 | tr(ji,jj,jk,jpdia,Krhs) = tr(ji,jj,jk,jpdia,Krhs) - zgrazsd |
---|
169 | tr(ji,jj,jk,jpnch,Krhs) = tr(ji,jj,jk,jpnch,Krhs) - zgrazp * tr(ji,jj,jk,jpnch,Kbb)/(tr(ji,jj,jk,jpphy,Kbb)+rtrn) |
---|
170 | tr(ji,jj,jk,jpdch,Krhs) = tr(ji,jj,jk,jpdch,Krhs) - zgrazsd * tr(ji,jj,jk,jpdch,Kbb)/(tr(ji,jj,jk,jpdia,Kbb)+rtrn) |
---|
171 | tr(ji,jj,jk,jpdsi,Krhs) = tr(ji,jj,jk,jpdsi,Krhs) - zgrazsd * tr(ji,jj,jk,jpdsi,Kbb)/(tr(ji,jj,jk,jpdia,Kbb)+rtrn) |
---|
172 | tr(ji,jj,jk,jpgsi,Krhs) = tr(ji,jj,jk,jpgsi,Krhs) + zgrazsd * tr(ji,jj,jk,jpdsi,Kbb)/(tr(ji,jj,jk,jpdia,Kbb)+rtrn) |
---|
173 | tr(ji,jj,jk,jpnfe,Krhs) = tr(ji,jj,jk,jpnfe,Krhs) - zgrazpf |
---|
174 | tr(ji,jj,jk,jpdfe,Krhs) = tr(ji,jj,jk,jpdfe,Krhs) - zgrazsf |
---|
175 | tr(ji,jj,jk,jppoc,Krhs) = tr(ji,jj,jk,jppoc,Krhs) + zmortz - zgrazm |
---|
176 | prodpoc(ji,jj,jk) = prodpoc(ji,jj,jk) + zmortz |
---|
177 | conspoc(ji,jj,jk) = conspoc(ji,jj,jk) - zgrazm |
---|
178 | tr(ji,jj,jk,jpsfe,Krhs) = tr(ji,jj,jk,jpsfe,Krhs) + ferat3 * zmortz - zgrazmf |
---|
179 | ! |
---|
180 | ! calcite production |
---|
181 | zprcaca = xfracal(ji,jj,jk) * zgrazp |
---|
182 | prodcal(ji,jj,jk) = prodcal(ji,jj,jk) + zprcaca ! prodcal=prodcal(nanophy)+prodcal(microzoo)+prodcal(mesozoo) |
---|
183 | ! |
---|
184 | zprcaca = part * zprcaca |
---|
185 | tr(ji,jj,jk,jpdic,Krhs) = tr(ji,jj,jk,jpdic,Krhs) - zprcaca |
---|
186 | tr(ji,jj,jk,jptal,Krhs) = tr(ji,jj,jk,jptal,Krhs) - 2. * zprcaca |
---|
187 | tr(ji,jj,jk,jpcal,Krhs) = tr(ji,jj,jk,jpcal,Krhs) + zprcaca |
---|
188 | END_3D |
---|
189 | ! |
---|
190 | IF( lk_iomput .AND. knt == nrdttrc ) THEN |
---|
191 | IF( iom_use("GRAZ1") ) THEN ! Total grazing of phyto by zooplankton |
---|
192 | zgrazing(:,:,jpk) = 0._wp ; CALL iom_put( "GRAZ1" , zgrazing(:,:,:) * 1.e+3 * rfact2r * tmask(:,:,:) ) |
---|
193 | ENDIF |
---|
194 | IF( iom_use("FEZOO") ) THEN |
---|
195 | zfezoo (:,:,jpk) = 0._wp ; CALL iom_put( "FEZOO", zfezoo(:,:,:) * 1e9 * 1.e+3 * rfact2r * tmask(:,:,:) ) |
---|
196 | ENDIF |
---|
197 | IF( ln_ligand ) THEN |
---|
198 | zzligprod(:,:,jpk) = 0._wp ; CALL iom_put( "LPRODZ", zzligprod(:,:,:) * 1e9 * 1.e+3 * rfact2r * tmask(:,:,:)) |
---|
199 | ENDIF |
---|
200 | ENDIF |
---|
201 | ! |
---|
202 | IF(sn_cfctl%l_prttrc) THEN ! print mean trends (used for debugging) |
---|
203 | WRITE(charout, FMT="('micro')") |
---|
204 | CALL prt_ctl_info( charout, cdcomp = 'top' ) |
---|
205 | CALL prt_ctl(tab4d_1=tr(:,:,:,:,Krhs), mask1=tmask, clinfo=ctrcnm) |
---|
206 | ENDIF |
---|
207 | ! |
---|
208 | IF( ln_timing ) CALL timing_stop('p4z_micro') |
---|
209 | ! |
---|
210 | END SUBROUTINE p4z_micro |
---|
211 | |
---|
212 | |
---|
213 | SUBROUTINE p4z_micro_init |
---|
214 | !!---------------------------------------------------------------------- |
---|
215 | !! *** ROUTINE p4z_micro_init *** |
---|
216 | !! |
---|
217 | !! ** Purpose : Initialization of microzooplankton parameters |
---|
218 | !! |
---|
219 | !! ** Method : Read the nampiszoo namelist and check the parameters |
---|
220 | !! called at the first timestep (nittrc000) |
---|
221 | !! |
---|
222 | !! ** input : Namelist nampiszoo |
---|
223 | !! |
---|
224 | !!---------------------------------------------------------------------- |
---|
225 | INTEGER :: ios ! Local integer |
---|
226 | ! |
---|
227 | NAMELIST/namp4zzoo/ part, grazrat, resrat, mzrat, xprefn, xprefc, & |
---|
228 | & xprefd, xthreshdia, xthreshphy, xthreshpoc, & |
---|
229 | & xthresh, xkgraz, epsher, epshermin, sigma1, unass |
---|
230 | !!---------------------------------------------------------------------- |
---|
231 | ! |
---|
232 | IF(lwp) THEN |
---|
233 | WRITE(numout,*) |
---|
234 | WRITE(numout,*) 'p4z_micro_init : Initialization of microzooplankton parameters' |
---|
235 | WRITE(numout,*) '~~~~~~~~~~~~~~' |
---|
236 | ENDIF |
---|
237 | ! |
---|
238 | READ ( numnatp_ref, namp4zzoo, IOSTAT = ios, ERR = 901) |
---|
239 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namp4zzoo in reference namelist' ) |
---|
240 | READ ( numnatp_cfg, namp4zzoo, IOSTAT = ios, ERR = 902 ) |
---|
241 | 902 IF( ios > 0 ) CALL ctl_nam ( ios , 'namp4zzoo in configuration namelist' ) |
---|
242 | IF(lwm) WRITE( numonp, namp4zzoo ) |
---|
243 | ! |
---|
244 | IF(lwp) THEN ! control print |
---|
245 | WRITE(numout,*) ' Namelist : namp4zzoo' |
---|
246 | WRITE(numout,*) ' part of calcite not dissolved in microzoo guts part =', part |
---|
247 | WRITE(numout,*) ' microzoo preference for POC xprefc =', xprefc |
---|
248 | WRITE(numout,*) ' microzoo preference for nano xprefn =', xprefn |
---|
249 | WRITE(numout,*) ' microzoo preference for diatoms xprefd =', xprefd |
---|
250 | WRITE(numout,*) ' diatoms feeding threshold for microzoo xthreshdia =', xthreshdia |
---|
251 | WRITE(numout,*) ' nanophyto feeding threshold for microzoo xthreshphy =', xthreshphy |
---|
252 | WRITE(numout,*) ' poc feeding threshold for microzoo xthreshpoc =', xthreshpoc |
---|
253 | WRITE(numout,*) ' feeding threshold for microzooplankton xthresh =', xthresh |
---|
254 | WRITE(numout,*) ' exsudation rate of microzooplankton resrat =', resrat |
---|
255 | WRITE(numout,*) ' microzooplankton mortality rate mzrat =', mzrat |
---|
256 | WRITE(numout,*) ' maximal microzoo grazing rate grazrat =', grazrat |
---|
257 | WRITE(numout,*) ' non assimilated fraction of P by microzoo unass =', unass |
---|
258 | WRITE(numout,*) ' Efficicency of microzoo growth epsher =', epsher |
---|
259 | WRITE(numout,*) ' Minimum efficicency of microzoo growth epshermin =', epshermin |
---|
260 | WRITE(numout,*) ' Fraction of microzoo excretion as DOM sigma1 =', sigma1 |
---|
261 | WRITE(numout,*) ' half sturation constant for grazing 1 xkgraz =', xkgraz |
---|
262 | ENDIF |
---|
263 | ! |
---|
264 | END SUBROUTINE p4z_micro_init |
---|
265 | |
---|
266 | !!====================================================================== |
---|
267 | END MODULE p4zmicro |
---|