1 | MODULE iom_ioipsl |
---|
2 | !!===================================================================== |
---|
3 | !! *** MODULE iom_ioipsl *** |
---|
4 | !! Input/Output manager : Library to read input files with IOIPSL (only fliocom module) |
---|
5 | !!==================================================================== |
---|
6 | !! History : 9.0 ! 05 12 (J. Belier) Original code |
---|
7 | !! 9.0 ! 06 02 (S. Masson) Adaptation to NEMO |
---|
8 | !! " ! 07 07 (D. Storkey) Changes to iom_ioipsl_gettime |
---|
9 | !!-------------------------------------------------------------------- |
---|
10 | !!gm caution add !DIR nec: improved performance to be checked as well as no result changes |
---|
11 | |
---|
12 | !!-------------------------------------------------------------------- |
---|
13 | !! iom_open : open a file read only |
---|
14 | !! iom_close : close a file or all files opened by iom |
---|
15 | !! iom_get : read a field (interfaced to several routines) |
---|
16 | !! iom_gettime : read the time axis kvid in the file |
---|
17 | !! iom_varid : get the id of a variable in a file |
---|
18 | !! iom_rstput : write a field in a restart file (interfaced to several routines) |
---|
19 | !!-------------------------------------------------------------------- |
---|
20 | USE dom_oce ! ocean space and time domain |
---|
21 | USE iom_def ! iom variables definitions |
---|
22 | USE ioipsl ! IOIPSL library |
---|
23 | USE in_out_manager ! I/O manager |
---|
24 | USE lib_mpp ! MPP library |
---|
25 | |
---|
26 | IMPLICIT NONE |
---|
27 | PRIVATE |
---|
28 | |
---|
29 | PUBLIC iom_ioipsl_open, iom_ioipsl_close, iom_ioipsl_varid, iom_ioipsl_get, iom_ioipsl_gettime, iom_ioipsl_rstput |
---|
30 | |
---|
31 | INTERFACE iom_ioipsl_get |
---|
32 | MODULE PROCEDURE iom_ioipsl_g0d, iom_ioipsl_g123d |
---|
33 | END INTERFACE |
---|
34 | INTERFACE iom_ioipsl_rstput |
---|
35 | MODULE PROCEDURE iom_ioipsl_rp0123d |
---|
36 | END INTERFACE |
---|
37 | !!---------------------------------------------------------------------- |
---|
38 | !! NEMO/OPA 3.3 , NEMO Consortium (2010) |
---|
39 | !! $Id$ |
---|
40 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
---|
41 | !!---------------------------------------------------------------------- |
---|
42 | |
---|
43 | CONTAINS |
---|
44 | |
---|
45 | SUBROUTINE iom_ioipsl_open( cdname, kiomid, ldwrt, ldok, kdompar ) |
---|
46 | !!--------------------------------------------------------------------- |
---|
47 | !! *** SUBROUTINE iom_open *** |
---|
48 | !! |
---|
49 | !! ** Purpose : open an input file with IOIPSL (only fliocom module) |
---|
50 | !!--------------------------------------------------------------------- |
---|
51 | CHARACTER(len=*) , INTENT(inout) :: cdname ! File name |
---|
52 | INTEGER , INTENT( out) :: kiomid ! ioipsl identifier of the opened file |
---|
53 | LOGICAL , INTENT(in ) :: ldwrt ! read or write the file? |
---|
54 | LOGICAL , INTENT(in ) :: ldok ! check the existence |
---|
55 | INTEGER, DIMENSION(2,5), INTENT(in ), OPTIONAL :: kdompar ! domain parameters: |
---|
56 | |
---|
57 | CHARACTER(LEN=100) :: clinfo ! info character |
---|
58 | CHARACTER(LEN=10 ) :: clstatus ! status of opened file (REPLACE or NEW) |
---|
59 | INTEGER :: iln ! lengths of character |
---|
60 | INTEGER :: istop ! temporary storage of nstop |
---|
61 | INTEGER :: ifliodom ! model domain identifier (see flio_dom_set) |
---|
62 | INTEGER :: ioipslid ! ioipsl identifier of the opened file |
---|
63 | INTEGER :: jl ! loop variable |
---|
64 | LOGICAL :: llclobber ! local definition of ln_clobber |
---|
65 | !--------------------------------------------------------------------- |
---|
66 | |
---|
67 | clinfo = ' iom_ioipsl_open ~~~ ' |
---|
68 | istop = nstop |
---|
69 | ! |
---|
70 | llclobber = ldwrt .AND. ln_clobber |
---|
71 | IF( ldok .AND. .NOT. llclobber ) THEN ! Open existing file... |
---|
72 | ! ! ============= |
---|
73 | IF( ldwrt ) THEN ! ... in write mode |
---|
74 | IF(lwp) WRITE(numout,*) TRIM(clinfo)//' open existing file: '//TRIM(cdname)//' in WRITE mode' |
---|
75 | CALL flioopfd( TRIM(cdname), ioipslid, "WRITE" ) |
---|
76 | ELSE ! ... in read mode |
---|
77 | IF(lwp) WRITE(numout,*) TRIM(clinfo)//' open existing file: '//TRIM(cdname)//' in READ mode' |
---|
78 | CALL flioopfd( TRIM(cdname), ioipslid ) |
---|
79 | ENDIF |
---|
80 | ELSE ! the file does not exist |
---|
81 | ! ! ============= |
---|
82 | iln = INDEX( cdname, '.nc' ) |
---|
83 | IF( ldwrt ) THEN ! the file should be open in write mode so we create it... |
---|
84 | IF( llclobber ) THEN ; clstatus = 'REPLACE 64' |
---|
85 | ELSE ; clstatus = 'NEW 64' |
---|
86 | ENDIF |
---|
87 | IF( jpnij > 1 ) THEN |
---|
88 | ! define the domain position regarding to the global domain (mainly useful in mpp) |
---|
89 | CALL flio_dom_set( jpnij, narea-1, (/1, 2/), (/jpiglo, jpjglo/) & |
---|
90 | & , kdompar(:,1), kdompar(:,2), kdompar(:,3), kdompar(:,4), kdompar(:,5) & |
---|
91 | & , 'BOX', ifliodom ) |
---|
92 | ! Note that fliocrfd may change the value of cdname (add the cpu number...) |
---|
93 | IF(lwp) WRITE(numout,*) TRIM(clinfo)//' create new file: '//cdname(1:iln-1)//'... in WRITE mode' |
---|
94 | CALL fliocrfd( cdname, (/'x' , 'y' , 'z', 't'/) & |
---|
95 | & , (/kdompar(1,1), kdompar(2,1), jpk, -1 /), ioipslid, ifliodom, mode = clstatus ) |
---|
96 | ELSE ! the file should be open for read mode so it must exist... |
---|
97 | IF(lwp) WRITE(numout,*) TRIM(clinfo)//' create new file: '//cdname//' in WRITE mode' |
---|
98 | CALL fliocrfd( cdname, (/'x' , 'y' , 'z', 't'/) & |
---|
99 | & , (/kdompar(1,1), kdompar(2,1), jpk, -1 /), ioipslid, mode = clstatus ) |
---|
100 | ENDIF |
---|
101 | ELSE ! the file should be open for read mode so it must exist... |
---|
102 | CALL ctl_stop( TRIM(clinfo), ' should be impossible case...' ) |
---|
103 | ENDIF |
---|
104 | ENDIF |
---|
105 | ! start to fill file informations |
---|
106 | ! ============= |
---|
107 | IF( istop == nstop ) THEN ! no error within this routine |
---|
108 | !does not work with some compilers kiomid = MINLOC(iom_file(:)%nfid, dim = 1) |
---|
109 | kiomid = 0 |
---|
110 | DO jl = jpmax_files, 1, -1 |
---|
111 | IF( iom_file(jl)%nfid == 0 ) kiomid = jl |
---|
112 | ENDDO |
---|
113 | iom_file(kiomid)%name = TRIM(cdname) |
---|
114 | iom_file(kiomid)%nfid = ioipslid |
---|
115 | iom_file(kiomid)%iolib = jpioipsl |
---|
116 | iom_file(kiomid)%nvars = 0 |
---|
117 | iom_file(kiomid)%irec = -1 ! useless for NetCDF files |
---|
118 | CALL flioinqf( ioipslid, id_uld = iom_file(kiomid)%iduld ) |
---|
119 | IF(lwp) WRITE(numout,*) ' ---> '//TRIM(cdname)//' OK' |
---|
120 | ELSE |
---|
121 | kiomid = 0 ! return error flag |
---|
122 | ENDIF |
---|
123 | ! |
---|
124 | END SUBROUTINE iom_ioipsl_open |
---|
125 | |
---|
126 | |
---|
127 | SUBROUTINE iom_ioipsl_close( kiomid ) |
---|
128 | !!-------------------------------------------------------------------- |
---|
129 | !! *** SUBROUTINE iom_ioipsl_close *** |
---|
130 | !! |
---|
131 | !! ** Purpose : close an input file with IOIPSL (only fliocom module) |
---|
132 | !!-------------------------------------------------------------------- |
---|
133 | INTEGER, INTENT(in) :: kiomid ! iom identifier of the file to be closed |
---|
134 | !--------------------------------------------------------------------- |
---|
135 | ! |
---|
136 | CALL flioclo( iom_file(kiomid)%nfid ) |
---|
137 | ! |
---|
138 | END SUBROUTINE iom_ioipsl_close |
---|
139 | |
---|
140 | |
---|
141 | FUNCTION iom_ioipsl_varid ( kiomid, cdvar, kiv, kdimsz ) |
---|
142 | !!----------------------------------------------------------------------- |
---|
143 | !! *** FUNCTION iom_varid *** |
---|
144 | !! |
---|
145 | !! ** Purpose : get the id of a variable in a file with IOIPSL (only fliocom module) |
---|
146 | !!----------------------------------------------------------------------- |
---|
147 | INTEGER , INTENT(in ) :: kiomid ! file Identifier |
---|
148 | CHARACTER(len=*) , INTENT(in ) :: cdvar ! name of the variable |
---|
149 | INTEGER , INTENT(in ) :: kiv ! |
---|
150 | INTEGER, DIMENSION(:), INTENT( out), OPTIONAL :: kdimsz ! size of the dimensions |
---|
151 | ! |
---|
152 | INTEGER :: iom_ioipsl_varid ! iom variable Id |
---|
153 | INTEGER :: ioipslid ! ioipsl file identifier |
---|
154 | INTEGER :: ji ! dummy loop index |
---|
155 | INTEGER :: i_nvd ! number of dimension of the variable |
---|
156 | INTEGER, DIMENSION(jpmax_dims) :: idimid ! dimension ids of the variable |
---|
157 | LOGICAL :: ll_fnd ! found test |
---|
158 | CHARACTER(LEN=100) :: clinfo ! info character |
---|
159 | !!----------------------------------------------------------------------- |
---|
160 | clinfo = 'iom_ioipsl_varid, file: '//trim(iom_file(kiomid)%name)//', var: '//trim(cdvar) |
---|
161 | iom_ioipsl_varid = 0 ! default definition |
---|
162 | IF( PRESENT(kdimsz) ) kdimsz(:) = 0 ! default definition |
---|
163 | ioipslid = iom_file(kiomid)%nfid ! get back ioipsl file identifier |
---|
164 | CALL flioinqv( ioipslid, cdvar, ll_fnd, nb_dims = i_nvd ) ! does the variable exist in the file |
---|
165 | IF( ll_fnd ) THEN |
---|
166 | IF( i_nvd <= jpmax_dims ) THEN |
---|
167 | iom_ioipsl_varid = kiv |
---|
168 | iom_file(kiomid)%nvars = kiv |
---|
169 | iom_file(kiomid)%nvid(kiv) = -1 ! variable id is not available in ioipsl |
---|
170 | iom_file(kiomid)%cn_var(kiv) = TRIM(cdvar) |
---|
171 | iom_file(kiomid)%ndims(kiv) = i_nvd |
---|
172 | CALL flioinqv( ioipslid, cdvar, ll_fnd, & |
---|
173 | & len_dims = iom_file(kiomid)%dimsz(1:i_nvd,kiv), & ! dimensions size |
---|
174 | & id_dims = idimid(1:i_nvd) ) ! dimensions ids |
---|
175 | iom_file(kiomid)%luld(kiv) = .FALSE. ! default value |
---|
176 | DO ji = 1, i_nvd ! find the unlimited dimension |
---|
177 | IF( idimid(ji) == iom_file(kiomid)%iduld ) iom_file(kiomid)%luld(kiv) = .TRUE. |
---|
178 | END DO |
---|
179 | !---------- Deal with scale_factor and add_offset |
---|
180 | CALL flioinqa( ioipslid, cdvar, 'scale_factor', ll_fnd ) |
---|
181 | IF( ll_fnd) THEN |
---|
182 | CALL fliogeta( ioipslid, cdvar, 'scale_factor', iom_file(kiomid)%scf(kiv) ) |
---|
183 | ELSE |
---|
184 | iom_file(kiomid)%scf(kiv) = 1. |
---|
185 | END IF |
---|
186 | CALL flioinqa( ioipslid, cdvar, 'add_offset', ll_fnd ) |
---|
187 | IF( ll_fnd ) THEN |
---|
188 | CALL fliogeta( ioipslid, cdvar, 'add_offset', iom_file(kiomid)%ofs(kiv) ) |
---|
189 | ELSE |
---|
190 | iom_file(kiomid)%ofs(kiv) = 0. |
---|
191 | END IF |
---|
192 | ! return the simension size |
---|
193 | IF( PRESENT(kdimsz) ) THEN |
---|
194 | IF( i_nvd == SIZE(kdimsz) ) THEN |
---|
195 | kdimsz(:) = iom_file(kiomid)%dimsz(1:i_nvd,kiv) |
---|
196 | ELSE |
---|
197 | WRITE(ctmp1,*) i_nvd, SIZE(kdimsz) |
---|
198 | CALL ctl_stop( TRIM(clinfo), 'error in kdimsz size'//TRIM(ctmp1) ) |
---|
199 | ENDIF |
---|
200 | ENDIF |
---|
201 | ELSE |
---|
202 | CALL ctl_stop( TRIM(clinfo), 'Too many dimensions in the file '//iom_file(kiomid)%name, & |
---|
203 | & 'increase the parameter jpmax_vars') |
---|
204 | ENDIF |
---|
205 | ELSE |
---|
206 | iom_ioipsl_varid = -1 ! variable not found, return error code: -1 |
---|
207 | ENDIF |
---|
208 | ! |
---|
209 | END FUNCTION iom_ioipsl_varid |
---|
210 | |
---|
211 | |
---|
212 | SUBROUTINE iom_ioipsl_g0d( kiomid, kvid, pvar ) |
---|
213 | !!----------------------------------------------------------------------- |
---|
214 | !! *** ROUTINE iom_ioipsl_g0d *** |
---|
215 | !! |
---|
216 | !! ** Purpose : read a scalar with IOIPSL (only fliocom module) |
---|
217 | !!----------------------------------------------------------------------- |
---|
218 | INTEGER , INTENT(in ) :: kiomid ! Identifier of the file |
---|
219 | INTEGER , INTENT(in ) :: kvid ! variable id |
---|
220 | REAL(wp), INTENT( out) :: pvar ! read field |
---|
221 | ! |
---|
222 | CALL fliogetv( iom_file(kiomid)%nfid, TRIM(iom_file(kiomid)%cn_var(kvid)), pvar ) |
---|
223 | ! |
---|
224 | END SUBROUTINE iom_ioipsl_g0d |
---|
225 | |
---|
226 | |
---|
227 | SUBROUTINE iom_ioipsl_g123d( kiomid, kvid, knbdim, kstart, kcount, kx1, kx2, ky1, ky2, & |
---|
228 | & pv_r1d, pv_r2d, pv_r3d) |
---|
229 | !!----------------------------------------------------------------------- |
---|
230 | !! *** ROUTINE iom_ioipsl_g123d *** |
---|
231 | !! |
---|
232 | !! ** Purpose : read a 1D/2D/3D variable with IOIPSL (only fliocom module) |
---|
233 | !! |
---|
234 | !! ** Method : read ONE record at each CALL |
---|
235 | !!----------------------------------------------------------------------- |
---|
236 | INTEGER , INTENT(in ) :: kiomid ! iom identifier of the file |
---|
237 | INTEGER , INTENT(in ) :: kvid ! Name of the variable |
---|
238 | INTEGER , INTENT(in ) :: knbdim ! number of dimensions of the variable |
---|
239 | INTEGER , DIMENSION(:) , INTENT(in ) :: kstart ! start position of the reading in each axis |
---|
240 | INTEGER , DIMENSION(:) , INTENT(in ) :: kcount ! number of points to be read in each axis |
---|
241 | INTEGER , INTENT(in ) :: kx1, kx2, ky1, ky2 ! subdomain indexes |
---|
242 | REAL(wp), DIMENSION(:) , INTENT( out), OPTIONAL :: pv_r1d ! read field (1D case) |
---|
243 | REAL(wp), DIMENSION(:,:) , INTENT( out), OPTIONAL :: pv_r2d ! read field (2D case) |
---|
244 | REAL(wp), DIMENSION(:,:,:) , INTENT( out), OPTIONAL :: pv_r3d ! read field (3D case) |
---|
245 | ! |
---|
246 | INTEGER :: ioipslid ! ioipsl file identifier |
---|
247 | CHARACTER(LEN=100) :: clvn ! variable name |
---|
248 | !--------------------------------------------------------------------- |
---|
249 | clvn = TRIM(iom_file(kiomid)%cn_var(kvid)) ! get back variable name |
---|
250 | ioipslid = iom_file(kiomid)%nfid ! get back IPIPSL file id |
---|
251 | ! |
---|
252 | IF( PRESENT(pv_r1d) ) THEN |
---|
253 | CALL fliogetv( ioipslid, clvn, pv_r1d(: ), start = kstart(1:knbdim), count = kcount(1:knbdim) ) |
---|
254 | ELSEIF( PRESENT(pv_r2d) ) THEN |
---|
255 | CALL fliogetv( ioipslid, clvn, pv_r2d(kx1:kx2,ky1:ky2 ), start = kstart(1:knbdim), count = kcount(1:knbdim) ) |
---|
256 | ELSEIF( PRESENT(pv_r3d) ) THEN |
---|
257 | CALL fliogetv( ioipslid, clvn, pv_r3d(kx1:kx2,ky1:ky2,:), start = kstart(1:knbdim), count = kcount(1:knbdim) ) |
---|
258 | ENDIF |
---|
259 | ! |
---|
260 | ! |
---|
261 | END SUBROUTINE iom_ioipsl_g123d |
---|
262 | |
---|
263 | |
---|
264 | SUBROUTINE iom_ioipsl_gettime( kiomid, kvid, ptime, cdunits, cdcalendar ) |
---|
265 | !!-------------------------------------------------------------------- |
---|
266 | !! *** SUBROUTINE iom_gettime *** |
---|
267 | !! |
---|
268 | !! ** Purpose : read the time axis kvid in the file with IOIPSL (only fliocom module) |
---|
269 | !!-------------------------------------------------------------------- |
---|
270 | INTEGER , INTENT(in ) :: kiomid ! file Identifier |
---|
271 | INTEGER , INTENT(in ) :: kvid ! variable id |
---|
272 | REAL(wp), DIMENSION(:) , INTENT( out) :: ptime ! the time axis |
---|
273 | CHARACTER(len=*), OPTIONAL, INTENT( out) :: cdunits ! units attribute |
---|
274 | CHARACTER(len=*), OPTIONAL, INTENT( out) :: cdcalendar ! calendar attribute |
---|
275 | !--------------------------------------------------------------------- |
---|
276 | ! |
---|
277 | CALL fliogetv( iom_file(kiomid)%nfid, TRIM(iom_file(kiomid)%cn_var(kvid)), ptime(:), & |
---|
278 | & start=(/ 1 /), count=(/ iom_file(kiomid)%dimsz(1, kvid) /) ) |
---|
279 | IF ( PRESENT(cdunits) ) THEN |
---|
280 | CALL fliogeta( iom_file(kiomid)%nfid, TRIM(iom_file(kiomid)%cn_var(kvid)), "units", cdunits ) |
---|
281 | ENDIF |
---|
282 | IF ( PRESENT(cdcalendar) ) THEN |
---|
283 | CALL fliogeta( iom_file(kiomid)%nfid, TRIM(iom_file(kiomid)%cn_var(kvid)), "calendar", cdcalendar ) |
---|
284 | ENDIF |
---|
285 | ! |
---|
286 | END SUBROUTINE iom_ioipsl_gettime |
---|
287 | |
---|
288 | |
---|
289 | SUBROUTINE iom_ioipsl_rp0123d( kt, kwrite, kiomid, cdvar , kvid , ktype, & |
---|
290 | & pv_r0d, pv_r1d, pv_r2d, pv_r3d ) |
---|
291 | !!-------------------------------------------------------------------- |
---|
292 | !! *** SUBROUTINE iom_ioipsl_rstput *** |
---|
293 | !! |
---|
294 | !! ** Purpose : read the time axis cdvar in the file |
---|
295 | !!-------------------------------------------------------------------- |
---|
296 | INTEGER , INTENT(in) :: kt ! ocean time-step |
---|
297 | INTEGER , INTENT(in) :: kwrite ! writing time-step |
---|
298 | INTEGER , INTENT(in) :: kiomid ! Identifier of the file |
---|
299 | CHARACTER(len=*) , INTENT(in) :: cdvar ! variable name |
---|
300 | INTEGER , INTENT(in) :: kvid ! variable id |
---|
301 | INTEGER , INTENT(in), OPTIONAL :: ktype ! variable type (default R8) |
---|
302 | REAL(wp) , INTENT(in), OPTIONAL :: pv_r0d ! written Od field |
---|
303 | REAL(wp), DIMENSION( :), INTENT(in), OPTIONAL :: pv_r1d ! written 1d field |
---|
304 | REAL(wp), DIMENSION(:, : ), INTENT(in), OPTIONAL :: pv_r2d ! written 2d field |
---|
305 | REAL(wp), DIMENSION(:, :, :), INTENT(in), OPTIONAL :: pv_r3d ! written 3d field |
---|
306 | ! |
---|
307 | INTEGER :: idims ! number of dimension |
---|
308 | INTEGER :: idvar ! variable id |
---|
309 | INTEGER :: itype ! variable type |
---|
310 | INTEGER :: ix1, ix2, iy1, iy2 ! subdomain indexes |
---|
311 | INTEGER, DIMENSION(4) :: idimsz ! dimensions size |
---|
312 | INTEGER, DIMENSION(4) :: idimid ! dimensions id |
---|
313 | CHARACTER(LEN=100) :: clinfo ! info character |
---|
314 | INTEGER :: ioipslid ! ioipsl file identifier |
---|
315 | !--------------------------------------------------------------------- |
---|
316 | ! |
---|
317 | clinfo = ' iom_ioipsl_rp0123d, file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(cdvar) |
---|
318 | ioipslid = iom_file(kiomid)%nfid |
---|
319 | ! |
---|
320 | ! define dimension variables if it is not already done |
---|
321 | ! ========================== |
---|
322 | IF( iom_file(kiomid)%nvars == 0 ) THEN |
---|
323 | ! define the dimension variables if it is not already done |
---|
324 | CALL fliodefv( ioipslid,'nav_lon', (/1,2/), v_t=flio_r4 , axis='X', & |
---|
325 | & long_name="Longitude", units="degrees_east" ) |
---|
326 | CALL fliodefv( ioipslid,'nav_lat', (/1,2/), v_t=flio_r4 , axis='Y', & |
---|
327 | & long_name="Latitude", units="degrees_north" ) |
---|
328 | CALL fliodefv( ioipslid,'nav_lev', (/3/) , v_t=flio_i4 , axis='Z', & |
---|
329 | & long_name="Model levels",units="model_levels") |
---|
330 | CALL fliodefv( ioipslid,'time_counter', (/4/), v_t=flio_r4, axis='T', & |
---|
331 | & long_name="Time axis", units='seconds since 0001-01-01 00:00:00' ) |
---|
332 | ! update informations structure related the dimension variable we just added... |
---|
333 | iom_file(kiomid)%nvars = 4 |
---|
334 | iom_file(kiomid)%luld(1:4) = (/ .FALSE., .FALSE., .FALSE., .TRUE. /) |
---|
335 | iom_file(kiomid)%cn_var(1:3) = (/ 'nav_lon', 'nav_lat', 'nav_lev' /) |
---|
336 | iom_file(kiomid)%cn_var(4) = 'time_counter' |
---|
337 | iom_file(kiomid)%ndims(1:4) = (/ 2, 2, 1, 1 /) |
---|
338 | ! trick: defined to 0 to say that dimension variables are defined but not yet written |
---|
339 | iom_file(kiomid)%dimsz(1, 1) = 0 |
---|
340 | IF(lwp) WRITE(numout,*) TRIM(clinfo)//' define dimension variables done' |
---|
341 | ENDIF |
---|
342 | |
---|
343 | ! define the data if it is not already done |
---|
344 | ! =============== |
---|
345 | IF( kvid <= 0 ) THEN |
---|
346 | ! variable definition |
---|
347 | IF( PRESENT(pv_r0d) ) THEN ; idims = 0 |
---|
348 | ELSEIF( PRESENT(pv_r1d) ) THEN ; idims = 2 ; idimid(1:idims) = (/ 3,4/) |
---|
349 | ELSEIF( PRESENT(pv_r2d) ) THEN ; idims = 3 ; idimid(1:idims) = (/1,2 ,4/) |
---|
350 | ELSEIF( PRESENT(pv_r3d) ) THEN ; idims = 4 ; idimid(1:idims) = (/1,2,3,4/) |
---|
351 | ENDIF |
---|
352 | IF( PRESENT(ktype) ) THEN ! variable external type |
---|
353 | SELECT CASE (ktype) |
---|
354 | CASE (jp_r8) ; itype = flio_r8 |
---|
355 | CASE (jp_r4) ; itype = flio_r4 |
---|
356 | CASE (jp_i4) ; itype = flio_i4 |
---|
357 | CASE (jp_i2) ; itype = flio_i2 |
---|
358 | CASE (jp_i1) ; itype = flio_i1 ! fliocom does not handle i1 type of variable |
---|
359 | CASE DEFAULT ; CALL ctl_stop( TRIM(clinfo)//' unknown variable type' ) |
---|
360 | END SELECT |
---|
361 | ELSE |
---|
362 | itype = flio_r8 |
---|
363 | ENDIF |
---|
364 | IF( PRESENT(pv_r0d) ) THEN ; CALL fliodefv (ioipslid, TRIM(cdvar) , v_t = itype) |
---|
365 | ELSE ; CALL fliodefv (ioipslid, TRIM(cdvar), idimid(1:idims), v_t = itype) |
---|
366 | ENDIF |
---|
367 | ! update informations structure related the new variable we want to add... |
---|
368 | idvar = iom_file(kiomid)%nvars + 1 |
---|
369 | iom_file(kiomid)%nvars = idvar |
---|
370 | iom_file(kiomid)%cn_var(idvar) = TRIM(cdvar) |
---|
371 | iom_file(kiomid)%nvid(idvar) = -1 ! netcdf variable id is not available in ioipsl |
---|
372 | iom_file(kiomid)%scf(idvar) = 1. |
---|
373 | iom_file(kiomid)%ofs(idvar) = 0. |
---|
374 | iom_file(kiomid)%ndims(idvar) = idims |
---|
375 | IF( .NOT. PRESENT(pv_r0d) ) THEN |
---|
376 | iom_file(kiomid)%luld(idvar) = .TRUE. |
---|
377 | CALL flioinqf( ioipslid, ln_dim = idimsz ) |
---|
378 | iom_file(kiomid)%dimsz(1:idims-1,idvar) = idimsz(idimid(1:idims-1)) |
---|
379 | ELSE |
---|
380 | iom_file(kiomid)%luld(idvar) = .FALSE. |
---|
381 | ENDIF |
---|
382 | IF(lwp) WRITE(numout,*) TRIM(clinfo)//' defined ok' |
---|
383 | ELSE |
---|
384 | idvar = kvid |
---|
385 | ENDIF |
---|
386 | |
---|
387 | ! time step kwrite : write the variable |
---|
388 | IF( kt == kwrite ) THEN |
---|
389 | ! on what kind of domain must the data be written? |
---|
390 | IF( PRESENT(pv_r2d) .OR. PRESENT(pv_r3d) ) THEN |
---|
391 | idimsz(1:2) = iom_file(kiomid)%dimsz(1:2,idvar) |
---|
392 | IF( idimsz(1) == (nlei - nldi + 1) .AND. idimsz(2) == (nlej - nldj + 1) ) THEN |
---|
393 | ix1 = nldi ; ix2 = nlei ; iy1 = nldj ; iy2 = nlej |
---|
394 | ELSEIF( idimsz(1) == nlci .AND. idimsz(2) == nlcj ) THEN |
---|
395 | ix1 = 1 ; ix2 = nlci ; iy1 = 1 ; iy2 = nlcj |
---|
396 | ELSEIF( idimsz(1) == jpi .AND. idimsz(2) == jpj ) THEN |
---|
397 | ix1 = 1 ; ix2 = jpi ; iy1 = 1 ; iy2 = jpj |
---|
398 | ELSE |
---|
399 | CALL ctl_stop( 'iom_ioipsl_rp0123d: should have been an impossible case...' ) |
---|
400 | ENDIF |
---|
401 | |
---|
402 | ! write dimension variables if it is not already done |
---|
403 | ! ============= |
---|
404 | ! trick: is defined to 0 => dimension variable are defined but not yet written |
---|
405 | IF( iom_file(kiomid)%dimsz(1, 1) == 0 ) THEN |
---|
406 | CALL flioputv( ioipslid, 'nav_lon' , glamt(ix1:ix2, iy1:iy2) ) |
---|
407 | CALL flioputv( ioipslid, 'nav_lat' , gphit(ix1:ix2, iy1:iy2) ) |
---|
408 | CALL flioputv( ioipslid, 'nav_lev' , gdept_0 ) |
---|
409 | ! +++ WRONG VALUE: to be improved but not really useful... |
---|
410 | CALL flioputv( ioipslid, 'time_counter', kt ) |
---|
411 | ! update the values of the variables dimensions size |
---|
412 | CALL flioinqf( ioipslid, ln_dim = idimsz ) |
---|
413 | iom_file(kiomid)%dimsz(1:2, 1) = idimsz(1:2) |
---|
414 | iom_file(kiomid)%dimsz(1:2, 2) = idimsz(1:2) |
---|
415 | iom_file(kiomid)%dimsz(1, 3:4) = (/idimsz(3), 1/) |
---|
416 | IF(lwp) WRITE(numout,*) TRIM(clinfo)//' write dimension variables done' |
---|
417 | ENDIF |
---|
418 | ENDIF |
---|
419 | |
---|
420 | ! write the data |
---|
421 | ! ============= |
---|
422 | IF( PRESENT(pv_r0d) ) THEN ; CALL flioputv( ioipslid, cdvar, pv_r0d ) |
---|
423 | ELSEIF( PRESENT(pv_r1d) ) THEN ; CALL flioputv( ioipslid, cdvar, pv_r1d( :) ) |
---|
424 | ELSEIF( PRESENT(pv_r2d) ) THEN ; CALL flioputv( ioipslid, cdvar, pv_r2d(ix1:ix2, iy1:iy2 ) ) |
---|
425 | ELSEIF( PRESENT(pv_r3d) ) THEN ; CALL flioputv( ioipslid, cdvar, pv_r3d(ix1:ix2, iy1:iy2, :) ) |
---|
426 | ENDIF |
---|
427 | ! add 1 to the size of the temporal dimension (not really useful...) |
---|
428 | IF( iom_file(kiomid)%luld(idvar) ) iom_file(kiomid)%dimsz(iom_file(kiomid)%ndims(idvar), idvar) & |
---|
429 | & = iom_file(kiomid)%dimsz(iom_file(kiomid)%ndims(idvar), idvar) + 1 |
---|
430 | IF(lwp) WRITE(numout,*) TRIM(clinfo)//' written ok' |
---|
431 | ENDIF |
---|
432 | ! |
---|
433 | END SUBROUTINE iom_ioipsl_rp0123d |
---|
434 | |
---|
435 | |
---|
436 | !!====================================================================== |
---|
437 | END MODULE iom_ioipsl |
---|