New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zlys.F90 in branches/2011/dev_LOCEAN_2011/NEMOGCM/NEMO/TOP_SRC/PISCES – NEMO

source: branches/2011/dev_LOCEAN_2011/NEMOGCM/NEMO/TOP_SRC/PISCES/p4zlys.F90 @ 2977

Last change on this file since 2977 was 2977, checked in by cetlod, 13 years ago

Add in branch 2011/dev_LOCEAN_2011 changes from 2011/dev_r2787_PISCES_improvment, 2011/dev_r2787_LOCEAN_offline_fldread and 2011/dev_r2787_LOCEAN3_TRA_TRP branches, see ticket #877
  • Property svn:keywords set to Id
File size: 9.4 KB
Line 
1MODULE p4zlys
2   !!======================================================================
3   !!                         ***  MODULE p4zlys  ***
4   !! TOP :   PISCES
5   !!======================================================================
6   !! History :    -   !  1988-07  (E. MAIER-REIMER) Original code
7   !!              -   !  1998     (O. Aumont) additions
8   !!              -   !  1999     (C. Le Quere) modifications
9   !!             1.0  !  2004     (O. Aumont) modifications
10   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
11   !!                  !  2011-02  (J. Simeon, J. Orr)  Calcon salinity dependence
12   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Improvment of calcite dissolution
13   !!----------------------------------------------------------------------
14#if defined key_pisces
15   !!----------------------------------------------------------------------
16   !!   'key_pisces'                                       PISCES bio-model
17   !!----------------------------------------------------------------------
18   !!   p4z_lys        :   Compute the CaCO3 dissolution
19   !!   p4z_lys_init   :   Read the namelist parameters
20   !!----------------------------------------------------------------------
21   USE oce_trc         !  shared variables between ocean and passive tracers
22   USE trc             !  passive tracers common variables
23   USE sms_pisces      !  PISCES Source Minus Sink variables
24   USE prtctl_trc      !  print control for debugging
25   USE iom             !  I/O manager
26
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC   p4z_lys         ! called in trcsms_pisces.F90
31   PUBLIC   p4z_lys_init    ! called in trcsms_pisces.F90
32
33   !! * Shared module variables
34   REAL(wp), PUBLIC :: kdca = 0.327e3_wp  !: diss. rate constant calcite
35   REAL(wp), PUBLIC :: nca  = 1.0_wp      !: order of reaction for calcite dissolution
36
37   !! * Module variables
38   REAL(wp) :: calcon = 1.03E-2           !: mean calcite concentration [Ca2+] in sea water [mole/kg solution]
39 
40   INTEGER  :: rmtss                      !: number of seconds per month
41
42   !!----------------------------------------------------------------------
43   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
44   !! $Id$
45   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
46   !!----------------------------------------------------------------------
47
48CONTAINS
49
50   SUBROUTINE p4z_lys( kt )
51      !!---------------------------------------------------------------------
52      !!                     ***  ROUTINE p4z_lys  ***
53      !!
54      !! ** Purpose :   CALCULATES DEGREE OF CACO3 SATURATION IN THE WATER
55      !!                COLUMN, DISSOLUTION/PRECIPITATION OF CACO3 AND LOSS
56      !!                OF CACO3 TO THE CACO3 SEDIMENT POOL.
57      !!
58      !! ** Method  : - ???
59      !!---------------------------------------------------------------------
60      USE wrk_nemo, ONLY: wrk_in_use, wrk_not_released
61      USE wrk_nemo, ONLY: zco3 => wrk_3d_2, zcaldiss => wrk_3d_3 
62      !
63      INTEGER, INTENT(in) ::   kt ! ocean time step
64      INTEGER  ::   ji, jj, jk, jn
65      REAL(wp) ::   zalk, zdic, zph, zremco3, zah2
66      REAL(wp) ::   zdispot, zfact, zcalcon, zalka, zaldi
67      REAL(wp) ::   zomegaca, zexcess, zexcess0
68      REAL(wp) ::   zrfact2
69      CHARACTER (len=25) :: charout
70      !!---------------------------------------------------------------------
71
72      IF(  wrk_in_use(3, 2,3) ) THEN
73         CALL ctl_stop('p4z_lys: requested workspace arrays unavailable')  ;  RETURN
74      END IF
75
76      zco3    (:,:,:) = 0.
77      zcaldiss(:,:,:) = 0.
78      !     -------------------------------------------
79      !     COMPUTE [CO3--] and [H+] CONCENTRATIONS
80      !     -------------------------------------------
81     
82      DO jn = 1, 5                               !  BEGIN OF ITERATION
83         !
84!CDIR NOVERRCHK
85         DO jk = 1, jpkm1
86!CDIR NOVERRCHK
87            DO jj = 1, jpj
88!CDIR NOVERRCHK
89               DO ji = 1, jpi
90                  zfact = rhop(ji,jj,jk) / 1000. + rtrn
91                  zph  = hi(ji,jj,jk) * tmask(ji,jj,jk) / zfact + ( 1.-tmask(ji,jj,jk) ) * 1.e-9 ! [H+]
92                  zdic  = trn(ji,jj,jk,jpdic) / zfact
93                  zalka = trn(ji,jj,jk,jptal) / zfact
94                  ! CALCULATE [ALK]([CO3--], [HCO3-])
95                  zalk  = zalka - ( akw3(ji,jj,jk) / zph - zph + borat(ji,jj,jk) / ( 1. + zph / akb3(ji,jj,jk) ) )
96                  ! CALCULATE [H+] and [CO3--]
97                  zaldi = zdic - zalk
98                  zah2  = SQRT( zaldi * zaldi + 4.* ( zalk * ak23(ji,jj,jk) / ak13(ji,jj,jk) ) * ( zdic + zaldi ) )
99                  zah2  = 0.5 * ak13(ji,jj,jk) / zalk * ( zaldi + zah2 )
100                  !
101                  zco3(ji,jj,jk) = zalk / ( 2. + zah2 / ak23(ji,jj,jk) ) * zfact
102                  hi(ji,jj,jk)   = zah2 * zfact
103               END DO
104            END DO
105         END DO
106         !
107      END DO 
108
109      !     ---------------------------------------------------------
110      !        CALCULATE DEGREE OF CACO3 SATURATION AND CORRESPONDING
111      !        DISSOLOUTION AND PRECIPITATION OF CACO3 (BE AWARE OF
112      !        MGCO3)
113      !     ---------------------------------------------------------
114
115      DO jk = 1, jpkm1
116         DO jj = 1, jpj
117            DO ji = 1, jpi
118
119               ! DEVIATION OF [CO3--] FROM SATURATION VALUE
120               ! Salinity dependance in zomegaca and divide by rhop/1000 to have good units
121               zcalcon  = calcon * ( tsn(ji,jj,jk,jp_sal) / 35._wp )
122               zfact    = rhop(ji,jj,jk) / 1000._wp
123               zomegaca = ( zcalcon * zco3(ji,jj,jk) * zfact ) / aksp(ji,jj,jk) 
124
125               ! SET DEGREE OF UNDER-/SUPERSATURATION
126               excess(ji,jj,jk) = 1._wp - zomegaca
127               zexcess0 = MAX( 0., excess(ji,jj,jk) )
128               zexcess  = zexcess0**nca
129
130               ! AMOUNT CACO3 (12C) THAT RE-ENTERS SOLUTION
131               !       (ACCORDING TO THIS FORMULATION ALSO SOME PARTICULATE
132               !       CACO3 GETS DISSOLVED EVEN IN THE CASE OF OVERSATURATION)
133               zdispot = kdca * zexcess * trn(ji,jj,jk,jpcal)
134# if defined key_degrad
135               zdispot = zdispot * facvol(ji,jj,jk)
136# endif
137              !  CHANGE OF [CO3--] , [ALK], PARTICULATE [CACO3],
138              !       AND [SUM(CO2)] DUE TO CACO3 DISSOLUTION/PRECIPITATION
139              zcaldiss(ji,jj,jk)  = zdispot / rmtss  ! calcite dissolution
140              zco3(ji,jj,jk)      = zco3(ji,jj,jk) + zcaldiss(ji,jj,jk) * rfact
141              !
142              tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + 2. * zcaldiss(ji,jj,jk)
143              tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) -      zcaldiss(ji,jj,jk)
144              tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) +      zcaldiss(ji,jj,jk)
145            END DO
146         END DO
147      END DO
148      !
149      IF( ln_diatrc )  THEN
150         !
151         IF( lk_iomput ) THEN
152            zrfact2 = 1.e3 * rfact2r
153            CALL iom_put( "PH"    , hi      (:,:,:)           * tmask(:,:,:) )
154            CALL iom_put( "CO3"   , zco3    (:,:,:)           * tmask(:,:,:) )
155            CALL iom_put( "CO3sat", aksp    (:,:,:) / calcon  * tmask(:,:,:) )
156            CALL iom_put( "DCAL"  , zcaldiss(:,:,:) * zrfact2 * tmask(:,:,:) )
157         ELSE
158            trc3d(:,:,:,jp_pcs0_3d    ) = hi  (:,:,:)          * tmask(:,:,:)
159            trc3d(:,:,:,jp_pcs0_3d + 1) = zco3(:,:,:)          * tmask(:,:,:)
160            trc3d(:,:,:,jp_pcs0_3d + 2) = aksp(:,:,:) / calcon * tmask(:,:,:)
161         ENDIF
162         !
163      ENDIF
164      !
165       IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
166         WRITE(charout, FMT="('lys ')")
167         CALL prt_ctl_trc_info(charout)
168         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
169       ENDIF
170
171      IF( wrk_not_released(3, 2,3) ) CALL ctl_stop('p4z_lys: failed to release workspace arrays')
172      !
173   END SUBROUTINE p4z_lys
174
175   SUBROUTINE p4z_lys_init
176
177      !!----------------------------------------------------------------------
178      !!                  ***  ROUTINE p4z_lys_init  ***
179      !!
180      !! ** Purpose :   Initialization of CaCO3 dissolution parameters
181      !!
182      !! ** Method  :   Read the nampiscal namelist and check the parameters
183      !!      called at the first timestep (nit000)
184      !!
185      !! ** input   :   Namelist nampiscal
186      !!
187      !!----------------------------------------------------------------------
188
189      NAMELIST/nampiscal/ kdca, nca
190
191      REWIND( numnatp )                     ! read numnatp
192      READ  ( numnatp, nampiscal )
193
194      IF(lwp) THEN                         ! control print
195         WRITE(numout,*) ' '
196         WRITE(numout,*) ' Namelist parameters for CaCO3 dissolution, nampiscal'
197         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
198         WRITE(numout,*) '    diss. rate constant calcite (per month)   kdca      =', kdca
199         WRITE(numout,*) '    order of reaction for calcite dissolution nca       =', nca
200      ENDIF
201
202      ! Number of seconds per month
203      rmtss =  nyear_len(1) * rday / raamo
204
205   END SUBROUTINE p4z_lys_init
206
207#else
208   !!======================================================================
209   !!  Dummy module :                                   No PISCES bio-model
210   !!======================================================================
211CONTAINS
212   SUBROUTINE p4z_lys( kt )                   ! Empty routine
213      INTEGER, INTENT( in ) ::   kt
214      WRITE(*,*) 'p4z_lys: You should not have seen this print! error?', kt
215   END SUBROUTINE p4z_lys
216#endif 
217   !!======================================================================
218END MODULE  p4zlys
Note: See TracBrowser for help on using the repository browser.