| 1 | MODULE zdftmx |
|---|
| 2 | !!======================================================================== |
|---|
| 3 | !! *** MODULE zdftmx *** |
|---|
| 4 | !! Ocean physics: vertical tidal mixing coefficient |
|---|
| 5 | !!======================================================================== |
|---|
| 6 | !! History : 1.0 ! 2004-04 (L. Bessieres, G. Madec) Original code |
|---|
| 7 | !! - ! 2006-08 (A. Koch-Larrouy) Indonesian strait |
|---|
| 8 | !! 3.3 ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase |
|---|
| 9 | !!---------------------------------------------------------------------- |
|---|
| 10 | #if defined key_zdftmx || defined key_esopa |
|---|
| 11 | !!---------------------------------------------------------------------- |
|---|
| 12 | !! 'key_zdftmx' Tidal vertical mixing |
|---|
| 13 | !!---------------------------------------------------------------------- |
|---|
| 14 | !! zdf_tmx : global momentum & tracer Kz with tidal induced Kz |
|---|
| 15 | !! tmx_itf : Indonesian momentum & tracer Kz with tidal induced Kz |
|---|
| 16 | !!---------------------------------------------------------------------- |
|---|
| 17 | USE oce ! ocean dynamics and tracers variables |
|---|
| 18 | USE dom_oce ! ocean space and time domain variables |
|---|
| 19 | USE zdf_oce ! ocean vertical physics variables |
|---|
| 20 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
|---|
| 21 | USE eosbn2 ! ocean equation of state |
|---|
| 22 | USE phycst ! physical constants |
|---|
| 23 | USE prtctl ! Print control |
|---|
| 24 | USE in_out_manager ! I/O manager |
|---|
| 25 | USE iom ! I/O Manager |
|---|
| 26 | USE lib_mpp ! MPP library |
|---|
| 27 | USE wrk_nemo ! work arrays |
|---|
| 28 | |
|---|
| 29 | IMPLICIT NONE |
|---|
| 30 | PRIVATE |
|---|
| 31 | |
|---|
| 32 | PUBLIC zdf_tmx ! called in step module |
|---|
| 33 | PUBLIC zdf_tmx_init ! called in opa module |
|---|
| 34 | PUBLIC zdf_tmx_alloc ! called in nemogcm module |
|---|
| 35 | |
|---|
| 36 | LOGICAL, PUBLIC, PARAMETER :: lk_zdftmx = .TRUE. !: tidal mixing flag |
|---|
| 37 | |
|---|
| 38 | ! !!* Namelist namzdf_tmx : tidal mixing * |
|---|
| 39 | REAL(wp) :: rn_htmx = 500. ! vertical decay scale for turbulence (meters) |
|---|
| 40 | REAL(wp) :: rn_n2min = 1.e-8 ! threshold of the Brunt-Vaisala frequency (s-1) |
|---|
| 41 | REAL(wp) :: rn_tfe = 1./3. ! tidal dissipation efficiency (St Laurent et al. 2002) |
|---|
| 42 | REAL(wp) :: rn_me = 0.2 ! mixing efficiency (Osborn 1980) |
|---|
| 43 | LOGICAL :: ln_tmx_itf = .TRUE. ! Indonesian Through Flow (ITF): Koch-Larrouy et al. (2007) parameterization |
|---|
| 44 | REAL(wp) :: rn_tfe_itf = 1. ! ITF tidal dissipation efficiency (St Laurent et al. 2002) |
|---|
| 45 | |
|---|
| 46 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: en_tmx ! energy available for tidal mixing (W/m2) |
|---|
| 47 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: mask_itf ! mask to use over Indonesian area |
|---|
| 48 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: az_tmx ! coefficient used to evaluate the tidal induced Kz |
|---|
| 49 | |
|---|
| 50 | !! * Substitutions |
|---|
| 51 | # include "domzgr_substitute.h90" |
|---|
| 52 | # include "vectopt_loop_substitute.h90" |
|---|
| 53 | !!---------------------------------------------------------------------- |
|---|
| 54 | !! NEMO/OPA 4.0 , NEMO Consortium (2011) |
|---|
| 55 | !! $Id$ |
|---|
| 56 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 57 | !!---------------------------------------------------------------------- |
|---|
| 58 | CONTAINS |
|---|
| 59 | |
|---|
| 60 | INTEGER FUNCTION zdf_tmx_alloc() |
|---|
| 61 | !!---------------------------------------------------------------------- |
|---|
| 62 | !! *** FUNCTION zdf_tmx_alloc *** |
|---|
| 63 | !!---------------------------------------------------------------------- |
|---|
| 64 | ALLOCATE(en_tmx(jpi,jpj), mask_itf(jpi,jpj), az_tmx(jpi,jpj,jpk), STAT=zdf_tmx_alloc ) |
|---|
| 65 | ! |
|---|
| 66 | IF( lk_mpp ) CALL mpp_sum ( zdf_tmx_alloc ) |
|---|
| 67 | IF( zdf_tmx_alloc /= 0 ) CALL ctl_warn('zdf_tmx_alloc: failed to allocate arrays') |
|---|
| 68 | END FUNCTION zdf_tmx_alloc |
|---|
| 69 | |
|---|
| 70 | |
|---|
| 71 | SUBROUTINE zdf_tmx( kt ) |
|---|
| 72 | !!---------------------------------------------------------------------- |
|---|
| 73 | !! *** ROUTINE zdf_tmx *** |
|---|
| 74 | !! |
|---|
| 75 | !! ** Purpose : add to the vertical mixing coefficients the effect of |
|---|
| 76 | !! tidal mixing (Simmons et al 2004). |
|---|
| 77 | !! |
|---|
| 78 | !! ** Method : - tidal-induced vertical mixing is given by: |
|---|
| 79 | !! Kz_tides = az_tmx / max( rn_n2min, N^2 ) |
|---|
| 80 | !! where az_tmx is a coefficient that specified the 3D space |
|---|
| 81 | !! distribution of the faction of tidal energy taht is used |
|---|
| 82 | !! for mixing. Its expression is set in zdf_tmx_init routine, |
|---|
| 83 | !! following Simmons et al. 2004. |
|---|
| 84 | !! NB: a specific bounding procedure is performed on av_tide |
|---|
| 85 | !! so that the input tidal energy is actually almost used. The |
|---|
| 86 | !! basic maximum value is 60 cm2/s, but values of 300 cm2/s |
|---|
| 87 | !! can be reached in area where bottom stratification is too |
|---|
| 88 | !! weak. |
|---|
| 89 | !! |
|---|
| 90 | !! - update av_tide in the Indonesian Through Flow area |
|---|
| 91 | !! following Koch-Larrouy et al. (2007) parameterisation |
|---|
| 92 | !! (see tmx_itf routine). |
|---|
| 93 | !! |
|---|
| 94 | !! - update the model vertical eddy viscosity and diffusivity: |
|---|
| 95 | !! avt = avt + av_tides |
|---|
| 96 | !! avm = avm + av_tides |
|---|
| 97 | !! avmu = avmu + mi(av_tides) |
|---|
| 98 | !! avmv = avmv + mj(av_tides) |
|---|
| 99 | !! |
|---|
| 100 | !! ** Action : avt, avm, avmu, avmv increased by tidal mixing |
|---|
| 101 | !! |
|---|
| 102 | !! References : Simmons et al. 2004, Ocean Modelling, 6, 3-4, 245-263. |
|---|
| 103 | !! Koch-Larrouy et al. 2007, GRL. |
|---|
| 104 | !!---------------------------------------------------------------------- |
|---|
| 105 | USE oce, zav_tide => ua ! use ua as workspace |
|---|
| 106 | !! |
|---|
| 107 | INTEGER, INTENT(in) :: kt ! ocean time-step |
|---|
| 108 | !! |
|---|
| 109 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 110 | REAL(wp) :: ztpc ! scalar workspace |
|---|
| 111 | REAL(wp), POINTER, DIMENSION(:,:) :: zkz |
|---|
| 112 | !!---------------------------------------------------------------------- |
|---|
| 113 | |
|---|
| 114 | CALL wrk_alloc( jpi,jpj, zkz ) |
|---|
| 115 | |
|---|
| 116 | ! ! ----------------------- ! |
|---|
| 117 | ! ! Standard tidal mixing ! (compute zav_tide) |
|---|
| 118 | ! ! ----------------------- ! |
|---|
| 119 | ! !* First estimation (with n2 bound by rn_n2min) bounded by 60 cm2/s |
|---|
| 120 | zav_tide(:,:,:) = MIN( 60.e-4, az_tmx(:,:,:) / MAX( rn_n2min, rn2(:,:,:) ) ) |
|---|
| 121 | |
|---|
| 122 | zkz(:,:) = 0.e0 !* Associated potential energy consummed over the whole water column |
|---|
| 123 | DO jk = 2, jpkm1 |
|---|
| 124 | zkz(:,:) = zkz(:,:) + fse3w(:,:,jk) * MAX( 0.e0, rn2(:,:,jk) ) * rau0 * zav_tide(:,:,jk)* tmask(:,:,jk) |
|---|
| 125 | END DO |
|---|
| 126 | |
|---|
| 127 | DO jj = 1, jpj !* Here zkz should be equal to en_tmx ==> multiply by en_tmx/zkz to recover en_tmx |
|---|
| 128 | DO ji = 1, jpi |
|---|
| 129 | IF( zkz(ji,jj) /= 0.e0 ) zkz(ji,jj) = en_tmx(ji,jj) / zkz(ji,jj) |
|---|
| 130 | END DO |
|---|
| 131 | END DO |
|---|
| 132 | |
|---|
| 133 | DO jk = 2, jpkm1 !* Mutiply by zkz to recover en_tmx, BUT bound by 30/6 ==> zav_tide bound by 300 cm2/s |
|---|
| 134 | zav_tide(:,:,jk) = zav_tide(:,:,jk) * MIN( zkz(:,:), 30./6. ) !kz max = 300 cm2/s |
|---|
| 135 | END DO |
|---|
| 136 | |
|---|
| 137 | IF( kt == nit000 ) THEN !* check at first time-step: diagnose the energy consumed by zav_tide |
|---|
| 138 | ztpc = 0.e0 |
|---|
| 139 | DO jk= 1, jpk |
|---|
| 140 | DO jj= 1, jpj |
|---|
| 141 | DO ji= 1, jpi |
|---|
| 142 | ztpc = ztpc + fse3w(ji,jj,jk) * e1t(ji,jj) * e2t(ji,jj) & |
|---|
| 143 | & * MAX( 0.e0, rn2(ji,jj,jk) ) * zav_tide(ji,jj,jk) * tmask(ji,jj,jk) * tmask_i(ji,jj) |
|---|
| 144 | END DO |
|---|
| 145 | END DO |
|---|
| 146 | END DO |
|---|
| 147 | ztpc= rau0 / ( rn_tfe * rn_me ) * ztpc |
|---|
| 148 | IF(lwp) WRITE(numout,*) |
|---|
| 149 | IF(lwp) WRITE(numout,*) ' N Total power consumption by av_tide : ztpc = ', ztpc * 1.e-12 ,'TW' |
|---|
| 150 | ENDIF |
|---|
| 151 | |
|---|
| 152 | ! ! ----------------------- ! |
|---|
| 153 | ! ! ITF tidal mixing ! (update zav_tide) |
|---|
| 154 | ! ! ----------------------- ! |
|---|
| 155 | IF( ln_tmx_itf ) CALL tmx_itf( kt, zav_tide ) |
|---|
| 156 | |
|---|
| 157 | ! ! ----------------------- ! |
|---|
| 158 | ! ! Update mixing coefs ! |
|---|
| 159 | ! ! ----------------------- ! |
|---|
| 160 | DO jk = 2, jpkm1 !* update momentum & tracer diffusivity with tidal mixing |
|---|
| 161 | avt(:,:,jk) = avt(:,:,jk) + zav_tide(:,:,jk) |
|---|
| 162 | avm(:,:,jk) = avm(:,:,jk) + zav_tide(:,:,jk) |
|---|
| 163 | DO jj = 2, jpjm1 |
|---|
| 164 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 165 | avmu(ji,jj,jk) = avmu(ji,jj,jk) + 0.5 * ( zav_tide(ji,jj,jk) + zav_tide(ji+1,jj ,jk) ) * umask(ji,jj,jk) |
|---|
| 166 | avmv(ji,jj,jk) = avmv(ji,jj,jk) + 0.5 * ( zav_tide(ji,jj,jk) + zav_tide(ji ,jj+1,jk) ) * vmask(ji,jj,jk) |
|---|
| 167 | END DO |
|---|
| 168 | END DO |
|---|
| 169 | END DO |
|---|
| 170 | CALL lbc_lnk( avmu, 'U', 1. ) ; CALL lbc_lnk( avmv, 'V', 1. ) ! lateral boundary condition |
|---|
| 171 | |
|---|
| 172 | ! !* output tidal mixing coefficient |
|---|
| 173 | CALL iom_put( "av_tide", zav_tide ) |
|---|
| 174 | |
|---|
| 175 | IF(ln_ctl) CALL prt_ctl(tab3d_1=zav_tide , clinfo1=' tmx - av_tide: ', tab3d_2=avt, clinfo2=' avt: ', ovlap=1, kdim=jpk) |
|---|
| 176 | ! |
|---|
| 177 | CALL wrk_dealloc( jpi,jpj, zkz ) |
|---|
| 178 | ! |
|---|
| 179 | END SUBROUTINE zdf_tmx |
|---|
| 180 | |
|---|
| 181 | |
|---|
| 182 | SUBROUTINE tmx_itf( kt, pav ) |
|---|
| 183 | !!---------------------------------------------------------------------- |
|---|
| 184 | !! *** ROUTINE tmx_itf *** |
|---|
| 185 | !! |
|---|
| 186 | !! ** Purpose : modify the vertical eddy diffusivity coefficients |
|---|
| 187 | !! (pav) in the Indonesian Through Flow area (ITF). |
|---|
| 188 | !! |
|---|
| 189 | !! ** Method : - Following Koch-Larrouy et al. (2007), in the ITF defined |
|---|
| 190 | !! by msk_itf (read in a file, see tmx_init), the tidal |
|---|
| 191 | !! mixing coefficient is computed with : |
|---|
| 192 | !! * q=1 (i.e. all the tidal energy remains trapped in |
|---|
| 193 | !! the area and thus is used for mixing) |
|---|
| 194 | !! * the vertical distribution of the tifal energy is a |
|---|
| 195 | !! proportional to N above the thermocline (d(N^2)/dz > 0) |
|---|
| 196 | !! and to N^2 below the thermocline (d(N^2)/dz < 0) |
|---|
| 197 | !! |
|---|
| 198 | !! ** Action : av_tide updated in the ITF area (msk_itf) |
|---|
| 199 | !! |
|---|
| 200 | !! References : Koch-Larrouy et al. 2007, GRL |
|---|
| 201 | !!---------------------------------------------------------------------- |
|---|
| 202 | INTEGER , INTENT(in ) :: kt ! ocean time-step |
|---|
| 203 | REAL(wp), INTENT(inout), DIMENSION(jpi,jpj,jpk) :: pav ! Tidal mixing coef. |
|---|
| 204 | !! |
|---|
| 205 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 206 | REAL(wp) :: zcoef, ztpc ! temporary scalar |
|---|
| 207 | REAL(wp), DIMENSION(:,:) , POINTER :: zkz ! 2D workspace |
|---|
| 208 | REAL(wp), DIMENSION(:,:) , POINTER :: zsum1 , zsum2 , zsum ! - - |
|---|
| 209 | REAL(wp), DIMENSION(:,:,:), POINTER :: zempba_3d_1, zempba_3d_2 ! 3D workspace |
|---|
| 210 | REAL(wp), DIMENSION(:,:,:), POINTER :: zempba_3d , zdn2dz ! - - |
|---|
| 211 | REAL(wp), DIMENSION(:,:,:), POINTER :: zavt_itf ! - - |
|---|
| 212 | !!---------------------------------------------------------------------- |
|---|
| 213 | ! |
|---|
| 214 | CALL wrk_alloc( jpi,jpj, zkz, zsum1 , zsum2 , zsum ) |
|---|
| 215 | CALL wrk_alloc( jpi,jpj,jpk, zempba_3d_1, zempba_3d_2, zempba_3d, zdn2dz, zavt_itf ) |
|---|
| 216 | |
|---|
| 217 | ! ! compute the form function using N2 at each time step |
|---|
| 218 | zempba_3d_1(:,:,jpk) = 0.e0 |
|---|
| 219 | zempba_3d_2(:,:,jpk) = 0.e0 |
|---|
| 220 | DO jk = 1, jpkm1 |
|---|
| 221 | zdn2dz (:,:,jk) = rn2(:,:,jk) - rn2(:,:,jk+1) ! Vertical profile of dN2/dz |
|---|
| 222 | !CDIR NOVERRCHK |
|---|
| 223 | zempba_3d_1(:,:,jk) = SQRT( MAX( 0.e0, rn2(:,:,jk) ) ) ! - - of N |
|---|
| 224 | zempba_3d_2(:,:,jk) = MAX( 0.e0, rn2(:,:,jk) ) ! - - of N^2 |
|---|
| 225 | END DO |
|---|
| 226 | ! |
|---|
| 227 | zsum (:,:) = 0.e0 |
|---|
| 228 | zsum1(:,:) = 0.e0 |
|---|
| 229 | zsum2(:,:) = 0.e0 |
|---|
| 230 | DO jk= 2, jpk |
|---|
| 231 | zsum1(:,:) = zsum1(:,:) + zempba_3d_1(:,:,jk) * fse3w(:,:,jk) |
|---|
| 232 | zsum2(:,:) = zsum2(:,:) + zempba_3d_2(:,:,jk) * fse3w(:,:,jk) |
|---|
| 233 | END DO |
|---|
| 234 | DO jj = 1, jpj |
|---|
| 235 | DO ji = 1, jpi |
|---|
| 236 | IF( zsum1(ji,jj) /= 0.e0 ) zsum1(ji,jj) = 1.e0 / zsum1(ji,jj) |
|---|
| 237 | IF( zsum2(ji,jj) /= 0.e0 ) zsum2(ji,jj) = 1.e0 / zsum2(ji,jj) |
|---|
| 238 | END DO |
|---|
| 239 | END DO |
|---|
| 240 | |
|---|
| 241 | DO jk= 1, jpk |
|---|
| 242 | DO jj = 1, jpj |
|---|
| 243 | DO ji = 1, jpi |
|---|
| 244 | zcoef = 0.5 - SIGN( 0.5, zdn2dz(ji,jj,jk) ) ! =0 if dN2/dz > 0, =1 otherwise |
|---|
| 245 | ztpc = zempba_3d_1(ji,jj,jk) * zsum1(ji,jj) * zcoef & |
|---|
| 246 | & + zempba_3d_2(ji,jj,jk) * zsum2(ji,jj) * ( 1. - zcoef ) |
|---|
| 247 | ! |
|---|
| 248 | zempba_3d(ji,jj,jk) = ztpc |
|---|
| 249 | zsum (ji,jj) = zsum(ji,jj) + ztpc * fse3w(ji,jj,jk) |
|---|
| 250 | END DO |
|---|
| 251 | END DO |
|---|
| 252 | END DO |
|---|
| 253 | DO jj = 1, jpj |
|---|
| 254 | DO ji = 1, jpi |
|---|
| 255 | IF( zsum(ji,jj) > 0.e0 ) zsum(ji,jj) = 1.e0 / zsum(ji,jj) |
|---|
| 256 | END DO |
|---|
| 257 | END DO |
|---|
| 258 | |
|---|
| 259 | ! ! first estimation bounded by 10 cm2/s (with n2 bounded by rn_n2min) |
|---|
| 260 | zcoef = rn_tfe_itf / ( rn_tfe * rau0 ) |
|---|
| 261 | DO jk = 1, jpk |
|---|
| 262 | zavt_itf(:,:,jk) = MIN( 10.e-4, zcoef * en_tmx(:,:) * zsum(:,:) * zempba_3d(:,:,jk) & |
|---|
| 263 | & / MAX( rn_n2min, rn2(:,:,jk) ) * tmask(:,:,jk) ) |
|---|
| 264 | END DO |
|---|
| 265 | |
|---|
| 266 | zkz(:,:) = 0.e0 ! Associated potential energy consummed over the whole water column |
|---|
| 267 | DO jk = 2, jpkm1 |
|---|
| 268 | zkz(:,:) = zkz(:,:) + fse3w(:,:,jk) * MAX( 0.e0, rn2(:,:,jk) ) * rau0 * zavt_itf(:,:,jk) * tmask(:,:,jk) |
|---|
| 269 | END DO |
|---|
| 270 | |
|---|
| 271 | DO jj = 1, jpj ! Here zkz should be equal to en_tmx ==> multiply by en_tmx/zkz to recover en_tmx |
|---|
| 272 | DO ji = 1, jpi |
|---|
| 273 | IF( zkz(ji,jj) /= 0.e0 ) zkz(ji,jj) = en_tmx(ji,jj) * rn_tfe_itf / rn_tfe / zkz(ji,jj) |
|---|
| 274 | END DO |
|---|
| 275 | END DO |
|---|
| 276 | |
|---|
| 277 | DO jk = 2, jpkm1 ! Mutiply by zkz to recover en_tmx, BUT bound by 30/6 ==> zavt_itf bound by 300 cm2/s |
|---|
| 278 | zavt_itf(:,:,jk) = zavt_itf(:,:,jk) * MIN( zkz(:,:), 120./10. ) ! kz max = 120 cm2/s |
|---|
| 279 | END DO |
|---|
| 280 | |
|---|
| 281 | IF( kt == nit000 ) THEN ! diagnose the nergy consumed by zavt_itf |
|---|
| 282 | ztpc = 0.e0 |
|---|
| 283 | DO jk= 1, jpk |
|---|
| 284 | DO jj= 1, jpj |
|---|
| 285 | DO ji= 1, jpi |
|---|
| 286 | ztpc = ztpc + e1t(ji,jj) * e2t(ji,jj) * fse3w(ji,jj,jk) * MAX( 0.e0, rn2(ji,jj,jk) ) & |
|---|
| 287 | & * zavt_itf(ji,jj,jk) * tmask(ji,jj,jk) * tmask_i(ji,jj) |
|---|
| 288 | END DO |
|---|
| 289 | END DO |
|---|
| 290 | END DO |
|---|
| 291 | ztpc= rau0 * ztpc / ( rn_me * rn_tfe_itf ) |
|---|
| 292 | IF(lwp) WRITE(numout,*) ' N Total power consumption by zavt_itf: ztpc = ', ztpc * 1.e-12 ,'TW' |
|---|
| 293 | ENDIF |
|---|
| 294 | |
|---|
| 295 | ! ! Update pav with the ITF mixing coefficient |
|---|
| 296 | DO jk = 2, jpkm1 |
|---|
| 297 | pav(:,:,jk) = pav (:,:,jk) * ( 1.e0 - mask_itf(:,:) ) & |
|---|
| 298 | & + zavt_itf(:,:,jk) * mask_itf(:,:) |
|---|
| 299 | END DO |
|---|
| 300 | ! |
|---|
| 301 | CALL wrk_dealloc( jpi,jpj, zkz, zsum1 , zsum2 , zsum ) |
|---|
| 302 | CALL wrk_dealloc( jpi,jpj,jpk, zempba_3d_1, zempba_3d_2, zempba_3d, zdn2dz, zavt_itf ) |
|---|
| 303 | ! |
|---|
| 304 | END SUBROUTINE tmx_itf |
|---|
| 305 | |
|---|
| 306 | |
|---|
| 307 | SUBROUTINE zdf_tmx_init |
|---|
| 308 | !!---------------------------------------------------------------------- |
|---|
| 309 | !! *** ROUTINE zdf_tmx_init *** |
|---|
| 310 | !! |
|---|
| 311 | !! ** Purpose : Initialization of the vertical tidal mixing, Reading |
|---|
| 312 | !! of M2 and K1 tidal energy in nc files |
|---|
| 313 | !! |
|---|
| 314 | !! ** Method : - Read the namtmx namelist and check the parameters |
|---|
| 315 | !! |
|---|
| 316 | !! - Read the input data in NetCDF files : |
|---|
| 317 | !! M2 and K1 tidal energy. The total tidal energy, en_tmx, |
|---|
| 318 | !! is the sum of M2, K1 and S2 energy where S2 is assumed |
|---|
| 319 | !! to be: S2=(1/2)^2 * M2 |
|---|
| 320 | !! mask_itf, a mask array that determine where substituing |
|---|
| 321 | !! the standard Simmons et al. (2005) formulation with the |
|---|
| 322 | !! one of Koch_Larrouy et al. (2007). |
|---|
| 323 | !! |
|---|
| 324 | !! - Compute az_tmx, a 3D coefficient that allows to compute |
|---|
| 325 | !! the standard tidal-induced vertical mixing as follows: |
|---|
| 326 | !! Kz_tides = az_tmx / max( rn_n2min, N^2 ) |
|---|
| 327 | !! with az_tmx a bottom intensified coefficient is given by: |
|---|
| 328 | !! az_tmx(z) = en_tmx / ( rau0 * rn_htmx ) * EXP( -(H-z)/rn_htmx ) |
|---|
| 329 | !! / ( 1. - EXP( - H /rn_htmx ) ) |
|---|
| 330 | !! where rn_htmx the characteristic length scale of the bottom |
|---|
| 331 | !! intensification, en_tmx the tidal energy, and H the ocean depth |
|---|
| 332 | !! |
|---|
| 333 | !! ** input : - Namlist namtmx |
|---|
| 334 | !! - NetCDF file : M2_ORCA2.nc, K1_ORCA2.nc, and mask_itf.nc |
|---|
| 335 | !! |
|---|
| 336 | !! ** Action : - Increase by 1 the nstop flag is setting problem encounter |
|---|
| 337 | !! - defined az_tmx used to compute tidal-induced mixing |
|---|
| 338 | !! |
|---|
| 339 | !! References : Simmons et al. 2004, Ocean Modelling, 6, 3-4, 245-263. |
|---|
| 340 | !! Koch-Larrouy et al. 2007, GRL. |
|---|
| 341 | !!---------------------------------------------------------------------- |
|---|
| 342 | USE oce , zav_tide => ua ! ua used as workspace |
|---|
| 343 | !! |
|---|
| 344 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 345 | INTEGER :: inum ! local integer |
|---|
| 346 | REAL(wp) :: ztpc, ze_z ! local scalars |
|---|
| 347 | REAL(wp), DIMENSION(:,:) , POINTER :: zem2, zek1 ! read M2 and K1 tidal energy |
|---|
| 348 | REAL(wp), DIMENSION(:,:) , POINTER :: zkz ! total M2, K1 and S2 tidal energy |
|---|
| 349 | REAL(wp), DIMENSION(:,:) , POINTER :: zfact ! used for vertical structure function |
|---|
| 350 | REAL(wp), DIMENSION(:,:) , POINTER :: zhdep ! Ocean depth |
|---|
| 351 | REAL(wp), DIMENSION(:,:,:), POINTER :: zpc ! power consumption |
|---|
| 352 | !! |
|---|
| 353 | NAMELIST/namzdf_tmx/ rn_htmx, rn_n2min, rn_tfe, rn_me, ln_tmx_itf, rn_tfe_itf |
|---|
| 354 | !!---------------------------------------------------------------------- |
|---|
| 355 | |
|---|
| 356 | CALL wrk_alloc( jpi,jpj, zem2, zek1, zkz, zfact, zhdep ) |
|---|
| 357 | CALL wrk_alloc( jpi,jpj,jpk, zpc ) |
|---|
| 358 | |
|---|
| 359 | REWIND( numnam ) ! Read Namelist namtmx : Tidal Mixing |
|---|
| 360 | READ ( numnam, namzdf_tmx ) |
|---|
| 361 | |
|---|
| 362 | IF(lwp) THEN ! Control print |
|---|
| 363 | WRITE(numout,*) |
|---|
| 364 | WRITE(numout,*) 'zdf_tmx_init : tidal mixing' |
|---|
| 365 | WRITE(numout,*) '~~~~~~~~~~~~' |
|---|
| 366 | WRITE(numout,*) ' Namelist namzdf_tmx : set tidal mixing parameters' |
|---|
| 367 | WRITE(numout,*) ' Vertical decay scale for turbulence = ', rn_htmx |
|---|
| 368 | WRITE(numout,*) ' Brunt-Vaisala frequency threshold = ', rn_n2min |
|---|
| 369 | WRITE(numout,*) ' Tidal dissipation efficiency = ', rn_tfe |
|---|
| 370 | WRITE(numout,*) ' Mixing efficiency = ', rn_me |
|---|
| 371 | WRITE(numout,*) ' ITF specific parameterisation = ', ln_tmx_itf |
|---|
| 372 | WRITE(numout,*) ' ITF tidal dissipation efficiency = ', rn_tfe_itf |
|---|
| 373 | ENDIF |
|---|
| 374 | |
|---|
| 375 | ! ! allocate tmx arrays |
|---|
| 376 | IF( zdf_tmx_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'zdf_tmx_init : unable to allocate tmx arrays' ) |
|---|
| 377 | |
|---|
| 378 | IF( ln_tmx_itf ) THEN ! read the Indonesian Through Flow mask |
|---|
| 379 | CALL iom_open('mask_itf',inum) |
|---|
| 380 | CALL iom_get (inum, jpdom_data, 'tmaskitf',mask_itf,1) ! |
|---|
| 381 | CALL iom_close(inum) |
|---|
| 382 | ENDIF |
|---|
| 383 | |
|---|
| 384 | ! read M2 tidal energy flux : W/m2 ( zem2 < 0 ) |
|---|
| 385 | CALL iom_open('M2rowdrg',inum) |
|---|
| 386 | CALL iom_get (inum, jpdom_data, 'field',zem2,1) ! |
|---|
| 387 | CALL iom_close(inum) |
|---|
| 388 | |
|---|
| 389 | ! read K1 tidal energy flux : W/m2 ( zek1 < 0 ) |
|---|
| 390 | CALL iom_open('K1rowdrg',inum) |
|---|
| 391 | CALL iom_get (inum, jpdom_data, 'field',zek1,1) ! |
|---|
| 392 | CALL iom_close(inum) |
|---|
| 393 | |
|---|
| 394 | ! Total tidal energy ( M2, S2 and K1 with S2=(1/2)^2 * M2 ) |
|---|
| 395 | ! only the energy available for mixing is taken into account, |
|---|
| 396 | ! (mixing efficiency tidal dissipation efficiency) |
|---|
| 397 | en_tmx(:,:) = - rn_tfe * rn_me * ( zem2(:,:) * 1.25 + zek1(:,:) ) * tmask(:,:,1) |
|---|
| 398 | |
|---|
| 399 | ! Vertical structure (az_tmx) |
|---|
| 400 | DO jj = 1, jpj ! part independent of the level |
|---|
| 401 | DO ji = 1, jpi |
|---|
| 402 | zhdep(ji,jj) = fsdepw(ji,jj,mbkt(ji,jj)+1) ! depth of the ocean |
|---|
| 403 | zfact(ji,jj) = rau0 * rn_htmx * ( 1. - EXP( -zhdep(ji,jj) / rn_htmx ) ) |
|---|
| 404 | IF( zfact(ji,jj) /= 0 ) zfact(ji,jj) = en_tmx(ji,jj) / zfact(ji,jj) |
|---|
| 405 | END DO |
|---|
| 406 | END DO |
|---|
| 407 | DO jk= 1, jpk ! complete with the level-dependent part |
|---|
| 408 | DO jj = 1, jpj |
|---|
| 409 | DO ji = 1, jpi |
|---|
| 410 | az_tmx(ji,jj,jk) = zfact(ji,jj) * EXP( -( zhdep(ji,jj)-fsdepw(ji,jj,jk) ) / rn_htmx ) * tmask(ji,jj,jk) |
|---|
| 411 | END DO |
|---|
| 412 | END DO |
|---|
| 413 | END DO |
|---|
| 414 | |
|---|
| 415 | IF( nprint == 1 .AND. lwp ) THEN |
|---|
| 416 | ! Control print |
|---|
| 417 | ! Total power consumption due to vertical mixing |
|---|
| 418 | ! zpc = rau0 * 1/rn_me * rn2 * zav_tide |
|---|
| 419 | zav_tide(:,:,:) = 0.e0 |
|---|
| 420 | DO jk = 2, jpkm1 |
|---|
| 421 | zav_tide(:,:,jk) = az_tmx(:,:,jk) / MAX( rn_n2min, rn2(:,:,jk) ) |
|---|
| 422 | END DO |
|---|
| 423 | |
|---|
| 424 | ztpc = 0.e0 |
|---|
| 425 | zpc(:,:,:) = MAX(rn_n2min,rn2(:,:,:)) * zav_tide(:,:,:) |
|---|
| 426 | DO jk= 2, jpkm1 |
|---|
| 427 | DO jj = 1, jpj |
|---|
| 428 | DO ji = 1, jpi |
|---|
| 429 | ztpc = ztpc + fse3w(ji,jj,jk) * e1t(ji,jj) * e2t(ji,jj) * zpc(ji,jj,jk) * tmask(ji,jj,jk) * tmask_i(ji,jj) |
|---|
| 430 | END DO |
|---|
| 431 | END DO |
|---|
| 432 | END DO |
|---|
| 433 | ztpc= rau0 * 1/(rn_tfe * rn_me) * ztpc |
|---|
| 434 | |
|---|
| 435 | WRITE(numout,*) |
|---|
| 436 | WRITE(numout,*) ' Total power consumption of the tidally driven part of Kz : ztpc = ', ztpc * 1.e-12 ,'TW' |
|---|
| 437 | |
|---|
| 438 | |
|---|
| 439 | ! control print 2 |
|---|
| 440 | zav_tide(:,:,:) = MIN( zav_tide(:,:,:), 60.e-4 ) |
|---|
| 441 | zkz(:,:) = 0.e0 |
|---|
| 442 | DO jk = 2, jpkm1 |
|---|
| 443 | DO jj = 1, jpj |
|---|
| 444 | DO ji = 1, jpi |
|---|
| 445 | zkz(ji,jj) = zkz(ji,jj) + fse3w(ji,jj,jk) * MAX( 0.e0, rn2(ji,jj,jk) ) * rau0 * zav_tide(ji,jj,jk)* tmask(ji,jj,jk) |
|---|
| 446 | END DO |
|---|
| 447 | END DO |
|---|
| 448 | END DO |
|---|
| 449 | ! Here zkz should be equal to en_tmx ==> multiply by en_tmx/zkz |
|---|
| 450 | DO jj = 1, jpj |
|---|
| 451 | DO ji = 1, jpi |
|---|
| 452 | IF( zkz(ji,jj) /= 0.e0 ) THEN |
|---|
| 453 | zkz(ji,jj) = en_tmx(ji,jj) / zkz(ji,jj) |
|---|
| 454 | ENDIF |
|---|
| 455 | END DO |
|---|
| 456 | END DO |
|---|
| 457 | ztpc = 1.e50 |
|---|
| 458 | DO jj = 1, jpj |
|---|
| 459 | DO ji = 1, jpi |
|---|
| 460 | IF( zkz(ji,jj) /= 0.e0 ) THEN |
|---|
| 461 | ztpc = Min( zkz(ji,jj), ztpc) |
|---|
| 462 | ENDIF |
|---|
| 463 | END DO |
|---|
| 464 | END DO |
|---|
| 465 | WRITE(numout,*) ' Min de zkz ', ztpc, ' Max = ', maxval(zkz(:,:) ) |
|---|
| 466 | |
|---|
| 467 | DO jk = 2, jpkm1 |
|---|
| 468 | zav_tide(:,:,jk) = zav_tide(:,:,jk) * MIN( zkz(:,:), 30./6. ) !kz max = 300 cm2/s |
|---|
| 469 | END DO |
|---|
| 470 | ztpc = 0.e0 |
|---|
| 471 | zpc(:,:,:) = Max(0.e0,rn2(:,:,:)) * zav_tide(:,:,:) |
|---|
| 472 | DO jk= 1, jpk |
|---|
| 473 | DO jj = 1, jpj |
|---|
| 474 | DO ji = 1, jpi |
|---|
| 475 | ztpc = ztpc + fse3w(ji,jj,jk) * e1t(ji,jj) * e2t(ji,jj) * zpc(ji,jj,jk) * tmask(ji,jj,jk) * tmask_i(ji,jj) |
|---|
| 476 | END DO |
|---|
| 477 | END DO |
|---|
| 478 | END DO |
|---|
| 479 | ztpc= rau0 * 1/(rn_tfe * rn_me) * ztpc |
|---|
| 480 | WRITE(numout,*) ' 2 Total power consumption of the tidally driven part of Kz : ztpc = ', ztpc * 1.e-12 ,'TW' |
|---|
| 481 | |
|---|
| 482 | DO jk = 1, jpk |
|---|
| 483 | ze_z = SUM( e1t(:,:) * e2t(:,:) * zav_tide(:,:,jk) * tmask_i(:,:) ) & |
|---|
| 484 | & / MAX( 1.e-20, SUM( e1t(:,:) * e2t(:,:) * tmask (:,:,jk) * tmask_i(:,:) ) ) |
|---|
| 485 | ztpc = 1.E50 |
|---|
| 486 | DO jj = 1, jpj |
|---|
| 487 | DO ji = 1, jpi |
|---|
| 488 | IF( zav_tide(ji,jj,jk) /= 0.e0 ) ztpc =Min( ztpc, zav_tide(ji,jj,jk) ) |
|---|
| 489 | END DO |
|---|
| 490 | END DO |
|---|
| 491 | WRITE(numout,*) ' N2 min - jk= ', jk,' ', ze_z * 1.e4,' cm2/s min= ',ztpc*1.e4, & |
|---|
| 492 | & 'max= ', MAXVAL(zav_tide(:,:,jk) )*1.e4, ' cm2/s' |
|---|
| 493 | END DO |
|---|
| 494 | |
|---|
| 495 | WRITE(numout,*) ' e_tide : ', SUM( e1t*e2t*en_tmx ) / ( rn_tfe * rn_me ) * 1.e-12, 'TW' |
|---|
| 496 | WRITE(numout,*) |
|---|
| 497 | WRITE(numout,*) ' Initial profile of tidal vertical mixing' |
|---|
| 498 | DO jk = 1, jpk |
|---|
| 499 | DO jj = 1,jpj |
|---|
| 500 | DO ji = 1,jpi |
|---|
| 501 | zkz(ji,jj) = az_tmx(ji,jj,jk) /MAX( rn_n2min, rn2(ji,jj,jk) ) |
|---|
| 502 | END DO |
|---|
| 503 | END DO |
|---|
| 504 | ze_z = SUM( e1t(:,:) * e2t(:,:) * zkz(:,:) * tmask_i(:,:) ) & |
|---|
| 505 | & / MAX( 1.e-20, SUM( e1t(:,:) * e2t(:,:) * tmask (:,:,jk) * tmask_i(:,:) ) ) |
|---|
| 506 | WRITE(numout,*) ' jk= ', jk,' ', ze_z * 1.e4,' cm2/s' |
|---|
| 507 | END DO |
|---|
| 508 | DO jk = 1, jpk |
|---|
| 509 | zkz(:,:) = az_tmx(:,:,jk) /rn_n2min |
|---|
| 510 | ze_z = SUM( e1t(:,:) * e2t(:,:) * zkz(:,:) * tmask_i(:,:) ) & |
|---|
| 511 | & / MAX( 1.e-20, SUM( e1t(:,:) * e2t(:,:) * tmask (:,:,jk) * tmask_i(:,:) ) ) |
|---|
| 512 | WRITE(numout,*) |
|---|
| 513 | WRITE(numout,*) ' N2 min - jk= ', jk,' ', ze_z * 1.e4,' cm2/s min= ',MINVAL(zkz)*1.e4, & |
|---|
| 514 | & 'max= ', MAXVAL(zkz)*1.e4, ' cm2/s' |
|---|
| 515 | END DO |
|---|
| 516 | ! |
|---|
| 517 | ENDIF |
|---|
| 518 | ! |
|---|
| 519 | CALL wrk_dealloc( jpi,jpj, zem2, zek1, zkz, zfact, zhdep ) |
|---|
| 520 | CALL wrk_dealloc( jpi,jpj,jpk, zpc ) |
|---|
| 521 | ! |
|---|
| 522 | END SUBROUTINE zdf_tmx_init |
|---|
| 523 | |
|---|
| 524 | #else |
|---|
| 525 | !!---------------------------------------------------------------------- |
|---|
| 526 | !! Default option Dummy module NO Tidal MiXing |
|---|
| 527 | !!---------------------------------------------------------------------- |
|---|
| 528 | LOGICAL, PUBLIC, PARAMETER :: lk_zdftmx = .FALSE. !: tidal mixing flag |
|---|
| 529 | CONTAINS |
|---|
| 530 | SUBROUTINE zdf_tmx_init ! Dummy routine |
|---|
| 531 | WRITE(*,*) 'zdf_tmx: You should not have seen this print! error?' |
|---|
| 532 | END SUBROUTINE zdf_tmx_init |
|---|
| 533 | SUBROUTINE zdf_tmx( kt ) ! Dummy routine |
|---|
| 534 | WRITE(*,*) 'zdf_tmx: You should not have seen this print! error?', kt |
|---|
| 535 | END SUBROUTINE zdf_tmx |
|---|
| 536 | #endif |
|---|
| 537 | |
|---|
| 538 | !!====================================================================== |
|---|
| 539 | END MODULE zdftmx |
|---|
