1 | MODULE zdftmx |
---|
2 | !!======================================================================== |
---|
3 | !! *** MODULE zdftmx *** |
---|
4 | !! Ocean physics: vertical tidal mixing coefficient |
---|
5 | !!======================================================================== |
---|
6 | !! History : 1.0 ! 2004-04 (L. Bessieres, G. Madec) Original code |
---|
7 | !! - ! 2006-08 (A. Koch-Larrouy) Indonesian strait |
---|
8 | !! 3.3 ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase |
---|
9 | !!---------------------------------------------------------------------- |
---|
10 | #if defined key_zdftmx || defined key_esopa |
---|
11 | !!---------------------------------------------------------------------- |
---|
12 | !! 'key_zdftmx' Tidal vertical mixing |
---|
13 | !!---------------------------------------------------------------------- |
---|
14 | !! zdf_tmx : global momentum & tracer Kz with tidal induced Kz |
---|
15 | !! tmx_itf : Indonesian momentum & tracer Kz with tidal induced Kz |
---|
16 | !!---------------------------------------------------------------------- |
---|
17 | USE oce ! ocean dynamics and tracers variables |
---|
18 | USE dom_oce ! ocean space and time domain variables |
---|
19 | USE zdf_oce ! ocean vertical physics variables |
---|
20 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
---|
21 | USE eosbn2 ! ocean equation of state |
---|
22 | USE phycst ! physical constants |
---|
23 | USE prtctl ! Print control |
---|
24 | USE in_out_manager ! I/O manager |
---|
25 | USE iom ! I/O Manager |
---|
26 | USE lib_mpp ! MPP library |
---|
27 | USE wrk_nemo, ONLY: wrk_in_use, wrk_not_released |
---|
28 | |
---|
29 | IMPLICIT NONE |
---|
30 | PRIVATE |
---|
31 | |
---|
32 | PUBLIC zdf_tmx ! called in step module |
---|
33 | PUBLIC zdf_tmx_init ! called in opa module |
---|
34 | PUBLIC zdf_tmx_alloc ! called in nemogcm module |
---|
35 | |
---|
36 | LOGICAL, PUBLIC, PARAMETER :: lk_zdftmx = .TRUE. !: tidal mixing flag |
---|
37 | |
---|
38 | ! !!* Namelist namzdf_tmx : tidal mixing * |
---|
39 | REAL(wp) :: rn_htmx = 500. ! vertical decay scale for turbulence (meters) |
---|
40 | REAL(wp) :: rn_n2min = 1.e-8 ! threshold of the Brunt-Vaisala frequency (s-1) |
---|
41 | REAL(wp) :: rn_tfe = 1./3. ! tidal dissipation efficiency (St Laurent et al. 2002) |
---|
42 | REAL(wp) :: rn_me = 0.2 ! mixing efficiency (Osborn 1980) |
---|
43 | LOGICAL :: ln_tmx_itf = .TRUE. ! Indonesian Through Flow (ITF): Koch-Larrouy et al. (2007) parameterization |
---|
44 | REAL(wp) :: rn_tfe_itf = 1. ! ITF tidal dissipation efficiency (St Laurent et al. 2002) |
---|
45 | |
---|
46 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: en_tmx ! energy available for tidal mixing (W/m2) |
---|
47 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: mask_itf ! mask to use over Indonesian area |
---|
48 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: az_tmx ! coefficient used to evaluate the tidal induced Kz |
---|
49 | |
---|
50 | !! * Control permutation of array indices |
---|
51 | # include "oce_ftrans.h90" |
---|
52 | # include "dom_oce_ftrans.h90" |
---|
53 | # include "zdf_oce_ftrans.h90" |
---|
54 | !FTRANS az_tmx :I :I :z |
---|
55 | |
---|
56 | !! * Substitutions |
---|
57 | # include "domzgr_substitute.h90" |
---|
58 | # include "vectopt_loop_substitute.h90" |
---|
59 | !!---------------------------------------------------------------------- |
---|
60 | !! NEMO/OPA 4.0 , NEMO Consortium (2011) |
---|
61 | !! $Id$ |
---|
62 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
---|
63 | !!---------------------------------------------------------------------- |
---|
64 | CONTAINS |
---|
65 | |
---|
66 | INTEGER FUNCTION zdf_tmx_alloc() |
---|
67 | !!---------------------------------------------------------------------- |
---|
68 | !! *** FUNCTION zdf_tmx_alloc *** |
---|
69 | !!---------------------------------------------------------------------- |
---|
70 | ALLOCATE(en_tmx(jpi,jpj), mask_itf(jpi,jpj), az_tmx(jpi,jpj,jpkorig), & |
---|
71 | STAT=zdf_tmx_alloc ) |
---|
72 | ! |
---|
73 | IF( lk_mpp ) CALL mpp_sum ( zdf_tmx_alloc ) |
---|
74 | IF( zdf_tmx_alloc /= 0 ) CALL ctl_warn('zdf_tmx_alloc: failed to allocate arrays') |
---|
75 | END FUNCTION zdf_tmx_alloc |
---|
76 | |
---|
77 | |
---|
78 | SUBROUTINE zdf_tmx( kt ) |
---|
79 | !!---------------------------------------------------------------------- |
---|
80 | !! *** ROUTINE zdf_tmx *** |
---|
81 | !! |
---|
82 | !! ** Purpose : add to the vertical mixing coefficients the effect of |
---|
83 | !! tidal mixing (Simmons et al 2004). |
---|
84 | !! |
---|
85 | !! ** Method : - tidal-induced vertical mixing is given by: |
---|
86 | !! Kz_tides = az_tmx / max( rn_n2min, N^2 ) |
---|
87 | !! where az_tmx is a coefficient that specified the 3D space |
---|
88 | !! distribution of the faction of tidal energy taht is used |
---|
89 | !! for mixing. Its expression is set in zdf_tmx_init routine, |
---|
90 | !! following Simmons et al. 2004. |
---|
91 | !! NB: a specific bounding procedure is performed on av_tide |
---|
92 | !! so that the input tidal energy is actually almost used. The |
---|
93 | !! basic maximum value is 60 cm2/s, but values of 300 cm2/s |
---|
94 | !! can be reached in area where bottom stratification is too |
---|
95 | !! weak. |
---|
96 | !! |
---|
97 | !! - update av_tide in the Indonesian Through Flow area |
---|
98 | !! following Koch-Larrouy et al. (2007) parameterisation |
---|
99 | !! (see tmx_itf routine). |
---|
100 | !! |
---|
101 | !! - update the model vertical eddy viscosity and diffusivity: |
---|
102 | !! avt = avt + av_tides |
---|
103 | !! avm = avm + av_tides |
---|
104 | !! avmu = avmu + mi(av_tides) |
---|
105 | !! avmv = avmv + mj(av_tides) |
---|
106 | !! |
---|
107 | !! ** Action : avt, avm, avmu, avmv increased by tidal mixing |
---|
108 | !! |
---|
109 | !! References : Simmons et al. 2004, Ocean Modelling, 6, 3-4, 245-263. |
---|
110 | !! Koch-Larrouy et al. 2007, GRL. |
---|
111 | !!---------------------------------------------------------------------- |
---|
112 | USE oce, zav_tide => ua ! use ua as workspace |
---|
113 | USE wrk_nemo, ONLY: zkz => wrk_2d_1 |
---|
114 | !! |
---|
115 | INTEGER, INTENT(in) :: kt ! ocean time-step |
---|
116 | !! |
---|
117 | INTEGER :: ji, jj, jk ! dummy loop indices |
---|
118 | REAL(wp) :: ztpc ! scalar workspace |
---|
119 | #if defined key_z_first |
---|
120 | REAL(wp) :: ztpc ! scalar workspace |
---|
121 | #endif |
---|
122 | !!---------------------------------------------------------------------- |
---|
123 | |
---|
124 | IF(wrk_in_use(2, 1))THEN |
---|
125 | CALL ctl_stop('zdf_tmx : requested workspace array unavailable.') ; RETURN |
---|
126 | END IF |
---|
127 | ! ! ----------------------- ! |
---|
128 | ! ! Standard tidal mixing ! (compute zav_tide) |
---|
129 | ! ! ----------------------- ! |
---|
130 | ! !* First estimation (with n2 bound by rn_n2min) bounded by 60 cm2/s |
---|
131 | zav_tide(:,:,:) = MIN( 60.e-4, az_tmx(:,:,:) / MAX( rn_n2min, rn2(:,:,:) ) ) |
---|
132 | |
---|
133 | zkz(:,:) = 0.e0 !* Associated potential energy consummed over the whole water column |
---|
134 | DO jk = 2, jpkm1 |
---|
135 | zkz(:,:) = zkz(:,:) + fse3w(:,:,jk) * MAX( 0.e0, rn2(:,:,jk) ) * rau0 * zav_tide(:,:,jk)* tmask(:,:,jk) |
---|
136 | END DO |
---|
137 | |
---|
138 | DO jj = 1, jpj !* Here zkz should be equal to en_tmx ==> multiply by en_tmx/zkz to recover en_tmx |
---|
139 | DO ji = 1, jpi |
---|
140 | IF( zkz(ji,jj) /= 0.e0 ) zkz(ji,jj) = en_tmx(ji,jj) / zkz(ji,jj) |
---|
141 | END DO |
---|
142 | END DO |
---|
143 | |
---|
144 | #if defined key_z_first |
---|
145 | DO jj = 1, jpj |
---|
146 | DO ji = 1, jpi |
---|
147 | zscal = MIN( zkz(ji,jj), 30./6. ) !kz max = 300 cm2/s |
---|
148 | DO jk = 2, jpkm1 !* Mutiply by zkz to recover en_tmx, BUT bound by 30/6 ==> zav_tide bound by 300 cm2/s |
---|
149 | zav_tide(ji,jj,jk) = zav_tide(ji,jj,jk) * zscal |
---|
150 | END DO |
---|
151 | END DO |
---|
152 | END DO |
---|
153 | #else |
---|
154 | DO jk = 2, jpkm1 !* Mutiply by zkz to recover en_tmx, BUT bound by 30/6 ==> zav_tide bound by 300 cm2/s |
---|
155 | zav_tide(:,:,jk) = zav_tide(:,:,jk) * MIN( zkz(:,:), 30./6. ) !kz max = 300 cm2/s |
---|
156 | END DO |
---|
157 | #endif |
---|
158 | |
---|
159 | IF( kt == nit000 ) THEN !* check at first time-step: diagnose the energy consumed by zav_tide |
---|
160 | ztpc = 0.e0 |
---|
161 | #if defined key_z_first |
---|
162 | DO jj = 1, jpj |
---|
163 | DO ji = 1, jpi |
---|
164 | DO jk = 1, jpk |
---|
165 | #else |
---|
166 | DO jk= 1, jpk |
---|
167 | DO jj= 1, jpj |
---|
168 | DO ji= 1, jpi |
---|
169 | #endif |
---|
170 | ztpc = ztpc + fse3w(ji,jj,jk) * e1t(ji,jj) * e2t(ji,jj) & |
---|
171 | & * MAX( 0.e0, rn2(ji,jj,jk) ) * zav_tide(ji,jj,jk) * tmask(ji,jj,jk) * tmask_i(ji,jj) |
---|
172 | END DO |
---|
173 | END DO |
---|
174 | END DO |
---|
175 | ztpc= rau0 / ( rn_tfe * rn_me ) * ztpc |
---|
176 | IF(lwp) WRITE(numout,*) |
---|
177 | IF(lwp) WRITE(numout,*) ' N Total power consumption by av_tide : ztpc = ', ztpc * 1.e-12 ,'TW' |
---|
178 | ENDIF |
---|
179 | |
---|
180 | ! ! ----------------------- ! |
---|
181 | ! ! ITF tidal mixing ! (update zav_tide) |
---|
182 | ! ! ----------------------- ! |
---|
183 | IF( ln_tmx_itf ) CALL tmx_itf( kt, zav_tide ) |
---|
184 | |
---|
185 | ! ! ----------------------- ! |
---|
186 | ! ! Update mixing coefs ! |
---|
187 | ! ! ----------------------- ! |
---|
188 | #if defined key_z_first |
---|
189 | !* update momentum & tracer diffusivity with tidal mixing |
---|
190 | DO jj = 1, jpj |
---|
191 | DO ji = 1, jpi |
---|
192 | DO jk = 2, jpkm1 |
---|
193 | avt(ji,jj,jk) = avt(ji,jj,jk) + zav_tide(ji,jj,jk) |
---|
194 | avm(ji,jj,jk) = avm(ji,jj,jk) + zav_tide(ji,jj,jk) |
---|
195 | END DO |
---|
196 | END DO |
---|
197 | END DO |
---|
198 | DO jj = 2, jpjm1 |
---|
199 | DO ji = 2, fpim1 |
---|
200 | DO jk = 2, jpkm1 |
---|
201 | avmu(ji,jj,jk) = avmu(ji,jj,jk) + 0.5 * ( zav_tide(ji,jj,jk) + zav_tide(ji+1,jj ,jk) ) * umask(ji,jj,jk) |
---|
202 | avmv(ji,jj,jk) = avmv(ji,jj,jk) + 0.5 * ( zav_tide(ji,jj,jk) + zav_tide(ji ,jj+1,jk) ) * vmask(ji,jj,jk) |
---|
203 | END DO |
---|
204 | END DO |
---|
205 | END DO |
---|
206 | #else |
---|
207 | DO jk = 2, jpkm1 !* update momentum & tracer diffusivity with tidal mixing |
---|
208 | avt(:,:,jk) = avt(:,:,jk) + zav_tide(:,:,jk) |
---|
209 | avm(:,:,jk) = avm(:,:,jk) + zav_tide(:,:,jk) |
---|
210 | DO jj = 2, jpjm1 |
---|
211 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
212 | avmu(ji,jj,jk) = avmu(ji,jj,jk) + 0.5 * ( zav_tide(ji,jj,jk) + zav_tide(ji+1,jj ,jk) ) * umask(ji,jj,jk) |
---|
213 | avmv(ji,jj,jk) = avmv(ji,jj,jk) + 0.5 * ( zav_tide(ji,jj,jk) + zav_tide(ji ,jj+1,jk) ) * vmask(ji,jj,jk) |
---|
214 | END DO |
---|
215 | END DO |
---|
216 | END DO |
---|
217 | #endif |
---|
218 | CALL lbc_lnk( avmu, 'U', 1. ) ; CALL lbc_lnk( avmv, 'V', 1. ) ! lateral boundary condition |
---|
219 | |
---|
220 | ! !* output tidal mixing coefficient |
---|
221 | CALL iom_put( "av_tide", zav_tide ) |
---|
222 | |
---|
223 | IF(ln_ctl) CALL prt_ctl(tab3d_1=zav_tide , clinfo1=' tmx - av_tide: ', tab3d_2=avt, clinfo2=' avt: ', ovlap=1, kdim=jpk) |
---|
224 | ! |
---|
225 | IF(wrk_not_released(2, 1))THEN |
---|
226 | CALL ctl_stop('zdf_tmx : failed to release workspace array.') |
---|
227 | END IF |
---|
228 | ! |
---|
229 | END SUBROUTINE zdf_tmx |
---|
230 | |
---|
231 | |
---|
232 | SUBROUTINE tmx_itf( kt, pav ) |
---|
233 | !!---------------------------------------------------------------------- |
---|
234 | !! *** ROUTINE tmx_itf *** |
---|
235 | !! |
---|
236 | !! ** Purpose : modify the vertical eddy diffusivity coefficients |
---|
237 | !! (pav) in the Indonesian Through Flow area (ITF). |
---|
238 | !! |
---|
239 | !! ** Method : - Following Koch-Larrouy et al. (2007), in the ITF defined |
---|
240 | !! by msk_itf (read in a file, see tmx_init), the tidal |
---|
241 | !! mixing coefficient is computed with : |
---|
242 | !! * q=1 (i.e. all the tidal energy remains trapped in |
---|
243 | !! the area and thus is used for mixing) |
---|
244 | !! * the vertical distribution of the tifal energy is a |
---|
245 | !! proportional to N above the thermocline (d(N^2)/dz > 0) |
---|
246 | !! and to N^2 below the thermocline (d(N^2)/dz < 0) |
---|
247 | !! |
---|
248 | !! ** Action : av_tide updated in the ITF area (msk_itf) |
---|
249 | !! |
---|
250 | !! References : Koch-Larrouy et al. 2007, GRL |
---|
251 | !!---------------------------------------------------------------------- |
---|
252 | USE wrk_nemo, ONLY: zkz => wrk_2d_5 |
---|
253 | USE wrk_nemo, ONLY: zsum1 => wrk_2d_2, zsum2 => wrk_2d_3, zsum => wrk_2d_4 |
---|
254 | USE wrk_nemo, ONLY: zempba_3d_1 => wrk_3d_1, zempba_3d_2 => wrk_3d_2 |
---|
255 | USE wrk_nemo, ONLY: zempba_3d => wrk_3d_3, zdn2dz => wrk_3d_4 |
---|
256 | USE wrk_nemo, ONLY: zavt_itf => wrk_3d_5 |
---|
257 | !! DCSE_NEMO: need additional directives for renamed module variables |
---|
258 | !FTRANS zempba_3d_1 zempba_3d_2 zempba_3d zdn2dz zavt_itf :I :I :z |
---|
259 | !! |
---|
260 | INTEGER , INTENT(in ) :: kt ! ocean time-step |
---|
261 | |
---|
262 | !! DCSE_NEMO: This style defeats ftrans |
---|
263 | ! REAL(wp), INTENT(inout), DIMENSION(jpi,jpj,jpk) :: pav ! Tidal mixing coef. |
---|
264 | !FTRANS pav :I :I :z |
---|
265 | REAL(wp), INTENT(inout) :: pav(jpi,jpj,jpkorig) ! Tidal mixing coef. |
---|
266 | !! |
---|
267 | INTEGER :: ji, jj, jk ! dummy loop indices |
---|
268 | REAL(wp) :: zcoef, ztpc ! temporary scalar |
---|
269 | !!---------------------------------------------------------------------- |
---|
270 | ! |
---|
271 | IF( wrk_in_use(2, 2,3,4,5) .OR. wrk_in_use(3, 1,2,3,4,5) )THEN |
---|
272 | CALL ctl_stop('tmx_itf : requested workspace arrays unavailable.') |
---|
273 | RETURN |
---|
274 | END IF |
---|
275 | ! ! compute the form function using N2 at each time step |
---|
276 | #if defined key_z_first |
---|
277 | DO jj = 1, jpj |
---|
278 | DO ji = 1, jpi |
---|
279 | DO jk = 1, jpkm1 |
---|
280 | zdn2dz (ji,jj,jk) = rn2(ji,jj,jk) - rn2(ji,jj,jk+1) ! Vertical profile of dN2/dz |
---|
281 | zempba_3d_1(ji,jj,jk) = SQRT( MAX( 0.e0, rn2(ji,jj,jk) ) ) ! - - of N |
---|
282 | zempba_3d_2(ji,jj,jk) = MAX( 0.e0, rn2(ji,jj,jk) ) ! - - of N^2 |
---|
283 | END DO |
---|
284 | zempba_3d_1(ji,jj,jpk) = 0.e0 |
---|
285 | zempba_3d_2(ji,jj,jpk) = 0.e0 |
---|
286 | END DO |
---|
287 | END DO |
---|
288 | #else |
---|
289 | zempba_3d_1(:,:,jpk) = 0.e0 |
---|
290 | zempba_3d_2(:,:,jpk) = 0.e0 |
---|
291 | DO jk = 1, jpkm1 |
---|
292 | zdn2dz (:,:,jk) = rn2(:,:,jk) - rn2(:,:,jk+1) ! Vertical profile of dN2/dz |
---|
293 | !CDIR NOVERRCHK |
---|
294 | zempba_3d_1(:,:,jk) = SQRT( MAX( 0.e0, rn2(:,:,jk) ) ) ! - - of N |
---|
295 | zempba_3d_2(:,:,jk) = MAX( 0.e0, rn2(:,:,jk) ) ! - - of N^2 |
---|
296 | END DO |
---|
297 | #endif |
---|
298 | ! |
---|
299 | #if defined key_z_first |
---|
300 | DO jj = 1, jpj |
---|
301 | DO ji = 1, jpj |
---|
302 | zsum1(ji,jj) = 0.e0 |
---|
303 | zsum2(ji,jj) = 0.e0 |
---|
304 | DO jk= 2, jpk |
---|
305 | zsum1(ji,jj) = zsum1(ji,jj) + zempba_3d_1(ji,jj,jk) * fse3w(ji,jj,jk) |
---|
306 | zsum2(ji,jj) = zsum2(ji,jj) + zempba_3d_2(ji,jj,jk) * fse3w(ji,jj,jk) |
---|
307 | END DO |
---|
308 | IF( zsum1(ji,jj) /= 0.e0 ) zsum1(ji,jj) = 1.e0 / zsum1(ji,jj) |
---|
309 | IF( zsum2(ji,jj) /= 0.e0 ) zsum2(ji,jj) = 1.e0 / zsum2(ji,jj) |
---|
310 | END DO |
---|
311 | END DO |
---|
312 | #else |
---|
313 | zsum1(:,:) = 0.e0 |
---|
314 | zsum2(:,:) = 0.e0 |
---|
315 | DO jk= 2, jpk |
---|
316 | zsum1(:,:) = zsum1(:,:) + zempba_3d_1(:,:,jk) * fse3w(:,:,jk) |
---|
317 | zsum2(:,:) = zsum2(:,:) + zempba_3d_2(:,:,jk) * fse3w(:,:,jk) |
---|
318 | END DO |
---|
319 | DO jj = 1, jpj |
---|
320 | DO ji = 1, jpi |
---|
321 | IF( zsum1(ji,jj) /= 0.e0 ) zsum1(ji,jj) = 1.e0 / zsum1(ji,jj) |
---|
322 | IF( zsum2(ji,jj) /= 0.e0 ) zsum2(ji,jj) = 1.e0 / zsum2(ji,jj) |
---|
323 | END DO |
---|
324 | END DO |
---|
325 | #endif |
---|
326 | |
---|
327 | zsum (:,:) = 0.e0 |
---|
328 | |
---|
329 | #if defined key_z_first |
---|
330 | DO jj = 1, jpj |
---|
331 | DO ji = 1, jpi |
---|
332 | DO jk = 1, jpk |
---|
333 | #else |
---|
334 | DO jk = 1, jpk |
---|
335 | DO jj = 1, jpj |
---|
336 | DO ji = 1, jpi |
---|
337 | #endif |
---|
338 | zcoef = 0.5 - SIGN( 0.5, zdn2dz(ji,jj,jk) ) ! =0 if dN2/dz > 0, =1 otherwise |
---|
339 | ztpc = zempba_3d_1(ji,jj,jk) * zsum1(ji,jj) * zcoef & |
---|
340 | & + zempba_3d_2(ji,jj,jk) * zsum2(ji,jj) * ( 1. - zcoef ) |
---|
341 | ! |
---|
342 | zempba_3d(ji,jj,jk) = ztpc |
---|
343 | zsum (ji,jj) = zsum(ji,jj) + ztpc * fse3w(ji,jj,jk) |
---|
344 | END DO |
---|
345 | #if !defined key_z_first |
---|
346 | END DO |
---|
347 | END DO |
---|
348 | DO jj = 1, jpj |
---|
349 | DO ji = 1, jpi |
---|
350 | #endif |
---|
351 | IF( zsum(ji,jj) > 0.e0 ) zsum(ji,jj) = 1.e0 / zsum(ji,jj) |
---|
352 | END DO |
---|
353 | END DO |
---|
354 | |
---|
355 | ! ! first estimation bounded by 10 cm2/s (with n2 bounded by rn_n2min) |
---|
356 | zcoef = rn_tfe_itf / ( rn_tfe * rau0 ) |
---|
357 | #if defined key_z_first |
---|
358 | DO jj = 1, jpj |
---|
359 | DO ji = 1, jpi |
---|
360 | DO jk = 1, jpk |
---|
361 | zavt_itf(ji,jj,jk) = MIN( 10.e-4, zcoef * en_tmx(ji,jj) * zsum(ji,jj) * zempba_3d(ji,jj,jk) & |
---|
362 | & / MAX( rn_n2min, rn2(ji,jj,jk) ) * tmask(ji,jj,jk) ) |
---|
363 | END DO |
---|
364 | END DO |
---|
365 | END DO |
---|
366 | #else |
---|
367 | DO jk = 1, jpk |
---|
368 | zavt_itf(:,:,jk) = MIN( 10.e-4, zcoef * en_tmx(:,:) * zsum(:,:) * zempba_3d(:,:,jk) & |
---|
369 | & / MAX( rn_n2min, rn2(:,:,jk) ) * tmask(:,:,jk) ) |
---|
370 | END DO |
---|
371 | #endif |
---|
372 | |
---|
373 | #if defined key_z_first |
---|
374 | DO jj = 1, jpj |
---|
375 | DO ji = 1, jpi |
---|
376 | zkz(ji,jj) = 0.e0 ! Associated potential energy consummed over the whole water column |
---|
377 | DO jk = 2, jpkm1 |
---|
378 | zkz(ji,jj) = zkz(ji,jj) + fse3w(ji,jj,jk) & |
---|
379 | & * MAX( 0.e0, rn2(ji,jj,jk) ) * rau0 * zavt_itf(ji,jj,jk) * tmask(ji,jj,jk) |
---|
380 | END DO |
---|
381 | END DO |
---|
382 | END DO |
---|
383 | #else |
---|
384 | zkz(:,:) = 0.e0 ! Associated potential energy consummed over the whole water column |
---|
385 | DO jk = 2, jpkm1 |
---|
386 | zkz(:,:) = zkz(:,:) + fse3w(:,:,jk) * MAX( 0.e0, rn2(:,:,jk) ) * rau0 * zavt_itf(:,:,jk) * tmask(:,:,jk) |
---|
387 | END DO |
---|
388 | #endif |
---|
389 | |
---|
390 | DO jj = 1, jpj ! Here zkz should be equal to en_tmx ==> multiply by en_tmx/zkz to recover en_tmx |
---|
391 | DO ji = 1, jpi |
---|
392 | IF( zkz(ji,jj) /= 0.e0 ) zkz(ji,jj) = en_tmx(ji,jj) * rn_tfe_itf / rn_tfe / zkz(ji,jj) |
---|
393 | END DO |
---|
394 | END DO |
---|
395 | |
---|
396 | #if defined key_z_first |
---|
397 | DO jj = 1, jpj |
---|
398 | DO ji = 1, jpi |
---|
399 | zcoef = MIN( zkz(:,:), 120./10. ) ! kz max = 120 cm2/s |
---|
400 | DO jk = 2, jpkm1 ! Mutiply by zkz to recover en_tmx, BUT bound by 30/6 ==> zavt_itf bound by 300 cm2/s |
---|
401 | zavt_itf(ji,jj,jk) = zavt_itf(ji,jj,jk) * zcoef |
---|
402 | END DO |
---|
403 | END DO |
---|
404 | END DO |
---|
405 | #else |
---|
406 | DO jk = 2, jpkm1 ! Mutiply by zkz to recover en_tmx, BUT bound by 30/6 ==> zavt_itf bound by 300 cm2/s |
---|
407 | zavt_itf(:,:,jk) = zavt_itf(:,:,jk) * MIN( zkz(:,:), 120./10. ) ! kz max = 120 cm2/s |
---|
408 | END DO |
---|
409 | #endif |
---|
410 | |
---|
411 | IF( kt == nit000 ) THEN ! diagnose the energy consumed by zavt_itf |
---|
412 | ztpc = 0.e0 |
---|
413 | #if defined key_z_first |
---|
414 | DO jj = 1, jpj |
---|
415 | DO ji = 1, jpi |
---|
416 | DO jk = 1, jpk |
---|
417 | #else |
---|
418 | DO jk = 1, jpk |
---|
419 | DO jj = 1, jpj |
---|
420 | DO ji = 1, jpi |
---|
421 | #endif |
---|
422 | ztpc = ztpc + e1t(ji,jj) * e2t(ji,jj) * fse3w(ji,jj,jk) * MAX( 0.e0, rn2(ji,jj,jk) ) & |
---|
423 | & * zavt_itf(ji,jj,jk) * tmask(ji,jj,jk) * tmask_i(ji,jj) |
---|
424 | END DO |
---|
425 | END DO |
---|
426 | END DO |
---|
427 | ztpc= rau0 * ztpc / ( rn_me * rn_tfe_itf ) |
---|
428 | IF(lwp) WRITE(numout,*) ' N Total power consumption by zavt_itf: ztpc = ', ztpc * 1.e-12 ,'TW' |
---|
429 | ENDIF |
---|
430 | |
---|
431 | ! ! Update pav with the ITF mixing coefficient |
---|
432 | #if defined key_z_first |
---|
433 | DO jj = 1, jpj |
---|
434 | DO ji = 1, jpi |
---|
435 | DO jk = 2, jpkm1 |
---|
436 | pav(ji,jj,jk) = pav (ji,jj,jk) * ( 1.e0 - mask_itf(ji,jj) ) & |
---|
437 | & + zavt_itf(ji,jj,jk) * mask_itf(ji,jj) |
---|
438 | END DO |
---|
439 | END DO |
---|
440 | END DO |
---|
441 | #else |
---|
442 | DO jk = 2, jpkm1 |
---|
443 | pav(:,:,jk) = pav (:,:,jk) * ( 1.e0 - mask_itf(:,:) ) & |
---|
444 | & + zavt_itf(:,:,jk) * mask_itf(:,:) |
---|
445 | END DO |
---|
446 | #endif |
---|
447 | ! |
---|
448 | IF( wrk_not_released(2, 2,3,4,5) .OR. & |
---|
449 | wrk_not_released(3, 1,2,3,4,5) )THEN |
---|
450 | CALL ctl_stop('tmx_itf : failed to release workspace arrays.') |
---|
451 | END IF |
---|
452 | ! |
---|
453 | END SUBROUTINE tmx_itf |
---|
454 | |
---|
455 | !! * Reset control of array index permutation |
---|
456 | # include "oce_ftrans.h90" |
---|
457 | # include "dom_oce_ftrans.h90" |
---|
458 | # include "zdf_oce_ftrans.h90" |
---|
459 | !FTRANS az_tmx :I :I :z |
---|
460 | |
---|
461 | SUBROUTINE zdf_tmx_init |
---|
462 | !!---------------------------------------------------------------------- |
---|
463 | !! *** ROUTINE zdf_tmx_init *** |
---|
464 | !! |
---|
465 | !! ** Purpose : Initialization of the vertical tidal mixing, Reading |
---|
466 | !! of M2 and K1 tidal energy in nc files |
---|
467 | !! |
---|
468 | !! ** Method : - Read the namtmx namelist and check the parameters |
---|
469 | !! |
---|
470 | !! - Read the input data in NetCDF files : |
---|
471 | !! M2 and K1 tidal energy. The total tidal energy, en_tmx, |
---|
472 | !! is the sum of M2, K1 and S2 energy where S2 is assumed |
---|
473 | !! to be: S2=(1/2)^2 * M2 |
---|
474 | !! mask_itf, a mask array that determine where substituing |
---|
475 | !! the standard Simmons et al. (2005) formulation with the |
---|
476 | !! one of Koch_Larrouy et al. (2007). |
---|
477 | !! |
---|
478 | !! - Compute az_tmx, a 3D coefficient that allows to compute |
---|
479 | !! the standard tidal-induced vertical mixing as follows: |
---|
480 | !! Kz_tides = az_tmx / max( rn_n2min, N^2 ) |
---|
481 | !! with az_tmx a bottom intensified coefficient is given by: |
---|
482 | !! az_tmx(z) = en_tmx / ( rau0 * rn_htmx ) * EXP( -(H-z)/rn_htmx ) |
---|
483 | !! / ( 1. - EXP( - H /rn_htmx ) ) |
---|
484 | !! where rn_htmx the characteristic length scale of the bottom |
---|
485 | !! intensification, en_tmx the tidal energy, and H the ocean depth |
---|
486 | !! |
---|
487 | !! ** input : - Namlist namtmx |
---|
488 | !! - NetCDF file : M2_ORCA2.nc, K1_ORCA2.nc, and mask_itf.nc |
---|
489 | !! |
---|
490 | !! ** Action : - Increase by 1 the nstop flag is setting problem encounter |
---|
491 | !! - defined az_tmx used to compute tidal-induced mixing |
---|
492 | !! |
---|
493 | !! References : Simmons et al. 2004, Ocean Modelling, 6, 3-4, 245-263. |
---|
494 | !! Koch-Larrouy et al. 2007, GRL. |
---|
495 | !!---------------------------------------------------------------------- |
---|
496 | USE oce , zav_tide => ua ! ua used as workspace |
---|
497 | USE wrk_nemo, ONLY: zem2 => wrk_2d_1 ! read M2 and |
---|
498 | USE wrk_nemo, ONLY: zek1 => wrk_2d_2 ! K1 tidal energy |
---|
499 | USE wrk_nemo, ONLY: zkz => wrk_2d_3 ! total M2, K1 and S2 tidal energy |
---|
500 | USE wrk_nemo, ONLY: zfact => wrk_2d_4 ! used for vertical structure function |
---|
501 | USE wrk_nemo, ONLY: zhdep => wrk_2d_5 ! Ocean depth |
---|
502 | USE wrk_nemo, ONLY: zpc => wrk_3d_1 ! power consumption |
---|
503 | |
---|
504 | !! DCSE_NEMO: need additional directives for renamed module variables |
---|
505 | !FTRANS zpc :I :I :z |
---|
506 | |
---|
507 | !! |
---|
508 | INTEGER :: ji, jj, jk ! dummy loop indices |
---|
509 | INTEGER :: inum ! local integer |
---|
510 | REAL(wp) :: ztpc, ze_z ! local scalars |
---|
511 | #if defined key_z_first |
---|
512 | REAL(wp) :: zcoef ! local scalar |
---|
513 | #endif |
---|
514 | |
---|
515 | !! |
---|
516 | NAMELIST/namzdf_tmx/ rn_htmx, rn_n2min, rn_tfe, rn_me, ln_tmx_itf, rn_tfe_itf |
---|
517 | !!---------------------------------------------------------------------- |
---|
518 | |
---|
519 | IF( wrk_in_use(2, 1,2,3,4,5) .OR. wrk_in_use(3, 1) ) THEN |
---|
520 | CALL ctl_stop('zdf_tmx_init : requested workspace arrays unavailable.') ; RETURN |
---|
521 | END IF |
---|
522 | |
---|
523 | REWIND( numnam ) ! Read Namelist namtmx : Tidal Mixing |
---|
524 | READ ( numnam, namzdf_tmx ) |
---|
525 | |
---|
526 | IF(lwp) THEN ! Control print |
---|
527 | WRITE(numout,*) |
---|
528 | WRITE(numout,*) 'zdf_tmx_init : tidal mixing' |
---|
529 | WRITE(numout,*) '~~~~~~~~~~~~' |
---|
530 | WRITE(numout,*) ' Namelist namzdf_tmx : set tidal mixing parameters' |
---|
531 | WRITE(numout,*) ' Vertical decay scale for turbulence = ', rn_htmx |
---|
532 | WRITE(numout,*) ' Brunt-Vaisala frequency threshold = ', rn_n2min |
---|
533 | WRITE(numout,*) ' Tidal dissipation efficiency = ', rn_tfe |
---|
534 | WRITE(numout,*) ' Mixing efficiency = ', rn_me |
---|
535 | WRITE(numout,*) ' ITF specific parameterisation = ', ln_tmx_itf |
---|
536 | WRITE(numout,*) ' ITF tidal dissipation efficiency = ', rn_tfe_itf |
---|
537 | ENDIF |
---|
538 | |
---|
539 | ! ! allocate tmx arrays |
---|
540 | IF( zdf_tmx_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'zdf_tmx_init : unable to allocate tmx arrays' ) |
---|
541 | |
---|
542 | IF( ln_tmx_itf ) THEN ! read the Indonesian Through Flow mask |
---|
543 | CALL iom_open('mask_itf',inum) |
---|
544 | CALL iom_get (inum, jpdom_data, 'tmaskitf',mask_itf,1) ! |
---|
545 | CALL iom_close(inum) |
---|
546 | ENDIF |
---|
547 | |
---|
548 | ! read M2 tidal energy flux : W/m2 ( zem2 < 0 ) |
---|
549 | CALL iom_open('M2rowdrg',inum) |
---|
550 | CALL iom_get (inum, jpdom_data, 'field',zem2,1) ! |
---|
551 | CALL iom_close(inum) |
---|
552 | |
---|
553 | ! read K1 tidal energy flux : W/m2 ( zek1 < 0 ) |
---|
554 | CALL iom_open('K1rowdrg',inum) |
---|
555 | CALL iom_get (inum, jpdom_data, 'field',zek1,1) ! |
---|
556 | CALL iom_close(inum) |
---|
557 | |
---|
558 | ! Total tidal energy ( M2, S2 and K1 with S2=(1/2)^2 * M2 ) |
---|
559 | ! only the energy available for mixing is taken into account, |
---|
560 | ! (mixing efficiency tidal dissipation efficiency) |
---|
561 | en_tmx(:,:) = - rn_tfe * rn_me * ( zem2(:,:) * 1.25 + zek1(:,:) ) * tmask(:,:,1) |
---|
562 | |
---|
563 | ! Vertical structure (az_tmx) |
---|
564 | DO jj = 1, jpj ! part independent of the level |
---|
565 | DO ji = 1, jpi |
---|
566 | zhdep(ji,jj) = fsdepw(ji,jj,mbkt(ji,jj)+1) ! depth of the ocean |
---|
567 | zfact(ji,jj) = rau0 * rn_htmx * ( 1. - EXP( -zhdep(ji,jj) / rn_htmx ) ) |
---|
568 | IF( zfact(ji,jj) /= 0 ) zfact(ji,jj) = en_tmx(ji,jj) / zfact(ji,jj) |
---|
569 | END DO |
---|
570 | END DO |
---|
571 | #if defined key_z_first |
---|
572 | DO jj = 1, jpj |
---|
573 | DO ji = 1, jpi |
---|
574 | DO jk= 1, jpk ! complete with the level-dependent part |
---|
575 | #else |
---|
576 | DO jk= 1, jpk ! complete with the level-dependent part |
---|
577 | DO jj = 1, jpj |
---|
578 | DO ji = 1, jpi |
---|
579 | #endif |
---|
580 | az_tmx(ji,jj,jk) = zfact(ji,jj) * EXP( -( zhdep(ji,jj)-fsdepw(ji,jj,jk) ) / rn_htmx ) * tmask(ji,jj,jk) |
---|
581 | END DO |
---|
582 | END DO |
---|
583 | END DO |
---|
584 | |
---|
585 | IF( nprint == 1 .AND. lwp ) THEN |
---|
586 | ! Control print |
---|
587 | ! Total power consumption due to vertical mixing |
---|
588 | ! zpc = rau0 * 1/rn_me * rn2 * zav_tide |
---|
589 | #if defined key_z_first |
---|
590 | DO jj = 1, jpj |
---|
591 | DO ji = 1, jpi |
---|
592 | zav_tide(ji,jj,1) = 0.e0 |
---|
593 | DO jk = 2, jpkm1 |
---|
594 | zav_tide(:,:,jk) = az_tmx(:,:,jk) / MAX( rn_n2min, rn2(:,:,jk) ) |
---|
595 | END DO |
---|
596 | zav_tide(ji,jj,jpk) = 0.e0 |
---|
597 | END DO |
---|
598 | END DO |
---|
599 | #else |
---|
600 | zav_tide(:,:,:) = 0.e0 |
---|
601 | DO jk = 2, jpkm1 |
---|
602 | zav_tide(:,:,jk) = az_tmx(:,:,jk) / MAX( rn_n2min, rn2(:,:,jk) ) |
---|
603 | END DO |
---|
604 | #endif |
---|
605 | |
---|
606 | ztpc = 0.e0 |
---|
607 | zpc(:,:,:) = MAX(rn_n2min,rn2(:,:,:)) * zav_tide(:,:,:) |
---|
608 | #if defined key_z_first |
---|
609 | DO jj = 1, jpj |
---|
610 | DO ji = 1, jpi |
---|
611 | DO jk= 2, jpkm1 |
---|
612 | #else |
---|
613 | DO jk= 2, jpkm1 |
---|
614 | DO jj = 1, jpj |
---|
615 | DO ji = 1, jpi |
---|
616 | #endif |
---|
617 | ztpc = ztpc + fse3w(ji,jj,jk) * e1t(ji,jj) * e2t(ji,jj) * zpc(ji,jj,jk) * tmask(ji,jj,jk) * tmask_i(ji,jj) |
---|
618 | END DO |
---|
619 | END DO |
---|
620 | END DO |
---|
621 | ztpc= rau0 * 1/(rn_tfe * rn_me) * ztpc |
---|
622 | |
---|
623 | WRITE(numout,*) |
---|
624 | WRITE(numout,*) ' Total power consumption of the tidally driven part of Kz : ztpc = ', ztpc * 1.e-12 ,'TW' |
---|
625 | |
---|
626 | |
---|
627 | ! control print 2 |
---|
628 | zav_tide(:,:,:) = MIN( zav_tide(:,:,:), 60.e-4 ) |
---|
629 | #if defined key_z_first |
---|
630 | DO jj = 1, jpj |
---|
631 | DO ji = 1, jpi |
---|
632 | zkz(ji,jj) = 0.e0 |
---|
633 | DO jk = 2, jpkm1 |
---|
634 | #else |
---|
635 | zkz(:,:) = 0.e0 |
---|
636 | DO jk = 2, jpkm1 |
---|
637 | DO jj = 1, jpj |
---|
638 | DO ji = 1, jpi |
---|
639 | #endif |
---|
640 | zkz(ji,jj) = zkz(ji,jj) + fse3w(ji,jj,jk) & |
---|
641 | & * MAX( 0.e0, rn2(ji,jj,jk) ) * rau0 * zav_tide(ji,jj,jk)* tmask(ji,jj,jk) |
---|
642 | END DO |
---|
643 | END DO |
---|
644 | END DO |
---|
645 | ! Here zkz should be equal to en_tmx ==> multiply by en_tmx/zkz |
---|
646 | DO jj = 1, jpj |
---|
647 | DO ji = 1, jpi |
---|
648 | IF( zkz(ji,jj) /= 0.e0 ) THEN |
---|
649 | zkz(ji,jj) = en_tmx(ji,jj) / zkz(ji,jj) |
---|
650 | ENDIF |
---|
651 | END DO |
---|
652 | END DO |
---|
653 | ztpc = 1.e50 |
---|
654 | DO jj = 1, jpj |
---|
655 | DO ji = 1, jpi |
---|
656 | IF( zkz(ji,jj) /= 0.e0 ) THEN |
---|
657 | ztpc = MIN( zkz(ji,jj), ztpc) |
---|
658 | ENDIF |
---|
659 | END DO |
---|
660 | END DO |
---|
661 | WRITE(numout,*) ' Min de zkz ', ztpc, ' Max = ', MAXVAL(zkz(:,:) ) |
---|
662 | |
---|
663 | #if defined key_z_first |
---|
664 | DO jj = 1, jpj |
---|
665 | DO ji = 1, jpi |
---|
666 | zcoef = MIN( zkz(ji,jj), 30./6. ) !kz max = 300 cm2/s |
---|
667 | DO jk = 2, jpkm1 |
---|
668 | zav_tide(ji,jj,jk) = zav_tide(ji,jj,jk) * zcoef |
---|
669 | END DO |
---|
670 | END DO |
---|
671 | END DO |
---|
672 | #else |
---|
673 | DO jk = 2, jpkm1 |
---|
674 | zav_tide(:,:,jk) = zav_tide(:,:,jk) * MIN( zkz(:,:), 30./6. ) !kz max = 300 cm2/s |
---|
675 | END DO |
---|
676 | #endif |
---|
677 | ztpc = 0.e0 |
---|
678 | zpc(:,:,:) = MAX(0.e0,rn2(:,:,:)) * zav_tide(:,:,:) |
---|
679 | #if defined key_z_first |
---|
680 | DO jj = 1, jpj |
---|
681 | DO ji = 1, jpi |
---|
682 | DO jk= 1, jpk |
---|
683 | #else |
---|
684 | DO jk= 1, jpk |
---|
685 | DO jj = 1, jpj |
---|
686 | DO ji = 1, jpi |
---|
687 | #endif |
---|
688 | ztpc = ztpc + fse3w(ji,jj,jk) * e1t(ji,jj) * e2t(ji,jj) * zpc(ji,jj,jk) * tmask(ji,jj,jk) * tmask_i(ji,jj) |
---|
689 | END DO |
---|
690 | END DO |
---|
691 | END DO |
---|
692 | ztpc= rau0 * 1/(rn_tfe * rn_me) * ztpc |
---|
693 | WRITE(numout,*) ' 2 Total power consumption of the tidally driven part of Kz : ztpc = ', ztpc * 1.e-12 ,'TW' |
---|
694 | |
---|
695 | DO jk = 1, jpk |
---|
696 | ze_z = SUM( e1t(:,:) * e2t(:,:) * zav_tide(:,:,jk) * tmask_i(:,:) ) & |
---|
697 | & / MAX( 1.e-20, SUM( e1t(:,:) * e2t(:,:) * tmask (:,:,jk) * tmask_i(:,:) ) ) |
---|
698 | ztpc = 1.E50 |
---|
699 | DO jj = 1, jpj |
---|
700 | DO ji = 1, jpi |
---|
701 | IF( zav_tide(ji,jj,jk) /= 0.e0 ) ztpc =Min( ztpc, zav_tide(ji,jj,jk) ) |
---|
702 | END DO |
---|
703 | END DO |
---|
704 | WRITE(numout,*) ' N2 min - jk= ', jk,' ', ze_z * 1.e4,' cm2/s min= ',ztpc*1.e4, & |
---|
705 | & 'max= ', MAXVAL(zav_tide(:,:,jk) )*1.e4, ' cm2/s' |
---|
706 | END DO |
---|
707 | |
---|
708 | WRITE(numout,*) ' e_tide : ', SUM( e1t*e2t*en_tmx ) / ( rn_tfe * rn_me ) * 1.e-12, 'TW' |
---|
709 | WRITE(numout,*) |
---|
710 | WRITE(numout,*) ' Initial profile of tidal vertical mixing' |
---|
711 | DO jk = 1, jpk |
---|
712 | DO jj = 1,jpj |
---|
713 | DO ji = 1,jpi |
---|
714 | zkz(ji,jj) = az_tmx(ji,jj,jk) /MAX( rn_n2min, rn2(ji,jj,jk) ) |
---|
715 | END DO |
---|
716 | END DO |
---|
717 | ze_z = SUM( e1t(:,:) * e2t(:,:) * zkz(:,:) * tmask_i(:,:) ) & |
---|
718 | & / MAX( 1.e-20, SUM( e1t(:,:) * e2t(:,:) * tmask (:,:,jk) * tmask_i(:,:) ) ) |
---|
719 | WRITE(numout,*) ' jk= ', jk,' ', ze_z * 1.e4,' cm2/s' |
---|
720 | END DO |
---|
721 | DO jk = 1, jpk |
---|
722 | zkz(:,:) = az_tmx(:,:,jk) /rn_n2min |
---|
723 | ze_z = SUM( e1t(:,:) * e2t(:,:) * zkz(:,:) * tmask_i(:,:) ) & |
---|
724 | & / MAX( 1.e-20, SUM( e1t(:,:) * e2t(:,:) * tmask (:,:,jk) * tmask_i(:,:) ) ) |
---|
725 | WRITE(numout,*) |
---|
726 | WRITE(numout,*) ' N2 min - jk= ', jk,' ', ze_z * 1.e4,' cm2/s min= ',MINVAL(zkz)*1.e4, & |
---|
727 | & 'max= ', MAXVAL(zkz)*1.e4, ' cm2/s' |
---|
728 | END DO |
---|
729 | ! |
---|
730 | ENDIF |
---|
731 | ! |
---|
732 | IF(wrk_not_released(2, 1,2,3,4,5) .OR. & |
---|
733 | wrk_not_released(3, 1) ) CALL ctl_stop( 'zdf_tmx_init : failed to release workspace arrays' ) |
---|
734 | ! |
---|
735 | END SUBROUTINE zdf_tmx_init |
---|
736 | |
---|
737 | #else |
---|
738 | !!---------------------------------------------------------------------- |
---|
739 | !! Default option Dummy module NO Tidal MiXing |
---|
740 | !!---------------------------------------------------------------------- |
---|
741 | LOGICAL, PUBLIC, PARAMETER :: lk_zdftmx = .FALSE. !: tidal mixing flag |
---|
742 | CONTAINS |
---|
743 | SUBROUTINE zdf_tmx_init ! Dummy routine |
---|
744 | WRITE(*,*) 'zdf_tmx: You should not have seen this print! error?' |
---|
745 | END SUBROUTINE zdf_tmx_init |
---|
746 | SUBROUTINE zdf_tmx( kt ) ! Dummy routine |
---|
747 | WRITE(*,*) 'zdf_tmx: You should not have seen this print! error?', kt |
---|
748 | END SUBROUTINE zdf_tmx |
---|
749 | #endif |
---|
750 | |
---|
751 | !!====================================================================== |
---|
752 | END MODULE zdftmx |
---|