New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dtatsd.F90 in branches/2011/dev_NEMO_MERGE_2011/NEMOGCM/NEMO/OPA_SRC/DOM – NEMO

source: branches/2011/dev_NEMO_MERGE_2011/NEMOGCM/NEMO/OPA_SRC/DOM/dtatsd.F90 @ 3140

Last change on this file since 3140 was 3132, checked in by cetlod, 13 years ago

dev_NEMO_MERGE_2011: Move dtatsd from DTA to DOM and suppress the sub-dir DTA since it contains no other module
File size: 15.2 KB
Line 
1MODULE dtatsd
2   !!======================================================================
3   !!                     ***  MODULE  dtatsd  ***
4   !! Ocean data  :  read ocean Temperature & Salinity Data from gridded data
5   !!======================================================================
6   !! History :  OPA  ! 1991-03  ()  Original code
7   !!             -   ! 1992-07  (M. Imbard)
8   !!            8.0  ! 1999-10  (M.A. Foujols, M. Imbard)  NetCDF FORMAT
9   !!   NEMO     1.0  ! 2002-06  (G. Madec)  F90: Free form and module
10   !!            3.3  ! 2010-10  (C. Bricaud, S. Masson)  use of fldread
11   !!            3.4  ! 2010-11  (G. Madec, C. Ethe) Merge of dtatem and dtasal + suppression of CPP keys
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   dta_tsd      : read and time interpolated ocean Temperature & Salinity Data
16   !!----------------------------------------------------------------------
17   USE oce             ! ocean dynamics and tracers
18   USE dom_oce         ! ocean space and time domain
19   USE fldread         ! read input fields
20   USE in_out_manager  ! I/O manager
21   USE phycst          ! physical constants
22   USE lib_mpp         ! MPP library
23
24   IMPLICIT NONE
25   PRIVATE
26
27   PUBLIC   dta_tsd_init   ! called by opa.F90
28   PUBLIC   dta_tsd        ! called by istate.F90 and tradmp.90
29
30   LOGICAL , PUBLIC ::   ln_tsd_init   = .FALSE.    !: T & S data flag
31   LOGICAL , PUBLIC ::   ln_tsd_tradmp = .FALSE.    !: internal damping toward input data flag
32
33   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_tsd   ! structure of input SST (file informations, fields read)
34
35   !! * Substitutions
36#  include "domzgr_substitute.h90"
37   !!----------------------------------------------------------------------
38   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
39   !! $Id: dtatem.F90 2392 2010-11-15 21:20:05Z gm $
40   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
41   !!----------------------------------------------------------------------
42CONTAINS
43
44   SUBROUTINE dta_tsd_init( ld_tradmp )
45      !!----------------------------------------------------------------------
46      !!                   ***  ROUTINE dta_tsd_init  ***
47      !!                   
48      !! ** Purpose :   initialisation of T & S input data
49      !!
50      !! ** Method  : - Read namtsd namelist
51      !!              - allocates T & S data structure
52      !!----------------------------------------------------------------------
53      LOGICAL, INTENT(in), OPTIONAL ::   ld_tradmp   ! force the initialization when tradp is used
54      !
55      INTEGER ::   ierr0, ierr1, ierr2, ierr3   ! temporary integers
56      !
57      CHARACTER(len=100)            ::   cn_dir          ! Root directory for location of ssr files
58      TYPE(FLD_N), DIMENSION( jpts) ::   slf_i           ! array of namelist informations on the fields to read
59      TYPE(FLD_N)                   ::   sn_tem, sn_sal
60      !!
61      NAMELIST/namtsd/   ln_tsd_init, ln_tsd_tradmp, cn_dir, sn_tem, sn_sal
62      !!----------------------------------------------------------------------
63 
64      !                             ! set default namelist values
65      cn_dir = './'                       ! directory in which the model is executed
66      !                                   ! sn_... default values (NB: frequency positive => hours, negative => months)
67      !            !   file    ! frequency ! variable  ! time intep !  clim   ! 'yearly' or ! weights  ! rotation !
68      !            !   name    !  (hours)  !  name     !   (T/F)    !  (T/F)  !  'monthly'  ! filename ! pairs    !
69      sn_tem = FLD_N( 'temperature',  -1.  , 'votemper',  .false.   , .true.  ,  'monthly'  , ''       , ''       )
70      sn_sal = FLD_N( 'salinity'   ,  -1.  , 'vosaline',  .false.   , .true.  ,  'monthly'  , ''       , ''       )
71
72      REWIND( numnam )              ! read in namlist namdta_tsd
73      READ  ( numnam, namtsd ) 
74
75      IF( PRESENT( ld_tradmp ) )   ln_tsd_tradmp = .TRUE.     ! forces the initialization when tradmp is used
76     
77      IF(lwp) THEN                  ! control print
78         WRITE(numout,*)
79         WRITE(numout,*) 'dta_tsd_init : Temperature & Salinity data '
80         WRITE(numout,*) '~~~~~~~~~~~~ '
81         WRITE(numout,*) '   Namelist namtsd'
82         WRITE(numout,*) '      Initialisation of ocean T & S with T &S input data   ln_tsd_init   = ', ln_tsd_init
83         WRITE(numout,*) '      damping of ocean T & S toward T &S input data        ln_tsd_tradmp = ', ln_tsd_tradmp
84         WRITE(numout,*)
85         IF( .NOT.ln_tsd_init .AND. .NOT.ln_tsd_tradmp ) THEN
86            WRITE(numout,*)
87            WRITE(numout,*) '   T & S data not used'
88         ENDIF
89      ENDIF
90      !
91      IF( ln_rstart .AND. ln_tsd_init ) THEN
92         CALL ctl_warn( 'dta_tsd_init: ocean restart and T & S data intialisation, ',   &
93            &           'we keep the restart T & S values and set ln_tsd_init to FALSE' )
94         ln_tsd_init = .FALSE.
95      ENDIF
96      !
97      !                             ! allocate the arrays (if necessary)
98      IF(  ln_tsd_init .OR. ln_tsd_tradmp  ) THEN
99         !
100         ALLOCATE( sf_tsd(jpts), STAT=ierr0 )
101         IF( ierr0 > 0 ) THEN
102            CALL ctl_stop( 'dta_tsd_init: unable to allocate sf_tsd structure' )   ;   RETURN
103         ENDIF
104         !
105                                ALLOCATE( sf_tsd(jp_tem)%fnow(jpi,jpj,jpk)   , STAT=ierr0 )
106         IF( sn_tem%ln_tint )   ALLOCATE( sf_tsd(jp_tem)%fdta(jpi,jpj,jpk,2) , STAT=ierr1 )
107                                ALLOCATE( sf_tsd(jp_sal)%fnow(jpi,jpj,jpk)   , STAT=ierr2 )
108         IF( sn_sal%ln_tint )   ALLOCATE( sf_tsd(jp_sal)%fdta(jpi,jpj,jpk,2) , STAT=ierr3 )
109         !
110         IF( ierr0 + ierr1 + ierr2 + ierr3 > 0 ) THEN
111            CALL ctl_stop( 'dta_tsd : unable to allocate T & S data arrays' )   ;   RETURN
112         ENDIF
113         !                         ! fill sf_tsd with sn_tem & sn_sal and control print
114         slf_i(jp_tem) = sn_tem   ;   slf_i(jp_sal) = sn_sal
115         CALL fld_fill( sf_tsd, slf_i, cn_dir, 'dta_tsd', 'Temperature & Salinity data', 'namtsd' )
116         !
117      ENDIF
118      !
119   END SUBROUTINE dta_tsd_init
120
121
122   SUBROUTINE dta_tsd( kt, ptsd )
123      !!----------------------------------------------------------------------
124      !!                   ***  ROUTINE dta_tsd  ***
125      !!                   
126      !! ** Purpose :   provides T and S data at kt
127      !!
128      !! ** Method  : - call fldread routine
129      !!              - ORCA_R2: add some hand made alteration to read data 
130      !!              - 'key_orca_lev10' interpolates on 10 times more levels
131      !!              - s- or mixed z-s coordinate: vertical interpolation on model mesh
132      !!              - ln_tsd_tradmp=F: deallocates the T-S data structure
133      !!                as T-S data are no are used
134      !!
135      !! ** Action  :   ptsd   T-S data on medl mesh and interpolated at time-step kt
136      !!----------------------------------------------------------------------
137      INTEGER                              , INTENT(in   ) ::   kt     ! ocean time-step
138      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts), INTENT(  out) ::   ptsd   ! T & S data
139      !
140      INTEGER ::   ji, jj, jk, jl, jkk   ! dummy loop indicies
141      INTEGER ::   ik, il0, il1, ii0, ii1, ij0, ij1   ! local integers
142      REAL(wp)::   zl, zi
143      REAL(wp), DIMENSION(jpk) ::  ztp, zsp   ! 1D workspace
144      !!----------------------------------------------------------------------
145      !
146      CALL fld_read( kt, 1, sf_tsd )      !==   read T & S data at kt time step   ==!
147      !
148      !
149      !                                   !==   ORCA_R2 configuration and T & S damping   ==!
150      IF( cp_cfg == "orca" .AND. jp_cfg == 2 .AND. ln_tsd_tradmp ) THEN    ! some hand made alterations
151         !
152         ij0 = 101   ;   ij1 = 109                       ! Reduced T & S in the Alboran Sea
153         ii0 = 141   ;   ii1 = 155
154         DO jj = mj0(ij0), mj1(ij1)
155            DO ji = mi0(ii0), mi1(ii1)
156               sf_tsd(jp_tem)%fnow(ji,jj,13:13) = sf_tsd(jp_tem)%fnow(ji,jj,13:13) - 0.20_wp
157               sf_tsd(jp_tem)%fnow(ji,jj,14:15) = sf_tsd(jp_tem)%fnow(ji,jj,14:15) - 0.35_wp
158               sf_tsd(jp_tem)%fnow(ji,jj,16:25) = sf_tsd(jp_tem)%fnow(ji,jj,16:25) - 0.40_wp
159               !
160               sf_tsd(jp_sal)%fnow(ji,jj,13:13) = sf_tsd(jp_sal)%fnow(ji,jj,13:13) - 0.15_wp
161               sf_tsd(jp_sal)%fnow(ji,jj,14:15) = sf_tsd(jp_sal)%fnow(ji,jj,14:15) - 0.25_wp
162               sf_tsd(jp_sal)%fnow(ji,jj,16:17) = sf_tsd(jp_sal)%fnow(ji,jj,16:17) - 0.30_wp
163               sf_tsd(jp_sal)%fnow(ji,jj,18:25) = sf_tsd(jp_sal)%fnow(ji,jj,18:25) - 0.35_wp
164            END DO
165         END DO
166         IF( nn_cla == 1 ) THEN                          ! Cross Land advection
167            il0 = 138   ;   il1 = 138                          ! set T & S profile at Gibraltar Strait
168            ij0 = 101   ;   ij1 = 102
169            ii0 = 139   ;   ii1 = 139
170            DO jl = mi0(il0), mi1(il1)
171               DO jj = mj0(ij0), mj1(ij1)
172                  DO ji = mi0(ii0), mi1(ii1)
173                     sf_tsd(jp_tem)%fnow(ji,jj,:) = sf_tsd(jp_tem)%fnow(jl,jj,:)
174                     sf_tsd(jp_sal)%fnow(ji,jj,:) = sf_tsd(jp_sal)%fnow(jl,jj,:)
175                  END DO
176               END DO
177            END DO
178            il0 = 164   ;   il1 = 164                          ! set T & S profile at Bab el Mandeb Strait
179            ij0 =  87   ;   ij1 =  88
180            ii0 = 161   ;   ii1 = 163
181            DO jl = mi0(il0), mi1(il1)
182               DO jj = mj0(ij0), mj1(ij1)
183                  DO ji = mi0(ii0), mi1(ii1)
184                     sf_tsd(jp_tem)%fnow(ji,jj,:) = sf_tsd(jp_tem)%fnow(jl,jj,:)
185                     sf_tsd(jp_sal)%fnow(ji,jj,:) = sf_tsd(jp_sal)%fnow(jl,jj,:)
186                  END DO
187               END DO
188            END DO
189         ELSE                                            ! No Cross Land advection
190            ij0 =  87   ;   ij1 =  96                          ! Reduced temperature in Red Sea
191            ii0 = 148   ;   ii1 = 160
192            sf_tsd(jp_tem)%fnow( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) ,  4:10 ) = 7.0_wp
193            sf_tsd(jp_tem)%fnow( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) , 11:13 ) = 6.5_wp
194            sf_tsd(jp_tem)%fnow( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) , 14:20 ) = 6.0_wp
195         ENDIF
196      ENDIF
197      !
198      ptsd(:,:,:,jp_tem) = sf_tsd(jp_tem)%fnow(:,:,:)    ! NO mask
199      ptsd(:,:,:,jp_sal) = sf_tsd(jp_sal)%fnow(:,:,:) 
200      !
201      IF( ln_sco ) THEN                   !==   s- or mixed s-zps-coordinate   ==!
202         !
203         IF( kt == nit000 .AND. lwp )THEN
204            WRITE(numout,*)
205            WRITE(numout,*) 'dta_tsd: interpolates T & S data onto the s- or mixed s-z-coordinate mesh'
206         ENDIF
207         !
208         DO jj = 1, jpj                         ! vertical interpolation of T & S
209            DO ji = 1, jpi
210               DO jk = 1, jpk                        ! determines the intepolated T-S profiles at each (i,j) points
211                  zl = fsdept_0(ji,jj,jk)
212                  IF(     zl < gdept_0(1  ) ) THEN          ! above the first level of data
213                     ztp(jk) =  ptsd(ji,jj,1    ,jp_tem)
214                     zsp(jk) =  ptsd(ji,jj,1    ,jp_sal)
215                  ELSEIF( zl > gdept_0(jpk) ) THEN          ! below the last level of data
216                     ztp(jk) =  ptsd(ji,jj,jpkm1,jp_tem)
217                     zsp(jk) =  ptsd(ji,jj,jpkm1,jp_sal)
218                  ELSE                                      ! inbetween : vertical interpolation between jkk & jkk+1
219                     DO jkk = 1, jpkm1                                  ! when  gdept(jkk) < zl < gdept(jkk+1)
220                        IF( (zl-gdept_0(jkk)) * (zl-gdept_0(jkk+1)) <= 0._wp ) THEN
221                           zi = ( zl - gdept_0(jkk) ) / (gdept_0(jkk+1)-gdept_0(jkk))
222                           ztp(jk) = ptsd(ji,jj,jkk,jp_tem) + ( ptsd(ji,jj,jkk+1,jp_tem) - ptsd(ji,jj,jkk,jp_tem) ) * zi 
223                           zsp(jk) = ptsd(ji,jj,jkk,jp_sal) + ( ptsd(ji,jj,jkk+1,jp_sal) - ptsd(ji,jj,jkk,jp_sal) ) * zi
224                        ENDIF
225                     END DO
226                  ENDIF
227               END DO
228               DO jk = 1, jpkm1
229                  ptsd(ji,jj,jk,jp_tem) = ztp(jk) * tmask(ji,jj,jk)     ! mask required for mixed zps-s-coord
230                  ptsd(ji,jj,jk,jp_sal) = zsp(jk) * tmask(ji,jj,jk)
231               END DO
232               ptsd(ji,jj,jpk,jp_tem) = 0._wp
233               ptsd(ji,jj,jpk,jp_sal) = 0._wp
234            END DO
235         END DO
236         !
237      ELSE                                !==   z- or zps- coordinate   ==!
238         !                             
239         ptsd(:,:,:,jp_tem) = ptsd(:,:,:,jp_tem) * tmask(:,:,:)    ! Mask
240         ptsd(:,:,:,jp_sal) = ptsd(:,:,:,jp_sal) * tmask(:,:,:)
241         !
242         IF( ln_zps ) THEN                      ! zps-coordinate (partial steps) interpolation at the last ocean level
243            DO jj = 1, jpj
244               DO ji = 1, jpi
245                  ik = mbkt(ji,jj) 
246                  IF( ik > 1 ) THEN
247                     zl = ( gdept_0(ik) - fsdept_0(ji,jj,ik) ) / ( gdept_0(ik) - gdept_0(ik-1) )
248                     ptsd(ji,jj,ik,jp_tem) = (1.-zl) * ptsd(ji,jj,ik,jp_tem) + zl * ptsd(ji,jj,ik-1,jp_tem)
249                     ptsd(ji,jj,ik,jp_sal) = (1.-zl) * ptsd(ji,jj,ik,jp_sal) + zl * ptsd(ji,jj,ik-1,jp_sal)
250                  ENDIF
251               END DO
252            END DO
253         ENDIF
254         !
255      ENDIF
256      !
257      IF( lwp .AND. kt == nit000 ) THEN
258         WRITE(numout,*) ' temperature Levitus '
259         WRITE(numout,*)
260         WRITE(numout,*)'  level = 1'
261         CALL prihre( ptsd(:,:,1    ,jp_tem), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1., numout )
262         WRITE(numout,*)'  level = ', jpk/2
263         CALL prihre( ptsd(:,:,jpk/2,jp_tem), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1., numout )
264         WRITE(numout,*)'  level = ', jpkm1
265         CALL prihre( ptsd(:,:,jpkm1,jp_tem), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1., numout )
266         WRITE(numout,*)
267         WRITE(numout,*) ' salinity Levitus '
268         WRITE(numout,*)
269         WRITE(numout,*)'  level = 1'
270         CALL prihre( ptsd(:,:,1    ,jp_sal), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1., numout )
271         WRITE(numout,*)'  level = ', jpk/2
272         CALL prihre( ptsd(:,:,jpk/2,jp_sal), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1., numout )
273         WRITE(numout,*)'  level = ', jpkm1
274         CALL prihre( ptsd(:,:,jpkm1,jp_sal), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1., numout )
275         WRITE(numout,*)
276      ENDIF
277      !
278      IF( .NOT.ln_tsd_tradmp ) THEN                   !==   deallocate T & S structure   ==!
279         !                                              (data used only for initialisation)
280         IF(lwp) WRITE(numout,*) 'dta_tsd: deallocte T & S arrays as they are only use to initialize the run'
281                                        DEALLOCATE( sf_tsd(jp_tem)%fnow )     ! T arrays in the structure
282         IF( sf_tsd(jp_tem)%ln_tint )   DEALLOCATE( sf_tsd(jp_tem)%fdta )
283                                        DEALLOCATE( sf_tsd(jp_sal)%fnow )     ! S arrays in the structure
284         IF( sf_tsd(jp_sal)%ln_tint )   DEALLOCATE( sf_tsd(jp_sal)%fdta )
285                                        DEALLOCATE( sf_tsd              )     ! the structure itself
286      ENDIF
287      !
288   END SUBROUTINE dta_tsd
289
290   !!======================================================================
291END MODULE dtatsd
Note: See TracBrowser for help on using the repository browser.