New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
tradmp.F90 in NEMO/trunk/tests/ISOMIP+/MY_SRC – NEMO

source: NEMO/trunk/tests/ISOMIP+/MY_SRC/tradmp.F90

Last change on this file was 15529, checked in by techene, 2 years ago

#2695 : isf+qco are now compatible
File size: 11.6 KB
Line 
1MODULE tradmp
2   !!======================================================================
3   !!                       ***  MODULE  tradmp  ***
4   !! Ocean physics: internal restoring trend on active tracers (T and S)
5   !!======================================================================
6   !! History :  OPA  ! 1991-03  (O. Marti, G. Madec)  Original code
7   !!                 ! 1992-06  (M. Imbard)  doctor norme
8   !!                 ! 1998-07  (M. Imbard, G. Madec) ORCA version
9   !!            7.0  ! 2001-02  (M. Imbard)  add distance to coast, Original code
10   !!            8.1  ! 2001-02  (G. Madec, E. Durand)  cleaning
11   !!  NEMO      1.0  ! 2002-08  (G. Madec, E. Durand)  free form + modules
12   !!            3.2  ! 2009-08  (G. Madec, C. Talandier)  DOCTOR norm for namelist parameter
13   !!            3.3  ! 2010-06  (C. Ethe, G. Madec) merge TRA-TRC
14   !!            3.4  ! 2011-04  (G. Madec, C. Ethe) Merge of dtatem and dtasal + suppression of CPP keys
15   !!            3.6  ! 2015-06  (T. Graham)  read restoring coefficient in a file
16   !!            3.7  ! 2015-10  (G. Madec)  remove useless trends arrays
17   !!----------------------------------------------------------------------
18
19   !!----------------------------------------------------------------------
20   !!   tra_dmp_alloc : allocate tradmp arrays
21   !!   tra_dmp       : update the tracer trend with the internal damping
22   !!   tra_dmp_init  : initialization, namlist read, parameters control
23   !!----------------------------------------------------------------------
24   USE oce            ! ocean: variables
25   USE dom_oce        ! ocean: domain variables
26   USE c1d            ! 1D vertical configuration
27   USE trd_oce        ! trends: ocean variables
28   USE trdtra         ! trends manager: tracers
29   USE zdf_oce        ! ocean: vertical physics
30   USE phycst         ! physical constants
31   USE dtatsd         ! data: temperature & salinity
32   USE zdfmxl         ! vertical physics: mixed layer depth
33   !
34   USE in_out_manager ! I/O manager
35   USE iom            ! XIOS
36   USE lib_mpp        ! MPP library
37   USE prtctl         ! Print control
38   USE timing         ! Timing
39
40   IMPLICIT NONE
41   PRIVATE
42
43   PUBLIC   tra_dmp        ! called by step.F90
44   PUBLIC   tra_dmp_init   ! called by nemogcm.F90
45
46   !                                           !!* Namelist namtra_dmp : T & S newtonian damping *
47   LOGICAL            , PUBLIC ::   ln_tradmp   !: internal damping flag
48   INTEGER            , PUBLIC ::   nn_zdmp     !: = 0/1/2 flag for damping in the mixed layer
49   CHARACTER(LEN=200) , PUBLIC ::   cn_resto    !: name of netcdf file containing restoration coefficient field
50   !
51   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   resto    !: restoring coeff. on T and S (s-1)
52
53   !! * Substitutions
54#  include "do_loop_substitute.h90"
55#  include "domzgr_substitute.h90"
56   !!----------------------------------------------------------------------
57   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
58   !! $Id: tradmp.F90 10425 2018-12-19 21:54:16Z smasson $
59   !! Software governed by the CeCILL license (see ./LICENSE)
60   !!----------------------------------------------------------------------
61CONTAINS
62
63   INTEGER FUNCTION tra_dmp_alloc()
64      !!----------------------------------------------------------------------
65      !!                ***  FUNCTION tra_dmp_alloc  ***
66      !!----------------------------------------------------------------------
67      ALLOCATE( resto(jpi,jpj,jpk), STAT= tra_dmp_alloc )
68      !
69      CALL mpp_sum ( 'tradmp', tra_dmp_alloc )
70      IF( tra_dmp_alloc > 0 )   CALL ctl_warn('tra_dmp_alloc: allocation of arrays failed')
71      !
72   END FUNCTION tra_dmp_alloc
73
74
75   SUBROUTINE tra_dmp( kt, Kbb, Kmm, pts, Krhs )
76      !!----------------------------------------------------------------------
77      !!                   ***  ROUTINE tra_dmp  ***
78      !!
79      !! ** Purpose :   Compute the tracer trend due to a newtonian damping
80      !!      of the tracer field towards given data field and add it to the
81      !!      general tracer trends.
82      !!
83      !! ** Method  :   Newtonian damping towards t_dta and s_dta computed
84      !!      and add to the general tracer trends:
85      !!                     ta = ta + resto * (t_dta - tb)
86      !!                     sa = sa + resto * (s_dta - sb)
87      !!         The trend is computed either throughout the water column
88      !!      (nlmdmp=0) or in area of weak vertical mixing (nlmdmp=1) or
89      !!      below the well mixed layer (nlmdmp=2)
90      !!
91      !! ** Action  : - tsa: tracer trends updated with the damping trend
92      !!----------------------------------------------------------------------
93      INTEGER,                                   INTENT(in   ) :: kt              ! ocean time-step index
94      INTEGER,                                   INTENT(in   ) :: Kbb, Kmm, Krhs  ! time level indices
95      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts,jpt), INTENT(inout) :: pts             ! active tracers and RHS of tracer equation
96      !
97      INTEGER ::   ji, jj, jk, jn   ! dummy loop indices
98      REAL(wp), DIMENSION(A2D(nn_hls),jpk,jpts)     ::  zts_dta
99      REAL(wp), DIMENSION(jpi,jpj,jpk)              ::  ze3t
100      REAL(wp), DIMENSION(:,:,:,:), ALLOCATABLE ::  ztrdts
101      !!----------------------------------------------------------------------
102      !
103      IF( ln_timing )   CALL timing_start('tra_dmp')
104      !
105      IF( l_trdtra .OR. iom_use('hflx_dmp_cea') .OR. iom_use('sflx_dmp_cea') ) THEN   !* Save ta and sa trends
106         ALLOCATE( ztrdts(jpi,jpj,jpk,jpts) )
107         ztrdts(:,:,:,:) = pts(:,:,:,:,Krhs)
108      ENDIF
109      !                           !==  input T-S data at kt  ==!
110      CALL dta_tsd( kt, 'dmp', zts_dta )            ! read and interpolates T-S data at kt
111      !
112      SELECT CASE ( nn_zdmp )     !==  type of damping  ==!
113      !
114      CASE( 0 )                        !*  newtonian damping throughout the water column  *!
115         DO jn = 1, jpts
116            DO_3D( 0, 0, 0, 0, 1, jpkm1 )
117               pts(ji,jj,jk,jn,Krhs) = pts(ji,jj,jk,jn,Krhs)           &
118                  &                  + resto(ji,jj,jk) * ( zts_dta(ji,jj,jk,jn) - pts(ji,jj,jk,jn,Kbb) )
119            END_3D
120         END DO
121         !
122      CASE ( 1 )                       !*  no damping in the turbocline (avt > 5 cm2/s)  *!
123         DO_3D( 0, 0, 0, 0, 1, jpkm1 )
124            IF( avt(ji,jj,jk) <= avt_c ) THEN
125               pts(ji,jj,jk,jp_tem,Krhs) = pts(ji,jj,jk,jp_tem,Krhs)   &
126                  &                      + resto(ji,jj,jk) * ( zts_dta(ji,jj,jk,jp_tem) - pts(ji,jj,jk,jp_tem,Kbb) )
127               pts(ji,jj,jk,jp_sal,Krhs) = pts(ji,jj,jk,jp_sal,Krhs)   &
128                  &                      + resto(ji,jj,jk) * ( zts_dta(ji,jj,jk,jp_sal) - pts(ji,jj,jk,jp_sal,Kbb) )
129            ENDIF
130         END_3D
131         !
132      CASE ( 2 )                       !*  no damping in the mixed layer   *!
133         DO_3D( 0, 0, 0, 0, 1, jpkm1 )
134            IF( gdept(ji,jj,jk,Kmm) >= hmlp (ji,jj) ) THEN
135               pts(ji,jj,jk,jp_tem,Krhs) = pts(ji,jj,jk,jp_tem,Krhs)   &
136                  &                      + resto(ji,jj,jk) * ( zts_dta(ji,jj,jk,jp_tem) - pts(ji,jj,jk,jp_tem,Kbb) )
137               pts(ji,jj,jk,jp_sal,Krhs) = pts(ji,jj,jk,jp_sal,Krhs)   &
138                  &                      + resto(ji,jj,jk) * ( zts_dta(ji,jj,jk,jp_sal) - pts(ji,jj,jk,jp_sal,Kbb) )
139            ENDIF
140         END_3D
141         !
142      END SELECT
143      !
144      ! outputs (clem trunk)
145      DO jk = 1, jpk
146         ze3t(:,:,jk) = e3t(:,:,jk,Kmm)
147      END DO     
148      !
149      IF( iom_use('hflx_dmp_cea') )       &
150         &   CALL iom_put('hflx_dmp_cea', &
151         &   SUM( ( pts(:,:,:,jp_tem,Krhs) - ztrdts(:,:,:,jp_tem) ) * ze3t(:,:,:), dim=3 ) * rcp * rho0 ) ! W/m2
152      IF( iom_use('sflx_dmp_cea') )       &
153         &   CALL iom_put('sflx_dmp_cea', &
154         &   SUM( ( pts(:,:,:,jp_sal,Krhs) - ztrdts(:,:,:,jp_sal) ) * ze3t(:,:,:), dim=3 ) * rho0 )       ! g/m2/s
155      !
156      IF( l_trdtra )   THEN       ! trend diagnostic
157         ztrdts(:,:,:,:) = pts(:,:,:,:,Krhs) - ztrdts(:,:,:,:)
158         CALL trd_tra( kt, Kmm, Krhs, 'TRA', jp_tem, jptra_dmp, ztrdts(:,:,:,jp_tem) )
159         CALL trd_tra( kt, Kmm, Krhs, 'TRA', jp_sal, jptra_dmp, ztrdts(:,:,:,jp_sal) )
160         DEALLOCATE( ztrdts )
161      ENDIF
162      !                           ! Control print
163      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab3d_1=pts(:,:,:,jp_tem,Krhs), clinfo1=' dmp  - Ta: ', mask1=tmask,   &
164         &                                  tab3d_2=pts(:,:,:,jp_sal,Krhs), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
165      !
166      IF( ln_timing )   CALL timing_stop('tra_dmp')
167      !
168   END SUBROUTINE tra_dmp
169
170
171   SUBROUTINE tra_dmp_init
172      !!----------------------------------------------------------------------
173      !!                  ***  ROUTINE tra_dmp_init  ***
174      !!
175      !! ** Purpose :   Initialization for the newtonian damping
176      !!
177      !! ** Method  :   read the namtra_dmp namelist and check the parameters
178      !!----------------------------------------------------------------------
179      INTEGER ::   ios, imask   ! local integers
180      !
181      NAMELIST/namtra_dmp/ ln_tradmp, nn_zdmp, cn_resto
182      !!----------------------------------------------------------------------
183      !
184      READ  ( numnam_ref, namtra_dmp, IOSTAT = ios, ERR = 901)
185901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namtra_dmp in reference namelist' )
186      !
187      READ  ( numnam_cfg, namtra_dmp, IOSTAT = ios, ERR = 902 )
188902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namtra_dmp in configuration namelist' )
189      IF(lwm) WRITE ( numond, namtra_dmp )
190      !
191      IF(lwp) THEN                  ! Namelist print
192         WRITE(numout,*)
193         WRITE(numout,*) 'tra_dmp_init : T and S newtonian relaxation'
194         WRITE(numout,*) '~~~~~~~~~~~~'
195         WRITE(numout,*) '   Namelist namtra_dmp : set relaxation parameters'
196         WRITE(numout,*) '      Apply relaxation   or not       ln_tradmp   = ', ln_tradmp
197         WRITE(numout,*) '         mixed layer damping option      nn_zdmp  = ', nn_zdmp
198         WRITE(numout,*) '         Damping file name               cn_resto = ', cn_resto
199         WRITE(numout,*)
200      ENDIF
201      !
202      IF( ln_tradmp ) THEN
203         !                          ! Allocate arrays
204         IF( tra_dmp_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'tra_dmp_init: unable to allocate arrays' )
205         !
206         SELECT CASE (nn_zdmp)      ! Check values of nn_zdmp
207         CASE ( 0 )   ;   IF(lwp) WRITE(numout,*) '   tracer damping as specified by mask'
208         CASE ( 1 )   ;   IF(lwp) WRITE(numout,*) '   no tracer damping in the mixing layer (kz > 5 cm2/s)'
209         CASE ( 2 )   ;   IF(lwp) WRITE(numout,*) '   no tracer damping in the mixed  layer'
210         CASE DEFAULT
211            CALL ctl_stop('tra_dmp_init : wrong value of nn_zdmp')
212         END SELECT
213         !
214         !!TG: Initialisation of dtatsd - Would it be better to have dmpdta routine
215         !    so can damp to something other than intitial conditions files?
216         !!gm: In principle yes. Nevertheless, we can't anticipate demands that have never been formulated.
217         IF( .NOT.ln_tsd_dmp ) THEN
218            IF(lwp) WRITE(numout,*)
219            IF(lwp) WRITE(numout, *)  '   read T-S data not initialized, we force ln_tsd_dmp=T'
220            CALL dta_tsd_init( ld_tradmp=ln_tradmp )        ! forces the initialisation of T-S data
221         ENDIF
222         !                          ! Read in mask from file
223         CALL iom_open ( cn_resto, imask)
224         CALL iom_get  ( imask, jpdom_auto, 'resto', resto )
225         CALL iom_close( imask )
226      ENDIF
227      !
228   END SUBROUTINE tra_dmp_init
229
230   !!======================================================================
231END MODULE tradmp
Note: See TracBrowser for help on using the repository browser.