1 | MODULE usrdef_zgr |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE usrdef_zgr *** |
---|
4 | !! |
---|
5 | !! === DOME case === |
---|
6 | !! |
---|
7 | !! user defined : vertical coordinate system of a user configuration |
---|
8 | !!====================================================================== |
---|
9 | !! History : 4.0 ! 2020-12 (J. Chanut) Original code |
---|
10 | !!---------------------------------------------------------------------- |
---|
11 | |
---|
12 | !!---------------------------------------------------------------------- |
---|
13 | !! usr_def_zgr : user defined vertical coordinate system (required) |
---|
14 | !! zgr_z1d : reference 1D z-coordinate |
---|
15 | !!--------------------------------------------------------------------- |
---|
16 | USE oce ! ocean variables |
---|
17 | USE dom_oce , ONLY: mi0, mi1 ! ocean space and time domain |
---|
18 | USE dom_oce , ONLY: glamt, gphit ! ocean space and time domain |
---|
19 | USE usrdef_nam ! User defined : namelist variables |
---|
20 | ! |
---|
21 | USE in_out_manager ! I/O manager |
---|
22 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
---|
23 | USE lib_mpp ! distributed memory computing library |
---|
24 | USE timing ! Timing |
---|
25 | |
---|
26 | IMPLICIT NONE |
---|
27 | PRIVATE |
---|
28 | |
---|
29 | PUBLIC usr_def_zgr ! called by domzgr.F90 |
---|
30 | |
---|
31 | !! * Substitutions |
---|
32 | # include "do_loop_substitute.h90" |
---|
33 | !!---------------------------------------------------------------------- |
---|
34 | !! NEMO/OCE 4.0 , NEMO Consortium (2018) |
---|
35 | !! $Id: usrdef_zgr.F90 14053 2020-12-03 13:48:38Z techene $ |
---|
36 | !! Software governed by the CeCILL license (see ./LICENSE) |
---|
37 | !!---------------------------------------------------------------------- |
---|
38 | CONTAINS |
---|
39 | |
---|
40 | SUBROUTINE usr_def_zgr( ld_zco , ld_zps , ld_sco , ld_isfcav, & ! type of vertical coordinate |
---|
41 | & pdept_1d, pdepw_1d, pe3t_1d , pe3w_1d , & ! 1D reference vertical coordinate |
---|
42 | & pdept , pdepw , & ! 3D t & w-points depth |
---|
43 | & pe3t , pe3u , pe3v , pe3f , & ! vertical scale factors |
---|
44 | & pe3w , pe3uw , pe3vw, & ! - - - |
---|
45 | & k_top , k_bot ) ! top & bottom ocean level |
---|
46 | !!--------------------------------------------------------------------- |
---|
47 | !! *** ROUTINE usr_def_zgr *** |
---|
48 | !! |
---|
49 | !! ** Purpose : User defined the vertical coordinates |
---|
50 | !! |
---|
51 | !!---------------------------------------------------------------------- |
---|
52 | LOGICAL , INTENT(in ) :: ld_zco, ld_zps, ld_sco ! vertical coordinate flags ( read in namusr_def ) |
---|
53 | LOGICAL , INTENT( out) :: ld_isfcav ! under iceshelf cavity flag |
---|
54 | REAL(wp), DIMENSION(:) , INTENT( out) :: pdept_1d, pdepw_1d ! 1D grid-point depth [m] |
---|
55 | REAL(wp), DIMENSION(:) , INTENT( out) :: pe3t_1d , pe3w_1d ! 1D grid-point depth [m] |
---|
56 | REAL(wp), DIMENSION(:,:,:), INTENT( out) :: pdept, pdepw ! grid-point depth [m] |
---|
57 | REAL(wp), DIMENSION(:,:,:), INTENT( out) :: pe3t , pe3u , pe3v , pe3f ! vertical scale factors [m] |
---|
58 | REAL(wp), DIMENSION(:,:,:), INTENT( out) :: pe3w , pe3uw, pe3vw ! i-scale factors |
---|
59 | INTEGER , DIMENSION(:,:) , INTENT( out) :: k_top, k_bot ! first & last ocean level |
---|
60 | ! |
---|
61 | INTEGER :: ji, jj, jk ! dummy indices |
---|
62 | INTEGER :: ik ! local integers |
---|
63 | REAL(wp) :: zfact, z1_jpkm1 ! local scalar |
---|
64 | REAL(wp) :: ze3min ! local scalar |
---|
65 | REAL(wp), DIMENSION(jpi,jpj) :: zht, zhu, zhv, zhf, z2d ! 2D workspace |
---|
66 | !!---------------------------------------------------------------------- |
---|
67 | ! |
---|
68 | IF(lwp) WRITE(numout,*) |
---|
69 | IF(lwp) WRITE(numout,*) 'usr_def_zgr : DOME configuration (z(ps)- or s-coordinate closed box ocean without cavities)' |
---|
70 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~~' |
---|
71 | ! |
---|
72 | ! |
---|
73 | ! type of vertical coordinate |
---|
74 | ! --------------------------- |
---|
75 | ! already set in usrdef_nam.F90 by reading the namusr_def namelist except for ISF |
---|
76 | ld_isfcav = .FALSE. |
---|
77 | ! |
---|
78 | ! |
---|
79 | ! Build the vertical coordinate system |
---|
80 | ! ------------------------------------ |
---|
81 | ! |
---|
82 | ! !== UNmasked meter bathymetry ==! |
---|
83 | ! |
---|
84 | zht(:,:) = MIN(3600._wp, MAX( 600._wp, 600._wp - gphit(:,:)*1.e3*0.01 )) |
---|
85 | ! |
---|
86 | ! at u/v/f-point: averaging zht |
---|
87 | zhu(:,:) = 600_wp ; zhv(:,:) = 600_wp ; zhf(:,:) = 600_wp |
---|
88 | DO_2D( 0, 0, 0, 0 ) |
---|
89 | zhu(ji,jj) = 0.5_wp * ( zht(ji,jj ) + zht(ji+1,jj ) ) |
---|
90 | zhv(jj,jj) = 0.5_wp * ( zht(ji,jj ) + zht(ji ,jj+1) ) |
---|
91 | zhf(ji,jj) = 0.25_wp * ( zht(ji,jj ) + zht(ji+1,jj ) & |
---|
92 | & + zht(ji,jj+1) + zht(ji+1,jj+1) ) |
---|
93 | END_2D |
---|
94 | CALL lbc_lnk( 'usrdef_zgr', zhu, 'U', 1.0_wp, zhv, 'V', 1.0_wp, zhf, 'F', 1.0_wp) |
---|
95 | ! |
---|
96 | CALL zgr_z1d( pdept_1d, pdepw_1d, pe3t_1d , pe3w_1d ) ! Reference z-coordinate system |
---|
97 | ! |
---|
98 | ! |
---|
99 | ! !== top masked level bathymetry ==! (all coordinates) |
---|
100 | ! |
---|
101 | ! no ocean cavities : top ocean level is ONE, except over land |
---|
102 | ! the ocean basin surrounded by land (1+nn_hls grid-point) set through lbc_lnk call |
---|
103 | z2d(:,:) = 1._wp ! surface ocean is the 1st level |
---|
104 | WHERE (gphit(:,:)>0._wp) z2d(:,:) = 0._wp |
---|
105 | ! Dig inlet: |
---|
106 | WHERE ((gphit(:,:)>0._wp).AND.(glamt(:,:)>-50._wp).AND.(glamt(:,:)<50._wp)) z2d(:,:) = 1._wp |
---|
107 | CALL lbc_lnk( 'usrdef_zgr', z2d, 'T', 1. ) ! closed basin, see userdef_nam.F90 |
---|
108 | k_top(:,:) = NINT( z2d(:,:) ) |
---|
109 | ! |
---|
110 | ! |
---|
111 | ! |
---|
112 | IF ( ld_sco ) THEN !== s-coordinate ==! (terrain-following coordinate) |
---|
113 | ! |
---|
114 | k_bot(:,:) = jpkm1 * k_top(:,:) !* bottom ocean = jpk-1 (here use k_top as a land mask) |
---|
115 | ! |
---|
116 | ! !* terrain-following coordinate with e3.(k)=cst) |
---|
117 | z1_jpkm1 = 1._wp / REAL( jpkm1 , wp) |
---|
118 | DO jk = 1, jpk |
---|
119 | pdept(:,:,jk) = zht(:,:) * z1_jpkm1 * ( REAL( jk , wp ) - 0.5_wp ) |
---|
120 | pdepw(:,:,jk) = zht(:,:) * z1_jpkm1 * ( REAL( jk-1 , wp ) ) |
---|
121 | pe3t (:,:,jk) = zht(:,:) * z1_jpkm1 |
---|
122 | pe3u (:,:,jk) = zhu(:,:) * z1_jpkm1 |
---|
123 | pe3v (:,:,jk) = zhv(:,:) * z1_jpkm1 |
---|
124 | pe3f (:,:,jk) = zhf(:,:) * z1_jpkm1 |
---|
125 | pe3w (:,:,jk) = zht(:,:) * z1_jpkm1 |
---|
126 | pe3uw(:,:,jk) = zhu(:,:) * z1_jpkm1 |
---|
127 | pe3vw(:,:,jk) = zhv(:,:) * z1_jpkm1 |
---|
128 | END DO |
---|
129 | ENDIF |
---|
130 | ! |
---|
131 | ! |
---|
132 | IF ( ld_zco ) THEN !== z-coordinate ==! (step-like topography) |
---|
133 | ! |
---|
134 | ! !* bottom ocean compute from the depth of grid-points |
---|
135 | k_bot(:,:) = jpkm1 * k_top(:,:) ! here use k_top as a land mask |
---|
136 | DO jk = 1, jpkm1 |
---|
137 | WHERE( pdept_1d(jk) < zht(:,:) .AND. zht(:,:) <= pdept_1d(jk+1) ) k_bot(:,:) = jk * k_top(:,:) |
---|
138 | END DO |
---|
139 | ! !* horizontally uniform coordinate (reference z-co everywhere) |
---|
140 | DO jk = 1, jpk |
---|
141 | pdept(:,:,jk) = pdept_1d(jk) |
---|
142 | pdepw(:,:,jk) = pdepw_1d(jk) |
---|
143 | pe3t (:,:,jk) = pe3t_1d (jk) |
---|
144 | pe3u (:,:,jk) = pe3t_1d (jk) |
---|
145 | pe3v (:,:,jk) = pe3t_1d (jk) |
---|
146 | pe3f (:,:,jk) = pe3t_1d (jk) |
---|
147 | pe3w (:,:,jk) = pe3w_1d (jk) |
---|
148 | pe3uw(:,:,jk) = pe3w_1d (jk) |
---|
149 | pe3vw(:,:,jk) = pe3w_1d (jk) |
---|
150 | END DO |
---|
151 | ENDIF |
---|
152 | ! |
---|
153 | ! |
---|
154 | IF ( ld_zps ) THEN !== zps-coordinate ==! (partial bottom-steps) |
---|
155 | ! |
---|
156 | ze3min = 0.1_wp * rn_dz |
---|
157 | IF(lwp) WRITE(numout,*) ' minimum thickness of the partial cells = 10 % of e3 = ', ze3min |
---|
158 | ! |
---|
159 | ! |
---|
160 | ! !* bottom ocean compute from the depth of grid-points |
---|
161 | k_bot(:,:) = jpkm1 |
---|
162 | DO jk = jpkm1, 1, -1 |
---|
163 | WHERE( zht(:,:) < pdepw_1d(jk) + ze3min ) k_bot(:,:) = jk-1 |
---|
164 | END DO |
---|
165 | ! |
---|
166 | ! !* vertical coordinate system |
---|
167 | DO jk = 1, jpk ! initialization to the reference z-coordinate |
---|
168 | pdept(:,:,jk) = pdept_1d(jk) |
---|
169 | pdepw(:,:,jk) = pdepw_1d(jk) |
---|
170 | pe3t (:,:,jk) = pe3t_1d (jk) |
---|
171 | pe3u (:,:,jk) = pe3t_1d (jk) |
---|
172 | pe3v (:,:,jk) = pe3t_1d (jk) |
---|
173 | pe3f (:,:,jk) = pe3t_1d (jk) |
---|
174 | pe3w (:,:,jk) = pe3w_1d (jk) |
---|
175 | pe3uw(:,:,jk) = pe3w_1d (jk) |
---|
176 | pe3vw(:,:,jk) = pe3w_1d (jk) |
---|
177 | END DO |
---|
178 | DO_2D( 1, 1, 1, 1 ) |
---|
179 | ik = k_bot(ji,jj) |
---|
180 | pdepw(ji,jj,ik+1) = MIN( zht(ji,jj) , pdepw_1d(ik+1) ) |
---|
181 | pe3t (ji,jj,ik ) = pdepw(ji,jj,ik+1) - pdepw(ji,jj,ik) |
---|
182 | pe3t (ji,jj,ik+1) = pe3t (ji,jj,ik ) |
---|
183 | ! |
---|
184 | pdept(ji,jj,ik ) = pdepw(ji,jj,ik ) + pe3t (ji,jj,ik ) * 0.5_wp |
---|
185 | pdept(ji,jj,ik+1) = pdepw(ji,jj,ik+1) + pe3t (ji,jj,ik+1) * 0.5_wp |
---|
186 | pe3w (ji,jj,ik+1) = pdept(ji,jj,ik+1) - pdept(ji,jj,ik) ! = pe3t (ji,jj,ik ) |
---|
187 | pe3w (ji,jj,ik ) = pdept(ji,jj,ik ) - pdept(ji,jj,ik-1) ! st caution ik > 1 |
---|
188 | END_2D |
---|
189 | ! |
---|
190 | DO_3D( 0, 0, 0, 0, 1, jpk ) |
---|
191 | pe3u (ji,jj,jk) = MIN( pe3t(ji,jj,jk), pe3t(ji+1,jj,jk) ) |
---|
192 | pe3v (ji,jj,jk) = MIN( pe3t(ji,jj,jk), pe3t(ji,jj+1,jk) ) |
---|
193 | pe3uw(ji,jj,jk) = MIN( pe3w(ji,jj,jk), pe3w(ji+1,jj,jk) ) |
---|
194 | pe3vw(ji,jj,jk) = MIN( pe3w(ji,jj,jk), pe3w(ji,jj+1,jk) ) |
---|
195 | END_3D |
---|
196 | ! |
---|
197 | CALL lbc_lnk('usrdef_zgr', pe3u , 'U', 1._wp, pe3uw, 'U', 1._wp ) |
---|
198 | CALL lbc_lnk('usrdef_zgr', pe3v , 'V', 1._wp, pe3vw, 'V', 1._wp ) |
---|
199 | ! |
---|
200 | DO jk = 1, jpk |
---|
201 | WHERE( pe3u (:,:,jk) == 0._wp ) pe3u (:,:,jk) = pe3t_1d(jk) |
---|
202 | WHERE( pe3v (:,:,jk) == 0._wp ) pe3v (:,:,jk) = pe3t_1d(jk) |
---|
203 | WHERE( pe3uw(:,:,jk) == 0._wp ) pe3uw(:,:,jk) = pe3w_1d(jk) |
---|
204 | WHERE( pe3vw(:,:,jk) == 0._wp ) pe3vw(:,:,jk) = pe3w_1d(jk) |
---|
205 | END DO |
---|
206 | |
---|
207 | DO_3D( 0, 0, 0, 0, 1, jpk ) |
---|
208 | pe3f(ji,jj,jk) = MIN( pe3v(ji,jj,jk), pe3v(ji+1,jj,jk) ) |
---|
209 | END_3D |
---|
210 | CALL lbc_lnk('usrdef_zgr', pe3f, 'F', 1._wp ) |
---|
211 | ! |
---|
212 | ENDIF |
---|
213 | ! |
---|
214 | END SUBROUTINE usr_def_zgr |
---|
215 | |
---|
216 | |
---|
217 | SUBROUTINE zgr_z1d( pdept_1d, pdepw_1d, pe3t_1d , pe3w_1d ) ! 1D reference vertical coordinate |
---|
218 | !!---------------------------------------------------------------------- |
---|
219 | !! *** ROUTINE zgr_z1d *** |
---|
220 | !! |
---|
221 | !! ** Purpose : set the depth of model levels and the resulting |
---|
222 | !! vertical scale factors. |
---|
223 | !! |
---|
224 | !! ** Method : 1D z-coordinate system (use in all type of coordinate) |
---|
225 | !! The depth of model levels is set from dep(k), an analytical function: |
---|
226 | !! w-level: depw_1d = dep(k) |
---|
227 | !! t-level: dept_1d = dep(k+0.5) |
---|
228 | !! The scale factors are the discrete derivative of the depth: |
---|
229 | !! e3w_1d(jk) = dk[ dept_1d ] |
---|
230 | !! e3t_1d(jk) = dk[ depw_1d ] |
---|
231 | !! |
---|
232 | !! === Here constant vertical resolution === |
---|
233 | !! |
---|
234 | !! ** Action : - pdept_1d, pdepw_1d : depth of T- and W-point (m) |
---|
235 | !! - pe3t_1d , pe3w_1d : scale factors at T- and W-levels (m) |
---|
236 | !!---------------------------------------------------------------------- |
---|
237 | REAL(wp), DIMENSION(:), INTENT(out) :: pdept_1d, pdepw_1d ! 1D grid-point depth [m] |
---|
238 | REAL(wp), DIMENSION(:), INTENT(out) :: pe3t_1d , pe3w_1d ! 1D vertical scale factors [m] |
---|
239 | ! |
---|
240 | INTEGER :: jk ! dummy loop indices |
---|
241 | REAL(wp) :: zt, zw ! local scalar |
---|
242 | !!---------------------------------------------------------------------- |
---|
243 | ! |
---|
244 | IF(lwp) THEN ! Parameter print |
---|
245 | WRITE(numout,*) |
---|
246 | WRITE(numout,*) ' zgr_z1d : Reference vertical z-coordinates: uniform dz = ', rn_dz |
---|
247 | WRITE(numout,*) ' ~~~~~~~' |
---|
248 | ENDIF |
---|
249 | ! |
---|
250 | ! Reference z-coordinate (depth - scale factor at T- and W-points) ! Madec & Imbard 1996 function |
---|
251 | ! ---------------------- |
---|
252 | DO jk = 1, jpk |
---|
253 | zw = REAL( jk , wp ) |
---|
254 | zt = REAL( jk , wp ) + 0.5_wp |
---|
255 | pdepw_1d(jk) = rn_dz * REAL( jk-1 , wp ) |
---|
256 | pdept_1d(jk) = rn_dz * ( REAL( jk-1 , wp ) + 0.5_wp ) |
---|
257 | pe3w_1d (jk) = rn_dz |
---|
258 | pe3t_1d (jk) = rn_dz |
---|
259 | END DO |
---|
260 | ! |
---|
261 | IF(lwp) THEN ! control print |
---|
262 | WRITE(numout,*) |
---|
263 | WRITE(numout,*) ' Reference 1D z-coordinate depth and scale factors:' |
---|
264 | WRITE(numout, "(9x,' level gdept_1d gdepw_1d e3t_1d e3w_1d ')" ) |
---|
265 | WRITE(numout, "(10x, i4, 4f9.2)" ) ( jk, pdept_1d(jk), pdepw_1d(jk), pe3t_1d(jk), pe3w_1d(jk), jk = 1, jpk ) |
---|
266 | ENDIF |
---|
267 | ! |
---|
268 | END SUBROUTINE zgr_z1d |
---|
269 | |
---|
270 | !!====================================================================== |
---|
271 | END MODULE usrdef_zgr |
---|