source: NEMO/trunk/src/TOP/trcstp.F90 @ 12136

Last change on this file since 12136 was 12136, checked in by cetlod, 7 months ago

TOP updates

  • Property svn:keywords set to Id
File size: 12.1 KB
Line 
1MODULE trcstp
2   !!======================================================================
3   !!                       ***  MODULE trcstp  ***
4   !! Time-stepping    : time loop of opa for passive tracer
5   !!======================================================================
6   !! History :  1.0  !  2004-03  (C. Ethe)  Original
7   !!----------------------------------------------------------------------
8#if defined key_top
9   !!----------------------------------------------------------------------
10   !!   trc_stp       : passive tracer system time-stepping
11   !!----------------------------------------------------------------------
12   USE oce_trc        ! ocean dynamics and active tracers variables
13   USE sbc_oce
14   USE trc
15   USE trctrp         ! passive tracers transport
16   USE trcsms         ! passive tracers sources and sinks
17   USE trcwri
18   USE trcrst
19   USE trcsub         !
20   USE trdtrc_oce
21   USE trdmxl_trc
22   USE sms_pisces,  ONLY : ln_check_mass
23   !
24   USE prtctl_trc     ! Print control for debbuging
25   USE iom            !
26   USE in_out_manager !
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC   trc_stp    ! called by step
32
33   LOGICAL  ::   llnew                   ! ???
34   REAL(wp) ::   rdt_sampl               ! ???
35   INTEGER  ::   nb_rec_per_day, ktdcy   ! ???
36   REAL(wp) ::   rsecfst, rseclast       ! ???
37   REAL(wp), DIMENSION(:,:,:), SAVE, ALLOCATABLE ::   qsr_arr   ! save qsr during TOP time-step
38
39   !!----------------------------------------------------------------------
40   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
41   !! $Id$
42   !! Software governed by the CeCILL license (see ./LICENSE)
43   !!----------------------------------------------------------------------
44CONTAINS
45
46   SUBROUTINE trc_stp( kt )
47      !!-------------------------------------------------------------------
48      !!                     ***  ROUTINE trc_stp  ***
49      !!                     
50      !! ** Purpose :   Time loop of opa for passive tracer
51      !!
52      !! ** Method  :   Compute the passive tracers trends
53      !!                Update the passive tracers
54      !!-------------------------------------------------------------------
55      INTEGER, INTENT( in ) ::   kt   ! ocean time-step index
56      !
57      INTEGER ::   jk, jn   ! dummy loop indices
58      REAL(wp)::   ztrai    ! local scalar
59      LOGICAL ::   ll_trcstat ! local logical
60      CHARACTER (len=25) ::   charout   !
61      !!-------------------------------------------------------------------
62      !
63      IF( ln_timing )   CALL timing_start('trc_stp')
64      !
65      IF( ( neuler == 0 .AND. kt == nittrc000 ) .OR. ln_top_euler ) THEN     ! at nittrc000
66         r2dttrc =  rdttrc           ! = rdttrc (use or restarting with Euler time stepping)
67      ELSEIF( kt <= nittrc000 + nn_dttrc ) THEN          ! at nittrc000 or nittrc000+1
68         r2dttrc = 2. * rdttrc       ! = 2 rdttrc (leapfrog)
69      ENDIF
70      !
71      ll_trcstat  = ( ln_ctl .OR. sn_cfctl%l_trcstat ) .AND. &
72     &              ( ( MOD( kt, sn_cfctl%ptimincr ) == 0 ) .OR. ( kt == nitend ) )
73
74      IF( kt == nittrc000 )                      CALL trc_stp_ctl   ! control
75      IF( kt == nittrc000 .AND. lk_trdmxl_trc )  CALL trd_mxl_trc_init    ! trends: Mixed-layer
76      !
77      IF( .NOT.ln_linssh ) THEN                                           ! update ocean volume due to ssh temporal evolution
78         DO jk = 1, jpk
79            cvol(:,:,jk) = e1e2t(:,:) * e3t_n(:,:,jk) * tmask(:,:,jk)
80         END DO
81         IF ( ln_ctl .OR. kt == nitrst .OR. ( ln_check_mass .AND. kt == nitend )              &
82            & .OR. iom_use( "pno3tot" ) .OR. iom_use( "ppo4tot" ) .OR. iom_use( "psiltot" )   &
83            & .OR. iom_use( "palktot" ) .OR. iom_use( "pfertot" ) )                           &
84            &     areatot = glob_sum( 'trcstp', cvol(:,:,:) )
85      ENDIF
86      !
87      IF( l_trcdm2dc )   CALL trc_mean_qsr( kt )
88      !   
89      IF( nn_dttrc /= 1 )   CALL trc_sub_stp( kt )  ! averaging physical variables for sub-stepping
90      !   
91      IF( MOD( kt , nn_dttrc ) == 0 ) THEN      ! only every nn_dttrc time step
92         !
93         IF(ln_ctl) THEN
94            WRITE(charout,FMT="('kt =', I4,'  d/m/y =',I2,I2,I4)") kt, nday, nmonth, nyear
95            CALL prt_ctl_trc_info(charout)
96         ENDIF
97         !
98         tra(:,:,:,:) = 0.e0
99         !
100                                   CALL trc_rst_opn  ( kt )       ! Open tracer restart file
101         IF( lrst_trc )            CALL trc_rst_cal  ( kt, 'WRITE' )   ! calendar
102                                   CALL trc_wri      ( kt )       ! output of passive tracers with iom I/O manager
103                                   CALL trc_sms      ( kt )       ! tracers: sinks and sources
104                                   CALL trc_trp      ( kt )       ! transport of passive tracers
105         IF( kt == nittrc000 ) THEN
106            CALL iom_close( numrtr )       ! close input tracer restart file
107            IF(lwm) CALL FLUSH( numont )   ! flush namelist output
108         ENDIF
109         IF( lrst_trc )            CALL trc_rst_wri  ( kt )       ! write tracer restart file
110         IF( lk_trdmxl_trc  )      CALL trd_mxl_trc  ( kt )       ! trends: Mixed-layer
111         !
112         IF( nn_dttrc /= 1   )     CALL trc_sub_reset( kt )       ! resetting physical variables when sub-stepping
113         !
114      ENDIF
115      !
116      IF (ll_trcstat) THEN
117         ztrai = 0._wp                                                   !  content of all tracers
118         DO jn = 1, jptra
119            ztrai = ztrai + glob_sum( 'trcstp', trn(:,:,:,jn) * cvol(:,:,:)   )
120         END DO
121         IF( lwm ) WRITE(numstr,9300) kt,  ztrai / areatot
122      ENDIF
1239300  FORMAT(i10,D23.16)
124      !
125      IF( ln_timing )   CALL timing_stop('trc_stp')
126      !
127   END SUBROUTINE trc_stp
128
129   SUBROUTINE trc_stp_ctl
130      !!----------------------------------------------------------------------
131      !!                     ***  ROUTINE trc_stp_ctl  ***
132      !! ** Purpose :        Control  + ocean volume
133      !!----------------------------------------------------------------------
134      !
135      ! Define logical parameter ton control dirunal cycle in TOP
136      l_trcdm2dc = ln_dm2dc .OR. ( ln_cpl .AND. ncpl_qsr_freq /= 1 )
137      l_trcdm2dc = l_trcdm2dc  .AND. .NOT. l_offline
138      IF( l_trcdm2dc .AND. lwp )   CALL ctl_warn( 'Coupling with passive tracers and used of diurnal cycle.',   &
139         &                           'Computation of a daily mean shortwave for some biogeochemical models ' )
140      !
141   END SUBROUTINE trc_stp_ctl
142
143
144   SUBROUTINE trc_mean_qsr( kt )
145      !!----------------------------------------------------------------------
146      !!             ***  ROUTINE trc_mean_qsr  ***
147      !!
148      !! ** Purpose :  Compute daily mean qsr for biogeochemical model in case
149      !!               of diurnal cycle
150      !!
151      !! ** Method  : store in TOP the qsr every hour ( or every time-step if the latter
152      !!              is greater than 1 hour ) and then, compute the  mean with
153      !!              a moving average over 24 hours.
154      !!              In coupled mode, the sampling is done at every coupling frequency
155      !!----------------------------------------------------------------------
156      INTEGER, INTENT( in ) ::   kt   ! ocean time-step index
157      !
158      INTEGER  ::   jn   ! dummy loop indices
159      REAL(wp) ::   zkt, zrec     ! local scalars
160      CHARACTER(len=1) ::   cl1   ! 1 character
161      CHARACTER(len=2) ::   cl2   ! 2 characters
162      !!----------------------------------------------------------------------
163      !
164      IF( ln_timing )   CALL timing_start('trc_mean_qsr')
165      !
166      IF( kt == nittrc000 ) THEN
167         IF( ln_cpl )  THEN 
168            rdt_sampl = rday / ncpl_qsr_freq
169            nb_rec_per_day = ncpl_qsr_freq
170         ELSE 
171            rdt_sampl = MAX( 3600., rdttrc )
172            nb_rec_per_day = INT( rday / rdt_sampl )
173         ENDIF
174         !
175         IF(lwp) THEN
176            WRITE(numout,*) 
177            WRITE(numout,*) ' Sampling frequency dt = ', rdt_sampl, 's','   Number of sampling per day  nrec = ', nb_rec_per_day
178            WRITE(numout,*) 
179         ENDIF
180         !
181         ALLOCATE( qsr_arr(jpi,jpj,nb_rec_per_day ) )
182         !
183         !                                            !* Restart: read in restart file
184         IF( ln_rsttr .AND. nn_rsttr /= 0 .AND. iom_varid( numrtr, 'qsr_mean' , ldstop = .FALSE. ) > 0  &
185           &                              .AND. iom_varid( numrtr, 'qsr_arr_1', ldstop = .FALSE. ) > 0  &
186           &                              .AND. iom_varid( numrtr, 'ktdcy'    , ldstop = .FALSE. ) > 0  &
187           &                              .AND. iom_varid( numrtr, 'nrdcy'    , ldstop = .FALSE. ) > 0  ) THEN
188
189            CALL iom_get( numrtr, 'ktdcy', zkt ) 
190            rsecfst = INT( zkt ) * rdttrc
191            IF(lwp) WRITE(numout,*) 'trc_qsr_mean:   qsr_mean read in the restart file at time-step rsecfst =', rsecfst, ' s '
192            CALL iom_get( numrtr, jpdom_autoglo, 'qsr_mean', qsr_mean )   !  A mean of qsr
193            CALL iom_get( numrtr, 'nrdcy', zrec )   !  Number of record per days
194            IF( INT( zrec ) == nb_rec_per_day ) THEN
195               DO jn = 1, nb_rec_per_day 
196                  IF( jn <= 9 )  THEN
197                    WRITE(cl1,'(i1)') jn
198                    CALL iom_get( numrtr, jpdom_autoglo, 'qsr_arr_'//cl1, qsr_arr(:,:,jn) )   !  A mean of qsr
199                  ELSE
200                    WRITE(cl2,'(i2.2)') jn
201                    CALL iom_get( numrtr, jpdom_autoglo, 'qsr_arr_'//cl2, qsr_arr(:,:,jn) )   !  A mean of qsr
202                  ENDIF
203              END DO
204            ELSE
205               DO jn = 1, nb_rec_per_day
206                  qsr_arr(:,:,jn) = qsr_mean(:,:)
207               ENDDO
208            ENDIF
209         ELSE                                         !* no restart: set from nit000 values
210            IF(lwp) WRITE(numout,*) 'trc_qsr_mean:   qsr_mean set to nit000 values'
211            rsecfst  = kt * rdttrc
212            !
213            qsr_mean(:,:) = qsr(:,:)
214            DO jn = 1, nb_rec_per_day
215               qsr_arr(:,:,jn) = qsr_mean(:,:)
216            END DO
217         ENDIF
218         !
219      ENDIF
220      !
221      rseclast = kt * rdttrc
222      !
223      llnew   = ( rseclast - rsecfst ) .ge.  rdt_sampl    !   new shortwave to store
224      IF( llnew ) THEN
225          ktdcy = kt
226          IF( lwp .AND. kt < nittrc000 + 100 ) WRITE(numout,*) ' New shortwave to sample for TOP at time kt = ', ktdcy, &
227             &                      ' time = ', rseclast/3600.,'hours '
228          rsecfst = rseclast
229          DO jn = 1, nb_rec_per_day - 1
230             qsr_arr(:,:,jn) = qsr_arr(:,:,jn+1)
231          ENDDO
232          qsr_arr (:,:,nb_rec_per_day) = qsr(:,:)
233          qsr_mean(:,:                ) = SUM( qsr_arr(:,:,:), 3 ) / nb_rec_per_day
234      ENDIF
235      !
236      IF( lrst_trc ) THEN    !* Write the mean of qsr in restart file
237         IF(lwp) WRITE(numout,*)
238         IF(lwp) WRITE(numout,*) 'trc_mean_qsr : write qsr_mean in restart file  kt =', kt
239         IF(lwp) WRITE(numout,*) '~~~~~~~'
240         zkt  = REAL( ktdcy, wp )
241         zrec = REAL( nb_rec_per_day, wp )
242         CALL iom_rstput( kt, nitrst, numrtw, 'ktdcy', zkt  )
243         CALL iom_rstput( kt, nitrst, numrtw, 'nrdcy', zrec )
244          DO jn = 1, nb_rec_per_day 
245             IF( jn <= 9 )  THEN
246               WRITE(cl1,'(i1)') jn
247               CALL iom_rstput( kt, nitrst, numrtw, 'qsr_arr_'//cl1, qsr_arr(:,:,jn) )
248             ELSE
249               WRITE(cl2,'(i2.2)') jn
250               CALL iom_rstput( kt, nitrst, numrtw, 'qsr_arr_'//cl2, qsr_arr(:,:,jn) )
251             ENDIF
252         END DO
253         CALL iom_rstput( kt, nitrst, numrtw, 'qsr_mean', qsr_mean(:,:) )
254      ENDIF
255      !
256      IF( ln_timing )   CALL timing_stop('trc_mean_qsr')
257      !
258   END SUBROUTINE trc_mean_qsr
259
260#else
261   !!----------------------------------------------------------------------
262   !!   Default key                                     NO passive tracers
263   !!----------------------------------------------------------------------
264CONTAINS
265   SUBROUTINE trc_stp( kt )        ! Empty routine
266      WRITE(*,*) 'trc_stp: You should not have seen this print! error?', kt
267   END SUBROUTINE trc_stp
268#endif
269
270   !!======================================================================
271END MODULE trcstp
Note: See TracBrowser for help on using the repository browser.