New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynhpg.F90 in branches/2011/dev_NEMO_MERGE_2011/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

source: branches/2011/dev_NEMO_MERGE_2011/NEMOGCM/NEMO/OPA_SRC/DYN/dynhpg.F90 @ 3142

Last change on this file since 3142 was 3142, checked in by acc, 12 years ago

Branch dev_NEMO_MERGE_2011. Minor documentation changes and check in dynhpg.F90 to prevent use of buggy horizontal pressure gradient option

  • Property svn:keywords set to Id
File size: 52.8 KB
Line 
1MODULE dynhpg
2   !!======================================================================
3   !!                       ***  MODULE  dynhpg  ***
4   !! Ocean dynamics:  hydrostatic pressure gradient trend
5   !!======================================================================
6   !! History :  OPA  !  1987-09  (P. Andrich, M.-A. Foujols)  hpg_zco: Original code
7   !!            5.0  !  1991-11  (G. Madec)
8   !!            7.0  !  1996-01  (G. Madec)  hpg_sco: Original code for s-coordinates
9   !!            8.0  !  1997-05  (G. Madec)  split dynber into dynkeg and dynhpg
10   !!            8.5  !  2002-07  (G. Madec)  F90: Free form and module
11   !!            8.5  !  2002-08  (A. Bozec)  hpg_zps: Original code
12   !!   NEMO     1.0  !  2005-10  (A. Beckmann, B.W. An)  various s-coordinate options
13   !!                 !         Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14   !!             -   !  2005-11  (G. Madec) style & small optimisation
15   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
16   !!            3.4  !  2011-11  (A. Coward, H. Liu) introduction of prj scheme;
17   !!                 !           suppression of hel, wdj and rot options
18   !!----------------------------------------------------------------------
19
20   !!----------------------------------------------------------------------
21   !!   dyn_hpg      : update the momentum trend with the now horizontal
22   !!                  gradient of the hydrostatic pressure
23   !!   dyn_hpg_init : initialisation and control of options
24   !!       hpg_zco  : z-coordinate scheme
25   !!       hpg_zps  : z-coordinate plus partial steps (interpolation)
26   !!       hpg_sco  : s-coordinate (standard jacobian formulation)
27   !!       hpg_djc  : s-coordinate (Density Jacobian with Cubic polynomial)
28   !!       hpg_prj  : s-coordinate (Pressure Jacobian with Cubic polynomial)
29   !!----------------------------------------------------------------------
30   USE oce             ! ocean dynamics and tracers
31   USE dom_oce         ! ocean space and time domain
32   USE phycst          ! physical constants
33   USE trdmod          ! ocean dynamics trends
34   USE trdmod_oce      ! ocean variables trends
35   USE in_out_manager  ! I/O manager
36   USE prtctl          ! Print control
37   USE lbclnk          ! lateral boundary condition
38   USE lib_mpp         ! MPP library
39
40   IMPLICIT NONE
41   PRIVATE
42
43   PUBLIC   dyn_hpg        ! routine called by step module
44   PUBLIC   dyn_hpg_init   ! routine called by opa module
45
46   !                                              !!* Namelist namdyn_hpg : hydrostatic pressure gradient
47   LOGICAL , PUBLIC ::   ln_hpg_zco    = .TRUE.    !: z-coordinate - full steps
48   LOGICAL , PUBLIC ::   ln_hpg_zps    = .FALSE.   !: z-coordinate - partial steps (interpolation)
49   LOGICAL , PUBLIC ::   ln_hpg_sco    = .FALSE.   !: s-coordinate (standard jacobian formulation)
50   LOGICAL , PUBLIC ::   ln_hpg_djc    = .FALSE.   !: s-coordinate (Density Jacobian with Cubic polynomial)
51   LOGICAL , PUBLIC ::   ln_hpg_prj    = .FALSE.   !: s-coordinate (Pressure Jacobian scheme)
52   LOGICAL , PUBLIC ::   ln_dynhpg_imp = .FALSE.   !: semi-implicite hpg flag
53
54   INTEGER  ::   nhpg  =  0   ! = 0 to 7, type of pressure gradient scheme used ! (deduced from ln_hpg_... flags)
55
56   !! * Substitutions
57#  include "domzgr_substitute.h90"
58#  include "vectopt_loop_substitute.h90"
59   !!----------------------------------------------------------------------
60   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
61   !! $Id$
62   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
63   !!----------------------------------------------------------------------
64CONTAINS
65
66   SUBROUTINE dyn_hpg( kt )
67      !!---------------------------------------------------------------------
68      !!                  ***  ROUTINE dyn_hpg  ***
69      !!
70      !! ** Method  :   Call the hydrostatic pressure gradient routine
71      !!              using the scheme defined in the namelist
72      !!   
73      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
74      !!             - Save the trend (l_trddyn=T)
75      !!----------------------------------------------------------------------
76      USE oce, ONLY:   tsa                         ! (tsa) used as 2 3D workspace
77      !!
78      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
79      REAL(wp), POINTER, DIMENSION(:,:,:) ::  ztrdu, ztrdv
80      !!----------------------------------------------------------------------
81      !
82      IF( l_trddyn ) THEN                    ! Temporary saving of ua and va trends (l_trddyn)
83         ztrdu => tsa(:,:,:,1) 
84         ztrdv => tsa(:,:,:,2) 
85         !
86         ztrdu(:,:,:) = ua(:,:,:) 
87         ztrdv(:,:,:) = va(:,:,:) 
88      ENDIF     
89      !
90      SELECT CASE ( nhpg )      ! Hydrostatic pressure gradient computation
91      CASE (  0 )   ;   CALL hpg_zco    ( kt )      ! z-coordinate
92      CASE (  1 )   ;   CALL hpg_zps    ( kt )      ! z-coordinate plus partial steps (interpolation)
93      CASE (  2 )   ;   CALL hpg_sco    ( kt )      ! s-coordinate (standard jacobian formulation)
94      CASE (  3 )   ;   CALL hpg_djc    ( kt )      ! s-coordinate (Density Jacobian with Cubic polynomial)
95      CASE (  4 )   ;   CALL hpg_prj    ( kt )      ! s-coordinate (Pressure Jacobian scheme)
96      END SELECT
97      !
98      IF( l_trddyn ) THEN      ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
99         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
100         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
101         CALL trd_mod( ztrdu, ztrdv, jpdyn_trd_hpg, 'DYN', kt )
102      ENDIF         
103      !
104      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' hpg  - Ua: ', mask1=umask,   &
105         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
106      !
107   END SUBROUTINE dyn_hpg
108
109
110   SUBROUTINE dyn_hpg_init
111      !!----------------------------------------------------------------------
112      !!                 ***  ROUTINE dyn_hpg_init  ***
113      !!
114      !! ** Purpose :   initializations for the hydrostatic pressure gradient
115      !!              computation and consistency control
116      !!
117      !! ** Action  :   Read the namelist namdyn_hpg and check the consistency
118      !!      with the type of vertical coordinate used (zco, zps, sco)
119      !!----------------------------------------------------------------------
120      INTEGER ::   ioptio = 0      ! temporary integer
121      !!
122      NAMELIST/namdyn_hpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco,     &
123         &                 ln_hpg_djc, ln_hpg_prj, ln_dynhpg_imp
124      !!----------------------------------------------------------------------
125      !
126      REWIND( numnam )               ! Read Namelist namdyn_hpg
127      READ  ( numnam, namdyn_hpg )
128      !
129      IF(lwp) THEN                   ! Control print
130         WRITE(numout,*)
131         WRITE(numout,*) 'dyn_hpg_init : hydrostatic pressure gradient initialisation'
132         WRITE(numout,*) '~~~~~~~~~~~~'
133         WRITE(numout,*) '   Namelist namdyn_hpg : choice of hpg scheme'
134         WRITE(numout,*) '      z-coord. - full steps                             ln_hpg_zco    = ', ln_hpg_zco
135         WRITE(numout,*) '      z-coord. - partial steps (interpolation)          ln_hpg_zps    = ', ln_hpg_zps
136         WRITE(numout,*) '      s-coord. (standard jacobian formulation)          ln_hpg_sco    = ', ln_hpg_sco
137         WRITE(numout,*) '      s-coord. (Density Jacobian: Cubic polynomial)     ln_hpg_djc    = ', ln_hpg_djc
138         WRITE(numout,*) '      s-coord. (Pressure Jacobian: Cubic polynomial)    ln_hpg_prj    = ', ln_hpg_prj
139         WRITE(numout,*) '      time stepping: centered (F) or semi-implicit (T)  ln_dynhpg_imp = ', ln_dynhpg_imp
140      ENDIF
141      !
142      IF( ln_hpg_djc )   &
143         &   CALL ctl_stop('dyn_hpg_init : Density Jacobian: Cubic polynominal method &
144                           & currently disabled (bugs under investigation). Please select &
145                           & either  ln_hpg_sco or  ln_hpg_prj instead')
146      !
147      IF( lk_vvl .AND. .NOT. (ln_hpg_sco.OR.ln_hpg_prj) )   &
148         &   CALL ctl_stop('dyn_hpg_init : variable volume key_vvl requires:&
149                           & the standard jacobian formulation hpg_sco or &
150                           & the pressure jacobian formulation hpg_prj')
151      !
152      !                               ! Set nhpg from ln_hpg_... flags
153      IF( ln_hpg_zco )   nhpg = 0
154      IF( ln_hpg_zps )   nhpg = 1
155      IF( ln_hpg_sco )   nhpg = 2
156      IF( ln_hpg_djc )   nhpg = 3
157      IF( ln_hpg_prj )   nhpg = 4
158      !
159      !                               ! Consistency check
160      ioptio = 0 
161      IF( ln_hpg_zco )   ioptio = ioptio + 1
162      IF( ln_hpg_zps )   ioptio = ioptio + 1
163      IF( ln_hpg_sco )   ioptio = ioptio + 1
164      IF( ln_hpg_djc )   ioptio = ioptio + 1
165      IF( ln_hpg_prj )   ioptio = ioptio + 1
166      IF( ioptio /= 1 )   CALL ctl_stop( 'NO or several hydrostatic pressure gradient options used' )
167      !
168   END SUBROUTINE dyn_hpg_init
169
170
171   SUBROUTINE hpg_zco( kt )
172      !!---------------------------------------------------------------------
173      !!                  ***  ROUTINE hpg_zco  ***
174      !!
175      !! ** Method  :   z-coordinate case, levels are horizontal surfaces.
176      !!      The now hydrostatic pressure gradient at a given level, jk,
177      !!      is computed by taking the vertical integral of the in-situ
178      !!      density gradient along the model level from the suface to that
179      !!      level:    zhpi = grav .....
180      !!                zhpj = grav .....
181      !!      add it to the general momentum trend (ua,va).
182      !!            ua = ua - 1/e1u * zhpi
183      !!            va = va - 1/e2v * zhpj
184      !!
185      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
186      !!----------------------------------------------------------------------
187      USE oce, ONLY:   tsa                         ! (tsa) used as 2 3D workspace
188      !!
189      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
190      !!
191      INTEGER  ::   ji, jj, jk       ! dummy loop indices
192      REAL(wp) ::   zcoef0, zcoef1   ! temporary scalars
193      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj 
194      !!----------------------------------------------------------------------
195     
196      zhpi => tsa(:,:,:,1) 
197      zhpj => tsa(:,:,:,2) 
198      !
199      IF( kt == nit000 ) THEN
200         IF(lwp) WRITE(numout,*)
201         IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
202         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate case '
203      ENDIF
204     
205      zcoef0 = - grav * 0.5_wp      ! Local constant initialization
206
207      ! Surface value
208      DO jj = 2, jpjm1
209         DO ji = fs_2, fs_jpim1   ! vector opt.
210            zcoef1 = zcoef0 * fse3w(ji,jj,1)
211            ! hydrostatic pressure gradient
212            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
213            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
214            ! add to the general momentum trend
215            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
216            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
217         END DO
218      END DO
219
220      !
221      ! interior value (2=<jk=<jpkm1)
222      DO jk = 2, jpkm1
223         DO jj = 2, jpjm1
224            DO ji = fs_2, fs_jpim1   ! vector opt.
225               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
226               ! hydrostatic pressure gradient
227               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
228                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) )   &
229                  &                       - ( rhd(ji  ,jj,jk)+rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
230
231               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
232                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) )   &
233                  &                       - ( rhd(ji,jj,  jk)+rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
234               ! add to the general momentum trend
235               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
236               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
237            END DO
238         END DO
239      END DO
240      !
241   END SUBROUTINE hpg_zco
242
243
244   SUBROUTINE hpg_zps( kt )
245      !!---------------------------------------------------------------------
246      !!                 ***  ROUTINE hpg_zps  ***
247      !!                   
248      !! ** Method  :   z-coordinate plus partial steps case.  blahblah...
249      !!
250      !! ** Action  : - Update (ua,va) with the now hydrastatic pressure trend
251      !!----------------------------------------------------------------------
252      USE oce, ONLY:   tsa                         ! (tsa) used as 2 3D workspace
253      !!
254      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
255      !!
256      INTEGER  ::   ji, jj, jk                       ! dummy loop indices
257      INTEGER  ::   iku, ikv                         ! temporary integers
258      REAL(wp) ::   zcoef0, zcoef1, zcoef2, zcoef3   ! temporary scalars
259      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj 
260      !!----------------------------------------------------------------------
261       
262      zhpi => tsa(:,:,:,1) 
263      zhpj => tsa(:,:,:,2) 
264      !
265      IF( kt == nit000 ) THEN
266         IF(lwp) WRITE(numout,*)
267         IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
268         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate with partial steps - vector optimization'
269      ENDIF
270
271
272      ! Local constant initialization
273      zcoef0 = - grav * 0.5_wp
274
275      !  Surface value (also valid in partial step case)
276      DO jj = 2, jpjm1
277         DO ji = fs_2, fs_jpim1   ! vector opt.
278            zcoef1 = zcoef0 * fse3w(ji,jj,1)
279            ! hydrostatic pressure gradient
280            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj  ,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
281            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji  ,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
282            ! add to the general momentum trend
283            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
284            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
285         END DO
286      END DO
287
288
289      ! interior value (2=<jk=<jpkm1)
290      DO jk = 2, jpkm1
291         DO jj = 2, jpjm1
292            DO ji = fs_2, fs_jpim1   ! vector opt.
293               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
294               ! hydrostatic pressure gradient
295               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
296                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) )   &
297                  &                       - ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
298
299               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
300                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) )   &
301                  &                       - ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
302               ! add to the general momentum trend
303               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
304               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
305            END DO
306         END DO
307      END DO
308
309
310      ! partial steps correction at the last level  (use gru & grv computed in zpshde.F90)
311# if defined key_vectopt_loop
312         jj = 1
313         DO ji = jpi+2, jpij-jpi-1   ! vector opt. (forced unrolling)
314# else
315      DO jj = 2, jpjm1
316         DO ji = 2, jpim1
317# endif
318            iku = mbku(ji,jj)
319            ikv = mbkv(ji,jj)
320            zcoef2 = zcoef0 * MIN( fse3w(ji,jj,iku), fse3w(ji+1,jj  ,iku) )
321            zcoef3 = zcoef0 * MIN( fse3w(ji,jj,ikv), fse3w(ji  ,jj+1,ikv) )
322            IF( iku > 1 ) THEN            ! on i-direction (level 2 or more)
323               ua  (ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku)         ! subtract old value
324               zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1)                   &   ! compute the new one
325                  &            + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + gru(ji,jj) ) / e1u(ji,jj)
326               ua  (ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku)         ! add the new one to the general momentum trend
327            ENDIF
328            IF( ikv > 1 ) THEN            ! on j-direction (level 2 or more)
329               va  (ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv)         ! subtract old value
330               zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1)                   &   ! compute the new one
331                  &            + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + grv(ji,jj) ) / e2v(ji,jj)
332               va  (ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv)         ! add the new one to the general momentum trend
333            ENDIF
334# if ! defined key_vectopt_loop
335         END DO
336# endif
337      END DO
338      !
339
340   END SUBROUTINE hpg_zps
341
342
343   SUBROUTINE hpg_sco( kt )
344      !!---------------------------------------------------------------------
345      !!                  ***  ROUTINE hpg_sco  ***
346      !!
347      !! ** Method  :   s-coordinate case. Jacobian scheme.
348      !!      The now hydrostatic pressure gradient at a given level, jk,
349      !!      is computed by taking the vertical integral of the in-situ
350      !!      density gradient along the model level from the suface to that
351      !!      level. s-coordinates (ln_sco): a corrective term is added
352      !!      to the horizontal pressure gradient :
353      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
354      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
355      !!      add it to the general momentum trend (ua,va).
356      !!         ua = ua - 1/e1u * zhpi
357      !!         va = va - 1/e2v * zhpj
358      !!
359      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
360      !!----------------------------------------------------------------------
361      USE oce, ONLY:   tsa                         ! (tsa) used as 2 3D workspace
362      !!
363      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
364      !!
365      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
366      REAL(wp) ::   zcoef0, zuap, zvap, znad   ! temporary scalars
367      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj 
368      !!----------------------------------------------------------------------
369
370      zhpi => tsa(:,:,:,1) 
371      zhpj => tsa(:,:,:,2) 
372      !
373      IF( kt == nit000 ) THEN
374         IF(lwp) WRITE(numout,*)
375         IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
376         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OPA original scheme used'
377      ENDIF
378
379      ! Local constant initialization
380      zcoef0 = - grav * 0.5_wp
381      ! To use density and not density anomaly
382      IF ( lk_vvl ) THEN   ;     znad = 1._wp          ! Variable volume
383      ELSE                 ;     znad = 0._wp         ! Fixed volume
384      ENDIF
385
386      ! Surface value
387      DO jj = 2, jpjm1
388         DO ji = fs_2, fs_jpim1   ! vector opt.   
389            ! hydrostatic pressure gradient along s-surfaces
390            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( fse3w(ji+1,jj  ,1) * ( znad + rhd(ji+1,jj  ,1) )   &
391               &                                  - fse3w(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) ) )
392            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( fse3w(ji  ,jj+1,1) * ( znad + rhd(ji  ,jj+1,1) )   &
393               &                                  - fse3w(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) ) )
394            ! s-coordinate pressure gradient correction
395            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
396               &           * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
397            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
398               &           * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
399            ! add to the general momentum trend
400            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
401            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
402         END DO 
403      END DO   
404           
405      ! interior value (2=<jk=<jpkm1)
406      DO jk = 2, jpkm1                                 
407         DO jj = 2, jpjm1     
408            DO ji = fs_2, fs_jpim1   ! vector opt.     
409               ! hydrostatic pressure gradient along s-surfaces
410               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj)   & 
411                  &           * (  fse3w(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad )   & 
412                  &              - fse3w(ji  ,jj,jk) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) + 2*znad )  )
413               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj)   &
414                  &           * (  fse3w(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad )   &
415                  &              - fse3w(ji,jj  ,jk) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) + 2*znad )  )
416               ! s-coordinate pressure gradient correction
417               zuap = -zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
418                  &           * ( fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj)
419               zvap = -zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
420                  &           * ( fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj)
421               ! add to the general momentum trend
422               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk) + zuap
423               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk) + zvap
424            END DO
425         END DO
426      END DO
427      !
428   END SUBROUTINE hpg_sco
429
430   SUBROUTINE hpg_djc( kt )
431      !!---------------------------------------------------------------------
432      !!                  ***  ROUTINE hpg_djc  ***
433      !!
434      !! ** Method  :   Density Jacobian with Cubic polynomial scheme
435      !!
436      !! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
437      !!----------------------------------------------------------------------
438      USE wrk_nemo, ONLY:   wrk_in_use, wrk_not_released
439      USE oce     , ONLY:   tsa                         ! (tsa) used as 2 3D workspace
440      USE wrk_nemo, ONLY:   drhox => wrk_3d_1  , dzx  => wrk_3d_2
441      USE wrk_nemo, ONLY:   drhou => wrk_3d_3  , dzu  => wrk_3d_4 , rho_i => wrk_3d_5
442      USE wrk_nemo, ONLY:   drhoy => wrk_3d_6  , dzy  => wrk_3d_7
443      USE wrk_nemo, ONLY:   drhov => wrk_3d_8  , dzv  => wrk_3d_9 , rho_j => wrk_3d_10
444      USE wrk_nemo, ONLY:   drhoz => wrk_3d_11 , dzz  => wrk_3d_12 
445      USE wrk_nemo, ONLY:   drhow => wrk_3d_13 , dzw  => wrk_3d_14
446      USE wrk_nemo, ONLY:   rho_k => wrk_3d_15
447      !!
448      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
449      !!
450      INTEGER  ::   ji, jj, jk          ! dummy loop indices
451      REAL(wp) ::   zcoef0, zep, cffw   ! temporary scalars
452      REAL(wp) ::   z1_10, cffu, cffx   !    "         "
453      REAL(wp) ::   z1_12, cffv, cffy   !    "         "
454      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj 
455      !!----------------------------------------------------------------------
456
457      IF( wrk_in_use(3, 1,2,3,4,5,6,7,8,9,10,11,12,13,14,15) ) THEN
458         CALL ctl_stop('dyn:hpg_djc: requested workspace arrays unavailable')   ;   RETURN
459      ENDIF
460      !
461      zhpi => tsa(:,:,:,1) 
462      zhpj => tsa(:,:,:,2) 
463
464      IF( kt == nit000 ) THEN
465         IF(lwp) WRITE(numout,*)
466         IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
467         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, density Jacobian with cubic polynomial scheme'
468      ENDIF
469
470      ! Local constant initialization
471      zcoef0 = - grav * 0.5_wp
472      z1_10  = 1._wp / 10._wp
473      z1_12  = 1._wp / 12._wp
474
475      !----------------------------------------------------------------------------------------
476      !  compute and store in provisional arrays elementary vertical and horizontal differences
477      !----------------------------------------------------------------------------------------
478
479!!bug gm   Not a true bug, but... dzz=e3w  for dzx, dzy verify what it is really
480
481      DO jk = 2, jpkm1
482         DO jj = 2, jpjm1
483            DO ji = fs_2, fs_jpim1   ! vector opt.
484               drhoz(ji,jj,jk) = rhd   (ji  ,jj  ,jk) - rhd   (ji,jj,jk-1)
485               dzz  (ji,jj,jk) = fsde3w(ji  ,jj  ,jk) - fsde3w(ji,jj,jk-1)
486               drhox(ji,jj,jk) = rhd   (ji+1,jj  ,jk) - rhd   (ji,jj,jk  )
487               dzx  (ji,jj,jk) = fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk  )
488               drhoy(ji,jj,jk) = rhd   (ji  ,jj+1,jk) - rhd   (ji,jj,jk  )
489               dzy  (ji,jj,jk) = fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk  )
490            END DO
491         END DO
492      END DO
493
494      !-------------------------------------------------------------------------
495      ! compute harmonic averages using eq. 5.18
496      !-------------------------------------------------------------------------
497      zep = 1.e-15
498
499!!bug  gm  drhoz not defined at level 1 and used (jk-1 with jk=2)
500!!bug  gm  idem for drhox, drhoy et ji=jpi and jj=jpj
501
502      DO jk = 2, jpkm1
503         DO jj = 2, jpjm1
504            DO ji = fs_2, fs_jpim1   ! vector opt.
505               cffw = 2._wp * drhoz(ji  ,jj  ,jk) * drhoz(ji,jj,jk-1)
506
507               cffu = 2._wp * drhox(ji+1,jj  ,jk) * drhox(ji,jj,jk  )
508               cffx = 2._wp * dzx  (ji+1,jj  ,jk) * dzx  (ji,jj,jk  )
509 
510               cffv = 2._wp * drhoy(ji  ,jj+1,jk) * drhoy(ji,jj,jk  )
511               cffy = 2._wp * dzy  (ji  ,jj+1,jk) * dzy  (ji,jj,jk  )
512
513               IF( cffw > zep) THEN
514                  drhow(ji,jj,jk) = 2._wp *   drhoz(ji,jj,jk) * drhoz(ji,jj,jk-1)   &
515                     &                    / ( drhoz(ji,jj,jk) + drhoz(ji,jj,jk-1) )
516               ELSE
517                  drhow(ji,jj,jk) = 0._wp
518               ENDIF
519
520               dzw(ji,jj,jk) = 2._wp *   dzz(ji,jj,jk) * dzz(ji,jj,jk-1)   &
521                  &                  / ( dzz(ji,jj,jk) + dzz(ji,jj,jk-1) )
522
523               IF( cffu > zep ) THEN
524                  drhou(ji,jj,jk) = 2._wp *   drhox(ji+1,jj,jk) * drhox(ji,jj,jk)   &
525                     &                    / ( drhox(ji+1,jj,jk) + drhox(ji,jj,jk) )
526               ELSE
527                  drhou(ji,jj,jk ) = 0._wp
528               ENDIF
529
530               IF( cffx > zep ) THEN
531                  dzu(ji,jj,jk) = 2._wp *   dzx(ji+1,jj,jk) * dzx(ji,jj,jk)   &
532                     &                  / ( dzx(ji+1,jj,jk) + dzx(ji,jj,jk) )
533               ELSE
534                  dzu(ji,jj,jk) = 0._wp
535               ENDIF
536
537               IF( cffv > zep ) THEN
538                  drhov(ji,jj,jk) = 2._wp *   drhoy(ji,jj+1,jk) * drhoy(ji,jj,jk)   &
539                     &                    / ( drhoy(ji,jj+1,jk) + drhoy(ji,jj,jk) )
540               ELSE
541                  drhov(ji,jj,jk) = 0._wp
542               ENDIF
543
544               IF( cffy > zep ) THEN
545                  dzv(ji,jj,jk) = 2._wp *   dzy(ji,jj+1,jk) * dzy(ji,jj,jk)   &
546                     &                  / ( dzy(ji,jj+1,jk) + dzy(ji,jj,jk) )
547               ELSE
548                  dzv(ji,jj,jk) = 0._wp
549               ENDIF
550
551            END DO
552         END DO
553      END DO
554
555      !----------------------------------------------------------------------------------
556      ! apply boundary conditions at top and bottom using 5.36-5.37
557      !----------------------------------------------------------------------------------
558      drhow(:,:, 1 ) = 1.5_wp * ( drhoz(:,:, 2 ) - drhoz(:,:,  1  ) ) - 0.5_wp * drhow(:,:,  2  )
559      drhou(:,:, 1 ) = 1.5_wp * ( drhox(:,:, 2 ) - drhox(:,:,  1  ) ) - 0.5_wp * drhou(:,:,  2  )
560      drhov(:,:, 1 ) = 1.5_wp * ( drhoy(:,:, 2 ) - drhoy(:,:,  1  ) ) - 0.5_wp * drhov(:,:,  2  )
561
562      drhow(:,:,jpk) = 1.5_wp * ( drhoz(:,:,jpk) - drhoz(:,:,jpkm1) ) - 0.5_wp * drhow(:,:,jpkm1)
563      drhou(:,:,jpk) = 1.5_wp * ( drhox(:,:,jpk) - drhox(:,:,jpkm1) ) - 0.5_wp * drhou(:,:,jpkm1)
564      drhov(:,:,jpk) = 1.5_wp * ( drhoy(:,:,jpk) - drhoy(:,:,jpkm1) ) - 0.5_wp * drhov(:,:,jpkm1)
565
566
567      !--------------------------------------------------------------
568      ! Upper half of top-most grid box, compute and store
569      !-------------------------------------------------------------
570
571!!bug gm   :  e3w-de3w = 0.5*e3w  ....  and de3w(2)-de3w(1)=e3w(2) ....   to be verified
572!          true if de3w is really defined as the sum of the e3w scale factors as, it seems to me, it should be
573
574      DO jj = 2, jpjm1
575         DO ji = fs_2, fs_jpim1   ! vector opt.
576            rho_k(ji,jj,1) = -grav * ( fse3w(ji,jj,1) - fsde3w(ji,jj,1) )               &
577               &                   * (  rhd(ji,jj,1)                                    &
578               &                     + 0.5_wp * ( rhd(ji,jj,2) - rhd(ji,jj,1) )         &
579               &                              * ( fse3w (ji,jj,1) - fsde3w(ji,jj,1) )   &
580               &                              / ( fsde3w(ji,jj,2) - fsde3w(ji,jj,1) )  ) 
581         END DO
582      END DO
583
584!!bug gm    : here also, simplification is possible
585!!bug gm    : optimisation: 1/10 and 1/12 the division should be done before the loop
586
587      DO jk = 2, jpkm1
588         DO jj = 2, jpjm1
589            DO ji = fs_2, fs_jpim1   ! vector opt.
590
591               rho_k(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj,jk) + rhd   (ji,jj,jk-1) )                                   &
592                  &                     * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) )                                   &
593                  &            - grav * z1_10 * (                                                                     &
594                  &     ( drhow (ji,jj,jk) - drhow (ji,jj,jk-1) )                                                     &
595                  &   * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) - z1_12 * ( dzw  (ji,jj,jk) + dzw  (ji,jj,jk-1) ) )   &
596                  &   - ( dzw   (ji,jj,jk) - dzw   (ji,jj,jk-1) )                                                     &
597                  &   * ( rhd   (ji,jj,jk) - rhd   (ji,jj,jk-1) - z1_12 * ( drhow(ji,jj,jk) + drhow(ji,jj,jk-1) ) )   &
598                  &                             )
599
600               rho_i(ji,jj,jk) = zcoef0 * ( rhd   (ji+1,jj,jk) + rhd   (ji,jj,jk) )                                   &
601                  &                     * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) )                                   &
602                  &            - grav* z1_10 * (                                                                      &
603                  &     ( drhou (ji+1,jj,jk) - drhou (ji,jj,jk) )                                                     &
604                  &   * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzu  (ji+1,jj,jk) + dzu  (ji,jj,jk) ) )   &
605                  &   - ( dzu   (ji+1,jj,jk) - dzu   (ji,jj,jk) )                                                     &
606                  &   * ( rhd   (ji+1,jj,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhou(ji+1,jj,jk) + drhou(ji,jj,jk) ) )   &
607                  &                            )
608
609               rho_j(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj+1,jk) + rhd   (ji,jj,jk) )                                   &
610                  &                     * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) )                                   &
611                  &            - grav* z1_10 * (                                                                      &
612                  &     ( drhov (ji,jj+1,jk) - drhov (ji,jj,jk) )                                                     &
613                  &   * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzv  (ji,jj+1,jk) + dzv  (ji,jj,jk) ) )   &
614                  &   - ( dzv   (ji,jj+1,jk) - dzv   (ji,jj,jk) )                                                     &
615                  &   * ( rhd   (ji,jj+1,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhov(ji,jj+1,jk) + drhov(ji,jj,jk) ) )   &
616                  &                            )
617
618            END DO
619         END DO
620      END DO
621      CALL lbc_lnk(rho_k,'W',1.)
622      CALL lbc_lnk(rho_i,'U',1.)
623      CALL lbc_lnk(rho_j,'V',1.)
624
625
626      ! ---------------
627      !  Surface value
628      ! ---------------
629      DO jj = 2, jpjm1
630         DO ji = fs_2, fs_jpim1   ! vector opt.
631            zhpi(ji,jj,1) = ( rho_k(ji+1,jj  ,1) - rho_k(ji,jj,1) - rho_i(ji,jj,1) ) / e1u(ji,jj)
632            zhpj(ji,jj,1) = ( rho_k(ji  ,jj+1,1) - rho_k(ji,jj,1) - rho_j(ji,jj,1) ) / e2v(ji,jj)
633            ! add to the general momentum trend
634            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
635            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
636         END DO
637      END DO
638
639      ! ----------------
640      !  interior value   (2=<jk=<jpkm1)
641      ! ----------------
642      DO jk = 2, jpkm1
643         DO jj = 2, jpjm1 
644            DO ji = fs_2, fs_jpim1   ! vector opt.
645               ! hydrostatic pressure gradient along s-surfaces
646               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)                                &
647                  &           + (  ( rho_k(ji+1,jj,jk) - rho_k(ji,jj,jk  ) )    &
648                  &              - ( rho_i(ji  ,jj,jk) - rho_i(ji,jj,jk-1) )  ) / e1u(ji,jj)
649               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)                                &
650                  &           + (  ( rho_k(ji,jj+1,jk) - rho_k(ji,jj,jk  ) )    &
651                  &               -( rho_j(ji,jj  ,jk) - rho_j(ji,jj,jk-1) )  ) / e2v(ji,jj)
652               ! add to the general momentum trend
653               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
654               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
655            END DO
656         END DO
657      END DO
658      !
659      IF( wrk_not_released(3, 1,2,3,4,5,6,7,8,9,10,11,12,13,14,15) )   &
660         CALL ctl_stop('dyn:hpg_djc: failed to release workspace arrays')
661      !
662   END SUBROUTINE hpg_djc
663
664
665   SUBROUTINE hpg_prj( kt )
666      !!---------------------------------------------------------------------
667      !!                  ***  ROUTINE hpg_prj  ***
668      !!
669      !! ** Method  :   s-coordinate case.
670      !!      A Pressure-Jacobian horizontal pressure gradient method
671      !!      based on the constrained cubic-spline interpolation for
672      !!      all vertical coordinate systems
673      !!
674      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
675      !!             - Save the trend (l_trddyn=T)
676      !!
677      !!----------------------------------------------------------------------
678
679      USE wrk_nemo, ONLY:   wrk_in_use, wrk_not_released
680      USE oce     , ONLY:   tsa                          ! (tsa) used as 2 3D workspace
681      USE wrk_nemo, ONLY:   zhpi => wrk_3d_3 
682      USE wrk_nemo, ONLY:   zu   => wrk_3d_4 
683      USE wrk_nemo, ONLY:   zv   => wrk_3d_5
684      USE wrk_nemo, ONLY:   fsp  => wrk_3d_6
685      USE wrk_nemo, ONLY:   xsp  => wrk_3d_7
686      USE wrk_nemo, ONLY:   asp  => wrk_3d_8
687      USE wrk_nemo, ONLY:   bsp  => wrk_3d_9
688      USE wrk_nemo, ONLY:   csp  => wrk_3d_10
689      USE wrk_nemo, ONLY:   dsp  => wrk_3d_11
690      !!
691      !!----------------------------------------------------------------------
692      !!
693      INTEGER, PARAMETER  :: polynomial_type = 1    ! 1: cubic spline, 2: linear
694      INTEGER, INTENT(in) ::   kt                   ! ocean time-step index
695      !!
696      INTEGER  ::   ji, jj, jk, jkk                 ! dummy loop indices
697      REAL(wp) ::   zcoef0, znad                    ! temporary scalars
698      !!
699      !! The local variables for the correction term
700      INTEGER  :: jk1, jis, jid, jjs, jjd
701      REAL(wp) :: zuijk, zvijk, zpwes, zpwed, zpnss, zpnsd, zdeps
702      REAL(wp) :: zrhdt1 
703      REAL(wp) :: zdpdx1, zdpdx2, zdpdy1, zdpdy2
704      INTEGER  :: zbhitwe, zbhitns
705      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zdeptht, zrhh 
706      !!----------------------------------------------------------------------
707
708      IF( wrk_in_use(3, 3,4,5,6,7,8,9,10,11) ) THEN
709         CALL ctl_stop('dyn:hpg_prj: requested workspace arrays unavailable')   ;   RETURN
710      ENDIF
711      !
712      zdeptht => tsa(:,:,:,1) 
713      zrhh    => tsa(:,:,:,2) 
714
715      IF( kt == nit000 ) THEN
716         IF(lwp) WRITE(numout,*)
717         IF(lwp) WRITE(numout,*) 'dyn:hpg_prj : hydrostatic pressure gradient trend'
718         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, cubic spline pressure Jacobian'
719      ENDIF
720
721      !!----------------------------------------------------------------------
722      ! Local constant initialization
723      zcoef0 = - grav 
724      znad = 0.0_wp
725      IF( lk_vvl ) znad = 1._wp
726
727      ! Clean 3-D work arrays
728      zhpi(:,:,:) = 0._wp
729      zrhh(:,:,:) = rhd(:,:,:)
730     
731      ! Preparing vertical density profile for hybrid-sco coordinate
732      DO jj = 1, jpj
733        DO ji = 1, jpi   
734          jk = mbathy(ji,jj)
735          IF( jk <= 0 ) THEN; zrhh(ji,jj,:) = 0._wp
736          ELSE IF(jk == 1) THEN; zrhh(ji,jj, jk+1:jpk) = rhd(ji,jj,jk)
737          ELSE IF(jk < jpkm1) THEN
738             DO jkk = jk+1, jpk
739                zrhh(ji,jj,jkk) = interp1(fsde3w(ji,jj,jkk),   fsde3w(ji,jj,jkk-1), &
740                                         fsde3w(ji,jj,jkk-2), rhd(ji,jj,jkk-1), rhd(ji,jj,jkk-2))
741             END DO
742          ENDIF
743        END DO
744      END DO
745
746      DO jj = 1, jpj
747        DO ji = 1, jpi
748          zdeptht(ji,jj,1) = 0.5_wp * fse3w(ji,jj,1)
749          zdeptht(ji,jj,1) = zdeptht(ji,jj,1) - sshn(ji,jj) * znad
750          DO jk = 2, jpk
751             zdeptht(ji,jj,jk) = zdeptht(ji,jj,jk-1) + fse3w(ji,jj,jk)
752          END DO
753        END DO
754      END DO
755
756      DO jk = 1, jpkm1
757        DO jj = 1, jpj
758          DO ji = 1, jpi
759            fsp(ji,jj,jk) = zrhh(ji,jj,jk)
760            xsp(ji,jj,jk) = zdeptht(ji,jj,jk)
761          END DO
762        END DO
763      END DO
764
765      ! Construct the vertical density profile with the
766      ! constrained cubic spline interpolation
767      CALL cspline(fsp,xsp,asp,bsp,csp,dsp,polynomial_type)     
768
769      ! Calculate the hydrostatic pressure at T(ji,jj,1)
770      DO jj = 2, jpj
771        DO ji = 2, jpi 
772          zrhdt1 = zrhh(ji,jj,1) - interp3(zdeptht(ji,jj,1),asp(ji,jj,1), &
773                                         bsp(ji,jj,1),   csp(ji,jj,1), &
774                                         dsp(ji,jj,1) ) * 0.5_wp * zdeptht(ji,jj,1)
775          zrhdt1 = MAX(zrhdt1, 1000._wp - rau0)        ! no lighter than fresh water
776
777          ! assuming linear profile across the top half surface layer
778          zhpi(ji,jj,1) =  0.5_wp * fse3w(ji,jj,1) * zrhdt1 
779        END DO
780      END DO
781
782      ! Calculate the pressure at T(ji,jj,2:jpkm1)
783      DO jk = 2, jpkm1                                 
784        DO jj = 2, jpj     
785          DO ji = 2, jpi
786            zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) +                          &
787                             integ2(zdeptht(ji,jj,jk-1), zdeptht(ji,jj,jk),&
788                                    asp(ji,jj,jk-1),    bsp(ji,jj,jk-1), &
789                                    csp(ji,jj,jk-1),    dsp(ji,jj,jk-1))
790          END DO
791        END DO
792      END DO
793
794      ! Z coordinate of U(ji,jj,1:jpkm1) and V(ji,jj,1:jpkm1)
795      DO jj = 2, jpjm1     
796        DO ji = 2, jpim1 
797          zu(ji,jj,1) = - ( fse3u(ji,jj,1) - sshu_n(ji,jj) * znad)
798          zv(ji,jj,1) = - ( fse3v(ji,jj,1) - sshv_n(ji,jj) * znad)
799        END DO
800      END DO
801
802      DO jk = 2, jpkm1                                 
803        DO jj = 2, jpjm1     
804          DO ji = 2, jpim1 
805            zu(ji,jj,jk) = zu(ji,jj,jk-1)- fse3u(ji,jj,jk)
806            zv(ji,jj,jk) = zv(ji,jj,jk-1)- fse3v(ji,jj,jk)
807          END DO
808        END DO
809      END DO
810               
811      DO jk = 1, jpkm1                                 
812        DO jj = 2, jpjm1     
813          DO ji = 2, jpim1 
814            zu(ji,jj,jk) = zu(ji,jj,jk) + 0.5_wp * fse3u(ji,jj,jk)
815            zv(ji,jj,jk) = zv(ji,jj,jk) + 0.5_wp * fse3v(ji,jj,jk)
816          END DO
817        END DO
818      END DO
819
820      DO jk = 1, jpkm1                                 
821        DO jj = 2, jpjm1     
822          DO ji = 2, jpim1 
823            zpwes = 0._wp; zpwed = 0._wp
824            zpnss = 0._wp; zpnsd = 0._wp
825            zuijk = zu(ji,jj,jk)
826            zvijk = zv(ji,jj,jk)
827
828            !!!!!     for u equation
829            IF( jk <= mbku(ji,jj) ) THEN
830               IF( -zdeptht(ji+1,jj,mbku(ji,jj)) >= -zdeptht(ji,jj,mbku(ji,jj)) ) THEN
831                 jis = ji + 1; jid = ji
832               ELSE
833                 jis = ji;     jid = ji +1
834               ENDIF
835
836               ! integrate the pressure on the shallow side
837               jk1 = jk 
838               zbhitwe = 0
839               DO WHILE ( -zdeptht(jis,jj,jk1) > zuijk )
840                 IF( jk1 == mbku(ji,jj) ) THEN
841                   zbhitwe = 1
842                   EXIT
843                 ENDIF
844                 zdeps = MIN(zdeptht(jis,jj,jk1+1), -zuijk)
845                 zpwes = zpwes +                                    & 
846                      integ2(zdeptht(jis,jj,jk1), zdeps,            &
847                             asp(jis,jj,jk1),    bsp(jis,jj,jk1), &
848                             csp(jis,jj,jk1),    dsp(jis,jj,jk1))
849                 jk1 = jk1 + 1
850               END DO
851           
852               IF(zbhitwe == 1) THEN
853                 zuijk = -zdeptht(jis,jj,jk1)
854               ENDIF
855
856               ! integrate the pressure on the deep side
857               jk1 = jk 
858               zbhitwe = 0
859               DO WHILE ( -zdeptht(jid,jj,jk1) < zuijk )
860                 IF( jk1 == 1 ) THEN
861                   zbhitwe = 1
862                   EXIT
863                 ENDIF
864                 zdeps = MAX(zdeptht(jid,jj,jk1-1), -zuijk)
865                 zpwed = zpwed +                                        & 
866                        integ2(zdeps,              zdeptht(jid,jj,jk1), &
867                               asp(jid,jj,jk1-1), bsp(jid,jj,jk1-1),  &
868                               csp(jid,jj,jk1-1), dsp(jid,jj,jk1-1) )
869                 jk1 = jk1 - 1
870               END DO
871           
872               IF( zbhitwe == 1 ) THEN
873                 zdeps = zdeptht(jid,jj,1) + MIN(zuijk, sshn(jid,jj)*znad)
874                 zrhdt1 = zrhh(jid,jj,1) - interp3(zdeptht(jid,jj,1), asp(jid,jj,1), &
875                                                 bsp(jid,jj,1),    csp(jid,jj,1), &
876                                                 dsp(jid,jj,1)) * zdeps
877                 zrhdt1 = MAX(zrhdt1, 1000._wp - rau0)        ! no lighter than fresh water
878                 zpwed  = zpwed + 0.5_wp * (zrhh(jid,jj,1) + zrhdt1) * zdeps
879               ENDIF
880
881               ! update the momentum trends in u direction
882
883               zdpdx1 = zcoef0 / e1u(ji,jj) * (zhpi(ji+1,jj,jk) - zhpi(ji,jj,jk))
884               IF( lk_vvl ) THEN
885                 zdpdx2 = zcoef0 / e1u(ji,jj) * & 
886                         ( REAL(jis-jid, wp) * (zpwes + zpwed) + (sshn(ji+1,jj)-sshn(ji,jj)) ) 
887                ELSE
888                 zdpdx2 = zcoef0 / e1u(ji,jj) * REAL(jis-jid, wp) * (zpwes + zpwed) 
889               ENDIF
890
891               ua(ji,jj,jk) = ua(ji,jj,jk) + (zdpdx1 + zdpdx2) * &
892               &           umask(ji,jj,jk) * tmask(ji,jj,jk) * tmask(ji+1,jj,jk)
893            ENDIF
894 
895            !!!!!     for v equation
896            IF( jk <= mbkv(ji,jj) ) THEN
897               IF( -zdeptht(ji,jj+1,mbkv(ji,jj)) >= -zdeptht(ji,jj,mbkv(ji,jj)) ) THEN
898                 jjs = jj + 1; jjd = jj
899               ELSE
900                 jjs = jj    ; jjd = jj + 1
901               ENDIF
902
903               ! integrate the pressure on the shallow side
904               jk1 = jk 
905               zbhitns = 0
906               DO WHILE ( -zdeptht(ji,jjs,jk1) > zvijk )
907                 IF( jk1 == mbkv(ji,jj) ) THEN
908                   zbhitns = 1
909                   EXIT
910                 ENDIF
911                 zdeps = MIN(zdeptht(ji,jjs,jk1+1), -zvijk)
912                 zpnss = zpnss +                                      & 
913                        integ2(zdeptht(ji,jjs,jk1), zdeps,            &
914                               asp(ji,jjs,jk1),    bsp(ji,jjs,jk1), &
915                               csp(ji,jjs,jk1),    dsp(ji,jjs,jk1) )
916                 jk1 = jk1 + 1
917               END DO
918           
919               IF(zbhitns == 1) THEN
920                 zvijk = -zdeptht(ji,jjs,jk1)
921               ENDIF
922
923               ! integrate the pressure on the deep side
924               jk1 = jk 
925               zbhitns = 0
926               DO WHILE ( -zdeptht(ji,jjd,jk1) < zvijk )
927                 IF( jk1 == 1 ) THEN
928                   zbhitns = 1
929                   EXIT
930                 ENDIF
931                 zdeps = MAX(zdeptht(ji,jjd,jk1-1), -zvijk)
932                 zpnsd = zpnsd +                                        & 
933                        integ2(zdeps,              zdeptht(ji,jjd,jk1), &
934                               asp(ji,jjd,jk1-1), bsp(ji,jjd,jk1-1), &
935                               csp(ji,jjd,jk1-1), dsp(ji,jjd,jk1-1) )
936                 jk1 = jk1 - 1
937               END DO
938           
939               IF( zbhitns == 1 ) THEN
940                 zdeps = zdeptht(ji,jjd,1) + MIN(zvijk, sshn(ji,jjd)*znad)
941                 zrhdt1 = zrhh(ji,jjd,1) - interp3(zdeptht(ji,jjd,1), asp(ji,jjd,1), &
942                                                 bsp(ji,jjd,1),    csp(ji,jjd,1), &
943                                                 dsp(ji,jjd,1) ) * zdeps
944                 zrhdt1 = MAX(zrhdt1, 1000._wp - rau0)        ! no lighter than fresh water
945                 zpnsd  = zpnsd + 0.5_wp * (zrhh(ji,jjd,1) + zrhdt1) * zdeps
946               ENDIF
947
948               ! update the momentum trends in v direction
949
950               zdpdy1 = zcoef0 / e2v(ji,jj) * (zhpi(ji,jj+1,jk) - zhpi(ji,jj,jk))
951               IF( lk_vvl ) THEN
952                   zdpdy2 = zcoef0 / e2v(ji,jj) * &
953                           ( REAL(jjs-jjd, wp) * (zpnss + zpnsd) + (sshn(ji,jj+1)-sshn(ji,jj)) ) 
954               ELSE
955                   zdpdy2 = zcoef0 / e2v(ji,jj) * REAL(jjs-jjd, wp) * (zpnss + zpnsd ) 
956               ENDIF
957
958               va(ji,jj,jk) = va(ji,jj,jk) + (zdpdy1 + zdpdy2)*&
959               &              vmask(ji,jj,jk)*tmask(ji,jj,jk)*tmask(ji,jj+1,jk)
960            ENDIF
961
962                   
963           END DO
964        END DO
965      END DO
966
967      !
968      IF( wrk_not_released(3, 3,4,5,6,7,8,9,10,11) )   &
969         CALL ctl_stop('dyn:hpg_prj: failed to release workspace arrays')
970      !
971   END SUBROUTINE hpg_prj
972
973   SUBROUTINE cspline(fsp, xsp, asp, bsp, csp, dsp, polynomial_type)
974      !!----------------------------------------------------------------------
975      !!                 ***  ROUTINE cspline  ***
976      !!       
977      !! ** Purpose :   constrained cubic spline interpolation
978      !!         
979      !! ** Method  :   f(x) = asp + bsp*x + csp*x^2 + dsp*x^3
980      !! Reference: K.W. Brodlie, A review of mehtods for curve and function
981      !!                          drawing, 1980
982      !!
983      !!----------------------------------------------------------------------
984      IMPLICIT NONE
985      REAL(wp), DIMENSION(:,:,:), INTENT(in)  :: fsp, xsp           ! value and coordinate
986      REAL(wp), DIMENSION(:,:,:), INTENT(out) :: asp, bsp, csp, dsp ! coefficients of
987                                                                    ! the interpoated function
988      INTEGER, INTENT(in) :: polynomial_type                        ! 1: cubic spline
989                                                                    ! 2: Linear
990
991      ! Local Variables     
992      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
993      INTEGER  ::   jpi, jpj, jpkm1
994      REAL(wp) ::   zdf1, zdf2, zddf1, zddf2, ztmp1, ztmp2, zdxtmp
995      REAL(wp) ::   zdxtmp1, zdxtmp2, zalpha
996      REAL(wp) ::   zdf(size(fsp,3))
997      !!----------------------------------------------------------------------
998
999      jpi   = size(fsp,1)
1000      jpj   = size(fsp,2)
1001      jpkm1 = size(fsp,3) - 1
1002
1003      ! Clean output arrays
1004      asp = 0.0_wp
1005      bsp = 0.0_wp
1006      csp = 0.0_wp
1007      dsp = 0.0_wp
1008     
1009      DO ji = 1, jpi
1010        DO jj = 1, jpj
1011          IF (polynomial_type == 1) THEN     ! Constrained Cubic Spline
1012             DO jk = 2, jpkm1-1
1013                zdxtmp1 = xsp(ji,jj,jk)   - xsp(ji,jj,jk-1) 
1014                zdxtmp2 = xsp(ji,jj,jk+1) - xsp(ji,jj,jk) 
1015                zdf1    = ( fsp(ji,jj,jk)   - fsp(ji,jj,jk-1) ) / zdxtmp1
1016                zdf2    = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk)   ) / zdxtmp2
1017   
1018                zalpha = ( zdxtmp1 + 2._wp * zdxtmp2 ) / ( zdxtmp1 + zdxtmp2 ) / 3._wp
1019             
1020                IF(zdf1 * zdf2 <= 0._wp) THEN
1021                    zdf(jk) = 0._wp
1022                ELSE
1023                  zdf(jk) = zdf1 * zdf2 / ( ( 1._wp - zalpha ) * zdf1 + zalpha * zdf2 )
1024                ENDIF
1025             END DO
1026
1027             zdf(1)     = 1.5_wp * ( fsp(ji,jj,2) - fsp(ji,jj,1) ) / &
1028                        &          ( xsp(ji,jj,2) - xsp(ji,jj,1) ) -  0.5_wp * zdf(2)
1029             zdf(jpkm1) = 1.5_wp * ( fsp(ji,jj,jpkm1) - fsp(ji,jj,jpkm1-1) ) / &
1030                        &          ( xsp(ji,jj,jpkm1) - xsp(ji,jj,jpkm1-1) ) - &
1031                        & 0.5_wp * zdf(jpkm1 - 1)
1032   
1033             DO jk = 1, jpkm1 - 1
1034                zdxtmp = xsp(ji,jj,jk+1) - xsp(ji,jj,jk) 
1035                ztmp1  = (zdf(jk+1) + 2._wp * zdf(jk)) / zdxtmp
1036                ztmp2  =  6._wp * (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / zdxtmp / zdxtmp
1037                zddf1  = -2._wp * ztmp1 + ztmp2 
1038                ztmp1  = (2._wp * zdf(jk+1) + zdf(jk)) / zdxtmp
1039                zddf2  =  2._wp * ztmp1 - ztmp2 
1040   
1041                dsp(ji,jj,jk) = (zddf2 - zddf1) / 6._wp / zdxtmp
1042                csp(ji,jj,jk) = ( xsp(ji,jj,jk+1) * zddf1 - xsp(ji,jj,jk)*zddf2 ) / 2._wp / zdxtmp
1043                bsp(ji,jj,jk) = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp - & 
1044                              & csp(ji,jj,jk) * ( xsp(ji,jj,jk+1) + xsp(ji,jj,jk) ) - &
1045                              & dsp(ji,jj,jk) * ( xsp(ji,jj,jk+1)**2 + &
1046                              &                   xsp(ji,jj,jk+1) * xsp(ji,jj,jk) + &
1047                              &                   xsp(ji,jj,jk)**2 )
1048                asp(ji,jj,jk) = fsp(ji,jj,jk) - bsp(ji,jj,jk) * xsp(ji,jj,jk) - &
1049                              &                 csp(ji,jj,jk) * xsp(ji,jj,jk)**2 - &
1050                              &                 dsp(ji,jj,jk) * xsp(ji,jj,jk)**3
1051             END DO
1052 
1053          ELSE IF (polynomial_type == 2) THEN     ! Linear
1054 
1055             DO jk = 1, jpkm1-1
1056                zdxtmp =xsp(ji,jj,jk+1) - xsp(ji,jj,jk) 
1057                ztmp1 = fsp(ji,jj,jk+1) - fsp(ji,jj,jk)
1058   
1059                dsp(ji,jj,jk) = 0._wp
1060                csp(ji,jj,jk) = 0._wp
1061                bsp(ji,jj,jk) = ztmp1 / zdxtmp
1062                asp(ji,jj,jk) = fsp(ji,jj,jk) - bsp(ji,jj,jk) * xsp(ji,jj,jk)
1063             END DO
1064
1065          ELSE
1066             CALL ctl_stop( 'invalid polynomial type in cspline' )
1067          ENDIF
1068
1069        END DO
1070      END DO
1071     
1072   END SUBROUTINE cspline
1073
1074
1075   FUNCTION interp1(x, xl, xr, fl, fr)  RESULT(f) 
1076      !!----------------------------------------------------------------------
1077      !!                 ***  ROUTINE interp1  ***
1078      !!       
1079      !! ** Purpose :   1-d linear interpolation
1080      !!         
1081      !! ** Method  : 
1082      !!                interpolation is straight forward
1083      !!                extrapolation is also permitted (no value limit)
1084      !!
1085      !! H.Liu, Jan 2009,  POL
1086      !!----------------------------------------------------------------------
1087      IMPLICIT NONE
1088      REAL(wp), INTENT(in) ::  x, xl, xr, fl, fr   
1089      REAL(wp)             ::  f ! result of the interpolation (extrapolation)
1090      REAL(wp)             ::  zdeltx
1091      !!----------------------------------------------------------------------
1092
1093      zdeltx = xr - xl
1094      IF(abs(zdeltx) <= 10._wp * EPSILON(x)) THEN
1095        f = 0.5_wp * (fl + fr)
1096      ELSE
1097        f = ( (x - xl ) * fr - ( x - xr ) * fl ) / zdeltx
1098      ENDIF
1099     
1100   END FUNCTION interp1
1101
1102   FUNCTION interp2(x, a, b, c, d)  RESULT(f) 
1103      !!----------------------------------------------------------------------
1104      !!                 ***  ROUTINE interp1  ***
1105      !!       
1106      !! ** Purpose :   1-d constrained cubic spline interpolation
1107      !!         
1108      !! ** Method  :  cubic spline interpolation
1109      !!
1110      !!----------------------------------------------------------------------
1111      IMPLICIT NONE
1112      REAL(wp), INTENT(in) ::  x, a, b, c, d   
1113      REAL(wp)             ::  f ! value from the interpolation
1114      !!----------------------------------------------------------------------
1115
1116      f = a + x* ( b + x * ( c + d * x ) ) 
1117
1118   END FUNCTION interp2
1119
1120
1121   FUNCTION interp3(x, a, b, c, d)  RESULT(f) 
1122      !!----------------------------------------------------------------------
1123      !!                 ***  ROUTINE interp1  ***
1124      !!       
1125      !! ** Purpose :   Calculate the first order of deriavtive of
1126      !!                a cubic spline function y=a+b*x+c*x^2+d*x^3
1127      !!         
1128      !! ** Method  :   f=dy/dx=b+2*c*x+3*d*x^2
1129      !!
1130      !!----------------------------------------------------------------------
1131      IMPLICIT NONE
1132      REAL(wp), INTENT(in) ::  x, a, b, c, d   
1133      REAL(wp)             ::  f ! value from the interpolation
1134      !!----------------------------------------------------------------------
1135
1136      f = b + x * ( 2._wp * c + 3._wp * d * x)
1137
1138   END FUNCTION interp3
1139
1140   
1141   FUNCTION integ2(xl, xr, a, b, c, d)  RESULT(f) 
1142      !!----------------------------------------------------------------------
1143      !!                 ***  ROUTINE interp1  ***
1144      !!       
1145      !! ** Purpose :   1-d constrained cubic spline integration
1146      !!         
1147      !! ** Method  :  integrate polynomial a+bx+cx^2+dx^3 from xl to xr
1148      !!
1149      !!----------------------------------------------------------------------
1150      IMPLICIT NONE
1151      REAL(wp), INTENT(in) ::  xl, xr, a, b, c, d   
1152      REAL(wp)             ::  za1, za2, za3     
1153      REAL(wp)             ::  f                   ! integration result
1154      !!----------------------------------------------------------------------
1155
1156      za1 = 0.5_wp * b 
1157      za2 = c / 3.0_wp 
1158      za3 = 0.25_wp * d 
1159
1160      f  = xr * ( a + xr * ( za1 + xr * ( za2 + za3 * xr ) ) ) - &
1161         & xl * ( a + xl * ( za1 + xl * ( za2 + za3 * xl ) ) )
1162
1163   END FUNCTION integ2
1164
1165
1166   !!======================================================================
1167END MODULE dynhpg
Note: See TracBrowser for help on using the repository browser.