New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zsink.F90 in branches/2011/dev_LOCEAN_2011/NEMOGCM/NEMO/TOP_SRC/PISCES – NEMO

source: branches/2011/dev_LOCEAN_2011/NEMOGCM/NEMO/TOP_SRC/PISCES/p4zsink.F90 @ 2977

Last change on this file since 2977 was 2977, checked in by cetlod, 13 years ago

Add in branch 2011/dev_LOCEAN_2011 changes from 2011/dev_r2787_PISCES_improvment, 2011/dev_r2787_LOCEAN_offline_fldread and 2011/dev_r2787_LOCEAN3_TRA_TRP branches, see ticket #877
  • Property svn:keywords set to Id
File size: 32.7 KB
Line 
1MODULE p4zsink
2   !!======================================================================
3   !!                         ***  MODULE p4zsink  ***
4   !! TOP :  PISCES  vertical flux of particulate matter due to gravitational sinking
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Change aggregation formula
9   !!----------------------------------------------------------------------
10#if defined key_pisces
11   !!----------------------------------------------------------------------
12   !!   p4z_sink       :  Compute vertical flux of particulate matter due to gravitational sinking
13   !!   p4z_sink_init  :  Unitialisation of sinking speed parameters
14   !!   p4z_sink_alloc :  Allocate sinking speed variables
15   !!----------------------------------------------------------------------
16   USE oce_trc         !  shared variables between ocean and passive tracers
17   USE trc             !  passive tracers common variables
18   USE sms_pisces      !  PISCES Source Minus Sink variables
19   USE prtctl_trc      !  print control for debugging
20   USE iom             !  I/O manager
21
22   IMPLICIT NONE
23   PRIVATE
24
25   PUBLIC   p4z_sink         ! called in p4zbio.F90
26   PUBLIC   p4z_sink_init    ! called in trcsms_pisces.F90
27   PUBLIC   p4z_sink_alloc
28
29   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   wsbio3   !: POC sinking speed
30   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   wsbio4   !: GOC sinking speed
31   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   wscal    !: Calcite and BSi sinking speeds
32
33   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinking, sinking2  !: POC sinking fluxes
34   !                                                          !  (different meanings depending on the parameterization)
35   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinkcal, sinksil   !: CaCO3 and BSi sinking fluxes
36   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinkfer            !: Small BFe sinking fluxes
37#if ! defined key_kriest
38   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinkfer2           !: Big iron sinking fluxes
39#endif
40
41   INTEGER  :: iksed  = 10
42
43#if  defined key_kriest
44   REAL(wp) ::  xkr_sfact    = 250.     !: Sinking factor
45   REAL(wp) ::  xkr_stick    = 0.2      !: Stickiness
46   REAL(wp) ::  xkr_nnano    = 2.337    !: Nbr of cell in nano size class
47   REAL(wp) ::  xkr_ndiat    = 3.718    !: Nbr of cell in diatoms size class
48   REAL(wp) ::  xkr_nmeso    = 7.147    !: Nbr of cell in mesozoo  size class
49   REAL(wp) ::  xkr_naggr    = 9.877    !: Nbr of cell in aggregates  size class
50
51   REAL(wp) ::  xkr_frac 
52
53   REAL(wp), PUBLIC ::  xkr_dnano       !: Size of particles in nano pool
54   REAL(wp), PUBLIC ::  xkr_ddiat       !: Size of particles in diatoms pool
55   REAL(wp), PUBLIC ::  xkr_dmeso       !: Size of particles in mesozoo pool
56   REAL(wp), PUBLIC ::  xkr_daggr       !: Size of particles in aggregates pool
57   REAL(wp), PUBLIC ::  xkr_wsbio_min   !: min vertical particle speed
58   REAL(wp), PUBLIC ::  xkr_wsbio_max   !: max vertical particle speed
59
60   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:) ::   xnumm   !:  maximum number of particles in aggregates
61#endif
62
63   !!* Substitution
64#  include "top_substitute.h90"
65   !!----------------------------------------------------------------------
66   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
67   !! $Id$
68   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
69   !!----------------------------------------------------------------------
70CONTAINS
71
72#if defined key_kriest
73   !!----------------------------------------------------------------------
74   !!   'key_kriest'                                                    ???
75   !!----------------------------------------------------------------------
76
77   SUBROUTINE p4z_sink ( kt, jnt )
78      !!---------------------------------------------------------------------
79      !!                ***  ROUTINE p4z_sink  ***
80      !!
81      !! ** Purpose :   Compute vertical flux of particulate matter due to
82      !!              gravitational sinking - Kriest parameterization
83      !!
84      !! ** Method  : - ???
85      !!---------------------------------------------------------------------
86      USE wrk_nemo, ONLY:   wrk_in_use, wrk_not_released
87      USE wrk_nemo, ONLY:   znum3d => wrk_3d_2
88      !
89      INTEGER, INTENT(in) :: kt, jnt
90      !
91      INTEGER  :: ji, jj, jk
92      REAL(wp) :: zagg1, zagg2, zagg3, zagg4, zagg5, zaggsi, zaggsh
93      REAL(wp) :: zagg , zaggdoc, znumdoc
94      REAL(wp) :: znum , zeps, zfm, zgm, zsm
95      REAL(wp) :: zdiv , zdiv1, zdiv2, zdiv3, zdiv4, zdiv5
96      REAL(wp) :: zval1, zval2, zval3, zval4
97      REAL(wp) :: zrfact2
98      INTEGER  :: ik1
99      CHARACTER (len=25) :: charout
100      !!---------------------------------------------------------------------
101      !
102      IF( wrk_in_use(3, 2 ) ) THEN
103         CALL ctl_stop('p4z_sink: requested workspace arrays unavailable')   ;   RETURN
104      ENDIF
105     
106      !     Initialisation of variables used to compute Sinking Speed
107      !     ---------------------------------------------------------
108
109      znum3d(:,:,:) = 0.e0
110      zval1 = 1. + xkr_zeta
111      zval2 = 1. + xkr_zeta + xkr_eta
112      zval3 = 1. + xkr_eta
113
114      !     Computation of the vertical sinking speed : Kriest et Evans, 2000
115      !     -----------------------------------------------------------------
116
117      DO jk = 1, jpkm1
118         DO jj = 1, jpj
119            DO ji = 1, jpi
120               IF( tmask(ji,jj,jk) /= 0.e0 ) THEN
121                  znum = trn(ji,jj,jk,jppoc) / ( trn(ji,jj,jk,jpnum) + rtrn ) / xkr_massp
122                  ! -------------- To avoid sinking speed over 50 m/day -------
123                  znum  = MIN( xnumm(jk), znum )
124                  znum  = MAX( 1.1      , znum )
125                  znum3d(ji,jj,jk) = znum
126                  !------------------------------------------------------------
127                  zeps  = ( zval1 * znum - 1. )/ ( znum - 1. )
128                  zfm   = xkr_frac**( 1. - zeps )
129                  zgm   = xkr_frac**( zval1 - zeps )
130                  zdiv  = MAX( 1.e-4, ABS( zeps - zval2 ) ) * SIGN( 1., ( zeps - zval2 ) )
131                  zdiv1 = zeps - zval3
132                  wsbio3(ji,jj,jk) = xkr_wsbio_min * ( zeps - zval1 ) / zdiv    &
133                     &             - xkr_wsbio_max *   zgm * xkr_eta  / zdiv
134                  wsbio4(ji,jj,jk) = xkr_wsbio_min *   ( zeps-1. )    / zdiv1   &
135                     &             - xkr_wsbio_max *   zfm * xkr_eta  / zdiv1
136                  IF( znum == 1.1)   wsbio3(ji,jj,jk) = wsbio4(ji,jj,jk)
137               ENDIF
138            END DO
139         END DO
140      END DO
141
142      wscal(:,:,:) = MAX( wsbio3(:,:,:), 50._wp )
143
144      !   INITIALIZE TO ZERO ALL THE SINKING ARRAYS
145      !   -----------------------------------------
146
147      sinking (:,:,:) = 0.e0
148      sinking2(:,:,:) = 0.e0
149      sinkcal (:,:,:) = 0.e0
150      sinkfer (:,:,:) = 0.e0
151      sinksil (:,:,:) = 0.e0
152
153     !   Compute the sedimentation term using p4zsink2 for all the sinking particles
154     !   -----------------------------------------------------
155
156      CALL p4z_sink2( wsbio3, sinking , jppoc )
157      CALL p4z_sink2( wsbio4, sinking2, jpnum )
158      CALL p4z_sink2( wsbio3, sinkfer , jpsfe )
159      CALL p4z_sink2( wscal , sinksil , jpdsi )
160      CALL p4z_sink2( wscal , sinkcal , jpcal )
161
162     !  Exchange between organic matter compartments due to coagulation/disaggregation
163     !  ---------------------------------------------------
164
165      zval1 = 1. + xkr_zeta
166      zval2 = 1. + xkr_eta
167      zval3 = 3. + xkr_eta
168      zval4 = 4. + xkr_eta
169
170      DO jk = 1,jpkm1
171         DO jj = 1,jpj
172            DO ji = 1,jpi
173               IF( tmask(ji,jj,jk) /= 0.e0 ) THEN
174
175                  znum = trn(ji,jj,jk,jppoc)/(trn(ji,jj,jk,jpnum)+rtrn) / xkr_massp
176                  !-------------- To avoid sinking speed over 50 m/day -------
177                  znum  = min(xnumm(jk),znum)
178                  znum  = MAX( 1.1,znum)
179                  !------------------------------------------------------------
180                  zeps  = ( zval1 * znum - 1.) / ( znum - 1.)
181                  zdiv  = MAX( 1.e-4, ABS( zeps - zval3) ) * SIGN( 1., zeps - zval3 )
182                  zdiv1 = MAX( 1.e-4, ABS( zeps - 4.   ) ) * SIGN( 1., zeps - 4.    )
183                  zdiv2 = zeps - 2.
184                  zdiv3 = zeps - 3.
185                  zdiv4 = zeps - zval2
186                  zdiv5 = 2.* zeps - zval4
187                  zfm   = xkr_frac**( 1.- zeps )
188                  zsm   = xkr_frac**xkr_eta
189
190                  !    Part I : Coagulation dependant on turbulence
191                  !    ----------------------------------------------
192
193                  zagg1 = ( 0.163 * trn(ji,jj,jk,jpnum)**2               &
194                     &            * 2.*( (zfm-1.)*(zfm*xkr_mass_max**3-xkr_mass_min**3)    &
195                     &            * (zeps-1)/zdiv1 + 3.*(zfm*xkr_mass_max-xkr_mass_min)    &
196                     &            * (zfm*xkr_mass_max**2-xkr_mass_min**2)                  &
197                     &            * (zeps-1.)**2/(zdiv2*zdiv3)) 
198                  zagg2 =  2*0.163*trn(ji,jj,jk,jpnum)**2*zfm*                       &
199                     &                   ((xkr_mass_max**3+3.*(xkr_mass_max**2          &
200                     &                    *xkr_mass_min*(zeps-1.)/zdiv2                 &
201                     &                    +xkr_mass_max*xkr_mass_min**2*(zeps-1.)/zdiv3)    &
202                     &                    +xkr_mass_min**3*(zeps-1)/zdiv1)                  &
203                     &                    -zfm*xkr_mass_max**3*(1.+3.*((zeps-1.)/           &
204                     &                    (zeps-2.)+(zeps-1.)/zdiv3)+(zeps-1.)/zdiv1))   
205
206                  zagg3 =  0.163*trn(ji,jj,jk,jpnum)**2*zfm**2*8. * xkr_mass_max**3 
207                 
208                 !    Aggregation of small into large particles
209                 !    Part II : Differential settling
210                 !    ----------------------------------------------
211
212                  zagg4 =  2.*3.141*0.125*trn(ji,jj,jk,jpnum)**2*                       &
213                     &                 xkr_wsbio_min*(zeps-1.)**2                         &
214                     &                 *(xkr_mass_min**2*((1.-zsm*zfm)/(zdiv3*zdiv4)      &
215                     &                 -(1.-zfm)/(zdiv*(zeps-1.)))-                       &
216                     &                 ((zfm*zfm*xkr_mass_max**2*zsm-xkr_mass_min**2)     &
217                     &                 *xkr_eta)/(zdiv*zdiv3*zdiv5) )   
218
219                  zagg5 =   2.*3.141*0.125*trn(ji,jj,jk,jpnum)**2                         &
220                     &                 *(zeps-1.)*zfm*xkr_wsbio_min                        &
221                     &                 *(zsm*(xkr_mass_min**2-zfm*xkr_mass_max**2)         &
222                     &                 /zdiv3-(xkr_mass_min**2-zfm*zsm*xkr_mass_max**2)    &
223                     &                 /zdiv) 
224                  zaggsi = ( zagg4 + zagg5 ) * xstep / 10.
225
226                  zagg = 0.5 * xkr_stick * ( zaggsh + zaggsi )
227
228                  !     Aggregation of DOC to small particles
229                  !     --------------------------------------
230
231                  zaggdoc = ( 0.4 * trn(ji,jj,jk,jpdoc)               &
232                     &        + 1018.  * trn(ji,jj,jk,jppoc)  ) * xstep    &
233                     &        * xdiss(ji,jj,jk) * trn(ji,jj,jk,jpdoc)
234
235# if defined key_degrad
236                   zagg1   = zagg1   * facvol(ji,jj,jk)                 
237                   zagg2   = zagg2   * facvol(ji,jj,jk)                 
238                   zagg3   = zagg3   * facvol(ji,jj,jk)                 
239                   zagg4   = zagg4   * facvol(ji,jj,jk)                 
240                   zagg5   = zagg5   * facvol(ji,jj,jk)                 
241                   zaggdoc = zaggdoc * facvol(ji,jj,jk)                 
242# endif
243                  zaggsh = ( zagg1 + zagg2 + zagg3 ) * rfact2 * xdiss(ji,jj,jk) / 1000.
244                  zaggsi = ( zagg4 + zagg5 ) * xstep / 10.
245                  zagg = 0.5 * xkr_stick * ( zaggsh + zaggsi )
246                  !
247                  znumdoc = trn(ji,jj,jk,jpnum) / ( trn(ji,jj,jk,jppoc) + rtrn )
248                  tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zaggdoc
249                  tra(ji,jj,jk,jpnum) = tra(ji,jj,jk,jpnum) + zaggdoc * znumdoc - zagg
250                  tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) - zaggdoc
251
252               ENDIF
253            END DO
254         END DO
255      END DO
256
257      IF( ln_diatrc ) THEN
258         !
259         ik1 = iksed + 1
260         zrfact2 = 1.e3 * rfact2r
261         IF( jnt == nrdttrc ) THEN
262           CALL iom_put( "POCFlx"  , sinking (:,:,:)      * zrfact2 * tmask(:,:,:) )  ! POC export
263           CALL iom_put( "NumFlx"  , sinking2 (:,:,:)     * zrfact2 * tmask(:,:,:) )  ! Num export
264           CALL iom_put( "SiFlx"   , sinksil (:,:,:)      * zrfact2 * tmask(:,:,:) )  ! Silica export
265           CALL iom_put( "CaCO3Flx", sinkcal (:,:,:)      * zrfact2 * tmask(:,:,:) )  ! Calcite export
266           CALL iom_put( "xnum"    , znum3d  (:,:,:)                * tmask(:,:,:) )  ! Number of particles in aggregats
267           CALL iom_put( "W1"      , wsbio3  (:,:,:)                * tmask(:,:,:) )  ! sinking speed of POC
268           CALL iom_put( "W2"      , wsbio4  (:,:,:)                * tmask(:,:,:) )  ! sinking speed of aggregats
269           CALL iom_put( "PMO"     , sinking (:,:,ik1)    * zrfact2 * tmask(:,:,1) )  ! POC export at 100m
270           CALL iom_put( "PMO2"    , sinking2(:,:,ik1)    * zrfact2 * tmask(:,:,1) )  ! Num export at 100m
271           CALL iom_put( "ExpFe1"  , sinkfer (:,:,ik1)    * zrfact2 * tmask(:,:,1) )  ! Export of iron at 100m
272           CALL iom_put( "ExpSi"   , sinksil (:,:,ik1)    * zrfact2 * tmask(:,:,1) )  ! export of silica at 100m
273           CALL iom_put( "ExpCaCO3", sinkcal (:,:,ik1)    * zrfact2 * tmask(:,:,1) )  ! export of calcite at 100m
274         ENDIF
275# if ! defined key_iomput
276         trc2d(:,:  ,jp_pcs0_2d + 4)  = sinking (:,:,ik1)    * zrfact2 * tmask(:,:,1)
277         trc2d(:,:  ,jp_pcs0_2d + 5)  = sinking2(:,:,ik1)    * zrfact2 * tmask(:,:,1)
278         trc2d(:,:  ,jp_pcs0_2d + 6)  = sinkfer (:,:,ik1)    * zrfact2 * tmask(:,:,1)
279         trc2d(:,:  ,jp_pcs0_2d + 7)  = sinksil (:,:,ik1)    * zrfact2 * tmask(:,:,1)
280         trc2d(:,:  ,jp_pcs0_2d + 8)  = sinkcal (:,:,ik1)    * zrfact2 * tmask(:,:,1)
281         trc3d(:,:,:,jp_pcs0_3d + 11) = sinking (:,:,:)      * zrfact2 * tmask(:,:,:)
282         trc3d(:,:,:,jp_pcs0_3d + 12) = sinking2(:,:,:)      * zrfact2 * tmask(:,:,:)
283         trc3d(:,:,:,jp_pcs0_3d + 13) = sinksil (:,:,:)      * zrfact2 * tmask(:,:,:)
284         trc3d(:,:,:,jp_pcs0_3d + 14) = sinkcal (:,:,:)      * zrfact2 * tmask(:,:,:)
285         trc3d(:,:,:,jp_pcs0_3d + 15) = znum3d  (:,:,:)                * tmask(:,:,:)
286         trc3d(:,:,:,jp_pcs0_3d + 16) = wsbio3  (:,:,:)                * tmask(:,:,:)
287         trc3d(:,:,:,jp_pcs0_3d + 17) = wsbio4  (:,:,:)                * tmask(:,:,:)
288# endif
289        !
290      ENDIF
291      !
292      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
293         WRITE(charout, FMT="('sink')")
294         CALL prt_ctl_trc_info(charout)
295         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
296      ENDIF
297      !
298      IF( wrk_not_released(3, 2 ) )   CALL ctl_stop('p4z_sink: failed to release workspace arrays')
299      !
300   END SUBROUTINE p4z_sink
301
302
303   SUBROUTINE p4z_sink_init
304      !!----------------------------------------------------------------------
305      !!                  ***  ROUTINE p4z_sink_init  ***
306      !!
307      !! ** Purpose :   Initialization of sinking parameters
308      !!                Kriest parameterization only
309      !!
310      !! ** Method  :   Read the nampiskrs namelist and check the parameters
311      !!      called at the first timestep
312      !!
313      !! ** input   :   Namelist nampiskrs
314      !!----------------------------------------------------------------------
315      INTEGER  ::   jk, jn, kiter
316      REAL(wp) ::   znum, zdiv
317      REAL(wp) ::   zws, zwr, zwl,wmax, znummax
318      REAL(wp) ::   zmin, zmax, zl, zr, xacc
319      !
320      NAMELIST/nampiskrs/ xkr_sfact, xkr_stick ,  &
321         &                xkr_nnano, xkr_ndiat, xkr_nmeso, xkr_naggr
322      !!----------------------------------------------------------------------
323      !
324      REWIND( numnatp )                     ! read nampiskrs
325      READ  ( numnatp, nampiskrs )
326
327      IF(lwp) THEN
328         WRITE(numout,*)
329         WRITE(numout,*) ' Namelist : nampiskrs'
330         WRITE(numout,*) '    Sinking factor                           xkr_sfact    = ', xkr_sfact
331         WRITE(numout,*) '    Stickiness                               xkr_stick    = ', xkr_stick
332         WRITE(numout,*) '    Nbr of cell in nano size class           xkr_nnano    = ', xkr_nnano
333         WRITE(numout,*) '    Nbr of cell in diatoms size class        xkr_ndiat    = ', xkr_ndiat
334         WRITE(numout,*) '    Nbr of cell in mesozoo size class        xkr_nmeso    = ', xkr_nmeso
335         WRITE(numout,*) '    Nbr of cell in aggregates size class     xkr_naggr    = ', xkr_naggr
336      ENDIF
337
338
339      ! max and min vertical particle speed
340      xkr_wsbio_min = xkr_sfact * xkr_mass_min**xkr_eta
341      xkr_wsbio_max = xkr_sfact * xkr_mass_max**xkr_eta
342      WRITE(numout,*) ' max and min vertical particle speed ', xkr_wsbio_min, xkr_wsbio_max
343
344      !
345      !    effect of the sizes of the different living pools on particle numbers
346      !    nano = 2um-20um -> mean size=6.32 um -> ws=2.596 -> xnum=xnnano=2.337
347      !    diat and microzoo = 10um-200um -> 44.7 -> 8.732 -> xnum=xndiat=3.718
348      !    mesozoo = 200um-2mm -> 632.45 -> 45.14 -> xnum=xnmeso=7.147
349      !    aggregates = 200um-10mm -> 1414 -> 74.34 -> xnum=xnaggr=9.877
350      !    doc aggregates = 1um
351      ! ----------------------------------------------------------
352
353      xkr_dnano = 1. / ( xkr_massp * xkr_nnano )
354      xkr_ddiat = 1. / ( xkr_massp * xkr_ndiat )
355      xkr_dmeso = 1. / ( xkr_massp * xkr_nmeso )
356      xkr_daggr = 1. / ( xkr_massp * xkr_naggr )
357
358      !!---------------------------------------------------------------------
359      !!    'key_kriest'                                                  ???
360      !!---------------------------------------------------------------------
361      !  COMPUTATION OF THE VERTICAL PROFILE OF MAXIMUM SINKING SPEED
362      !  Search of the maximum number of particles in aggregates for each k-level.
363      !  Bissection Method
364      !--------------------------------------------------------------------
365      WRITE(numout,*)
366      WRITE(numout,*)'    kriest : Compute maximum number of particles in aggregates'
367
368      xacc     =  0.001_wp
369      kiter    = 50
370      zmin     =  1.10_wp
371      zmax     = xkr_mass_max / xkr_mass_min
372      xkr_frac = zmax
373
374      DO jk = 1,jpk
375         zl = zmin
376         zr = zmax
377         wmax = 0.5 * fse3t(1,1,jk) * rday / rfact2
378         zdiv = xkr_zeta + xkr_eta - xkr_eta * zl
379         znum = zl - 1.
380         zwl =  xkr_wsbio_min * xkr_zeta / zdiv &
381            & - ( xkr_wsbio_max * xkr_eta * znum * &
382            &     xkr_frac**( -xkr_zeta / znum ) / zdiv ) &
383            & - wmax
384
385         zdiv = xkr_zeta + xkr_eta - xkr_eta * zr
386         znum = zr - 1.
387         zwr =  xkr_wsbio_min * xkr_zeta / zdiv &
388            & - ( xkr_wsbio_max * xkr_eta * znum * &
389            &     xkr_frac**( -xkr_zeta / znum ) / zdiv ) &
390            & - wmax
391iflag:   DO jn = 1, kiter
392            IF    ( zwl == 0._wp ) THEN   ;   znummax = zl
393            ELSEIF( zwr == 0._wp ) THEN   ;   znummax = zr
394            ELSE
395               znummax = ( zr + zl ) / 2.
396               zdiv = xkr_zeta + xkr_eta - xkr_eta * znummax
397               znum = znummax - 1.
398               zws =  xkr_wsbio_min * xkr_zeta / zdiv &
399                  & - ( xkr_wsbio_max * xkr_eta * znum * &
400                  &     xkr_frac**( -xkr_zeta / znum ) / zdiv ) &
401                  & - wmax
402               IF( zws * zwl < 0. ) THEN   ;   zr = znummax
403               ELSE                        ;   zl = znummax
404               ENDIF
405               zdiv = xkr_zeta + xkr_eta - xkr_eta * zl
406               znum = zl - 1.
407               zwl =  xkr_wsbio_min * xkr_zeta / zdiv &
408                  & - ( xkr_wsbio_max * xkr_eta * znum * &
409                  &     xkr_frac**( -xkr_zeta / znum ) / zdiv ) &
410                  & - wmax
411
412               zdiv = xkr_zeta + xkr_eta - xkr_eta * zr
413               znum = zr - 1.
414               zwr =  xkr_wsbio_min * xkr_zeta / zdiv &
415                  & - ( xkr_wsbio_max * xkr_eta * znum * &
416                  &     xkr_frac**( -xkr_zeta / znum ) / zdiv ) &
417                  & - wmax
418               !
419               IF ( ABS ( zws )  <= xacc ) EXIT iflag
420               !
421            ENDIF
422            !
423         END DO iflag
424
425         xnumm(jk) = znummax
426         WRITE(numout,*) '       jk = ', jk, ' wmax = ', wmax,' xnum max = ', xnumm(jk)
427         !
428      END DO
429      !
430  END SUBROUTINE p4z_sink_init
431
432#else
433
434   SUBROUTINE p4z_sink ( kt, jnt )
435      !!---------------------------------------------------------------------
436      !!                     ***  ROUTINE p4z_sink  ***
437      !!
438      !! ** Purpose :   Compute vertical flux of particulate matter due to
439      !!                gravitational sinking
440      !!
441      !! ** Method  : - ???
442      !!---------------------------------------------------------------------
443      INTEGER, INTENT(in) :: kt, jnt
444      INTEGER  ::   ji, jj, jk
445      REAL(wp) ::   zagg1, zagg2, zagg3, zagg4
446      REAL(wp) ::   zagg , zaggfe, zaggdoc, zaggdoc2, zaggdoc3
447      REAL(wp) ::   zfact, zwsmax, zmax, zstep
448      REAL(wp) ::   zrfact2
449      INTEGER  ::   ik1
450      CHARACTER (len=25) :: charout
451      !!---------------------------------------------------------------------
452
453      !    Sinking speeds of detritus is increased with depth as shown
454      !    by data and from the coagulation theory
455      !    -----------------------------------------------------------
456      DO jk = 1, jpkm1
457         DO jj = 1, jpj
458            DO ji = 1,jpi
459               zmax  = MAX( heup(ji,jj), hmld(ji,jj) )
460               zfact = MAX( 0., fsdepw(ji,jj,jk+1) - zmax ) / 5000._wp
461               wsbio4(ji,jj,jk) = wsbio2 + ( 200.- wsbio2 ) * zfact
462            END DO
463         END DO
464      END DO
465
466      ! limit the values of the sinking speeds to avoid numerical instabilities 
467      wsbio3(:,:,:) = wsbio
468      !
469      ! OA Below, this is garbage. the ideal would be to find a time-splitting
470      ! OA algorithm that does not increase the computing cost by too much
471      ! OA In ROMS, I have included a time-splitting procedure. But it is
472      ! OA too expensive as the loop is computed globally. Thus, a small e3t
473      ! OA at one place determines the number of subtimesteps globally
474      ! OA AWFULLY EXPENSIVE !! Not able to find a better approach. Damned !!
475
476      DO jk = 1,jpkm1
477         DO jj = 1, jpj
478            DO ji = 1, jpi
479               zwsmax = 0.8 * fse3t(ji,jj,jk) / xstep
480               wsbio4(ji,jj,jk) = MIN( wsbio4(ji,jj,jk), zwsmax )
481               wsbio3(ji,jj,jk) = MIN( wsbio3(ji,jj,jk), zwsmax )
482            END DO
483         END DO
484      END DO
485
486      wscal(:,:,:) = wsbio4(:,:,:)
487
488      !  Initializa to zero all the sinking arrays
489      !   -----------------------------------------
490
491      sinking (:,:,:) = 0.e0
492      sinking2(:,:,:) = 0.e0
493      sinkcal (:,:,:) = 0.e0
494      sinkfer (:,:,:) = 0.e0
495      sinksil (:,:,:) = 0.e0
496      sinkfer2(:,:,:) = 0.e0
497
498      !   Compute the sedimentation term using p4zsink2 for all the sinking particles
499      !   -----------------------------------------------------
500
501      CALL p4z_sink2( wsbio3, sinking , jppoc )
502      CALL p4z_sink2( wsbio3, sinkfer , jpsfe )
503      CALL p4z_sink2( wsbio4, sinking2, jpgoc )
504      CALL p4z_sink2( wsbio4, sinkfer2, jpbfe )
505      CALL p4z_sink2( wsbio4, sinksil , jpdsi )
506      CALL p4z_sink2( wscal , sinkcal , jpcal )
507
508      !  Exchange between organic matter compartments due to coagulation/disaggregation
509      !  ---------------------------------------------------
510
511      DO jk = 1, jpkm1
512         DO jj = 1, jpj
513            DO ji = 1, jpi
514               !
515               zstep = xstep 
516# if defined key_degrad
517               zstep = zstep * facvol(ji,jj,jk)
518# endif
519               zfact = zstep * xdiss(ji,jj,jk)
520               !  Part I : Coagulation dependent on turbulence
521               zagg1 = 354.  * zfact * trn(ji,jj,jk,jppoc) * trn(ji,jj,jk,jppoc)
522               zagg2 = 4452. * zfact * trn(ji,jj,jk,jppoc) * trn(ji,jj,jk,jpgoc)
523
524               ! Part II : Differential settling
525
526               !  Aggregation of small into large particles
527               zagg3 =  4.7 * zstep * trn(ji,jj,jk,jppoc) * trn(ji,jj,jk,jpgoc)
528               zagg4 =  0.4 * zstep * trn(ji,jj,jk,jppoc) * trn(ji,jj,jk,jppoc)
529
530               zagg   = zagg1 + zagg2 + zagg3 + zagg4
531               zaggfe = zagg * trn(ji,jj,jk,jpsfe) / ( trn(ji,jj,jk,jppoc) + rtrn )
532
533               ! Aggregation of DOC to small particles
534               zaggdoc  = ( 0.83 * trn(ji,jj,jk,jpdoc) + 271. * trn(ji,jj,jk,jppoc) ) * zfact * trn(ji,jj,jk,jpdoc)
535               zaggdoc2 = 1.07e4 * zfact * trn(ji,jj,jk,jpgoc) * trn(ji,jj,jk,jpdoc)
536               zaggdoc3 =   0.02 * ( 16706. * trn(ji,jj,jk,jppoc) + 231. * trn(ji,jj,jk,jpdoc) ) * zstep * trn(ji,jj,jk,jpdoc)
537
538               !  Update the trends
539               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) - zagg + zaggdoc + zaggdoc3
540               tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) + zagg + zaggdoc2
541               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) - zaggfe
542               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + zaggfe
543               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) - zaggdoc - zaggdoc2 - zaggdoc3
544               !
545            END DO
546         END DO
547      END DO
548
549      IF( ln_diatrc ) THEN
550         zrfact2 = 1.e3 * rfact2r
551         ik1  = iksed + 1
552         IF( lk_iomput ) THEN
553           IF( jnt == nrdttrc ) THEN
554              CALL iom_put( "EPC100"  , ( sinking(:,:,ik1) + sinking2(:,:,ik1) ) * zrfact2 * tmask(:,:,1) ) ! Export of carbon at 100m
555              CALL iom_put( "EPFE100" , ( sinkfer(:,:,ik1) + sinkfer2(:,:,ik1) ) * zrfact2 * tmask(:,:,1) ) ! Export of iron at 100m
556              CALL iom_put( "EPCAL100",   sinkcal(:,:,ik1)                       * zrfact2 * tmask(:,:,1) ) ! Export of calcite  at 100m
557              CALL iom_put( "EPSI100" ,   sinksil(:,:,ik1)                       * zrfact2 * tmask(:,:,1) ) ! Export of biogenic silica at 100m
558           ENDIF
559         ELSE
560           trc2d(:,:,jp_pcs0_2d + 4) = sinking (:,:,ik1) * zrfact2 * tmask(:,:,1)
561           trc2d(:,:,jp_pcs0_2d + 5) = sinking2(:,:,ik1) * zrfact2 * tmask(:,:,1)
562           trc2d(:,:,jp_pcs0_2d + 6) = sinkfer (:,:,ik1) * zrfact2 * tmask(:,:,1)
563           trc2d(:,:,jp_pcs0_2d + 7) = sinkfer2(:,:,ik1) * zrfact2 * tmask(:,:,1)
564           trc2d(:,:,jp_pcs0_2d + 8) = sinksil (:,:,ik1) * zrfact2 * tmask(:,:,1)
565           trc2d(:,:,jp_pcs0_2d + 9) = sinkcal (:,:,ik1) * zrfact2 * tmask(:,:,1)
566         ENDIF
567      ENDIF
568      !
569      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
570         WRITE(charout, FMT="('sink')")
571         CALL prt_ctl_trc_info(charout)
572         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
573      ENDIF
574      !
575   END SUBROUTINE p4z_sink
576
577   SUBROUTINE p4z_sink_init
578      !!----------------------------------------------------------------------
579      !!                  ***  ROUTINE p4z_sink_init  ***
580      !!----------------------------------------------------------------------
581   END SUBROUTINE p4z_sink_init
582
583#endif
584
585
586
587   SUBROUTINE p4z_sink2( pwsink, psinkflx, jp_tra )
588      !!---------------------------------------------------------------------
589      !!                     ***  ROUTINE p4z_sink2  ***
590      !!
591      !! ** Purpose :   Compute the sedimentation terms for the various sinking
592      !!     particles. The scheme used to compute the trends is based
593      !!     on MUSCL.
594      !!
595      !! ** Method  : - this ROUTINE compute not exactly the advection but the
596      !!      transport term, i.e.  div(u*tra).
597      !!---------------------------------------------------------------------
598      USE wrk_nemo, ONLY: wrk_in_use, wrk_not_released
599      USE wrk_nemo, ONLY: ztraz => wrk_3d_2, zakz => wrk_3d_3, zwsink2 => wrk_3d_4
600      !
601      INTEGER , INTENT(in   )                         ::   jp_tra    ! tracer index index     
602      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj,jpk) ::   pwsink    ! sinking speed
603      REAL(wp), INTENT(inout), DIMENSION(jpi,jpj,jpk) ::   psinkflx  ! sinking fluxe
604      !!
605      INTEGER  ::   ji, jj, jk, jn
606      REAL(wp) ::   zigma,zew,zign, zflx, zstep
607      !!---------------------------------------------------------------------
608
609      IF(  wrk_in_use(3, 2,3,4 ) ) THEN
610         CALL ctl_stop('p4z_sink2: requested workspace arrays unavailable')
611         RETURN
612      END IF
613
614      zstep = rfact2 / 2.
615
616      ztraz(:,:,:) = 0.e0
617      zakz (:,:,:) = 0.e0
618
619      DO jk = 1, jpkm1
620         zwsink2(:,:,jk+1) = -pwsink(:,:,jk) / rday * tmask(:,:,jk+1) 
621      END DO
622      zwsink2(:,:,1) = 0.e0
623      IF( lk_degrad ) THEN
624         zwsink2(:,:,:) = zwsink2(:,:,:) * facvol(:,:,:)
625      ENDIF
626
627
628      ! Vertical advective flux
629      DO jn = 1, 2
630         !  first guess of the slopes interior values
631         DO jk = 2, jpkm1
632            ztraz(:,:,jk) = ( trn(:,:,jk-1,jp_tra) - trn(:,:,jk,jp_tra) ) * tmask(:,:,jk)
633         END DO
634         ztraz(:,:,1  ) = 0.0
635         ztraz(:,:,jpk) = 0.0
636
637         ! slopes
638         DO jk = 2, jpkm1
639            DO jj = 1,jpj
640               DO ji = 1, jpi
641                  zign = 0.25 + SIGN( 0.25, ztraz(ji,jj,jk) * ztraz(ji,jj,jk+1) )
642                  zakz(ji,jj,jk) = ( ztraz(ji,jj,jk) + ztraz(ji,jj,jk+1) ) * zign
643               END DO
644            END DO
645         END DO
646         
647         ! Slopes limitation
648         DO jk = 2, jpkm1
649            DO jj = 1, jpj
650               DO ji = 1, jpi
651                  zakz(ji,jj,jk) = SIGN( 1., zakz(ji,jj,jk) ) *        &
652                     &             MIN( ABS( zakz(ji,jj,jk) ), 2. * ABS(ztraz(ji,jj,jk+1)), 2. * ABS(ztraz(ji,jj,jk) ) )
653               END DO
654            END DO
655         END DO
656         
657         ! vertical advective flux
658         DO jk = 1, jpkm1
659            DO jj = 1, jpj     
660               DO ji = 1, jpi   
661                  zigma = zwsink2(ji,jj,jk+1) * zstep / fse3w(ji,jj,jk+1)
662                  zew   = zwsink2(ji,jj,jk+1)
663                  psinkflx(ji,jj,jk+1) = -zew * ( trn(ji,jj,jk,jp_tra) - 0.5 * ( 1 + zigma ) * zakz(ji,jj,jk) ) * zstep
664               END DO
665            END DO
666         END DO
667         !
668         ! Boundary conditions
669         psinkflx(:,:,1  ) = 0.e0
670         psinkflx(:,:,jpk) = 0.e0
671         
672         DO jk=1,jpkm1
673            DO jj = 1,jpj
674               DO ji = 1, jpi
675                  zflx = ( psinkflx(ji,jj,jk) - psinkflx(ji,jj,jk+1) ) / fse3t(ji,jj,jk)
676                  trn(ji,jj,jk,jp_tra) = trn(ji,jj,jk,jp_tra) + zflx
677               END DO
678            END DO
679         END DO
680
681      ENDDO
682
683      DO jk=1,jpkm1
684         DO jj = 1,jpj
685            DO ji = 1, jpi
686               zflx = ( psinkflx(ji,jj,jk) - psinkflx(ji,jj,jk+1) ) / fse3t(ji,jj,jk)
687               trb(ji,jj,jk,jp_tra) = trb(ji,jj,jk,jp_tra) + 2. * zflx
688            END DO
689         END DO
690      END DO
691
692      trn     (:,:,:,jp_tra) = trb(:,:,:,jp_tra)
693      psinkflx(:,:,:)        = 2. * psinkflx(:,:,:)
694      !
695      IF( wrk_not_released(3, 2,3,4) )   CALL ctl_stop('p4z_sink2: failed to release workspace arrays')
696      !
697   END SUBROUTINE p4z_sink2
698
699
700   INTEGER FUNCTION p4z_sink_alloc()
701      !!----------------------------------------------------------------------
702      !!                     ***  ROUTINE p4z_sink_alloc  ***
703      !!----------------------------------------------------------------------
704      ALLOCATE( wsbio3 (jpi,jpj,jpk) , wsbio4  (jpi,jpj,jpk) , wscal(jpi,jpj,jpk) ,     &
705         &      sinking(jpi,jpj,jpk) , sinking2(jpi,jpj,jpk)                      ,     &               
706         &      sinkcal(jpi,jpj,jpk) , sinksil (jpi,jpj,jpk)                      ,     &               
707#if defined key_kriest
708         &      xnumm(jpk)                                                        ,     &               
709#else
710         &      sinkfer2(jpi,jpj,jpk)                                             ,     &               
711#endif
712         &      sinkfer(jpi,jpj,jpk)                                              , STAT=p4z_sink_alloc )               
713         !
714      IF( p4z_sink_alloc /= 0 ) CALL ctl_warn('p4z_sink_alloc : failed to allocate arrays.')
715      !
716   END FUNCTION p4z_sink_alloc
717   
718#else
719   !!======================================================================
720   !!  Dummy module :                                   No PISCES bio-model
721   !!======================================================================
722CONTAINS
723   SUBROUTINE p4z_sink                    ! Empty routine
724   END SUBROUTINE p4z_sink
725#endif 
726
727   !!======================================================================
728END MODULE  p4zsink
Note: See TracBrowser for help on using the repository browser.