New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zmort.F90 in branches/2011/dev_LOCEAN_2011/NEMOGCM/NEMO/TOP_SRC/PISCES – NEMO

source: branches/2011/dev_LOCEAN_2011/NEMOGCM/NEMO/TOP_SRC/PISCES/p4zmort.F90 @ 2977

Last change on this file since 2977 was 2977, checked in by cetlod, 13 years ago

Add in branch 2011/dev_LOCEAN_2011 changes from 2011/dev_r2787_PISCES_improvment, 2011/dev_r2787_LOCEAN_offline_fldread and 2011/dev_r2787_LOCEAN3_TRA_TRP branches, see ticket #877
  • Property svn:keywords set to Id
File size: 11.4 KB
Line 
1MODULE p4zmort
2   !!======================================================================
3   !!                         ***  MODULE p4zmort  ***
4   !! TOP :   PISCES Compute the mortality terms for phytoplankton
5   !!======================================================================
6   !! History :   1.0  !  2002     (O. Aumont)  Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!----------------------------------------------------------------------
9#if defined key_pisces
10   !!----------------------------------------------------------------------
11   !!   'key_pisces'                                       PISCES bio-model
12   !!----------------------------------------------------------------------
13   !!   p4z_mort       :   Compute the mortality terms for phytoplankton
14   !!   p4z_mort_init  :   Initialize the mortality params for phytoplankton
15   !!----------------------------------------------------------------------
16   USE oce_trc         !  shared variables between ocean and passive tracers
17   USE trc             !  passive tracers common variables
18   USE sms_pisces      !  PISCES Source Minus Sink variables
19   USE p4zsink         !  vertical flux of particulate matter due to sinking
20   USE prtctl_trc      !  print control for debugging
21
22   IMPLICIT NONE
23   PRIVATE
24
25   PUBLIC   p4z_mort   
26   PUBLIC   p4z_mort_init   
27   PUBLIC   p4z_mort_alloc   
28
29   !! * Shared module variables
30   REAL(wp), PUBLIC :: wchl   = 0.001_wp  !:
31   REAL(wp), PUBLIC :: wchld  = 0.02_wp   !:
32   REAL(wp), PUBLIC :: mprat  = 0.01_wp   !:
33   REAL(wp), PUBLIC :: mprat2 = 0.01_wp   !:
34   REAL(wp), PUBLIC :: mpratm = 0.01_wp   !:
35
36
37   !!* Substitution
38#  include "top_substitute.h90"
39   !!----------------------------------------------------------------------
40   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
41   !! $Id$
42   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
43   !!----------------------------------------------------------------------
44
45CONTAINS
46
47   SUBROUTINE p4z_mort( kt )
48      !!---------------------------------------------------------------------
49      !!                     ***  ROUTINE p4z_mort  ***
50      !!
51      !! ** Purpose :   Calls the different subroutine to initialize and compute
52      !!                the different phytoplankton mortality terms
53      !!
54      !! ** Method  : - ???
55      !!---------------------------------------------------------------------
56      INTEGER, INTENT(in) ::   kt ! ocean time step
57      !!---------------------------------------------------------------------
58
59      CALL p4z_nano            ! nanophytoplankton
60
61      CALL p4z_diat            ! diatoms
62
63   END SUBROUTINE p4z_mort
64
65
66   SUBROUTINE p4z_nano
67      !!---------------------------------------------------------------------
68      !!                     ***  ROUTINE p4z_nano  ***
69      !!
70      !! ** Purpose :   Compute the mortality terms for nanophytoplankton
71      !!
72      !! ** Method  : - ???
73      !!---------------------------------------------------------------------
74      INTEGER  :: ji, jj, jk
75      REAL(wp) :: zcompaph
76      REAL(wp) :: zfactfe, zfactch, zprcaca, zfracal
77      REAL(wp) :: ztortp , zrespp , zmortp , zstep
78      CHARACTER (len=25) :: charout
79      !!---------------------------------------------------------------------
80
81      prodcal(:,:,:) = 0.  !: calcite production variable set to zero
82      DO jk = 1, jpkm1
83         DO jj = 1, jpj
84            DO ji = 1, jpi
85               zcompaph = MAX( ( trn(ji,jj,jk,jpphy) - 1e-8 ), 0.e0 )
86               zstep    = xstep
87# if defined key_degrad
88               zstep    = zstep * facvol(ji,jj,jk)
89# endif
90               !     Squared mortality of Phyto similar to a sedimentation term during
91               !     blooms (Doney et al. 1996)
92               zrespp = wchl * 1.e6 * zstep * xdiss(ji,jj,jk) * zcompaph * trn(ji,jj,jk,jpphy) 
93
94               !     Phytoplankton mortality. This mortality loss is slightly
95               !     increased when nutrients are limiting phytoplankton growth
96               !     as observed for instance in case of iron limitation.
97               ztortp = mprat * xstep * trn(ji,jj,jk,jpphy) / ( xkmort + trn(ji,jj,jk,jpphy) ) * zcompaph
98
99               zmortp = zrespp + ztortp
100
101               !   Update the arrays TRA which contains the biological sources and sinks
102
103               zfactfe = trn(ji,jj,jk,jpnfe)/(trn(ji,jj,jk,jpphy)+rtrn)
104               zfactch = trn(ji,jj,jk,jpnch)/(trn(ji,jj,jk,jpphy)+rtrn)
105
106               tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) - zmortp
107               tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) - zmortp * zfactch
108               tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) - zmortp * zfactfe
109               zprcaca = xfracal(ji,jj,jk) * zmortp
110               !
111               prodcal(ji,jj,jk) = prodcal(ji,jj,jk) + zprcaca  ! prodcal=prodcal(nanophy)+prodcal(microzoo)+prodcal(mesozoo)
112               !
113               zfracal = 0.5 * xfracal(ji,jj,jk)
114               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprcaca
115               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2. * zprcaca
116               tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) + zprcaca
117#if defined key_kriest
118               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zmortp
119               tra(ji,jj,jk,jpnum) = tra(ji,jj,jk,jpnum) + ztortp * xkr_dnano + zrespp * xkr_ddiat
120               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zmortp * zfactfe
121#else
122               tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) + zfracal * zmortp
123               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + ( 1. - zfracal ) * zmortp
124               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + ( 1. - zfracal ) * zmortp * zfactfe
125               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + zfracal * zmortp * zfactfe
126#endif
127            END DO
128         END DO
129      END DO
130      !
131       IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
132         WRITE(charout, FMT="('nano')")
133         CALL prt_ctl_trc_info(charout)
134         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
135       ENDIF
136
137   END SUBROUTINE p4z_nano
138
139   SUBROUTINE p4z_diat
140      !!---------------------------------------------------------------------
141      !!                     ***  ROUTINE p4z_diat  ***
142      !!
143      !! ** Purpose :   Compute the mortality terms for diatoms
144      !!
145      !! ** Method  : - ???
146      !!---------------------------------------------------------------------
147      INTEGER  ::  ji, jj, jk
148      REAL(wp) ::  zfactfe,zfactsi,zfactch, zcompadi
149      REAL(wp) ::  zrespp2, ztortp2, zmortp2, zstep
150      CHARACTER (len=25) :: charout
151 
152      !!---------------------------------------------------------------------
153
154
155      !    Aggregation term for diatoms is increased in case of nutrient
156      !    stress as observed in reality. The stressed cells become more
157      !    sticky and coagulate to sink quickly out of the euphotic zone
158      !     ------------------------------------------------------------
159
160      DO jk = 1, jpkm1
161         DO jj = 1, jpj
162            DO ji = 1, jpi
163
164               zcompadi = MAX( ( trn(ji,jj,jk,jpdia) - 1e-8), 0. )
165
166               !    Aggregation term for diatoms is increased in case of nutrient
167               !    stress as observed in reality. The stressed cells become more
168               !    sticky and coagulate to sink quickly out of the euphotic zone
169               !     ------------------------------------------------------------
170               zstep   = xstep
171# if defined key_degrad
172               zstep = zstep * facvol(ji,jj,jk)
173# endif
174               !  Phytoplankton respiration
175               !     ------------------------
176               zrespp2  = 1.e6 * zstep * (  wchl + wchld * ( 1.- xlimdia(ji,jj,jk) )  )    &
177                  &       * xdiss(ji,jj,jk) * zcompadi * trn(ji,jj,jk,jpdia)
178
179               !     Phytoplankton mortality.
180               !     ------------------------
181               ztortp2  = mprat2 * zstep * trn(ji,jj,jk,jpdia)  / ( xkmort + trn(ji,jj,jk,jpdia) ) * zcompadi 
182
183               zmortp2 = zrespp2 + ztortp2
184
185               !   Update the arrays tra which contains the biological sources and sinks
186               !   ---------------------------------------------------------------------
187               zfactch = trn(ji,jj,jk,jpdch) / ( trn(ji,jj,jk,jpdia) + rtrn )
188               zfactfe = trn(ji,jj,jk,jpdfe) / ( trn(ji,jj,jk,jpdia) + rtrn )
189               zfactsi = trn(ji,jj,jk,jpbsi) / ( trn(ji,jj,jk,jpdia) + rtrn )
190
191               tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) - zmortp2 
192               tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) - zmortp2 * zfactch
193               tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) - zmortp2 * zfactfe
194               tra(ji,jj,jk,jpbsi) = tra(ji,jj,jk,jpbsi) - zmortp2 * zfactsi
195               tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) + zmortp2 * zfactsi
196#if defined key_kriest
197               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zmortp2 
198               tra(ji,jj,jk,jpnum) = tra(ji,jj,jk,jpnum) + ztortp2 * xkr_ddiat + zrespp2 * xkr_daggr
199               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zmortp2 * zfactfe
200#else
201               tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) + zrespp2 + 0.5 * ztortp2
202               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + 0.5 * ztortp2
203               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + 0.5 * ztortp2 * zfactfe
204               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + ( zrespp2 + 0.5 * ztortp2 ) * zfactfe
205#endif
206            END DO
207         END DO
208      END DO
209      !
210        IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
211         WRITE(charout, FMT="('diat')")
212         CALL prt_ctl_trc_info(charout)
213         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
214       ENDIF
215             
216   END SUBROUTINE p4z_diat
217
218   SUBROUTINE p4z_mort_init
219
220      !!----------------------------------------------------------------------
221      !!                  ***  ROUTINE p4z_mort_init  ***
222      !!
223      !! ** Purpose :   Initialization of phytoplankton parameters
224      !!
225      !! ** Method  :   Read the nampismort namelist and check the parameters
226      !!      called at the first timestep
227      !!
228      !! ** input   :   Namelist nampismort
229      !!
230      !!----------------------------------------------------------------------
231
232      NAMELIST/nampismort/ wchl, wchld, mprat, mprat2, mpratm
233
234      REWIND( numnatp )                     ! read numnatp
235      READ  ( numnatp, nampismort )
236
237      IF(lwp) THEN                         ! control print
238         WRITE(numout,*) ' '
239         WRITE(numout,*) ' Namelist parameters for phytoplankton mortality, nampismort'
240         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
241         WRITE(numout,*) '    quadratic mortality of phytoplankton      wchl      =', wchl
242         WRITE(numout,*) '    maximum quadratic mortality of diatoms    wchld     =', wchld
243         WRITE(numout,*) '    phytoplankton mortality rate              mprat     =', mprat
244         WRITE(numout,*) '    Diatoms mortality rate                    mprat2    =', mprat2
245         WRITE(numout,*) '    Phytoplankton minimum mortality rate      mpratm    =', mpratm
246      ENDIF
247
248   END SUBROUTINE p4z_mort_init
249
250#else
251   !!======================================================================
252   !!  Dummy module :                                   No PISCES bio-model
253   !!======================================================================
254CONTAINS
255   SUBROUTINE p4z_mort                    ! Empty routine
256   END SUBROUTINE p4z_mort
257#endif 
258
259   !!======================================================================
260END MODULE  p4zmort
Note: See TracBrowser for help on using the repository browser.