New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcini.F90 in branches/2011/dev_LOCEAN_2011/NEMOGCM/NEMO/TOP_SRC – NEMO

source: branches/2011/dev_LOCEAN_2011/NEMOGCM/NEMO/TOP_SRC/trcini.F90 @ 2977

Last change on this file since 2977 was 2977, checked in by cetlod, 13 years ago

Add in branch 2011/dev_LOCEAN_2011 changes from 2011/dev_r2787_PISCES_improvment, 2011/dev_r2787_LOCEAN_offline_fldread and 2011/dev_r2787_LOCEAN3_TRA_TRP branches, see ticket #877
  • Property svn:keywords set to Id
File size: 9.1 KB
Line 
1MODULE trcini
2   !!======================================================================
3   !!                         ***  MODULE trcini  ***
4   !! TOP :   Manage the passive tracer initialization
5   !!======================================================================
6   !! History :   -   ! 1991-03 (O. Marti)  original code
7   !!            1.0  ! 2005-03 (O. Aumont, A. El Moussaoui) F90
8   !!            2.0  ! 2005-10 (C. Ethe, G. Madec) revised architecture
9   !!            4.0  ! 2011-01 (A. R. Porter, STFC Daresbury) dynamical allocation
10   !!----------------------------------------------------------------------
11#if defined key_top
12   !!----------------------------------------------------------------------
13   !!   'key_top'                                                TOP models
14   !!----------------------------------------------------------------------
15   !!   trc_init  :   Initialization for passive tracer
16   !!   top_alloc :   allocate the TOP arrays
17   !!----------------------------------------------------------------------
18   USE oce_trc         ! shared variables between ocean and passive tracers
19   USE trc             ! passive tracers common variables
20   USE trcrst          ! passive tracers restart
21   USE trcnam          ! Namelist read
22   USE trcini_cfc      ! CFC      initialisation
23   USE trcini_lobster  ! LOBSTER  initialisation
24   USE trcini_pisces   ! PISCES   initialisation
25   USE trcini_c14b     ! C14 bomb initialisation
26   USE trcini_my_trc   ! MY_TRC   initialisation
27   USE trcdta          ! initialisation form files
28   USE daymod          ! calendar manager
29   USE zpshde          ! partial step: hor. derivative   (zps_hde routine)
30   USE prtctl_trc      ! Print control passive tracers (prt_ctl_trc_init routine)
31   
32   IMPLICIT NONE
33   PRIVATE
34   
35   PUBLIC   trc_init   ! called by opa
36
37    !! * Substitutions
38#  include "domzgr_substitute.h90"
39   !!----------------------------------------------------------------------
40   !! NEMO/TOP 4.0 , NEMO Consortium (2011)
41   !! $Id$
42   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
43   !!----------------------------------------------------------------------
44CONTAINS
45   
46   SUBROUTINE trc_init
47      !!---------------------------------------------------------------------
48      !!                     ***  ROUTINE trc_init  ***
49      !!
50      !! ** Purpose :   Initialization of the passive tracer fields
51      !!
52      !! ** Method  : - read namelist
53      !!              - control the consistancy
54      !!              - compute specific initialisations
55      !!              - set initial tracer fields (either read restart
56      !!                or read data or analytical formulation
57      !!---------------------------------------------------------------------
58      INTEGER ::   jk, jn, jl    ! dummy loop indices
59      INTEGER ::   ierr          ! local integer
60      CHARACTER (len=25) :: charout
61      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:,:) ::  ztrcdta   ! 4D  workspace
62      !!---------------------------------------------------------------------
63
64      IF(lwp) WRITE(numout,*)
65      IF(lwp) WRITE(numout,*) 'trc_init : initial set up of the passive tracers'
66      IF(lwp) WRITE(numout,*) '~~~~~~~'
67
68      CALL top_alloc()              ! allocate TOP arrays
69
70      IF( ln_dm2dc .AND. ( lk_pisces .OR. lk_lobster ) )    &
71         &  CALL ctl_stop( ' The diurnal cycle is not compatible with PISCES or LOBSTER  ' )
72
73      IF( nn_cla == 1 )   &
74         &  CALL ctl_stop( ' Cross Land Advection not yet implemented with passive tracer ; nn_cla must be 0' )
75
76      CALL trc_nam                  ! read passive tracers namelists
77
78      IF( lk_lobster ) THEN   ;   CALL trc_ini_lobster      ! LOBSTER bio-model
79      ELSE                    ;   IF(lwp) WRITE(numout,*) '          LOBSTER not used'
80      ENDIF
81     
82      IF( lk_pisces  ) THEN   ;   CALL trc_ini_pisces       ! PISCES  bio-model
83      ELSE                    ;   IF(lwp) WRITE(numout,*) '          PISCES not used'
84      ENDIF
85     
86      IF( lk_cfc     ) THEN   ;   CALL trc_ini_cfc          ! CFC     tracers
87      ELSE                    ;   IF(lwp) WRITE(numout,*) '          CFC not used'
88      ENDIF
89
90      IF( lk_c14b    ) THEN   ;   CALL trc_ini_c14b         ! C14 bomb  tracer
91      ELSE                    ;   IF(lwp) WRITE(numout,*) '          C14 not used'
92      ENDIF
93     
94      IF( lk_my_trc  ) THEN   ;   CALL trc_ini_my_trc       ! MY_TRC  tracers
95      ELSE                    ;   IF(lwp) WRITE(numout,*) '          MY_TRC not used'
96      ENDIF
97
98      IF( ln_trcdta )             CALL trc_dta_init
99
100      IF( ln_rsttr ) THEN
101        !
102        IF( lk_offline )  neuler = 1   ! Set time-step indicator at nit000 (leap-frog)
103        CALL trc_rst_read              ! restart from a file
104        !
105      ELSE
106        IF( lk_offline )  THEN
107           neuler = 0                  ! Set time-step indicator at nit000 (euler)
108           CALL day_init               ! set calendar
109        ENDIF
110        IF( ln_trcdta .AND. nb_trcdta > 0 ) THEN  ! Initialisation of tracer from a file that may also be used for damping
111            ALLOCATE( ztrcdta(jpi,jpj,jpk,nb_trcdta), STAT=ierr )
112            IF( ierr > 0 ) THEN
113               CALL ctl_stop( 'trc_ini: unable to allocate ztrcdta array' )   ;   RETURN
114            ENDIF
115            !
116            CALL trc_dta( nit000, ztrcdta )   ! read tracer data at nit000
117            !
118            DO jn = 1, jptra
119               IF( ln_trc_ini(jn) ) THEN      ! update passive tracers arrays with input data read from file
120                  jl = n_trc_index(jn) 
121                  trn(:,:,:,jn) = ztrcdta(:,:,:,jl) * tmask(:,:,:) 
122               ENDIF
123            ENDDO
124            DEALLOCATE( ztrcdta ) 
125        ENDIF
126        !
127        trb(:,:,:,:) = trn(:,:,:,:)
128        !
129      ENDIF
130 
131      tra(:,:,:,:) = 0._wp
132     
133      IF( ln_zps .AND. .NOT. lk_c1d )   &              ! Partial steps: before horizontal gradient of passive
134        &    CALL zps_hde( nit000, jptra, trn, gtru, gtrv )       ! tracers at the bottom ocean level
135
136      !                                                              ! masked grid volume
137      DO jk = 1, jpk
138         cvol(:,:,jk) = e1e2t(:,:) * fse3t(:,:,jk) * tmask(:,:,jk)
139      END DO
140      IF( lk_degrad ) cvol(:,:,:) = cvol(:,:,:) * facvol(:,:,:)      ! degrad option: reduction by facvol
141      !                                                              ! total volume of the ocean
142      areatot = glob_sum( cvol(:,:,:) )
143
144      trai(:) = 0._wp                                                   ! initial content of all tracers
145      DO jn = 1, jptra
146         trai(jn) = trai(jn) + glob_sum( trn(:,:,:,jn) * cvol(:,:,:)   )
147      END DO
148
149      IF(lwp) THEN               ! control print
150         WRITE(numout,*)
151         WRITE(numout,*)
152         WRITE(numout,*) '          *** Total number of passive tracer jptra = ', jptra
153         WRITE(numout,*) '          *** Total volume of ocean                = ', areatot
154         WRITE(numout,*) '          *** Total inital content of all tracers '
155         DO jn = 1, jptra
156            WRITE(numout,*) ' tracer nb : ', jn, '  name : ', ctrcnm(jn), ' initial content :', trai(jn)
157         ENDDO
158         WRITE(numout,*)
159      ENDIF
160
161      IF(ln_ctl) THEN            ! print mean trends (used for debugging)
162         CALL prt_ctl_trc_init
163         WRITE(charout, FMT="('ini ')")
164         CALL prt_ctl_trc_info( charout )
165         CALL prt_ctl_trc( tab4d=trn, mask=tmask, clinfo=ctrcnm )
166      ENDIF
167      !
168   END SUBROUTINE trc_init
169
170
171   SUBROUTINE top_alloc
172      !!----------------------------------------------------------------------
173      !!                     ***  ROUTINE top_alloc  ***
174      !!
175      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
176      !!----------------------------------------------------------------------
177      USE trcadv        , ONLY:   trc_adv_alloc          ! TOP-related alloc routines...
178      USE trc           , ONLY:   trc_alloc
179      USE trcnxt        , ONLY:   trc_nxt_alloc
180      USE trczdf        , ONLY:   trc_zdf_alloc
181      USE trdmod_trc_oce, ONLY:   trd_mod_trc_oce_alloc
182#if defined key_trdmld_trc 
183      USE trdmld_trc    , ONLY:   trd_mld_trc_alloc
184#endif
185      !
186      INTEGER :: ierr
187      !!----------------------------------------------------------------------
188      !
189      ierr =        trc_adv_alloc()          ! Start of TOP-related alloc routines...
190      ierr = ierr + trc_alloc    ()
191      ierr = ierr + trc_nxt_alloc()
192      ierr = ierr + trc_zdf_alloc()
193      ierr = ierr + trd_mod_trc_oce_alloc()
194#if defined key_trdmld_trc 
195      ierr = ierr + trd_mld_trc_alloc()
196#endif
197      !
198      IF( lk_mpp    )   CALL mpp_sum( ierr )
199      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'top_alloc : unable to allocate standard ocean arrays' )
200      !
201   END SUBROUTINE top_alloc
202
203#else
204   !!----------------------------------------------------------------------
205   !!  Empty module :                                     No passive tracer
206   !!----------------------------------------------------------------------
207CONTAINS
208   SUBROUTINE trc_init                      ! Dummy routine   
209   END SUBROUTINE trc_init
210#endif
211
212   !!======================================================================
213END MODULE trcini
Note: See TracBrowser for help on using the repository browser.