source: NEMO/trunk/src/TOP/PISCES/P4Z/p4zopt.F90 @ 10069

Last change on this file since 10069 was 10069, checked in by nicolasmartin, 2 years ago

Fix mistakes of previous commit on SVN keywords property

  • Property svn:keywords set to Id
File size: 19.1 KB
Line 
1MODULE p4zopt
2   !!======================================================================
3   !!                         ***  MODULE p4zopt  ***
4   !! TOP - PISCES : Compute the light availability in the water column
5   !!======================================================================
6   !! History :  1.0  !  2004     (O. Aumont) Original code
7   !!            2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!            3.2  !  2009-04  (C. Ethe, G. Madec)  optimisation
9   !!            3.4  !  2011-06  (O. Aumont, C. Ethe) Improve light availability of nano & diat
10   !!----------------------------------------------------------------------
11   !!   p4z_opt       : light availability in the water column
12   !!----------------------------------------------------------------------
13   USE trc            ! tracer variables
14   USE oce_trc        ! tracer-ocean share variables
15   USE sms_pisces     ! Source Minus Sink of PISCES
16   USE iom            ! I/O manager
17   USE fldread        !  time interpolation
18   USE prtctl_trc     !  print control for debugging
19
20   IMPLICIT NONE
21   PRIVATE
22
23   PUBLIC   p4z_opt        ! called in p4zbio.F90 module
24   PUBLIC   p4z_opt_init   ! called in trcsms_pisces.F90 module
25   PUBLIC   p4z_opt_alloc
26
27   !! * Shared module variables
28
29   LOGICAL  ::   ln_varpar   ! boolean for variable PAR fraction
30   REAL(wp) ::   parlux      ! Fraction of shortwave as PAR
31   REAL(wp) ::   xparsw      ! parlux/3
32   REAL(wp) ::   xsi0r       ! 1. /rn_si0
33
34   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_par      ! structure of input par
35   INTEGER , PARAMETER :: nbtimes = 366  !: maximum number of times record in a file
36   INTEGER  :: ntimes_par                ! number of time steps in a file
37   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   par_varsw      ! PAR fraction of shortwave
38   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   ekb, ekg, ekr  ! wavelength (Red-Green-Blue)
39
40   INTEGER  ::   nksrp   ! levels below which the light cannot penetrate ( depth larger than 391 m)
41
42   REAL(wp), DIMENSION(3,61) ::   xkrgb   ! tabulated attenuation coefficients for RGB absorption
43   
44   !!----------------------------------------------------------------------
45   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
46   !! $Id$
47   !! Software governed by the CeCILL license (see ./LICENSE)
48   !!----------------------------------------------------------------------
49CONTAINS
50
51   SUBROUTINE p4z_opt( kt, knt )
52      !!---------------------------------------------------------------------
53      !!                     ***  ROUTINE p4z_opt  ***
54      !!
55      !! ** Purpose :   Compute the light availability in the water column
56      !!              depending on the depth and the chlorophyll concentration
57      !!
58      !! ** Method  : - ???
59      !!---------------------------------------------------------------------
60      INTEGER, INTENT(in) ::   kt, knt   ! ocean time step
61      !
62      INTEGER  ::   ji, jj, jk
63      INTEGER  ::   irgb
64      REAL(wp) ::   zchl
65      REAL(wp) ::   zc0 , zc1 , zc2, zc3, z1_dep
66      REAL(wp), ALLOCATABLE, DIMENSION(:,:  ) :: zetmp5
67      REAL(wp), DIMENSION(jpi,jpj    ) :: zdepmoy, zetmp1, zetmp2, zetmp3, zetmp4
68      REAL(wp), DIMENSION(jpi,jpj    ) :: zqsr100, zqsr_corr
69      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zpar, ze0, ze1, ze2, ze3, zchl3d
70      !!---------------------------------------------------------------------
71      !
72      IF( ln_timing )   CALL timing_start('p4z_opt')
73      IF( ln_p5z    )   ALLOCATE( zetmp5(jpi,jpj) )
74
75      IF( knt == 1 .AND. ln_varpar )   CALL p4z_opt_sbc( kt )
76
77      !     Initialisation of variables used to compute PAR
78      !     -----------------------------------------------
79      ze1(:,:,:) = 0._wp
80      ze2(:,:,:) = 0._wp
81      ze3(:,:,:) = 0._wp
82      !
83      !                                        !* attenuation coef. function of Chlorophyll and wavelength (Red-Green-Blue)
84      !                                        !  --------------------------------------------------------
85                     zchl3d(:,:,:) = trb(:,:,:,jpnch) + trb(:,:,:,jpdch)
86      IF( ln_p5z )   zchl3d(:,:,:) = zchl3d(:,:,:)    + trb(:,:,:,jppch)
87      !
88      DO jk = 1, jpkm1   
89         DO jj = 1, jpj
90            DO ji = 1, jpi
91               zchl = ( zchl3d(ji,jj,jk) + rtrn ) * 1.e6
92               zchl = MIN(  10. , MAX( 0.05, zchl )  )
93               irgb = NINT( 41 + 20.* LOG10( zchl ) + rtrn )
94               !                                                         
95               ekb(ji,jj,jk) = xkrgb(1,irgb) * e3t_n(ji,jj,jk)
96               ekg(ji,jj,jk) = xkrgb(2,irgb) * e3t_n(ji,jj,jk)
97               ekr(ji,jj,jk) = xkrgb(3,irgb) * e3t_n(ji,jj,jk)
98            END DO
99         END DO
100      END DO
101      !                                        !* Photosynthetically Available Radiation (PAR)
102      !                                        !  --------------------------------------
103      IF( l_trcdm2dc ) THEN                     !  diurnal cycle
104         !
105         zqsr_corr(:,:) = qsr_mean(:,:) / ( 1.-fr_i(:,:) + rtrn )
106         !
107         CALL p4z_opt_par( kt, zqsr_corr, ze1, ze2, ze3, pqsr100 = zqsr100 ) 
108         !
109         DO jk = 1, nksrp     
110            etot_ndcy(:,:,jk) =        ze1(:,:,jk) +        ze2(:,:,jk) +       ze3(:,:,jk)
111            enano    (:,:,jk) =  2.1 * ze1(:,:,jk) + 0.42 * ze2(:,:,jk) + 0.4 * ze3(:,:,jk)
112            ediat    (:,:,jk) =  1.6 * ze1(:,:,jk) + 0.69 * ze2(:,:,jk) + 0.7 * ze3(:,:,jk)
113         END DO
114         IF( ln_p5z ) THEN
115            DO jk = 1, nksrp     
116              epico  (:,:,jk) =  2.1 * ze1(:,:,jk) + 0.42 * ze2(:,:,jk) + 0.4 * ze3(:,:,jk)
117            END DO
118         ENDIF
119         !
120         zqsr_corr(:,:) = qsr(:,:) / ( 1.-fr_i(:,:) + rtrn )
121         !
122         CALL p4z_opt_par( kt, zqsr_corr, ze1, ze2, ze3 ) 
123         !
124         DO jk = 1, nksrp     
125            etot(:,:,jk) =  ze1(:,:,jk) + ze2(:,:,jk) + ze3(:,:,jk)
126         END DO
127         !
128      ELSE
129         !
130         zqsr_corr(:,:) = qsr(:,:) / ( 1.-fr_i(:,:) + rtrn )
131         !
132         CALL p4z_opt_par( kt, zqsr_corr, ze1, ze2, ze3, pqsr100 = zqsr100  ) 
133         !
134         DO jk = 1, nksrp     
135            etot (:,:,jk) =        ze1(:,:,jk) +        ze2(:,:,jk) +       ze3(:,:,jk)
136            enano(:,:,jk) =  2.1 * ze1(:,:,jk) + 0.42 * ze2(:,:,jk) + 0.4 * ze3(:,:,jk)
137            ediat(:,:,jk) =  1.6 * ze1(:,:,jk) + 0.69 * ze2(:,:,jk) + 0.7 * ze3(:,:,jk)
138         END DO
139         IF( ln_p5z ) THEN
140            DO jk = 1, nksrp     
141              epico(:,:,jk) =  2.1 * ze1(:,:,jk) + 0.42 * ze2(:,:,jk) + 0.4 * ze3(:,:,jk)
142            END DO
143         ENDIF
144         etot_ndcy(:,:,:) =  etot(:,:,:) 
145      ENDIF
146
147
148      IF( ln_qsr_bio ) THEN                    !* heat flux accros w-level (used in the dynamics)
149         !                                     !  ------------------------
150         CALL p4z_opt_par( kt, qsr, ze1, ze2, ze3, pe0=ze0 )
151         !
152         etot3(:,:,1) =  qsr(:,:) * tmask(:,:,1)
153         DO jk = 2, nksrp + 1
154            etot3(:,:,jk) =  ( ze0(:,:,jk) + ze1(:,:,jk) + ze2(:,:,jk) + ze3(:,:,jk) ) * tmask(:,:,jk)
155         END DO
156         !                                     !  ------------------------
157      ENDIF
158      !                                        !* Euphotic depth and level
159      neln   (:,:) = 1                            !  ------------------------
160      heup   (:,:) = gdepw_n(:,:,2)
161      heup_01(:,:) = gdepw_n(:,:,2)
162
163      DO jk = 2, nksrp
164         DO jj = 1, jpj
165           DO ji = 1, jpi
166              IF( etot_ndcy(ji,jj,jk) * tmask(ji,jj,jk) >=  zqsr100(ji,jj) )  THEN
167                 neln(ji,jj) = jk+1                    ! Euphotic level : 1rst T-level strictly below Euphotic layer
168                 !                                     ! nb: ensure the compatibility with nmld_trc definition in trd_mld_trc_zint
169                 heup(ji,jj) = gdepw_n(ji,jj,jk+1)     ! Euphotic layer depth
170              ENDIF
171              IF( etot_ndcy(ji,jj,jk) * tmask(ji,jj,jk) >= 0.50 )  THEN
172                 heup_01(ji,jj) = gdepw_n(ji,jj,jk+1)  ! Euphotic layer depth (light level definition)
173              ENDIF
174           END DO
175        END DO
176      END DO
177      !
178      heup   (:,:) = MIN( 300., heup   (:,:) )
179      heup_01(:,:) = MIN( 300., heup_01(:,:) )
180      !                                        !* mean light over the mixed layer
181      zdepmoy(:,:)   = 0.e0                    !  -------------------------------
182      zetmp1 (:,:)   = 0.e0
183      zetmp2 (:,:)   = 0.e0
184      zetmp3 (:,:)   = 0.e0
185      zetmp4 (:,:)   = 0.e0
186
187      DO jk = 1, nksrp
188         DO jj = 1, jpj
189            DO ji = 1, jpi
190               IF( gdepw_n(ji,jj,jk+1) <= hmld(ji,jj) ) THEN
191                  zetmp1 (ji,jj) = zetmp1 (ji,jj) + etot     (ji,jj,jk) * e3t_n(ji,jj,jk) ! remineralisation
192                  zetmp2 (ji,jj) = zetmp2 (ji,jj) + etot_ndcy(ji,jj,jk) * e3t_n(ji,jj,jk) ! production
193                  zetmp3 (ji,jj) = zetmp3 (ji,jj) + enano    (ji,jj,jk) * e3t_n(ji,jj,jk) ! production
194                  zetmp4 (ji,jj) = zetmp4 (ji,jj) + ediat    (ji,jj,jk) * e3t_n(ji,jj,jk) ! production
195                  zdepmoy(ji,jj) = zdepmoy(ji,jj) +                       e3t_n(ji,jj,jk)
196               ENDIF
197            END DO
198         END DO
199      END DO
200      !
201      emoy(:,:,:) = etot(:,:,:)       ! remineralisation
202      zpar(:,:,:) = etot_ndcy(:,:,:)  ! diagnostic : PAR with no diurnal cycle
203      !
204      DO jk = 1, nksrp
205         DO jj = 1, jpj
206            DO ji = 1, jpi
207               IF( gdepw_n(ji,jj,jk+1) <= hmld(ji,jj) ) THEN
208                  z1_dep = 1. / ( zdepmoy(ji,jj) + rtrn )
209                  emoy (ji,jj,jk) = zetmp1(ji,jj) * z1_dep
210                  zpar (ji,jj,jk) = zetmp2(ji,jj) * z1_dep
211                  enano(ji,jj,jk) = zetmp3(ji,jj) * z1_dep
212                  ediat(ji,jj,jk) = zetmp4(ji,jj) * z1_dep
213               ENDIF
214            END DO
215         END DO
216      END DO
217      !
218      IF( ln_p5z ) THEN
219         zetmp5 (:,:) = 0.e0
220         DO jk = 1, nksrp
221            DO jj = 1, jpj
222               DO ji = 1, jpi
223                  IF( gdepw_n(ji,jj,jk+1) <= hmld(ji,jj) ) THEN
224                     z1_dep = 1. / ( zdepmoy(ji,jj) + rtrn )
225                     zetmp5(ji,jj)  = zetmp5 (ji,jj) + epico(ji,jj,jk) * e3t_n(ji,jj,jk) ! production
226                     epico(ji,jj,jk) = zetmp5(ji,jj) * z1_dep
227                  ENDIF
228               END DO
229            END DO
230         END DO
231      ENDIF
232      IF( lk_iomput ) THEN
233        IF( knt == nrdttrc ) THEN
234           IF( iom_use( "Heup"  ) ) CALL iom_put( "Heup" , heup(:,:  ) * tmask(:,:,1) )  ! euphotic layer deptht
235           IF( iom_use( "PARDM" ) ) CALL iom_put( "PARDM", zpar(:,:,:) * tmask(:,:,:) )  ! Photosynthetically Available Radiation
236           IF( iom_use( "PAR"   ) ) CALL iom_put( "PAR"  , emoy(:,:,:) * tmask(:,:,:) )  ! Photosynthetically Available Radiation
237        ENDIF
238      ENDIF
239      !
240      IF( ln_p5z    )   DEALLOCATE( zetmp5 )
241      IF( ln_timing )   CALL timing_stop('p4z_opt')
242      !
243   END SUBROUTINE p4z_opt
244
245
246   SUBROUTINE p4z_opt_par( kt, pqsr, pe1, pe2, pe3, pe0, pqsr100 ) 
247      !!----------------------------------------------------------------------
248      !!                  ***  routine p4z_opt_par  ***
249      !!
250      !! ** purpose :   compute PAR of each wavelength (Red-Green-Blue)
251      !!                for a given shortwave radiation
252      !!
253      !!----------------------------------------------------------------------
254      INTEGER                         , INTENT(in)              ::   kt                ! ocean time-step
255      REAL(wp), DIMENSION(jpi,jpj)    , INTENT(in   )           ::   pqsr              ! shortwave
256      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout)           ::   pe1 , pe2 , pe3   ! PAR ( R-G-B)
257      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout), OPTIONAL ::   pe0               !
258      REAL(wp), DIMENSION(jpi,jpj)    , INTENT(  out), OPTIONAL ::   pqsr100           !
259      !
260      INTEGER    ::   ji, jj, jk     ! dummy loop indices
261      REAL(wp), DIMENSION(jpi,jpj) ::  zqsr   ! shortwave
262      !!----------------------------------------------------------------------
263
264      !  Real shortwave
265      IF( ln_varpar ) THEN  ;  zqsr(:,:) = par_varsw(:,:) * pqsr(:,:)
266      ELSE                  ;  zqsr(:,:) = xparsw         * pqsr(:,:)
267      ENDIF
268     
269      !  Light at the euphotic depth
270      IF( PRESENT( pqsr100 ) )   pqsr100(:,:) = 0.01 * 3. * zqsr(:,:)
271
272      IF( PRESENT( pe0 ) ) THEN     !  W-level
273         !
274         pe0(:,:,1) = pqsr(:,:) - 3. * zqsr(:,:)    !   ( 1 - 3 * alpha ) * q
275         pe1(:,:,1) = zqsr(:,:)         
276         pe2(:,:,1) = zqsr(:,:)
277         pe3(:,:,1) = zqsr(:,:)
278         !
279         DO jk = 2, nksrp + 1
280            DO jj = 1, jpj
281               DO ji = 1, jpi
282                  pe0(ji,jj,jk) = pe0(ji,jj,jk-1) * EXP( -e3t_n(ji,jj,jk-1) * xsi0r )
283                  pe1(ji,jj,jk) = pe1(ji,jj,jk-1) * EXP( -ekb  (ji,jj,jk-1 )        )
284                  pe2(ji,jj,jk) = pe2(ji,jj,jk-1) * EXP( -ekg  (ji,jj,jk-1 )        )
285                  pe3(ji,jj,jk) = pe3(ji,jj,jk-1) * EXP( -ekr  (ji,jj,jk-1 )        )
286               END DO
287              !
288            END DO
289            !
290         END DO
291        !
292      ELSE   ! T- level
293        !
294        pe1(:,:,1) = zqsr(:,:) * EXP( -0.5 * ekb(:,:,1) )
295        pe2(:,:,1) = zqsr(:,:) * EXP( -0.5 * ekg(:,:,1) )
296        pe3(:,:,1) = zqsr(:,:) * EXP( -0.5 * ekr(:,:,1) )
297        !
298        DO jk = 2, nksrp     
299           DO jj = 1, jpj
300              DO ji = 1, jpi
301                 pe1(ji,jj,jk) = pe1(ji,jj,jk-1) * EXP( -0.5 * ( ekb(ji,jj,jk-1) + ekb(ji,jj,jk) ) )
302                 pe2(ji,jj,jk) = pe2(ji,jj,jk-1) * EXP( -0.5 * ( ekg(ji,jj,jk-1) + ekg(ji,jj,jk) ) )
303                 pe3(ji,jj,jk) = pe3(ji,jj,jk-1) * EXP( -0.5 * ( ekr(ji,jj,jk-1) + ekr(ji,jj,jk) ) )
304              END DO
305           END DO
306        END DO   
307        !
308      ENDIF
309      !
310   END SUBROUTINE p4z_opt_par
311
312
313   SUBROUTINE p4z_opt_sbc( kt )
314      !!----------------------------------------------------------------------
315      !!                  ***  routine p4z_opt_sbc  ***
316      !!
317      !! ** purpose :   read and interpolate the variable PAR fraction
318      !!                of shortwave radiation
319      !!
320      !! ** method  :   read the files and interpolate the appropriate variables
321      !!
322      !! ** input   :   external netcdf files
323      !!
324      !!----------------------------------------------------------------------
325      INTEGER, INTENT(in) ::   kt   ! ocean time step
326      !
327      INTEGER  :: ji,jj
328      REAL(wp) :: zcoef
329      !!---------------------------------------------------------------------
330      !
331      IF( ln_timing )  CALL timing_start('p4z_optsbc')
332      !
333      ! Compute par_varsw at nit000 or only if there is more than 1 time record in par coefficient file
334      IF( ln_varpar ) THEN
335         IF( kt == nit000 .OR. ( kt /= nit000 .AND. ntimes_par > 1 ) ) THEN
336            CALL fld_read( kt, 1, sf_par )
337            par_varsw(:,:) = ( sf_par(1)%fnow(:,:,1) ) / 3.0
338         ENDIF
339      ENDIF
340      !
341      IF( ln_timing )  CALL timing_stop('p4z_optsbc')
342      !
343   END SUBROUTINE p4z_opt_sbc
344
345
346   SUBROUTINE p4z_opt_init
347      !!----------------------------------------------------------------------
348      !!                  ***  ROUTINE p4z_opt_init  ***
349      !!
350      !! ** Purpose :   Initialization of tabulated attenuation coef
351      !!                and of the percentage of PAR in Shortwave
352      !!
353      !! ** Input   :   external ascii and netcdf files
354      !!----------------------------------------------------------------------
355      INTEGER :: numpar, ierr, ios   ! Local integer
356      REAL(wp), DIMENSION(nbtimes) ::   zsteps   ! times records
357      !
358      CHARACTER(len=100) ::  cn_dir          ! Root directory for location of ssr files
359      TYPE(FLD_N) ::   sn_par                ! informations about the fields to be read
360      !
361      NAMELIST/nampisopt/cn_dir, sn_par, ln_varpar, parlux
362      !!----------------------------------------------------------------------
363      IF(lwp) THEN
364         WRITE(numout,*)
365         WRITE(numout,*) 'p4z_opt_init : '
366         WRITE(numout,*) '~~~~~~~~~~~~ '
367      ENDIF
368      REWIND( numnatp_ref )              ! Namelist nampisopt in reference namelist : Pisces attenuation coef. and PAR
369      READ  ( numnatp_ref, nampisopt, IOSTAT = ios, ERR = 901)
370901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nampisopt in reference namelist', lwp )
371      REWIND( numnatp_cfg )              ! Namelist nampisopt in configuration namelist : Pisces attenuation coef. and PAR
372      READ  ( numnatp_cfg, nampisopt, IOSTAT = ios, ERR = 902 )
373902   IF( ios >  0 )   CALL ctl_nam ( ios , 'nampisopt in configuration namelist', lwp )
374      IF(lwm) WRITE ( numonp, nampisopt )
375
376      IF(lwp) THEN
377         WRITE(numout,*) '   Namelist : nampisopt '
378         WRITE(numout,*) '      PAR as a variable fraction of SW     ln_varpar      = ', ln_varpar
379         WRITE(numout,*) '      Default value for the PAR fraction   parlux         = ', parlux
380      ENDIF
381      !
382      xparsw = parlux / 3.0
383      xsi0r  = 1.e0 / rn_si0
384      !
385      ! Variable PAR at the surface of the ocean
386      ! ----------------------------------------
387      IF( ln_varpar ) THEN
388         IF(lwp) WRITE(numout,*)
389         IF(lwp) WRITE(numout,*) '   ==>>>   initialize variable par fraction (ln_varpar=T)'
390         !
391         ALLOCATE( par_varsw(jpi,jpj) )
392         !
393         ALLOCATE( sf_par(1), STAT=ierr )           !* allocate and fill sf_sst (forcing structure) with sn_sst
394         IF( ierr > 0 )   CALL ctl_stop( 'STOP', 'p4z_opt_init: unable to allocate sf_par structure' )
395         !
396         CALL fld_fill( sf_par, (/ sn_par /), cn_dir, 'p4z_opt_init', 'Variable PAR fraction ', 'nampisopt' )
397                                   ALLOCATE( sf_par(1)%fnow(jpi,jpj,1)   )
398         IF( sn_par%ln_tint )      ALLOCATE( sf_par(1)%fdta(jpi,jpj,1,2) )
399
400         CALL iom_open (  TRIM( sn_par%clname ) , numpar )
401         CALL iom_gettime( numpar, zsteps, kntime=ntimes_par)  ! get number of record in file
402      ENDIF
403      !
404      CALL trc_oce_rgb( xkrgb )                  ! tabulated attenuation coefficients
405      nksrp = trc_oce_ext_lev( r_si2, 0.33e2 )     ! max level of light extinction (Blue Chl=0.01)
406      !
407      IF(lwp) WRITE(numout,*) '        level of light extinction = ', nksrp, ' ref depth = ', gdepw_1d(nksrp+1), ' m'
408      !
409                         ekr      (:,:,:) = 0._wp
410                         ekb      (:,:,:) = 0._wp
411                         ekg      (:,:,:) = 0._wp
412                         etot     (:,:,:) = 0._wp
413                         etot_ndcy(:,:,:) = 0._wp
414                         enano    (:,:,:) = 0._wp
415                         ediat    (:,:,:) = 0._wp
416      IF( ln_p5z     )   epico    (:,:,:) = 0._wp
417      IF( ln_qsr_bio )   etot3    (:,:,:) = 0._wp
418      !
419   END SUBROUTINE p4z_opt_init
420
421
422   INTEGER FUNCTION p4z_opt_alloc()
423      !!----------------------------------------------------------------------
424      !!                     ***  ROUTINE p4z_opt_alloc  ***
425      !!----------------------------------------------------------------------
426      !
427      ALLOCATE( ekb(jpi,jpj,jpk), ekr(jpi,jpj,jpk),  &
428                ekg(jpi,jpj,jpk), STAT= p4z_opt_alloc  ) 
429      !
430      IF( p4z_opt_alloc /= 0 ) CALL ctl_warn('p4z_opt_alloc : failed to allocate arrays.')
431      !
432   END FUNCTION p4z_opt_alloc
433
434   !!======================================================================
435END MODULE p4zopt
Note: See TracBrowser for help on using the repository browser.