source: branches/2011/UKMO_MERCATOR_obc_bdy_merge/NEMOGCM/NEMO/OPA_SRC/OBC/obcdyn2d.F90 @ 2797

MODULE obcdyn2d
   !!======================================================================
   !!                       ***  MODULE  obcdyn  ***
   !! Unstructured Open Boundary Cond. :   Flow relaxation scheme on velocities
   !!======================================================================
   !! History :  1.0  !  2005-02  (J. Chanut, A. Sellar)  Original code
   !!             -   !  2007-07  (D. Storkey) Move Flather implementation to separate routine.
   !!            3.0  !  2008-04  (NEMO team)  add in the reference version
   !!            3.2  !  2008-04  (R. Benshila) consider velocity instead of transport 
   !!            3.3  !  2010-09  (E.O'Dea) modifications for Shelf configurations 
   !!            3.3  !  2010-09  (D.Storkey) add ice boundary conditions
   !!----------------------------------------------------------------------
#if defined key_obc 
   !!----------------------------------------------------------------------
   !!   'key_obc' :                    Unstructured Open Boundary Condition
   !!----------------------------------------------------------------------
   !!   obc_dyn2d      : Apply open boundary conditions to barotropic variables.
   !!   obc_dyn2d_fla    : Apply Flather condition
   !!----------------------------------------------------------------------
   USE oce             ! ocean dynamics and tracers 
   USE dom_oce         ! ocean space and time domain
   USE obc_oce         ! ocean open boundary conditions
   USE dynspg_oce      ! for barotropic variables
   USE phycst          ! physical constants
   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
   USE obctides        ! for tidal harmonic forcing at boundary
   USE in_out_manager  !

   IMPLICIT NONE
   PRIVATE

   PUBLIC   obc_dyn2d     ! routine called in dynspg_ts (time splitting case ONLY)

   !!----------------------------------------------------------------------
   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
   !! $Id: obcdyn.F90 2528 2010-12-27 17:33:53Z rblod $ 
   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
   !!----------------------------------------------------------------------
CONTAINS

   SUBROUTINE obc_dyn2d( kt, pssh )
      !!----------------------------------------------------------------------
      !!                  ***  SUBROUTINE obc_dyn2d  ***
      !!
      !! ** Purpose : - Apply open boundary conditions for barotropic variables
      !!
      !!----------------------------------------------------------------------
      INTEGER,                      INTENT(in) ::   kt   ! Main time step counter
      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) ::   pssh
      !!
      INTEGER                                  ::   ib_obc ! Loop counter

      DO ib_obc=1, nb_obc

         SELECT CASE( nn_dyn2d(ib_obc) )
         CASE(jp_none)
            CYCLE
         CASE(jp_flather)
            CALL obc_dyn2d_fla( idx_obc(ib_obc), dta_obc(ib_obc), pssh )
         CASE DEFAULT
            CALL ctl_stop( 'obc_dyn3d : unrecognised option for open boundaries for barotropic variables' )
         END SELECT
      ENDDO

   END SUBROUTINE obc_dyn2d

   SUBROUTINE obc_dyn2d_fla( idx, dta, pssh )
      !!----------------------------------------------------------------------
      !!                 ***  SUBROUTINE obc_dyn_fla  ***
      !!             
      !!              - Apply Flather boundary conditions on normal barotropic velocities 
      !!                (ln_dyn_fla=.true. or ln_tides=.true.)
      !!
      !! ** WARNINGS about FLATHER implementation:
      !!1. According to Palma and Matano, 1998 "after ssh" is used. 
      !!   In ROMS and POM implementations, it is "now ssh". In the current 
      !!   implementation (tested only in the EEL-R5 conf.), both cases were unstable. 
      !!   So I use "before ssh" in the following.
      !!
      !!2. We assume that the normal ssh gradient at the obc is zero. As a matter of 
      !!   fact, the model ssh just inside the dynamical boundary is used (the outside  
      !!   ssh in the code is not updated).
      !!
      !! References:  Flather, R. A., 1976: A tidal model of the northwest European
      !!              continental shelf. Mem. Soc. R. Sci. Liege, Ser. 6,10, 141-164.     
      !!----------------------------------------------------------------------
      TYPE(OBC_INDEX),              INTENT(in) ::   idx  ! OBC indices
      TYPE(OBC_DATA),               INTENT(in) ::   dta  ! OBC external data
      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) ::   pssh

      INTEGER  ::   jb, igrd                         ! dummy loop indices
      INTEGER  ::   ii, ij, iim1, iip1, ijm1, ijp1   ! 2D addresses
      REAL(wp) ::   zcorr                            ! Flather correction
      REAL(wp) ::   zforc                            ! temporary scalar
      !!----------------------------------------------------------------------

      ! ---------------------------------!
      ! Flather boundary conditions     :!
      ! ---------------------------------! 
     
