1 | MODULE p4zopt |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE p4zopt *** |
---|
4 | !! TOP - PISCES : Compute the light availability in the water column |
---|
5 | !!====================================================================== |
---|
6 | !! History : 1.0 ! 2004 (O. Aumont) Original code |
---|
7 | !! 2.0 ! 2007-12 (C. Ethe, G. Madec) F90 |
---|
8 | !! 3.2 ! 2009-04 (C. Ethe, G. Madec) optimisation |
---|
9 | !! 3.4 ! 2011-06 (O. Aumont, C. Ethe) Improve light availability of nano & diat |
---|
10 | !!---------------------------------------------------------------------- |
---|
11 | #if defined key_pisces |
---|
12 | !!---------------------------------------------------------------------- |
---|
13 | !! 'key_pisces' PISCES bio-model |
---|
14 | !!---------------------------------------------------------------------- |
---|
15 | !! p4z_opt : light availability in the water column |
---|
16 | !!---------------------------------------------------------------------- |
---|
17 | USE trc ! tracer variables |
---|
18 | USE oce_trc ! tracer-ocean share variables |
---|
19 | USE sms_pisces ! Source Minus Sink of PISCES |
---|
20 | USE iom ! I/O manager |
---|
21 | |
---|
22 | IMPLICIT NONE |
---|
23 | PRIVATE |
---|
24 | |
---|
25 | PUBLIC p4z_opt ! called in p4zbio.F90 module |
---|
26 | PUBLIC p4z_opt_init ! called in trcsms_pisces.F90 module |
---|
27 | PUBLIC p4z_opt_alloc |
---|
28 | |
---|
29 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: etot, enano, ediat !: PAR for phyto, nano and diat |
---|
30 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: emoy !: averaged PAR in the mixed layer |
---|
31 | |
---|
32 | INTEGER :: nksrp ! levels below which the light cannot penetrate ( depth larger than 391 m) |
---|
33 | REAL(wp) :: parlux = 0.43_wp / 3._wp |
---|
34 | |
---|
35 | REAL(wp), DIMENSION(3,61), PUBLIC :: xkrgb !: tabulated attenuation coefficients for RGB absorption |
---|
36 | |
---|
37 | !!* Substitution |
---|
38 | # include "top_substitute.h90" |
---|
39 | !!---------------------------------------------------------------------- |
---|
40 | !! NEMO/TOP 3.3 , NEMO Consortium (2010) |
---|
41 | !! $Id$ |
---|
42 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
---|
43 | !!---------------------------------------------------------------------- |
---|
44 | CONTAINS |
---|
45 | |
---|
46 | SUBROUTINE p4z_opt( kt, jnt ) |
---|
47 | !!--------------------------------------------------------------------- |
---|
48 | !! *** ROUTINE p4z_opt *** |
---|
49 | !! |
---|
50 | !! ** Purpose : Compute the light availability in the water column |
---|
51 | !! depending on the depth and the chlorophyll concentration |
---|
52 | !! |
---|
53 | !! ** Method : - ??? |
---|
54 | !!--------------------------------------------------------------------- |
---|
55 | ! |
---|
56 | INTEGER, INTENT(in) :: kt, jnt ! ocean time step |
---|
57 | ! |
---|
58 | INTEGER :: ji, jj, jk |
---|
59 | INTEGER :: irgb |
---|
60 | REAL(wp) :: zchl, zxsi0r |
---|
61 | REAL(wp) :: zc0 , zc1 , zc2, zc3, z1_dep |
---|
62 | REAL(wp), POINTER, DIMENSION(:,: ) :: zdepmoy, zetmp, zetmp1, zetmp2 |
---|
63 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zekg, zekr, zekb, ze0, ze1, ze2, ze3 |
---|
64 | !!--------------------------------------------------------------------- |
---|
65 | |
---|
66 | ! Allocate temporary workspace |
---|
67 | CALL wrk_alloc( jpi, jpj, zdepmoy, zetmp, zetmp1, zetmp2 ) |
---|
68 | CALL wrk_alloc( jpi, jpj, jpk, zekg, zekr, zekb, ze0, ze1, ze2, ze3 ) |
---|
69 | |
---|
70 | ! Initialisation of variables used to compute PAR |
---|
71 | ! ----------------------------------------------- |
---|
72 | ze1 (:,:,jpk) = 0._wp |
---|
73 | ze2 (:,:,jpk) = 0._wp |
---|
74 | ze3 (:,:,jpk) = 0._wp |
---|
75 | |
---|
76 | ! !* attenuation coef. function of Chlorophyll and wavelength (Red-Green-Blue) |
---|
77 | DO jk = 1, jpkm1 ! -------------------------------------------------------- |
---|
78 | !CDIR NOVERRCHK |
---|
79 | DO jj = 1, jpj |
---|
80 | !CDIR NOVERRCHK |
---|
81 | DO ji = 1, jpi |
---|
82 | zchl = ( trn(ji,jj,jk,jpnch) + trn(ji,jj,jk,jpdch) + rtrn ) * 1.e6 |
---|
83 | zchl = MIN( 10. , MAX( 0.05, zchl ) ) |
---|
84 | irgb = NINT( 41 + 20.* LOG10( zchl ) + rtrn ) |
---|
85 | ! |
---|
86 | zekb(ji,jj,jk) = xkrgb(1,irgb) * fse3t(ji,jj,jk) |
---|
87 | zekg(ji,jj,jk) = xkrgb(2,irgb) * fse3t(ji,jj,jk) |
---|
88 | zekr(ji,jj,jk) = xkrgb(3,irgb) * fse3t(ji,jj,jk) |
---|
89 | END DO |
---|
90 | END DO |
---|
91 | END DO |
---|
92 | |
---|
93 | |
---|
94 | ! !* Photosynthetically Available Radiation (PAR) |
---|
95 | ! ! -------------------------------------- |
---|
96 | !CDIR NOVERRCHK |
---|
97 | DO jj = 1, jpj |
---|
98 | !CDIR NOVERRCHK |
---|
99 | DO ji = 1, jpi |
---|
100 | zc1 = parlux * qsr(ji,jj) * EXP( -0.5 * zekb(ji,jj,1) ) |
---|
101 | zc2 = parlux * qsr(ji,jj) * EXP( -0.5 * zekg(ji,jj,1) ) |
---|
102 | zc3 = parlux * qsr(ji,jj) * EXP( -0.5 * zekr(ji,jj,1) ) |
---|
103 | ze1 (ji,jj,1) = zc1 |
---|
104 | ze2 (ji,jj,1) = zc2 |
---|
105 | ze3 (ji,jj,1) = zc3 |
---|
106 | etot (ji,jj,1) = ( zc1 + zc2 + zc3 ) |
---|
107 | enano(ji,jj,1) = ( 2.1 * zc1 + 0.42 * zc2 + 0.4 * zc3 ) |
---|
108 | ediat(ji,jj,1) = ( 1.6 * zc1 + 0.69 * zc2 + 0.7 * zc3 ) |
---|
109 | END DO |
---|
110 | END DO |
---|
111 | |
---|
112 | |
---|
113 | DO jk = 2, nksrp |
---|
114 | !CDIR NOVERRCHK |
---|
115 | DO jj = 1, jpj |
---|
116 | !CDIR NOVERRCHK |
---|
117 | DO ji = 1, jpi |
---|
118 | zc1 = ze1(ji,jj,jk-1) * EXP( -0.5 * ( zekb(ji,jj,jk-1) + zekb(ji,jj,jk) ) ) |
---|
119 | zc2 = ze2(ji,jj,jk-1) * EXP( -0.5 * ( zekg(ji,jj,jk-1) + zekg(ji,jj,jk) ) ) |
---|
120 | zc3 = ze3(ji,jj,jk-1) * EXP( -0.5 * ( zekr(ji,jj,jk-1) + zekr(ji,jj,jk) ) ) |
---|
121 | ze1 (ji,jj,jk) = zc1 |
---|
122 | ze2 (ji,jj,jk) = zc2 |
---|
123 | ze3 (ji,jj,jk) = zc3 |
---|
124 | etot (ji,jj,jk) = ( zc1 + zc2 + zc3 ) |
---|
125 | enano(ji,jj,jk) = ( 2.1 * zc1 + 0.42 * zc2 + 0.4 * zc3 ) |
---|
126 | ediat(ji,jj,jk) = ( 1.6 * zc1 + 0.69 * zc2 + 0.7 * zc3 ) |
---|
127 | END DO |
---|
128 | END DO |
---|
129 | END DO |
---|
130 | |
---|
131 | IF( ln_qsr_bio ) THEN !* heat flux accros w-level (used in the dynamics) |
---|
132 | ! ! ------------------------ |
---|
133 | zxsi0r = 1.e0 / rn_si0 |
---|
134 | ! |
---|
135 | ze0 (:,:,1) = rn_abs * qsr(:,:) |
---|
136 | ze1 (:,:,1) = parlux * qsr(:,:) ! surface value : separation in R-G-B + near surface |
---|
137 | ze2 (:,:,1) = parlux * qsr(:,:) |
---|
138 | ze3 (:,:,1) = parlux * qsr(:,:) |
---|
139 | etot3(:,:,1) = qsr(:,:) * tmask(:,:,1) |
---|
140 | ! |
---|
141 | DO jk = 2, nksrp + 1 |
---|
142 | !CDIR NOVERRCHK |
---|
143 | DO jj = 1, jpj |
---|
144 | !CDIR NOVERRCHK |
---|
145 | DO ji = 1, jpi |
---|
146 | zc0 = ze0(ji,jj,jk-1) * EXP( -fse3t(ji,jj,jk-1) * zxsi0r ) |
---|
147 | zc1 = ze1(ji,jj,jk-1) * EXP( -zekb(ji,jj,jk-1 ) ) |
---|
148 | zc2 = ze2(ji,jj,jk-1) * EXP( -zekg(ji,jj,jk-1 ) ) |
---|
149 | zc3 = ze3(ji,jj,jk-1) * EXP( -zekr(ji,jj,jk-1 ) ) |
---|
150 | ze0(ji,jj,jk) = zc0 |
---|
151 | ze1(ji,jj,jk) = zc1 |
---|
152 | ze2(ji,jj,jk) = zc2 |
---|
153 | ze3(ji,jj,jk) = zc3 |
---|
154 | etot3(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk) |
---|
155 | END DO |
---|
156 | ! |
---|
157 | END DO |
---|
158 | ! |
---|
159 | END DO |
---|
160 | ! |
---|
161 | ENDIF |
---|
162 | |
---|
163 | ! !* Euphotic depth and level |
---|
164 | neln(:,:) = 1 ! ------------------------ |
---|
165 | heup(:,:) = 300. |
---|
166 | |
---|
167 | DO jk = 2, nksrp |
---|
168 | DO jj = 1, jpj |
---|
169 | DO ji = 1, jpi |
---|
170 | IF( etot(ji,jj,jk) >= 0.0043 * qsr(ji,jj) ) THEN |
---|
171 | neln(ji,jj) = jk+1 ! Euphotic level : 1rst T-level strictly below Euphotic layer |
---|
172 | ! ! nb: ensure the compatibility with nmld_trc definition in trd_mld_trc_zint |
---|
173 | heup(ji,jj) = fsdepw(ji,jj,jk+1) ! Euphotic layer depth |
---|
174 | ENDIF |
---|
175 | END DO |
---|
176 | END DO |
---|
177 | END DO |
---|
178 | |
---|
179 | heup(:,:) = MIN( 300., heup(:,:) ) |
---|
180 | |
---|
181 | ! !* mean light over the mixed layer |
---|
182 | zdepmoy(:,:) = 0.e0 ! ------------------------------- |
---|
183 | zetmp (:,:) = 0.e0 |
---|
184 | zetmp1 (:,:) = 0.e0 |
---|
185 | zetmp2 (:,:) = 0.e0 |
---|
186 | |
---|
187 | DO jk = 1, nksrp |
---|
188 | !CDIR NOVERRCHK |
---|
189 | DO jj = 1, jpj |
---|
190 | !CDIR NOVERRCHK |
---|
191 | DO ji = 1, jpi |
---|
192 | IF( fsdepw(ji,jj,jk+1) <= hmld(ji,jj) ) THEN |
---|
193 | zetmp (ji,jj) = zetmp (ji,jj) + etot (ji,jj,jk) * fse3t(ji,jj,jk) |
---|
194 | zetmp1 (ji,jj) = zetmp1 (ji,jj) + enano(ji,jj,jk) * fse3t(ji,jj,jk) |
---|
195 | zetmp2 (ji,jj) = zetmp2 (ji,jj) + ediat(ji,jj,jk) * fse3t(ji,jj,jk) |
---|
196 | zdepmoy(ji,jj) = zdepmoy(ji,jj) + fse3t(ji,jj,jk) |
---|
197 | ENDIF |
---|
198 | END DO |
---|
199 | END DO |
---|
200 | END DO |
---|
201 | ! |
---|
202 | emoy(:,:,:) = etot(:,:,:) |
---|
203 | ! |
---|
204 | DO jk = 1, nksrp |
---|
205 | !CDIR NOVERRCHK |
---|
206 | DO jj = 1, jpj |
---|
207 | !CDIR NOVERRCHK |
---|
208 | DO ji = 1, jpi |
---|
209 | IF( fsdepw(ji,jj,jk+1) <= hmld(ji,jj) ) THEN |
---|
210 | z1_dep = 1. / ( zdepmoy(ji,jj) + rtrn ) |
---|
211 | emoy (ji,jj,jk) = zetmp (ji,jj) * z1_dep |
---|
212 | enano(ji,jj,jk) = zetmp1(ji,jj) * z1_dep |
---|
213 | ediat(ji,jj,jk) = zetmp2(ji,jj) * z1_dep |
---|
214 | ENDIF |
---|
215 | END DO |
---|
216 | END DO |
---|
217 | END DO |
---|
218 | |
---|
219 | IF( ln_diatrc ) THEN ! save output diagnostics |
---|
220 | ! |
---|
221 | IF( lk_iomput ) THEN |
---|
222 | IF( jnt == nrdttrc ) THEN |
---|
223 | CALL iom_put( "Heup", heup(:,: ) * tmask(:,:,1) ) ! euphotic layer deptht |
---|
224 | CALL iom_put( "PAR" , etot(:,:,:) * tmask(:,:,:) ) ! Photosynthetically Available Radiation |
---|
225 | ENDIF |
---|
226 | ELSE |
---|
227 | trc2d(:,:, jp_pcs0_2d + 10) = heup(:,: ) * tmask(:,:,1) |
---|
228 | trc3d(:,:,:,jp_pcs0_3d + 3) = etot(:,:,:) * tmask(:,:,:) |
---|
229 | ENDIF |
---|
230 | ! |
---|
231 | ENDIF |
---|
232 | ! |
---|
233 | CALL wrk_dealloc( jpi, jpj, zdepmoy, zetmp, zetmp1, zetmp2 ) |
---|
234 | CALL wrk_dealloc( jpi, jpj, jpk, zekg, zekr, zekb, ze0, ze1, ze2, ze3 ) |
---|
235 | ! |
---|
236 | END SUBROUTINE p4z_opt |
---|
237 | |
---|
238 | |
---|
239 | SUBROUTINE p4z_opt_init |
---|
240 | !!---------------------------------------------------------------------- |
---|
241 | !! *** ROUTINE p4z_opt_init *** |
---|
242 | !! |
---|
243 | !! ** Purpose : Initialization of tabulated attenuation coef |
---|
244 | !!---------------------------------------------------------------------- |
---|
245 | ! |
---|
246 | CALL trc_oce_rgb( xkrgb ) ! tabulated attenuation coefficients |
---|
247 | nksrp = trc_oce_ext_lev( r_si2, 0.33e2 ) ! max level of light extinction (Blue Chl=0.01) |
---|
248 | ! |
---|
249 | IF(lwp) WRITE(numout,*) ' level of light extinction = ', nksrp, ' ref depth = ', gdepw_0(nksrp+1), ' m' |
---|
250 | ! |
---|
251 | etot (:,:,:) = 0._wp |
---|
252 | enano(:,:,:) = 0._wp |
---|
253 | ediat(:,:,:) = 0._wp |
---|
254 | IF( ln_qsr_bio ) etot3(:,:,:) = 0._wp |
---|
255 | ! |
---|
256 | END SUBROUTINE p4z_opt_init |
---|
257 | |
---|
258 | |
---|
259 | INTEGER FUNCTION p4z_opt_alloc() |
---|
260 | !!---------------------------------------------------------------------- |
---|
261 | !! *** ROUTINE p4z_opt_alloc *** |
---|
262 | !!---------------------------------------------------------------------- |
---|
263 | ALLOCATE( etot (jpi,jpj,jpk) , enano(jpi,jpj,jpk) , & |
---|
264 | & ediat(jpi,jpj,jpk) , emoy (jpi,jpj,jpk) , STAT=p4z_opt_alloc ) |
---|
265 | ! |
---|
266 | IF( p4z_opt_alloc /= 0 ) CALL ctl_warn('p4z_opt_alloc : failed to allocate arrays.') |
---|
267 | ! |
---|
268 | END FUNCTION p4z_opt_alloc |
---|
269 | |
---|
270 | #else |
---|
271 | !!---------------------------------------------------------------------- |
---|
272 | !! Dummy module : No PISCES bio-model |
---|
273 | !!---------------------------------------------------------------------- |
---|
274 | CONTAINS |
---|
275 | SUBROUTINE p4z_opt ! Empty routine |
---|
276 | END SUBROUTINE p4z_opt |
---|
277 | #endif |
---|
278 | |
---|
279 | !!====================================================================== |
---|
280 | END MODULE p4zopt |
---|