New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zprod.F90 in branches/2011/dev_NEMO_MERGE_2011/NEMOGCM/NEMO/TOP_SRC/PISCES – NEMO

source: branches/2011/dev_NEMO_MERGE_2011/NEMOGCM/NEMO/TOP_SRC/PISCES/p4zprod.F90 @ 3147

Last change on this file since 3147 was 3147, checked in by cetlod, 13 years ago

branch dev_NEMO_MERGE_2011:New dynamical allocation for TOP
  • Property svn:keywords set to Id
File size: 25.5 KB
Line 
1MODULE p4zprod
2   !!======================================================================
3   !!                         ***  MODULE p4zprod  ***
4   !! TOP :  Growth Rate of the two phytoplanktons groups
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-05  (O. Aumont, C. Ethe) New parameterization of light limitation
9   !!----------------------------------------------------------------------
10#if defined key_pisces
11   !!----------------------------------------------------------------------
12   !!   'key_pisces'                                       PISCES bio-model
13   !!----------------------------------------------------------------------
14   !!   p4z_prod       :   Compute the growth Rate of the two phytoplanktons groups
15   !!   p4z_prod_init  :   Initialization of the parameters for growth
16   !!   p4z_prod_alloc :   Allocate variables for growth
17   !!----------------------------------------------------------------------
18   USE oce_trc         !  shared variables between ocean and passive tracers
19   USE trc             !  passive tracers common variables
20   USE sms_pisces      !  PISCES Source Minus Sink variables
21   USE p4zopt          !  optical model
22   USE p4zlim          !  Co-limitations of differents nutrients
23   USE prtctl_trc      !  print control for debugging
24   USE iom             !  I/O manager
25   USE wrk_nemo_2      !  Memory allocation
26
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC   p4z_prod         ! called in p4zbio.F90
32   PUBLIC   p4z_prod_init    ! called in trcsms_pisces.F90
33   PUBLIC   p4z_prod_alloc
34
35   !! * Shared module variables
36   LOGICAL , PUBLIC ::  ln_newprod = .FALSE.
37   REAL(wp), PUBLIC ::  pislope    = 3.0_wp            !:
38   REAL(wp), PUBLIC ::  pislope2   = 3.0_wp            !:
39   REAL(wp), PUBLIC ::  excret     = 10.e-5_wp         !:
40   REAL(wp), PUBLIC ::  excret2    = 0.05_wp           !:
41   REAL(wp), PUBLIC ::  bresp      = 0.00333_wp        !:
42   REAL(wp), PUBLIC ::  chlcnm     = 0.033_wp          !:
43   REAL(wp), PUBLIC ::  chlcdm     = 0.05_wp           !:
44   REAL(wp), PUBLIC ::  chlcmin    = 0.00333_wp        !:
45   REAL(wp), PUBLIC ::  fecnm      = 10.E-6_wp         !:
46   REAL(wp), PUBLIC ::  fecdm      = 15.E-6_wp         !:
47   REAL(wp), PUBLIC ::  grosip     = 0.151_wp          !:
48
49   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   prmax    !: optimal production = f(temperature)
50   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   quotan   !: proxy of N quota in Nanophyto
51   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   quotad   !: proxy of N quota in diatomee
52   
53   REAL(wp) :: r1_rday                !: 1 / rday
54   REAL(wp) :: texcret                !: 1 - excret
55   REAL(wp) :: texcret2               !: 1 - excret2       
56   REAL(wp) :: tpp                    !: Total primary production
57
58
59   !!* Substitution
60#  include "top_substitute.h90"
61   !!----------------------------------------------------------------------
62   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
63   !! $Id$
64   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
65   !!----------------------------------------------------------------------
66CONTAINS
67
68   SUBROUTINE p4z_prod( kt , jnt )
69      !!---------------------------------------------------------------------
70      !!                     ***  ROUTINE p4z_prod  ***
71      !!
72      !! ** Purpose :   Compute the phytoplankton production depending on
73      !!              light, temperature and nutrient availability
74      !!
75      !! ** Method  : - ???
76      !!---------------------------------------------------------------------
77      !
78      INTEGER, INTENT(in) :: kt, jnt
79      !
80      INTEGER  ::   ji, jj, jk
81      REAL(wp) ::   zsilfac, zfact, znanotot, zdiattot, zconctemp, zconctemp2
82      REAL(wp) ::   zratio, zmax, zsilim, ztn, zadap
83      REAL(wp) ::   zlim, zsilfac2, zsiborn, zprod, zproreg, zproreg2
84      REAL(wp) ::   zmxltst, zmxlday, zmaxday
85      REAL(wp) ::   zpislopen  , zpislope2n
86      REAL(wp) ::   zrum, zcodel, zargu, zval
87      REAL(wp) ::   zrfact2
88      CHARACTER (len=25) :: charout
89      REAL(wp), POINTER, DIMENSION(:,:  ) :: zmixnano, zmixdiat, zstrn
90      REAL(wp), POINTER, DIMENSION(:,:,:) :: zpislopead, zpislopead2, zprdia, zprbio, zprdch, zprnch, zysopt   
91      REAL(wp), POINTER, DIMENSION(:,:,:) :: zprorca, zprorcad, zprofed, zprofen, zprochln, zprochld, zpronew, zpronewd
92
93      !!---------------------------------------------------------------------
94
95      !  Allocate temporary workspace
96      CALL wrk_alloc( jpi, jpj,      zmixnano, zmixdiat, zstrn                                                  )
97      CALL wrk_alloc( jpi, jpj, jpk, zpislopead, zpislopead2, zprdia, zprbio, zprdch, zprnch, zysopt            ) 
98      CALL wrk_alloc( jpi, jpj, jpk, zprorca, zprorcad, zprofed, zprofen, zprochln, zprochld, zpronew, zpronewd )
99      !
100      zprorca (:,:,:) = 0._wp
101      zprorcad(:,:,:) = 0._wp
102      zprofed (:,:,:) = 0._wp
103      zprofen (:,:,:) = 0._wp
104      zprochln(:,:,:) = 0._wp
105      zprochld(:,:,:) = 0._wp
106      zpronew (:,:,:) = 0._wp
107      zpronewd(:,:,:) = 0._wp
108      zprdia  (:,:,:) = 0._wp
109      zprbio  (:,:,:) = 0._wp
110      zprdch  (:,:,:) = 0._wp
111      zprnch  (:,:,:) = 0._wp
112      zysopt  (:,:,:) = 0._wp
113
114      ! Computation of the optimal production
115      prmax(:,:,:) = 0.6_wp * r1_rday * tgfunc(:,:,:) 
116      IF( lk_degrad )  prmax(:,:,:) = prmax(:,:,:) * facvol(:,:,:) 
117
118      ! compute the day length depending on latitude and the day
119      zrum = REAL( nday_year - 80, wp ) / REAL( nyear_len(1), wp )
120      zcodel = ASIN(  SIN( zrum * rpi * 2._wp ) * SIN( rad * 23.5_wp )  )
121
122      ! day length in hours
123      zstrn(:,:) = 0.
124      DO jj = 1, jpj
125         DO ji = 1, jpi
126            zargu = TAN( zcodel ) * TAN( gphit(ji,jj) * rad )
127            zargu = MAX( -1., MIN(  1., zargu ) )
128            zstrn(ji,jj) = MAX( 0.0, 24. - 2. * ACOS( zargu ) / rad / 15. )
129         END DO
130      END DO
131
132      IF( ln_newprod ) THEN
133         ! Impact of the day duration on phytoplankton growth
134         DO jk = 1, jpkm1
135            DO jj = 1 ,jpj
136               DO ji = 1, jpi
137                  zval = MAX( 1., zstrn(ji,jj) )
138                  zval = 1.5 * zval / ( 12. + zval )
139                  zprbio(ji,jj,jk) = prmax(ji,jj,jk) * zval
140                  zprdia(ji,jj,jk) = zprbio(ji,jj,jk)
141               END DO
142            END DO
143         END DO
144      ENDIF
145
146      ! Maximum light intensity
147      WHERE( zstrn(:,:) < 1.e0 ) zstrn(:,:) = 24.
148      zstrn(:,:) = 24. / zstrn(:,:)
149
150      IF( ln_newprod ) THEN
151!CDIR NOVERRCHK
152         DO jk = 1, jpkm1
153!CDIR NOVERRCHK
154            DO jj = 1, jpj
155!CDIR NOVERRCHK
156               DO ji = 1, jpi
157
158                  ! Computation of the P-I slope for nanos and diatoms
159                  IF( etot(ji,jj,jk) > 1.E-3 ) THEN
160                      ztn    = MAX( 0., tsn(ji,jj,jk,jp_tem) - 15. )
161                      zadap  = ztn / ( 2.+ ztn )
162
163                      zconctemp   = MAX( 0.e0 , trn(ji,jj,jk,jpdia) - 5e-7 )
164                      zconctemp2  = trn(ji,jj,jk,jpdia) - zconctemp
165
166                      znanotot = enano(ji,jj,jk) * zstrn(ji,jj)
167                      zdiattot = ediat(ji,jj,jk) * zstrn(ji,jj)
168
169                      zfact  = EXP( -0.21 * znanotot )
170                      zpislopead (ji,jj,jk) = pislope  * ( 1.+ zadap  * zfact )  &
171                         &                   * trn(ji,jj,jk,jpnch) /( trn(ji,jj,jk,jpphy) * 12. + rtrn)
172
173                      zpislopead2(ji,jj,jk) = (pislope * zconctemp2 + pislope2 * zconctemp) / ( trn(ji,jj,jk,jpdia) + rtrn )   &
174                         &                   * trn(ji,jj,jk,jpdch) /( trn(ji,jj,jk,jpdia) * 12. + rtrn)
175
176                      ! Computation of production function for Carbon
177                      !  ---------------------------------------------
178                      zpislopen  = zpislopead (ji,jj,jk) / ( ( r1_rday + bresp * r1_rday / chlcnm ) * rday + rtrn)
179                      zpislope2n = zpislopead2(ji,jj,jk) / ( ( r1_rday + bresp * r1_rday / chlcdm ) * rday + rtrn)
180                      zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1.- EXP( -zpislopen  * znanotot )  )
181                      zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1.- EXP( -zpislope2n * zdiattot )  )
182
183                      !  Computation of production function for Chlorophyll
184                      !--------------------------------------------------
185                      zmaxday  = 1._wp / ( prmax(ji,jj,jk) * rday + rtrn )
186                      zprnch(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpislopead (ji,jj,jk) * zmaxday * znanotot ) )
187                      zprdch(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpislopead2(ji,jj,jk) * zmaxday * zdiattot ) )
188                  ENDIF
189               END DO
190            END DO
191         END DO
192      ELSE
193!CDIR NOVERRCHK
194         DO jk = 1, jpkm1
195!CDIR NOVERRCHK
196            DO jj = 1, jpj
197!CDIR NOVERRCHK
198               DO ji = 1, jpi
199
200                  ! Computation of the P-I slope for nanos and diatoms
201                  IF( etot(ji,jj,jk) > 1.E-3 ) THEN
202                      ztn    = MAX( 0., tsn(ji,jj,jk,jp_tem) - 15. )
203                      zadap  = ztn / ( 2.+ ztn )
204
205                      zfact  = EXP( -0.21 * enano(ji,jj,jk) )
206                      zpislopead (ji,jj,jk) = pislope  * ( 1.+ zadap  * zfact )
207                      zpislopead2(ji,jj,jk) = pislope2
208
209                      zpislopen =  zpislopead(ji,jj,jk) * trn(ji,jj,jk,jpnch)                &
210                        &          / ( trn(ji,jj,jk,jpphy) * 12.                  + rtrn )   &
211                        &          / ( prmax(ji,jj,jk) * rday * xlimphy(ji,jj,jk) + rtrn )
212
213                      zpislope2n = zpislopead2(ji,jj,jk) * trn(ji,jj,jk,jpdch)                &
214                        &          / ( trn(ji,jj,jk,jpdia) * 12.                  + rtrn )   &
215                        &          / ( prmax(ji,jj,jk) * rday * xlimdia(ji,jj,jk) + rtrn )
216
217                      ! Computation of production function for Carbon
218                      !  ---------------------------------------------
219                      zprbio(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpislopen  * enano(ji,jj,jk) ) )
220                      zprdia(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpislope2n * ediat(ji,jj,jk) ) )
221
222                      !  Computation of production function for Chlorophyll
223                      !--------------------------------------------------
224                      zprnch(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpislopen  * enano(ji,jj,jk) * zstrn(ji,jj) ) )
225                      zprdch(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpislope2n * ediat(ji,jj,jk) * zstrn(ji,jj) ) )
226                  ENDIF
227               END DO
228            END DO
229         END DO
230      ENDIF
231
232      !  Computation of a proxy of the N/C ratio
233      !  ---------------------------------------
234!CDIR NOVERRCHK
235      DO jk = 1, jpkm1
236!CDIR NOVERRCHK
237         DO jj = 1, jpj
238!CDIR NOVERRCHK
239            DO ji = 1, jpi
240                zval = ( xnanonh4(ji,jj,jk) + xnanono3(ji,jj,jk) ) * prmax(ji,jj,jk) / ( zprbio(ji,jj,jk) + rtrn )
241                quotan(ji,jj,jk) = MIN( 1., 0.5 + 0.5 * zval )
242                zval = ( xdiatnh4(ji,jj,jk) + xdiatno3(ji,jj,jk) ) * prmax(ji,jj,jk) / ( zprdia(ji,jj,jk) + rtrn )
243                quotad(ji,jj,jk) = MIN( 1., 0.5 + 0.5 * zval )
244            END DO
245         END DO
246      END DO
247
248
249      DO jk = 1, jpkm1
250         DO jj = 1, jpj
251            DO ji = 1, jpi
252
253                IF( etot(ji,jj,jk) > 1.E-3 ) THEN
254                   !    Si/C of diatoms
255                   !    ------------------------
256                   !    Si/C increases with iron stress and silicate availability
257                   !    Si/C is arbitrariliy increased for very high Si concentrations
258                   !    to mimic the very high ratios observed in the Southern Ocean (silpot2)
259                  zlim  = trn(ji,jj,jk,jpsil) / ( trn(ji,jj,jk,jpsil) + xksi1 )
260                  zsilim = MIN( zprdia(ji,jj,jk) / ( prmax(ji,jj,jk) + rtrn ), xlimsi(ji,jj,jk) )
261                  zsilfac = 4.4 * EXP( -4.23 * zsilim ) * MAX( 0.e0, MIN( 1., 2.2 * ( zlim - 0.5 ) )  ) + 1.e0
262                  zsiborn = MAX( 0.e0, ( trn(ji,jj,jk,jpsil) - 15.e-6 ) )
263                  zsilfac2 = 1.+ 2.* zsiborn / ( zsiborn + xksi2 )
264                  zsilfac = MIN( 5.4, zsilfac * zsilfac2)
265                  zysopt(ji,jj,jk) = grosip * zlim * zsilfac
266              ENDIF
267            END DO
268         END DO
269      END DO
270
271      !  Computation of the limitation term due to a mixed layer deeper than the euphotic depth
272      DO jj = 1, jpj
273         DO ji = 1, jpi
274            zmxltst = MAX( 0.e0, hmld(ji,jj) - heup(ji,jj) )
275            zmxlday = zmxltst * zmxltst * r1_rday
276            zmixnano(ji,jj) = 1. - zmxlday / ( 3. + zmxlday )
277            zmixdiat(ji,jj) = 1. - zmxlday / ( 4. + zmxlday )
278         END DO
279      END DO
280 
281      !  Mixed-layer effect on production                                                                               
282      DO jk = 1, jpkm1
283         DO jj = 1, jpj
284            DO ji = 1, jpi
285               IF( fsdepw(ji,jj,jk+1) <= hmld(ji,jj) ) THEN
286                  zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * zmixnano(ji,jj)
287                  zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * zmixdiat(ji,jj)
288               ENDIF
289            END DO
290         END DO
291      END DO
292
293      ! Computation of the various production terms
294!CDIR NOVERRCHK
295      DO jk = 1, jpkm1
296!CDIR NOVERRCHK
297         DO jj = 1, jpj
298!CDIR NOVERRCHK
299            DO ji = 1, jpi
300               IF( etot(ji,jj,jk) > 1.E-3 ) THEN
301                  !  production terms for nanophyto.
302                  zprorca(ji,jj,jk) = zprbio(ji,jj,jk)  * xlimphy(ji,jj,jk) * trn(ji,jj,jk,jpphy) * rfact2
303                  zpronew(ji,jj,jk) = zprorca(ji,jj,jk) * xnanono3(ji,jj,jk) / ( xnanono3(ji,jj,jk) + xnanonh4(ji,jj,jk) + rtrn )
304                  !
305                  zratio = trn(ji,jj,jk,jpnfe) / ( trn(ji,jj,jk,jpphy) + rtrn )
306                  zratio = zratio / fecnm 
307                  zmax   = MAX( 0., ( 1. - zratio ) / ABS( 1.05 - zratio ) ) 
308                  zprofen(ji,jj,jk) = fecnm * prmax(ji,jj,jk)  &
309                  &             * ( 4. - 4.5 * xlimnfe(ji,jj,jk) / ( xlimnfe(ji,jj,jk) + 0.5 ) )    &
310                  &             * trn(ji,jj,jk,jpfer) / ( trn(ji,jj,jk,jpfer) + concnfe(ji,jj,jk) )  &
311                  &             * zmax * trn(ji,jj,jk,jpphy) * rfact2
312                  !  production terms for diatomees
313                  zprorcad(ji,jj,jk) = zprdia(ji,jj,jk) * xlimdia(ji,jj,jk) * trn(ji,jj,jk,jpdia) * rfact2
314                  zpronewd(ji,jj,jk) = zprorcad(ji,jj,jk) * xdiatno3(ji,jj,jk) / ( xdiatno3(ji,jj,jk) + xdiatnh4(ji,jj,jk) + rtrn )
315                  !
316                  zratio = trn(ji,jj,jk,jpdfe) / ( trn(ji,jj,jk,jpdia) + rtrn )
317                  zratio = zratio / fecdm 
318                  zmax   = MAX( 0., ( 1. - zratio ) / ABS( 1.05 - zratio ) ) 
319                  zprofed(ji,jj,jk) = fecdm * prmax(ji,jj,jk)  &
320                  &             * ( 4. - 4.5 * xlimdfe(ji,jj,jk) / ( xlimdfe(ji,jj,jk) + 0.5 ) )    &
321                  &             * trn(ji,jj,jk,jpfer) / ( trn(ji,jj,jk,jpfer) + concdfe(ji,jj,jk) )  &
322                  &             * zmax * trn(ji,jj,jk,jpdia) * rfact2
323               ENDIF
324            END DO
325         END DO
326      END DO
327
328      IF( ln_newprod ) THEN
329!CDIR NOVERRCHK
330         DO jk = 1, jpkm1
331!CDIR NOVERRCHK
332            DO jj = 1, jpj
333!CDIR NOVERRCHK
334               DO ji = 1, jpi
335                  IF( fsdepw(ji,jj,jk+1) <= hmld(ji,jj) ) THEN
336                     zprnch(ji,jj,jk) = zprnch(ji,jj,jk) * zmixnano(ji,jj)
337                     zprdch(ji,jj,jk) = zprdch(ji,jj,jk) * zmixdiat(ji,jj)
338                  ENDIF
339                  IF( etot(ji,jj,jk) > 1.E-3 ) THEN
340                     !  production terms for nanophyto. ( chlorophyll )
341                     znanotot = enano(ji,jj,jk) * zstrn(ji,jj)
342                     zprod    = rday * zprorca(ji,jj,jk) * zprnch(ji,jj,jk) * xlimphy(ji,jj,jk)
343                     zprochln(ji,jj,jk) = chlcmin * 12. * zprorca (ji,jj,jk)
344                     zprochln(ji,jj,jk) = zprochln(ji,jj,jk) + chlcnm * 12. * zprod / (  zpislopead(ji,jj,jk) * znanotot +rtrn)
345                     !  production terms for diatomees ( chlorophyll )
346                     zdiattot = ediat(ji,jj,jk) * zstrn(ji,jj)
347                     zprod = rday * zprorcad(ji,jj,jk) * zprdch(ji,jj,jk) * xlimdia(ji,jj,jk)
348                     zprochld(ji,jj,jk) = chlcmin * 12. * zprorcad(ji,jj,jk)
349                     zprochld(ji,jj,jk) = zprochld(ji,jj,jk) + chlcdm * 12. * zprod / ( zpislopead2(ji,jj,jk) * zdiattot +rtrn )
350                  ENDIF
351               END DO
352            END DO
353         END DO
354      ELSE
355!CDIR NOVERRCHK
356         DO jk = 1, jpkm1
357!CDIR NOVERRCHK
358            DO jj = 1, jpj
359!CDIR NOVERRCHK
360               DO ji = 1, jpi
361                  IF( etot(ji,jj,jk) > 1.E-3 ) THEN
362                     !  production terms for nanophyto. ( chlorophyll )
363                     znanotot = enano(ji,jj,jk) * zstrn(ji,jj)
364                     zprod = rday * zprorca(ji,jj,jk) * zprnch(ji,jj,jk) * trn(ji,jj,jk,jpphy) * xlimphy(ji,jj,jk)
365                     zprochln(ji,jj,jk) = chlcnm * 144. * zprod / (  zpislopead(ji,jj,jk) * trn(ji,jj,jk,jpnch) * znanotot +rtrn)
366                     !  production terms for diatomees ( chlorophyll )
367                     zdiattot = ediat(ji,jj,jk) * zstrn(ji,jj)
368                     zprod = rday * zprorcad(ji,jj,jk) * zprdch(ji,jj,jk) * trn(ji,jj,jk,jpdia) * xlimdia(ji,jj,jk)
369                     zprochld(ji,jj,jk) = chlcdm * 144. * zprod / ( zpislopead2(ji,jj,jk) * trn(ji,jj,jk,jpdch) * zdiattot +rtrn )
370                  ENDIF
371               END DO
372            END DO
373         END DO
374      ENDIF
375
376      !   Update the arrays TRA which contain the biological sources and sinks
377      DO jk = 1, jpkm1
378         DO jj = 1, jpj
379           DO ji =1 ,jpi
380              zproreg  = zprorca(ji,jj,jk) - zpronew(ji,jj,jk)
381              zproreg2 = zprorcad(ji,jj,jk) - zpronewd(ji,jj,jk)
382              tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) - zprorca(ji,jj,jk) - zprorcad(ji,jj,jk)
383              tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) - zpronew(ji,jj,jk) - zpronewd(ji,jj,jk)
384              tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) - zproreg - zproreg2
385              tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) + zprorca(ji,jj,jk) * texcret
386              tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) + zprochln(ji,jj,jk) * texcret
387              tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) + zprofen(ji,jj,jk) * texcret
388              tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) + zprorcad(ji,jj,jk) * texcret2
389              tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) + zprochld(ji,jj,jk) * texcret2
390              tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) + zprofed(ji,jj,jk) * texcret2
391              tra(ji,jj,jk,jpbsi) = tra(ji,jj,jk,jpbsi) + zprorcad(ji,jj,jk) * zysopt(ji,jj,jk) * texcret2
392              tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + excret2 * zprorcad(ji,jj,jk) + excret * zprorca(ji,jj,jk)
393              tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) + o2ut * ( zproreg + zproreg2) &
394                 &                + ( o2ut + o2nit ) * ( zpronew(ji,jj,jk) + zpronewd(ji,jj,jk) )
395              tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - texcret * zprofen(ji,jj,jk) - texcret2 * zprofed(ji,jj,jk)
396              tra(ji,jj,jk,jpsil) = tra(ji,jj,jk,jpsil) - texcret2 * zprorcad(ji,jj,jk) * zysopt(ji,jj,jk)
397              tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprorca(ji,jj,jk) - zprorcad(ji,jj,jk)
398              tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * ( zpronew(ji,jj,jk) + zpronewd(ji,jj,jk) ) &
399                 &                                      - rno3 * ( zproreg + zproreg2 )
400          END DO
401        END DO
402     END DO
403
404     ! Total primary production per year
405     tpp = tpp + glob_sum( ( zprorca(:,:,:) + zprorcad(:,:,:) ) * cvol(:,:,:) )
406
407     IF( kt == nitend .AND. jnt == nrdttrc ) THEN
408        WRITE(numout,*) 'Total PP (Gtc) :'
409        WRITE(numout,*) '-------------------- : ',tpp * 12. / 1.E12
410        WRITE(numout,*) 
411      ENDIF
412
413     IF( ln_diatrc ) THEN
414         !
415         zrfact2 = 1.e3 * rfact2r
416         IF( lk_iomput ) THEN
417           IF( jnt == nrdttrc ) THEN
418              CALL iom_put( "PPPHY" , zprorca (:,:,:) * zrfact2 * tmask(:,:,:) )  ! primary production by nanophyto
419              CALL iom_put( "PPPHY2", zprorcad(:,:,:) * zrfact2 * tmask(:,:,:) )  ! primary production by diatom
420              CALL iom_put( "PPNEWN", zpronew (:,:,:) * zrfact2 * tmask(:,:,:) )  ! new primary production by nanophyto
421              CALL iom_put( "PPNEWD", zpronewd(:,:,:) * zrfact2 * tmask(:,:,:) )  ! new primary production by diatom
422              CALL iom_put( "PBSi"  , zprorcad(:,:,:) * zrfact2 * tmask(:,:,:) * zysopt(:,:,:) ) ! biogenic silica production
423              CALL iom_put( "PFeD"  , zprofed (:,:,:) * zrfact2 * tmask(:,:,:) )  ! biogenic iron production by diatom
424              CALL iom_put( "PFeN"  , zprofen (:,:,:) * zrfact2 * tmask(:,:,:) )  ! biogenic iron production by nanophyto
425           ENDIF
426         ELSE
427              trc3d(:,:,:,jp_pcs0_3d + 4)  = zprorca (:,:,:) * zrfact2 * tmask(:,:,:)
428              trc3d(:,:,:,jp_pcs0_3d + 5)  = zprorcad(:,:,:) * zrfact2 * tmask(:,:,:)
429              trc3d(:,:,:,jp_pcs0_3d + 6)  = zpronew (:,:,:) * zrfact2 * tmask(:,:,:)
430              trc3d(:,:,:,jp_pcs0_3d + 7)  = zpronewd(:,:,:) * zrfact2 * tmask(:,:,:)
431              trc3d(:,:,:,jp_pcs0_3d + 8)  = zprorcad(:,:,:) * zrfact2 * tmask(:,:,:) * zysopt(:,:,:)
432              trc3d(:,:,:,jp_pcs0_3d + 9)  = zprofed (:,:,:) * zrfact2 * tmask(:,:,:)
433#  if ! defined key_kriest
434              trc3d(:,:,:,jp_pcs0_3d + 10) = zprofen (:,:,:) * zrfact2 * tmask(:,:,:)
435#  endif
436         ENDIF
437         !
438      ENDIF
439
440      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
441         WRITE(charout, FMT="('prod')")
442         CALL prt_ctl_trc_info(charout)
443         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
444      ENDIF
445      !
446      CALL wrk_dealloc( jpi, jpj,      zmixnano, zmixdiat, zstrn                                                  )
447      CALL wrk_dealloc( jpi, jpj, jpk, zpislopead, zpislopead2, zprdia, zprbio, zprdch, zprnch, zysopt            ) 
448      CALL wrk_dealloc( jpi, jpj, jpk, zprorca, zprorcad, zprofed, zprofen, zprochln, zprochld, zpronew, zpronewd )
449      !
450   END SUBROUTINE p4z_prod
451
452
453   SUBROUTINE p4z_prod_init
454      !!----------------------------------------------------------------------
455      !!                  ***  ROUTINE p4z_prod_init  ***
456      !!
457      !! ** Purpose :   Initialization of phytoplankton production parameters
458      !!
459      !! ** Method  :   Read the nampisprod namelist and check the parameters
460      !!      called at the first timestep (nittrc000)
461      !!
462      !! ** input   :   Namelist nampisprod
463      !!----------------------------------------------------------------------
464      !
465      NAMELIST/nampisprod/ pislope, pislope2, ln_newprod, bresp, excret, excret2,  &
466         &                 chlcnm, chlcdm, chlcmin, fecnm, fecdm, grosip
467      !!----------------------------------------------------------------------
468
469      REWIND( numnatp )                     ! read numnatp
470      READ  ( numnatp, nampisprod )
471
472      IF(lwp) THEN                         ! control print
473         WRITE(numout,*) ' '
474         WRITE(numout,*) ' Namelist parameters for phytoplankton growth, nampisprod'
475         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
476         WRITE(numout,*) '    Enable new parame. of production (T/F)   ln_newprod   =', ln_newprod
477         WRITE(numout,*) '    mean Si/C ratio                           grosip       =', grosip
478         WRITE(numout,*) '    P-I slope                                 pislope      =', pislope
479         WRITE(numout,*) '    excretion ratio of nanophytoplankton      excret       =', excret
480         WRITE(numout,*) '    excretion ratio of diatoms                excret2      =', excret2
481         IF( ln_newprod )  THEN
482            WRITE(numout,*) '    basal respiration in phytoplankton        bresp        =', bresp
483            WRITE(numout,*) '    Maximum Chl/C in phytoplankton            chlcmin      =', chlcmin
484         ENDIF
485         WRITE(numout,*) '    P-I slope  for diatoms                    pislope2     =', pislope2
486         WRITE(numout,*) '    Minimum Chl/C in nanophytoplankton        chlcnm       =', chlcnm
487         WRITE(numout,*) '    Minimum Chl/C in diatoms                  chlcdm       =', chlcdm
488         WRITE(numout,*) '    Maximum Fe/C in nanophytoplankton         fecnm        =', fecnm
489         WRITE(numout,*) '    Minimum Fe/C in diatoms                   fecdm        =', fecdm
490      ENDIF
491      !
492      r1_rday   = 1._wp / rday 
493      texcret   = 1._wp - excret
494      texcret2  = 1._wp - excret2
495      tpp       = 0._wp
496      !
497   END SUBROUTINE p4z_prod_init
498
499
500   INTEGER FUNCTION p4z_prod_alloc()
501      !!----------------------------------------------------------------------
502      !!                     ***  ROUTINE p4z_prod_alloc  ***
503      !!----------------------------------------------------------------------
504      ALLOCATE( prmax(jpi,jpj,jpk), quotan(jpi,jpj,jpk), quotad(jpi,jpj,jpk), STAT = p4z_prod_alloc )
505      !
506      IF( p4z_prod_alloc /= 0 ) CALL ctl_warn('p4z_prod_alloc : failed to allocate arrays.')
507      !
508   END FUNCTION p4z_prod_alloc
509
510#else
511   !!======================================================================
512   !!  Dummy module :                                   No PISCES bio-model
513   !!======================================================================
514CONTAINS
515   SUBROUTINE p4z_prod                    ! Empty routine
516   END SUBROUTINE p4z_prod
517#endif 
518
519   !!======================================================================
520END MODULE  p4zprod
Note: See TracBrowser for help on using the repository browser.