!!!!!!!!!!!! SOME WORK TO DO ON THE TIDES HERE !!!!!!!!!!!!!

      ! Fill temporary array with ssh data (here spgu):
      igrd = 1
      spgu(:,:) = 0.0
      DO jb = 1, idx%nblenrim(igrd)
         ii = idx%nbi(jb,igrd)
         ij = idx%nbj(jb,igrd)
         spgu(ii, ij) = dta%ssh(jb)
!!$         IF( ln_tides )   spgu(ii, ij) = spgu(ii, ij) + sshtide(jb)
      END DO
      !
      igrd = 2      ! Flather bc on u-velocity; 
      !             ! remember that flagu=-1 if normal velocity direction is outward
      !             ! I think we should rather use after ssh ?
      DO jb = 1, idx%nblenrim(igrd)
         ii  = idx%nbi(jb,igrd)
         ij  = idx%nbj(jb,igrd) 
         iim1 = ii + MAX( 0, INT( idx%flagu(jb) ) )   ! T pts i-indice inside the boundary
         iip1 = ii - MIN( 0, INT( idx%flagu(jb) ) )   ! T pts i-indice outside the boundary 
         !
         zcorr = - idx%flagu(jb) * SQRT( grav * hur_e(ii, ij) ) * ( pssh(iim1, ij) - spgu(iip1,ij) )
!!$         zforc = dta%u2d(jb) + utide(jb)
         zforc = dta%u2d(jb)
         ua_e(ii,ij) = zforc + zcorr * umask(ii,ij,1) 
      END DO
      !
      igrd = 3      ! Flather bc on v-velocity
      !             ! remember that flagv=-1 if normal velocity direction is outward
      DO jb = 1, idx%nblenrim(igrd)
         ii  = idx%nbi(jb,igrd)
         ij  = idx%nbj(jb,igrd) 
         ijm1 = ij + MAX( 0, INT( idx%flagv(jb) ) )   ! T pts j-indice inside the boundary
         ijp1 = ij - MIN( 0, INT( idx%flagv(jb) ) )   ! T pts j-indice outside the boundary 
         !
         zcorr = - idx%flagv(jb) * SQRT( grav * hvr_e(ii, ij) ) * ( pssh(ii, ijm1) - spgu(ii,ijp1) )
!!$         zforc = dta%v2d(jb) + vtide(jb)
         zforc = dta%v2d(jb)
         va_e(ii,ij) = zforc + zcorr * vmask(ii,ij,1)
      END DO
      CALL lbc_lnk( ua_e, 'U', -1. )   ! Boundary points should be updated
      CALL lbc_lnk( va_e, 'V', -1. )   !
      !
      !
   END SUBROUTINE obc_dyn2d_fla
#else
   !!----------------------------------------------------------------------
   !!   Dummy module                   NO Unstruct Open Boundary Conditions
   !!----------------------------------------------------------------------
CONTAINS
   SUBROUTINE obc_dyn2d( kt )      ! Empty routine
      WRITE(*,*) 'obc_dyn_frs: You should not have seen this print! error?', kt
   END SUBROUTINE obc_dyn2d
#endif

   !!======================================================================
END MODULE obcdyn2d