New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

nemogcm.F90 in branches/2011/dev_NEMO_MERGE_2011/NEMOGCM/NEMO/OPA_SRC – NEMO

Context Navigation

source: branches/2011/dev_NEMO_MERGE_2011/NEMOGCM/NEMO/OPA_SRC/nemogcm.F90 @ 3116

Last change on this file since 3116 was 3116, checked in by cetlod, 13 years ago
dev_NEMO_MERGE_2011: add in changes dev_NOC_UKMO_MERGE developments
Property svn:keywords set to `Id`
File size: 35.8 KB

Line
1	MODULE nemogcm
2	!!======================================================================
3	!! * MODULE nemogcm *
4	!! Ocean system : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5	!!======================================================================
6	!! History : OPA ! 1990-10 (C. Levy, G. Madec) Original code
7	!! 7.0 ! 1991-11 (M. Imbard, C. Levy, G. Madec)
8	!! 7.1 ! 1993-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9	!! P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10	!! - ! 1992-06 (L.Terray) coupling implementation
11	!! - ! 1993-11 (M.A. Filiberti) IGLOO sea-ice
12	!! 8.0 ! 1996-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13	!! P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14	!! 8.1 ! 1997-06 (M. Imbard, G. Madec)
15	!! 8.2 ! 1999-11 (M. Imbard, H. Goosse) LIM sea-ice model
16	!! ! 1999-12 (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols) OPEN-MP
17	!! ! 2000-07 (J-M Molines, M. Imbard) Open Boundary Conditions (CLIPPER)
18	!! NEMO 1.0 ! 2002-08 (G. Madec) F90: Free form and modules
19	!! - ! 2004-06 (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20	!! - ! 2004-08 (C. Talandier) New trends organization
21	!! - ! 2005-06 (C. Ethe) Add the 1D configuration possibility
22	!! - ! 2005-11 (V. Garnier) Surface pressure gradient organization
23	!! - ! 2006-03 (L. Debreu, C. Mazauric) Agrif implementation
24	!! - ! 2006-04 (G. Madec, R. Benshila) Step reorganization
25	!! - ! 2007-07 (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26	!! 3.2 ! 2009-08 (S. Masson) open/write in the listing file in mpp
27	!! 3.3 ! 2010-05 (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28	!! - ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase
29	!! 3.3.1! 2011-01 (A. R. Porter, STFC Daresbury) dynamical allocation
30	!! 3.4 ! 2011-11 (C. Harris) decomposition changes for running with CICE
31	!!----------------------------------------------------------------------
32
33	!!----------------------------------------------------------------------
34	!! nemo_gcm : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
35	!! nemo_init : initialization of the NEMO system
36	!! nemo_ctl : initialisation of the contol print
37	!! nemo_closefile : close remaining open files
38	!! nemo_alloc : dynamical allocation
39	!! nemo_partition : calculate MPP domain decomposition
40	!! factorise : calculate the factors of the no. of MPI processes
41	!!----------------------------------------------------------------------
42	USE step_oce ! module used in the ocean time stepping module
43	USE sbc_oce ! surface boundary condition: ocean
44	USE cla ! cross land advection (tra_cla routine)
45	USE domcfg ! domain configuration (dom_cfg routine)
46	USE mppini ! shared/distributed memory setting (mpp_init routine)
47	USE domain ! domain initialization (dom_init routine)
48	USE obcini ! open boundary cond. initialization (obc_ini routine)
49	USE bdyini ! open boundary cond. initialization (bdy_init routine)
50	USE bdydta ! open boundary cond. initialization (bdy_dta_init routine)
51	USE bdytides ! open boundary cond. initialization (tide_init routine)
52	USE istate ! initial state setting (istate_init routine)
53	USE ldfdyn ! lateral viscosity setting (ldfdyn_init routine)
54	USE ldftra ! lateral diffusivity setting (ldftra_init routine)
55	USE zdfini ! vertical physics setting (zdf_init routine)
56	USE phycst ! physical constant (par_cst routine)
57	USE trdmod ! momentum/tracers trends (trd_mod_init routine)
58	USE asminc ! assimilation increments (asm_inc_init routine)
59	USE asmtrj ! writing out state trajectory
60	USE sshwzv ! vertical velocity used in asm
61	USE diaptr ! poleward transports (dia_ptr_init routine)
62	USE diadct ! sections transports (dia_dct_init routine)
63	USE diaobs ! Observation diagnostics (dia_obs_init routine)
64	USE step ! NEMO time-stepping (stp routine)
65	#if defined key_oasis3
66	USE cpl_oasis3 ! OASIS3 coupling
67	#elif defined key_oasis4
68	USE cpl_oasis4 ! OASIS4 coupling (not working)
69	#endif
70	USE c1d ! 1D configuration
71	USE step_c1d ! Time stepping loop for the 1D configuration
72	USE dynnept ! simplified form of Neptune effect
73	#if defined key_top
74	USE trcini ! passive tracer initialisation
75	#endif
76	USE lib_mpp ! distributed memory computing
77	#if defined key_iomput
78	USE mod_ioclient
79	#endif
80
81	IMPLICIT NONE
82	PRIVATE
83
84	PUBLIC nemo_gcm ! called by model.F90
85	PUBLIC nemo_init ! needed by AGRIF
86
87	CHARACTER(lc) :: cform_aaa="( /, 'AAAAAAAA', / ) " ! flag for output listing
88
89	!!----------------------------------------------------------------------
90	!! NEMO/OPA 4.0 , NEMO Consortium (2011)
91	!! $Id$
92	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
93	!!----------------------------------------------------------------------
94	CONTAINS
95
96	SUBROUTINE nemo_gcm
97	!!----------------------------------------------------------------------
98	!! * ROUTINE nemo_gcm *
99	!!
100	!! ** Purpose : NEMO solves the primitive equations on an orthogonal
101	!! curvilinear mesh on the sphere.
102	!!
103	!! ** Method : - model general initialization
104	!! - launch the time-stepping (stp routine)
105	!! - finalize the run by closing files and communications
106	!!
107	!! References : Madec, Delecluse, Imbard, and Levy, 1997: internal report, IPSL.
108	!! Madec, 2008, internal report, IPSL.
109	!!----------------------------------------------------------------------
110	INTEGER :: istp ! time step index
111	!!----------------------------------------------------------------------
112	!
113	#if defined key_agrif
114	CALL Agrif_Init_Grids() ! AGRIF: set the meshes
115	#endif
116
117	! !-----------------------!
118	CALL nemo_init !== Initialisations ==!
119	! !-----------------------!
120	#if defined key_agrif
121	CALL Agrif_Declare_Var ! AGRIF: set the meshes
122	# if defined key_top
123	CALL Agrif_Declare_Var_Top ! AGRIF: set the meshes
124	# endif
125	#endif
126	! check that all process are still there... If some process have an error,
127	! they will never enter in step and other processes will wait until the end of the cpu time!
128	IF( lk_mpp ) CALL mpp_max( nstop )
129
130	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
131
132	! !-----------------------!
133	! !== time stepping ==!
134	! !-----------------------!
135	istp = nit000
136	#if defined key_c1d
137	DO WHILE ( istp <= nitend .AND. nstop == 0 )
138	CALL stp_c1d( istp )
139	istp = istp + 1
140	END DO
141	#else
142	IF( lk_asminc ) THEN
143	IF( ln_bkgwri ) CALL asm_bkg_wri( nit000 - 1 ) ! Output background fields
144	IF( ln_trjwri ) CALL asm_trj_wri( nit000 - 1 ) ! Output trajectory fields
145	IF( ln_asmdin ) THEN ! Direct initialization
146	IF( ln_trainc ) CALL tra_asm_inc( nit000 - 1 ) ! Tracers
147	IF( ln_dyninc ) THEN
148	CALL dyn_asm_inc( nit000 - 1 ) ! Dynamics
149	IF ( ln_asmdin ) CALL ssh_wzv ( nit000 - 1 ) ! update vertical velocity
150	ENDIF
151	IF( ln_sshinc ) CALL ssh_asm_inc( nit000 - 1 ) ! SSH
152	ENDIF
153	ENDIF
154
155	DO WHILE ( istp <= nitend .AND. nstop == 0 )
156	#if defined key_agrif
157	CALL Agrif_Step( stp ) ! AGRIF: time stepping
158	#else
159	CALL stp( istp ) ! standard time stepping
160	#endif
161	istp = istp + 1
162	IF( lk_mpp ) CALL mpp_max( nstop )
163	END DO
164	#endif
165
166	IF( lk_diaobs ) CALL dia_obs_wri
167
168	! !------------------------!
169	! !== finalize the run ==!
170	! !------------------------!
171	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
172	!
173	IF( nstop /= 0 .AND. lwp ) THEN ! error print
174	WRITE(numout,cform_err)
175	WRITE(numout,*) nstop, ' error have been found'
176	ENDIF
177	!
178	CALL nemo_closefile
179	#if defined key_oasis3 \|\| defined key_oasis4
180	CALL cpl_prism_finalize ! end coupling and mpp communications with OASIS
181	#else
182	IF( lk_mpp ) CALL mppstop ! end mpp communications
183	#endif
184	!
185	END SUBROUTINE nemo_gcm
186
187
188	SUBROUTINE nemo_init
189	!!----------------------------------------------------------------------
190	!! * ROUTINE nemo_init *
191	!!
192	!! ** Purpose : initialization of the NEMO GCM
193	!!----------------------------------------------------------------------
194	INTEGER :: ji ! dummy loop indices
195	INTEGER :: ilocal_comm ! local integer
196	CHARACTER(len=80), DIMENSION(16) :: cltxt
197	!!
198	NAMELIST/namctl/ ln_ctl , nn_print, nn_ictls, nn_ictle, &
199	& nn_isplt, nn_jsplt, nn_jctls, nn_jctle, nn_bench
200	!!----------------------------------------------------------------------
201	!
202	cltxt = ''
203	!
204	! ! open Namelist file
205	CALL ctl_opn( numnam, 'namelist', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
206	!
207	READ( numnam, namctl ) ! Namelist namctl : Control prints & Benchmark
208	!
209	! !--------------------------------------------!
210	! ! set communicator & select the local node !
211	! !--------------------------------------------!
212	#if defined key_iomput
213	IF( Agrif_Root() ) THEN
214	# if defined key_oasis3 \|\| defined key_oasis4
215	CALL cpl_prism_init( ilocal_comm ) ! nemo local communicator given by oasis
216	# endif
217	CALL init_ioclient( ilocal_comm ) ! exchange io_server nemo local communicator with the io_server
218	ENDIF
219	narea = mynode( cltxt, numnam, nstop, ilocal_comm ) ! Nodes selection
220	#else
221	# if defined key_oasis3 \|\| defined key_oasis4
222	IF( Agrif_Root() ) THEN
223	CALL cpl_prism_init( ilocal_comm ) ! nemo local communicator given by oasis
224	ENDIF
225	narea = mynode( cltxt, numnam, nstop, ilocal_comm ) ! Nodes selection (control print return in cltxt)
226	# else
227	ilocal_comm = 0
228	narea = mynode( cltxt, numnam, nstop ) ! Nodes selection (control print return in cltxt)
229	# endif
230	#endif
231	narea = narea + 1 ! mynode return the rank of proc (0 --> jpnij -1 )
232
233	lwp = (narea == 1) .OR. ln_ctl ! control of all listing output print
234
235	! If dimensions of processor grid weren't specified in the namelist file
236	! then we calculate them here now that we have our communicator size
237	IF( (jpni < 1) .OR. (jpnj < 1) )THEN
238	#if defined key_mpp_mpi
239	IF( Agrif_Root() ) CALL nemo_partition(mppsize)
240	#else
241	jpni = 1
242	jpnj = 1
243	jpnij = jpni*jpnj
244	#endif
245	END IF
246
247	! Calculate domain dimensions given calculated jpni and jpnj
248	! This used to be done in par_oce.F90 when they were parameters rather
249	! than variables
250	IF( Agrif_Root() ) THEN
251	jpi = ( jpiglo-2jpreci + (jpni-1) ) / jpni + 2jpreci ! first dim.
252	#if defined key_nemocice_decomp
253	jpj = ( jpjglo+1-2jprecj + (jpnj-1) ) / jpnj + 2jprecj ! second dim.
254	#else
255	jpj = ( jpjglo-2jprecj + (jpnj-1) ) / jpnj + 2jprecj ! second dim.
256	#endif
257	jpk = jpkdta ! third dim
258	jpim1 = jpi-1 ! inner domain indices
259	jpjm1 = jpj-1 ! " "
260	jpkm1 = jpk-1 ! " "
261	jpij = jpi*jpj ! jpi x j
262	ENDIF
263
264	IF(lwp) THEN ! open listing units
265	!
266	CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
267	!
268	WRITE(numout,*)
269	WRITE(numout,*) ' CNRS - NERC - Met OFFICE - MERCATOR-ocean'
270	WRITE(numout,*) ' NEMO team'
271	WRITE(numout,*) ' Ocean General Circulation Model'
272	WRITE(numout,*) ' version 3.3 (2010) '
273	WRITE(numout,*)
274	WRITE(numout,*)
275	DO ji = 1, SIZE(cltxt)
276	IF( TRIM(cltxt(ji)) /= '' ) WRITE(numout,*) cltxt(ji) ! control print of mynode
277	END DO
278	WRITE(numout,cform_aaa) ! Flag AAAAAAA
279	!
280	ENDIF
281
282	! Now we know the dimensions of the grid and numout has been set we can
283	! allocate arrays
284	CALL nemo_alloc()
285
286	! !-------------------------------!
287	! ! NEMO general initialization !
288	! !-------------------------------!
289
290	CALL nemo_ctl ! Control prints & Benchmark
291
292	! ! Domain decomposition
293	IF( jpni*jpnj == jpnij ) THEN ; CALL mpp_init ! standard cutting out
294	ELSE ; CALL mpp_init2 ! eliminate land processors
295	ENDIF
296	!
297	! ! General initialization
298	CALL phy_cst ! Physical constants
299	CALL eos_init ! Equation of state
300	CALL dom_cfg ! Domain configuration
301	CALL dom_init ! Domain
302
303	IF( ln_nnogather ) CALL nemo_northcomms ! Initialise the northfold neighbour lists (must be done after the masks are defined)
304
305	IF( ln_ctl ) CALL prt_ctl_init ! Print control
306
307	IF( lk_obc ) CALL obc_init ! Open boundaries
308	IF( lk_bdy ) CALL bdy_init ! Open boundaries initialisation
309	IF( lk_bdy ) CALL bdy_dta_init ! Open boundaries initialisation of external data arrays
310	IF( lk_bdy ) CALL tide_init ! Open boundaries initialisation of tidal harmonic forcing
311
312	CALL flush(numout)
313	CALL dyn_nept_init ! simplified form of Neptune effect
314	CALL flush(numout)
315
316	CALL istate_init ! ocean initial state (Dynamics and tracers)
317
318	! ! Ocean physics
319	CALL sbc_init ! Forcings : surface module
320	! ! Vertical physics
321	CALL zdf_init ! namelist read
322	CALL zdf_bfr_init ! bottom friction
323	IF( lk_zdfric ) CALL zdf_ric_init ! Richardson number dependent Kz
324	IF( lk_zdftke ) CALL zdf_tke_init ! TKE closure scheme
325	IF( lk_zdfgls ) CALL zdf_gls_init ! GLS closure scheme
326	IF( lk_zdfkpp ) CALL zdf_kpp_init ! KPP closure scheme
327	IF( lk_zdftmx ) CALL zdf_tmx_init ! tidal vertical mixing
328	IF( lk_zdfddm .AND. .NOT. lk_zdfkpp ) &
329	& CALL zdf_ddm_init ! double diffusive mixing
330	! ! Lateral physics
331	CALL ldf_tra_init ! Lateral ocean tracer physics
332	CALL ldf_dyn_init ! Lateral ocean momentum physics
333	IF( lk_ldfslp ) CALL ldf_slp_init ! slope of lateral mixing
334
335	! ! Active tracers
336	CALL tra_qsr_init ! penetrative solar radiation qsr
337	CALL tra_bbc_init ! bottom heat flux
338	IF( lk_trabbl ) CALL tra_bbl_init ! advective (and/or diffusive) bottom boundary layer scheme
339	IF( ln_tradmp ) CALL tra_dmp_init ! internal damping trends
340	CALL tra_adv_init ! horizontal & vertical advection
341	CALL tra_ldf_init ! lateral mixing
342	CALL tra_zdf_init ! vertical mixing and after tracer fields
343
344	! ! Dynamics
345	CALL dyn_adv_init ! advection (vector or flux form)
346	CALL dyn_vor_init ! vorticity term including Coriolis
347	CALL dyn_ldf_init ! lateral mixing
348	CALL dyn_hpg_init ! horizontal gradient of Hydrostatic pressure
349	CALL dyn_zdf_init ! vertical diffusion
350	CALL dyn_spg_init ! surface pressure gradient
351
352	! ! Misc. options
353	IF( nn_cla == 1 ) CALL cla_init ! Cross Land Advection
354
355	#if defined key_top
356	! ! Passive tracers
357	CALL trc_init
358	#endif
359	! ! Diagnostics
360	IF( lk_floats ) CALL flo_init ! drifting Floats
361	CALL iom_init ! iom_put initialization
362	IF( lk_diaar5 ) CALL dia_ar5_init ! ar5 diag
363	CALL dia_ptr_init ! Poleward TRansports initialization
364	IF( lk_diadct ) CALL dia_dct_init ! Sections tranports
365	CALL dia_hsb_init ! heat content, salt content and volume budgets
366	CALL trd_mod_init ! Mixed-layer/Vorticity/Integral constraints trends
367	IF( lk_diaobs ) THEN ! Observation & model comparison
368	CALL dia_obs_init ! Initialize observational data
369	CALL dia_obs( nit000 - 1 ) ! Observation operator for restart
370	ENDIF
371	! ! Assimilation increments
372	IF( lk_asminc ) CALL asm_inc_init ! Initialize assimilation increments
373	IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
374	!
375	END SUBROUTINE nemo_init
376
377
378	SUBROUTINE nemo_ctl
379	!!----------------------------------------------------------------------
380	!! * ROUTINE nemo_ctl *
381	!!
382	!! ** Purpose : control print setting
383	!!
384	!! ** Method : - print namctl information and check some consistencies
385	!!----------------------------------------------------------------------
386	!
387	IF(lwp) THEN ! control print
388	WRITE(numout,*)
389	WRITE(numout,*) 'nemo_ctl: Control prints & Benchmark'
390	WRITE(numout,*) '~~~~~~~ '
391	WRITE(numout,*) ' Namelist namctl'
392	WRITE(numout,*) ' run control (for debugging) ln_ctl = ', ln_ctl
393	WRITE(numout,*) ' level of print nn_print = ', nn_print
394	WRITE(numout,*) ' Start i indice for SUM control nn_ictls = ', nn_ictls
395	WRITE(numout,*) ' End i indice for SUM control nn_ictle = ', nn_ictle
396	WRITE(numout,*) ' Start j indice for SUM control nn_jctls = ', nn_jctls
397	WRITE(numout,*) ' End j indice for SUM control nn_jctle = ', nn_jctle
398	WRITE(numout,*) ' number of proc. following i nn_isplt = ', nn_isplt
399	WRITE(numout,*) ' number of proc. following j nn_jsplt = ', nn_jsplt
400	WRITE(numout,*) ' benchmark parameter (0/1) nn_bench = ', nn_bench
401	ENDIF
402	!
403	nprint = nn_print ! convert DOCTOR namelist names into OLD names
404	nictls = nn_ictls
405	nictle = nn_ictle
406	njctls = nn_jctls
407	njctle = nn_jctle
408	isplt = nn_isplt
409	jsplt = nn_jsplt
410	nbench = nn_bench
411	! ! Parameter control
412	!
413	IF( ln_ctl ) THEN ! sub-domain area indices for the control prints
414	IF( lk_mpp ) THEN
415	isplt = jpni ; jsplt = jpnj ; ijsplt = jpni*jpnj ! the domain is forced to the real split domain
416	ELSE
417	IF( isplt == 1 .AND. jsplt == 1 ) THEN
418	CALL ctl_warn( ' - isplt & jsplt are equal to 1', &
419	& ' - the print control will be done over the whole domain' )
420	ENDIF
421	ijsplt = isplt * jsplt ! total number of processors ijsplt
422	ENDIF
423	IF(lwp) WRITE(numout,*)' - The total number of processors over which the'
424	IF(lwp) WRITE(numout,*)' print control will be done is ijsplt : ', ijsplt
425	!
426	! ! indices used for the SUM control
427	IF( nictls+nictle+njctls+njctle == 0 ) THEN ! print control done over the default area
428	lsp_area = .FALSE.
429	ELSE ! print control done over a specific area
430	lsp_area = .TRUE.
431	IF( nictls < 1 .OR. nictls > jpiglo ) THEN
432	CALL ctl_warn( ' - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
433	nictls = 1
434	ENDIF
435	IF( nictle < 1 .OR. nictle > jpiglo ) THEN
436	CALL ctl_warn( ' - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
437	nictle = jpiglo
438	ENDIF
439	IF( njctls < 1 .OR. njctls > jpjglo ) THEN
440	CALL ctl_warn( ' - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
441	njctls = 1
442	ENDIF
443	IF( njctle < 1 .OR. njctle > jpjglo ) THEN
444	CALL ctl_warn( ' - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
445	njctle = jpjglo
446	ENDIF
447	ENDIF
448	ENDIF
449	!
450	IF( nbench == 1 ) THEN ! Benchmark
451	SELECT CASE ( cp_cfg )
452	CASE ( 'gyre' ) ; CALL ctl_warn( ' The Benchmark is activated ' )
453	CASE DEFAULT ; CALL ctl_stop( ' The Benchmark is based on the GYRE configuration:', &
454	& ' key_gyre must be used or set nbench = 0' )
455	END SELECT
456	ENDIF
457	!
458	IF( lk_c1d .AND. .NOT.lk_iomput ) CALL ctl_stop( 'nemo_ctl: The 1D configuration must be used ', &
459	& 'with the IOM Input/Output manager. ' , &
460	& 'Compile with key_iomput enabled' )
461	!
462	END SUBROUTINE nemo_ctl
463
464
465	SUBROUTINE nemo_closefile
466	!!----------------------------------------------------------------------
467	!! * ROUTINE nemo_closefile *
468	!!
469	!! ** Purpose : Close the files
470	!!----------------------------------------------------------------------
471	!
472	IF( lk_mpp ) CALL mppsync
473	!
474	CALL iom_close ! close all input/output files managed by iom_*
475	!
476	IF( numstp /= -1 ) CLOSE( numstp ) ! time-step file
477	IF( numsol /= -1 ) CLOSE( numsol ) ! solver file
478	IF( numnam /= -1 ) CLOSE( numnam ) ! oce namelist
479	IF( numnam_ice /= -1 ) CLOSE( numnam_ice ) ! ice namelist
480	IF( numevo_ice /= -1 ) CLOSE( numevo_ice ) ! ice variables (temp. evolution)
481	IF( numout /= 6 ) CLOSE( numout ) ! standard model output file
482	IF( numdct_vol /= -1 ) CLOSE( numdct_vol ) ! volume transports
483	IF( numdct_heat /= -1 ) CLOSE( numdct_heat ) ! heat transports
484	IF( numdct_salt /= -1 ) CLOSE( numdct_salt ) ! salt transports
485
486	!
487	numout = 6 ! redefine numout in case it is used after this point...
488	!
489	END SUBROUTINE nemo_closefile
490
491
492	SUBROUTINE nemo_alloc
493	!!----------------------------------------------------------------------
494	!! * ROUTINE nemo_alloc *
495	!!
496	!! ** Purpose : Allocate all the dynamic arrays of the OPA modules
497	!!
498	!! ** Method :
499	!!----------------------------------------------------------------------
500	USE diawri , ONLY: dia_wri_alloc
501	USE dom_oce , ONLY: dom_oce_alloc
502	USE ldfdyn_oce, ONLY: ldfdyn_oce_alloc
503	USE ldftra_oce, ONLY: ldftra_oce_alloc
504	USE trc_oce , ONLY: trc_oce_alloc
505	USE wrk_nemo , ONLY: wrk_alloc
506	!
507	INTEGER :: ierr
508	!!----------------------------------------------------------------------
509	!
510	ierr = oce_alloc () ! ocean
511	ierr = ierr + dia_wri_alloc ()
512	ierr = ierr + dom_oce_alloc () ! ocean domain
513	ierr = ierr + ldfdyn_oce_alloc() ! ocean lateral physics : dynamics
514	ierr = ierr + ldftra_oce_alloc() ! ocean lateral physics : tracers
515	ierr = ierr + zdf_oce_alloc () ! ocean vertical physics
516	!
517	ierr = ierr + lib_mpp_alloc (numout) ! mpp exchanges
518	ierr = ierr + trc_oce_alloc () ! shared TRC / TRA arrays
519	!
520	ierr = ierr + wrk_alloc(numout, lwp) ! workspace
521	!
522	IF( lk_mpp ) CALL mpp_sum( ierr )
523	IF( ierr /= 0 ) CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' )
524	!
525	END SUBROUTINE nemo_alloc
526
527
528	SUBROUTINE nemo_partition( num_pes )
529	!!----------------------------------------------------------------------
530	!! * ROUTINE nemo_partition *
531	!!
532	!! ** Purpose :
533	!!
534	!! ** Method :
535	!!----------------------------------------------------------------------
536	INTEGER, INTENT(in) :: num_pes ! The number of MPI processes we have
537	!
538	INTEGER, PARAMETER :: nfactmax = 20
539	INTEGER :: nfact ! The no. of factors returned
540	INTEGER :: ierr ! Error flag
541	INTEGER :: ji
542	INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
543	INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
544	!!----------------------------------------------------------------------
545
546	ierr = 0
547
548	CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
549
550	IF( nfact <= 1 ) THEN
551	WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
552	WRITE (numout, *) ' : using grid of ',num_pes,' x 1'
553	jpnj = 1
554	jpni = num_pes
555	ELSE
556	! Search through factors for the pair that are closest in value
557	mindiff = 1000000
558	imin = 1
559	DO ji = 1, nfact-1, 2
560	idiff = ABS( ifact(ji) - ifact(ji+1) )
561	IF( idiff < mindiff ) THEN
562	mindiff = idiff
563	imin = ji
564	ENDIF
565	END DO
566	jpnj = ifact(imin)
567	jpni = ifact(imin + 1)
568	ENDIF
569	!
570	jpnij = jpni*jpnj
571	!
572	END SUBROUTINE nemo_partition
573
574
575	SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
576	!!----------------------------------------------------------------------
577	!! * ROUTINE factorise *
578	!!
579	!! ** Purpose : return the prime factors of n.
580	!! knfax factors are returned in array kfax which is of
581	!! maximum dimension kmaxfax.
582	!! ** Method :
583	!!----------------------------------------------------------------------
584	INTEGER , INTENT(in ) :: kn, kmaxfax
585	INTEGER , INTENT( out) :: kerr, knfax
586	INTEGER, DIMENSION(kmaxfax), INTENT( out) :: kfax
587	!
588	INTEGER :: ifac, jl, inu
589	INTEGER, PARAMETER :: ntest = 14
590	INTEGER :: ilfax(ntest)
591
592	! lfax contains the set of allowed factors.
593	data (ilfax(jl),jl=1,ntest) / 16384, 8192, 4096, 2048, 1024, 512, 256, &
594	& 128, 64, 32, 16, 8, 4, 2 /
595	!!----------------------------------------------------------------------
596
597	! Clear the error flag and initialise output vars
598	kerr = 0
599	kfax = 1
600	knfax = 0
601
602	! Find the factors of n.
603	IF( kn == 1 ) GOTO 20
604
605	! nu holds the unfactorised part of the number.
606	! knfax holds the number of factors found.
607	! l points to the allowed factor list.
608	! ifac holds the current factor.
609
610	inu = kn
611	knfax = 0
612
613	DO jl = ntest, 1, -1
614	!
615	ifac = ilfax(jl)
616	IF( ifac > inu ) CYCLE
617
618	! Test whether the factor will divide.
619
620	IF( MOD(inu,ifac) == 0 ) THEN
621	!
622	knfax = knfax + 1 ! Add the factor to the list
623	IF( knfax > kmaxfax ) THEN
624	kerr = 6
625	write (,) 'FACTOR: insufficient space in factor array ', knfax
626	return
627	ENDIF
628	kfax(knfax) = ifac
629	! Store the other factor that goes with this one
630	knfax = knfax + 1
631	kfax(knfax) = inu / ifac
632	!WRITE (,) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
633	ENDIF
634	!
635	END DO
636
637	20 CONTINUE ! Label 20 is the exit point from the factor search loop.
638	!
639	END SUBROUTINE factorise
640
641	#if defined key_mpp_mpi
642	SUBROUTINE nemo_northcomms
643	!!======================================================================
644	!! * ROUTINE nemo_northcomms *
645	!! nemo_northcomms : Setup for north fold exchanges with explicit peer to peer messaging
646	!!=====================================================================
647	!!----------------------------------------------------------------------
648	!!
649	!! ** Purpose : Initialization of the northern neighbours lists.
650	!!----------------------------------------------------------------------
651	!! 1.0 ! 2011-10 (A. C. Coward, NOCS & J. Donners, PRACE)
652	!!----------------------------------------------------------------------
653
654	INTEGER :: ji, jj, jk, ij, jtyp ! dummy loop indices
655	INTEGER :: ijpj ! number of rows involved in north-fold exchange
656	INTEGER :: northcomms_alloc ! allocate return status
657	REAL(wp), ALLOCATABLE, DIMENSION ( :,: ) :: znnbrs ! workspace
658	LOGICAL, ALLOCATABLE, DIMENSION ( : ) :: lrankset ! workspace
659
660	IF(lwp) WRITE(numout,*)
661	IF(lwp) WRITE(numout,*) 'nemo_northcomms : Initialization of the northern neighbours lists'
662	IF(lwp) WRITE(numout,*) '~~~~~~~~~~'
663
664	!!----------------------------------------------------------------------
665	ALLOCATE( znnbrs(jpi,jpj), stat = northcomms_alloc )
666	ALLOCATE( lrankset(jpnij), stat = northcomms_alloc )
667	IF( northcomms_alloc /= 0 ) THEN
668	WRITE(numout,cform_war)
669	WRITE(numout,*) 'northcomms_alloc : failed to allocate arrays'
670	CALL ctl_stop( 'STOP', 'nemo_northcomms : unable to allocate temporary arrays' )
671	ENDIF
672	nsndto = 0
673	isendto = -1
674	ijpj = 4
675	!
676	! This routine has been called because ln_nnogather has been set true ( nammpp )
677	! However, these first few exchanges have to use the mpi_allgather method to
678	! establish the neighbour lists to use in subsequent peer to peer exchanges.
679	! Consequently, set l_north_nogather to be false here and set it true only after
680	! the lists have been established.
681	!
682	l_north_nogather = .FALSE.
683	!
684	! Exchange and store ranks on northern rows
685
686	DO jtyp = 1,4
687
688	lrankset = .FALSE.
689	znnbrs = narea
690	SELECT CASE (jtyp)
691	CASE(1)
692	CALL lbc_lnk( znnbrs, 'T', 1. ) ! Type 1: T,W-points
693	CASE(2)
694	CALL lbc_lnk( znnbrs, 'U', 1. ) ! Type 2: U-point
695	CASE(3)
696	CALL lbc_lnk( znnbrs, 'V', 1. ) ! Type 3: V-point
697	CASE(4)
698	CALL lbc_lnk( znnbrs, 'F', 1. ) ! Type 4: F-point
699	END SELECT
700
701	IF ( njmppt(narea) .EQ. MAXVAL( njmppt ) ) THEN
702	DO jj = nlcj-ijpj+1, nlcj
703	ij = jj - nlcj + ijpj
704	DO ji = 1,jpi
705	IF ( INT(znnbrs(ji,jj)) .NE. 0 .AND. INT(znnbrs(ji,jj)) .NE. narea ) &
706	& lrankset(INT(znnbrs(ji,jj))) = .true.
707	END DO
708	END DO
709
710	DO jj = 1,jpnij
711	IF ( lrankset(jj) ) THEN
712	nsndto(jtyp) = nsndto(jtyp) + 1
713	IF ( nsndto(jtyp) .GT. jpmaxngh ) THEN
714	CALL ctl_stop( ' Too many neighbours in nemo_northcomms ', &
715	& ' jpmaxngh will need to be increased ')
716	ENDIF
717	isendto(nsndto(jtyp),jtyp) = jj-1 ! narea converted to MPI rank
718	ENDIF
719	END DO
720	ENDIF
721
722	END DO
723
724	!
725	! Type 5: I-point
726	!
727	! ICE point exchanges may involve some averaging. The neighbours list is
728	! built up using two exchanges to ensure that the whole stencil is covered.
729	! lrankset should not be reset between these 'J' and 'K' point exchanges
730
731	jtyp = 5
732	lrankset = .FALSE.
733	znnbrs = narea
734	CALL lbc_lnk( znnbrs, 'J', 1. ) ! first ice U-V point
735
736	IF ( njmppt(narea) .EQ. MAXVAL( njmppt ) ) THEN
737	DO jj = nlcj-ijpj+1, nlcj
738	ij = jj - nlcj + ijpj
739	DO ji = 1,jpi
740	IF ( INT(znnbrs(ji,jj)) .NE. 0 .AND. INT(znnbrs(ji,jj)) .NE. narea ) &
741	& lrankset(INT(znnbrs(ji,jj))) = .true.
742	END DO
743	END DO
744	ENDIF
745
746	znnbrs = narea
747	CALL lbc_lnk( znnbrs, 'K', 1. ) ! second ice U-V point
748
749	IF ( njmppt(narea) .EQ. MAXVAL( njmppt )) THEN
750	DO jj = nlcj-ijpj+1, nlcj
751	ij = jj - nlcj + ijpj
752	DO ji = 1,jpi
753	IF ( INT(znnbrs(ji,jj)) .NE. 0 .AND. INT(znnbrs(ji,jj)) .NE. narea ) &
754	& lrankset( INT(znnbrs(ji,jj))) = .true.
755	END DO
756	END DO
757
758	DO jj = 1,jpnij
759	IF ( lrankset(jj) ) THEN
760	nsndto(jtyp) = nsndto(jtyp) + 1
761	IF ( nsndto(jtyp) .GT. jpmaxngh ) THEN
762	CALL ctl_stop( ' Too many neighbours in nemo_northcomms ', &
763	& ' jpmaxngh will need to be increased ')
764	ENDIF
765	isendto(nsndto(jtyp),jtyp) = jj-1 ! narea converted to MPI rank
766	ENDIF
767	END DO
768	!
769	! For northern row areas, set l_north_nogather so that all subsequent exchanges
770	! can use peer to peer communications at the north fold
771	!
772	l_north_nogather = .TRUE.
773	!
774	ENDIF
775	DEALLOCATE( znnbrs )
776	DEALLOCATE( lrankset )
777
778	END SUBROUTINE nemo_northcomms
779	#else
780	SUBROUTINE nemo_northcomms ! Dummy routine
781	WRITE(,) 'nemo_northcomms: You should not have seen this print! error?'
782	END SUBROUTINE nemo_northcomms
783	#endif
784	!!======================================================================
785	END MODULE nemogcm

Note: See TracBrowser for help on using the repository browser.

Download in other formats: