New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zsink.F90 in branches/2011/dev_NEMO_MERGE_2011/NEMOGCM/NEMO/TOP_SRC/PISCES – NEMO

source: branches/2011/dev_NEMO_MERGE_2011/NEMOGCM/NEMO/TOP_SRC/PISCES/p4zsink.F90 @ 3153

Last change on this file since 3153 was 3153, checked in by cetlod, 12 years ago

Add timing on TOP routines
  • Property svn:keywords set to Id
File size: 32.4 KB
Line 
1MODULE p4zsink
2   !!======================================================================
3   !!                         ***  MODULE p4zsink  ***
4   !! TOP :  PISCES  vertical flux of particulate matter due to gravitational sinking
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Change aggregation formula
9   !!----------------------------------------------------------------------
10#if defined key_pisces
11   !!----------------------------------------------------------------------
12   !!   p4z_sink       :  Compute vertical flux of particulate matter due to gravitational sinking
13   !!   p4z_sink_init  :  Unitialisation of sinking speed parameters
14   !!   p4z_sink_alloc :  Allocate sinking speed variables
15   !!----------------------------------------------------------------------
16   USE oce_trc         !  shared variables between ocean and passive tracers
17   USE trc             !  passive tracers common variables
18   USE sms_pisces      !  PISCES Source Minus Sink variables
19   USE prtctl_trc      !  print control for debugging
20   USE iom             !  I/O manager
21
22   IMPLICIT NONE
23   PRIVATE
24
25   PUBLIC   p4z_sink         ! called in p4zbio.F90
26   PUBLIC   p4z_sink_init    ! called in trcsms_pisces.F90
27   PUBLIC   p4z_sink_alloc
28
29   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   wsbio3   !: POC sinking speed
30   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   wsbio4   !: GOC sinking speed
31   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   wscal    !: Calcite and BSi sinking speeds
32
33   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinking, sinking2  !: POC sinking fluxes
34   !                                                          !  (different meanings depending on the parameterization)
35   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinkcal, sinksil   !: CaCO3 and BSi sinking fluxes
36   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinkfer            !: Small BFe sinking fluxes
37#if ! defined key_kriest
38   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinkfer2           !: Big iron sinking fluxes
39#endif
40
41   INTEGER  :: iksed  = 10
42
43#if  defined key_kriest
44   REAL(wp) ::  xkr_sfact    = 250.     !: Sinking factor
45   REAL(wp) ::  xkr_stick    = 0.2      !: Stickiness
46   REAL(wp) ::  xkr_nnano    = 2.337    !: Nbr of cell in nano size class
47   REAL(wp) ::  xkr_ndiat    = 3.718    !: Nbr of cell in diatoms size class
48   REAL(wp) ::  xkr_nmeso    = 7.147    !: Nbr of cell in mesozoo  size class
49   REAL(wp) ::  xkr_naggr    = 9.877    !: Nbr of cell in aggregates  size class
50
51   REAL(wp) ::  xkr_frac 
52
53   REAL(wp), PUBLIC ::  xkr_dnano       !: Size of particles in nano pool
54   REAL(wp), PUBLIC ::  xkr_ddiat       !: Size of particles in diatoms pool
55   REAL(wp), PUBLIC ::  xkr_dmeso       !: Size of particles in mesozoo pool
56   REAL(wp), PUBLIC ::  xkr_daggr       !: Size of particles in aggregates pool
57   REAL(wp), PUBLIC ::  xkr_wsbio_min   !: min vertical particle speed
58   REAL(wp), PUBLIC ::  xkr_wsbio_max   !: max vertical particle speed
59
60   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:) ::   xnumm   !:  maximum number of particles in aggregates
61#endif
62
63   !!* Substitution
64#  include "top_substitute.h90"
65   !!----------------------------------------------------------------------
66   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
67   !! $Id$
68   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
69   !!----------------------------------------------------------------------
70CONTAINS
71
72#if defined key_kriest
73   !!----------------------------------------------------------------------
74   !!   'key_kriest'                                                    ???
75   !!----------------------------------------------------------------------
76
77   SUBROUTINE p4z_sink ( kt, jnt )
78      !!---------------------------------------------------------------------
79      !!                ***  ROUTINE p4z_sink  ***
80      !!
81      !! ** Purpose :   Compute vertical flux of particulate matter due to
82      !!              gravitational sinking - Kriest parameterization
83      !!
84      !! ** Method  : - ???
85      !!---------------------------------------------------------------------
86      !
87      INTEGER, INTENT(in) :: kt, jnt
88      !
89      INTEGER  :: ji, jj, jk
90      REAL(wp) :: zagg1, zagg2, zagg3, zagg4, zagg5, zaggsi, zaggsh
91      REAL(wp) :: zagg , zaggdoc, znumdoc
92      REAL(wp) :: znum , zeps, zfm, zgm, zsm
93      REAL(wp) :: zdiv , zdiv1, zdiv2, zdiv3, zdiv4, zdiv5
94      REAL(wp) :: zval1, zval2, zval3, zval4
95      REAL(wp) :: zrfact2
96      INTEGER  :: ik1
97      CHARACTER (len=25) :: charout
98      REAL(wp), POINTER, DIMENSION(:,:,:) :: znum3d 
99      !!---------------------------------------------------------------------
100      !
101      CALL wrk_alloc( jpi, jpj, jpk, znum3d )
102      !
103      !     Initialisation of variables used to compute Sinking Speed
104      !     ---------------------------------------------------------
105
106      znum3d(:,:,:) = 0.e0
107      zval1 = 1. + xkr_zeta
108      zval2 = 1. + xkr_zeta + xkr_eta
109      zval3 = 1. + xkr_eta
110
111      !     Computation of the vertical sinking speed : Kriest et Evans, 2000
112      !     -----------------------------------------------------------------
113
114      DO jk = 1, jpkm1
115         DO jj = 1, jpj
116            DO ji = 1, jpi
117               IF( tmask(ji,jj,jk) /= 0.e0 ) THEN
118                  znum = trn(ji,jj,jk,jppoc) / ( trn(ji,jj,jk,jpnum) + rtrn ) / xkr_massp
119                  ! -------------- To avoid sinking speed over 50 m/day -------
120                  znum  = MIN( xnumm(jk), znum )
121                  znum  = MAX( 1.1      , znum )
122                  znum3d(ji,jj,jk) = znum
123                  !------------------------------------------------------------
124                  zeps  = ( zval1 * znum - 1. )/ ( znum - 1. )
125                  zfm   = xkr_frac**( 1. - zeps )
126                  zgm   = xkr_frac**( zval1 - zeps )
127                  zdiv  = MAX( 1.e-4, ABS( zeps - zval2 ) ) * SIGN( 1., ( zeps - zval2 ) )
128                  zdiv1 = zeps - zval3
129                  wsbio3(ji,jj,jk) = xkr_wsbio_min * ( zeps - zval1 ) / zdiv    &
130                     &             - xkr_wsbio_max *   zgm * xkr_eta  / zdiv
131                  wsbio4(ji,jj,jk) = xkr_wsbio_min *   ( zeps-1. )    / zdiv1   &
132                     &             - xkr_wsbio_max *   zfm * xkr_eta  / zdiv1
133                  IF( znum == 1.1)   wsbio3(ji,jj,jk) = wsbio4(ji,jj,jk)
134               ENDIF
135            END DO
136         END DO
137      END DO
138
139      wscal(:,:,:) = MAX( wsbio3(:,:,:), 50._wp )
140
141      !   INITIALIZE TO ZERO ALL THE SINKING ARRAYS
142      !   -----------------------------------------
143
144      sinking (:,:,:) = 0.e0
145      sinking2(:,:,:) = 0.e0
146      sinkcal (:,:,:) = 0.e0
147      sinkfer (:,:,:) = 0.e0
148      sinksil (:,:,:) = 0.e0
149
150     !   Compute the sedimentation term using p4zsink2 for all the sinking particles
151     !   -----------------------------------------------------
152
153      CALL p4z_sink2( wsbio3, sinking , jppoc )
154      CALL p4z_sink2( wsbio4, sinking2, jpnum )
155      CALL p4z_sink2( wsbio3, sinkfer , jpsfe )
156      CALL p4z_sink2( wscal , sinksil , jpdsi )
157      CALL p4z_sink2( wscal , sinkcal , jpcal )
158
159     !  Exchange between organic matter compartments due to coagulation/disaggregation
160     !  ---------------------------------------------------
161
162      zval1 = 1. + xkr_zeta
163      zval2 = 1. + xkr_eta
164      zval3 = 3. + xkr_eta
165      zval4 = 4. + xkr_eta
166
167      DO jk = 1,jpkm1
168         DO jj = 1,jpj
169            DO ji = 1,jpi
170               IF( tmask(ji,jj,jk) /= 0.e0 ) THEN
171
172                  znum = trn(ji,jj,jk,jppoc)/(trn(ji,jj,jk,jpnum)+rtrn) / xkr_massp
173                  !-------------- To avoid sinking speed over 50 m/day -------
174                  znum  = min(xnumm(jk),znum)
175                  znum  = MAX( 1.1,znum)
176                  !------------------------------------------------------------
177                  zeps  = ( zval1 * znum - 1.) / ( znum - 1.)
178                  zdiv  = MAX( 1.e-4, ABS( zeps - zval3) ) * SIGN( 1., zeps - zval3 )
179                  zdiv1 = MAX( 1.e-4, ABS( zeps - 4.   ) ) * SIGN( 1., zeps - 4.    )
180                  zdiv2 = zeps - 2.
181                  zdiv3 = zeps - 3.
182                  zdiv4 = zeps - zval2
183                  zdiv5 = 2.* zeps - zval4
184                  zfm   = xkr_frac**( 1.- zeps )
185                  zsm   = xkr_frac**xkr_eta
186
187                  !    Part I : Coagulation dependant on turbulence
188                  !    ----------------------------------------------
189
190                  zagg1 = ( 0.163 * trn(ji,jj,jk,jpnum)**2               &
191                     &            * 2.*( (zfm-1.)*(zfm*xkr_mass_max**3-xkr_mass_min**3)    &
192                     &            * (zeps-1)/zdiv1 + 3.*(zfm*xkr_mass_max-xkr_mass_min)    &
193                     &            * (zfm*xkr_mass_max**2-xkr_mass_min**2)                  &
194                     &            * (zeps-1.)**2/(zdiv2*zdiv3)) 
195                  zagg2 =  2*0.163*trn(ji,jj,jk,jpnum)**2*zfm*                       &
196                     &                   ((xkr_mass_max**3+3.*(xkr_mass_max**2          &
197                     &                    *xkr_mass_min*(zeps-1.)/zdiv2                 &
198                     &                    +xkr_mass_max*xkr_mass_min**2*(zeps-1.)/zdiv3)    &
199                     &                    +xkr_mass_min**3*(zeps-1)/zdiv1)                  &
200                     &                    -zfm*xkr_mass_max**3*(1.+3.*((zeps-1.)/           &
201                     &                    (zeps-2.)+(zeps-1.)/zdiv3)+(zeps-1.)/zdiv1))   
202
203                  zagg3 =  0.163*trn(ji,jj,jk,jpnum)**2*zfm**2*8. * xkr_mass_max**3 
204                 
205                 !    Aggregation of small into large particles
206                 !    Part II : Differential settling
207                 !    ----------------------------------------------
208
209                  zagg4 =  2.*3.141*0.125*trn(ji,jj,jk,jpnum)**2*                       &
210                     &                 xkr_wsbio_min*(zeps-1.)**2                         &
211                     &                 *(xkr_mass_min**2*((1.-zsm*zfm)/(zdiv3*zdiv4)      &
212                     &                 -(1.-zfm)/(zdiv*(zeps-1.)))-                       &
213                     &                 ((zfm*zfm*xkr_mass_max**2*zsm-xkr_mass_min**2)     &
214                     &                 *xkr_eta)/(zdiv*zdiv3*zdiv5) )   
215
216                  zagg5 =   2.*3.141*0.125*trn(ji,jj,jk,jpnum)**2                         &
217                     &                 *(zeps-1.)*zfm*xkr_wsbio_min                        &
218                     &                 *(zsm*(xkr_mass_min**2-zfm*xkr_mass_max**2)         &
219                     &                 /zdiv3-(xkr_mass_min**2-zfm*zsm*xkr_mass_max**2)    &
220                     &                 /zdiv) 
221                  zaggsi = ( zagg4 + zagg5 ) * xstep / 10.
222
223                  zagg = 0.5 * xkr_stick * ( zaggsh + zaggsi )
224
225                  !     Aggregation of DOC to small particles
226                  !     --------------------------------------
227
228                  zaggdoc = ( 0.4 * trn(ji,jj,jk,jpdoc)               &
229                     &        + 1018.  * trn(ji,jj,jk,jppoc)  ) * xstep    &
230                     &        * xdiss(ji,jj,jk) * trn(ji,jj,jk,jpdoc)
231
232# if defined key_degrad
233                   zagg1   = zagg1   * facvol(ji,jj,jk)                 
234                   zagg2   = zagg2   * facvol(ji,jj,jk)                 
235                   zagg3   = zagg3   * facvol(ji,jj,jk)                 
236                   zagg4   = zagg4   * facvol(ji,jj,jk)                 
237                   zagg5   = zagg5   * facvol(ji,jj,jk)                 
238                   zaggdoc = zaggdoc * facvol(ji,jj,jk)                 
239# endif
240                  zaggsh = ( zagg1 + zagg2 + zagg3 ) * rfact2 * xdiss(ji,jj,jk) / 1000.
241                  zaggsi = ( zagg4 + zagg5 ) * xstep / 10.
242                  zagg = 0.5 * xkr_stick * ( zaggsh + zaggsi )
243                  !
244                  znumdoc = trn(ji,jj,jk,jpnum) / ( trn(ji,jj,jk,jppoc) + rtrn )
245                  tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zaggdoc
246                  tra(ji,jj,jk,jpnum) = tra(ji,jj,jk,jpnum) + zaggdoc * znumdoc - zagg
247                  tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) - zaggdoc
248
249               ENDIF
250            END DO
251         END DO
252      END DO
253
254      IF( ln_diatrc ) THEN
255         !
256         ik1 = iksed + 1
257         zrfact2 = 1.e3 * rfact2r
258         IF( jnt == nrdttrc ) THEN
259           CALL iom_put( "POCFlx"  , sinking (:,:,:)      * zrfact2 * tmask(:,:,:) )  ! POC export
260           CALL iom_put( "NumFlx"  , sinking2 (:,:,:)     * zrfact2 * tmask(:,:,:) )  ! Num export
261           CALL iom_put( "SiFlx"   , sinksil (:,:,:)      * zrfact2 * tmask(:,:,:) )  ! Silica export
262           CALL iom_put( "CaCO3Flx", sinkcal (:,:,:)      * zrfact2 * tmask(:,:,:) )  ! Calcite export
263           CALL iom_put( "xnum"    , znum3d  (:,:,:)                * tmask(:,:,:) )  ! Number of particles in aggregats
264           CALL iom_put( "W1"      , wsbio3  (:,:,:)                * tmask(:,:,:) )  ! sinking speed of POC
265           CALL iom_put( "W2"      , wsbio4  (:,:,:)                * tmask(:,:,:) )  ! sinking speed of aggregats
266           CALL iom_put( "PMO"     , sinking (:,:,ik1)    * zrfact2 * tmask(:,:,1) )  ! POC export at 100m
267           CALL iom_put( "PMO2"    , sinking2(:,:,ik1)    * zrfact2 * tmask(:,:,1) )  ! Num export at 100m
268           CALL iom_put( "ExpFe1"  , sinkfer (:,:,ik1)    * zrfact2 * tmask(:,:,1) )  ! Export of iron at 100m
269           CALL iom_put( "ExpSi"   , sinksil (:,:,ik1)    * zrfact2 * tmask(:,:,1) )  ! export of silica at 100m
270           CALL iom_put( "ExpCaCO3", sinkcal (:,:,ik1)    * zrfact2 * tmask(:,:,1) )  ! export of calcite at 100m
271         ENDIF
272# if ! defined key_iomput
273         trc2d(:,:  ,jp_pcs0_2d + 4)  = sinking (:,:,ik1)    * zrfact2 * tmask(:,:,1)
274         trc2d(:,:  ,jp_pcs0_2d + 5)  = sinking2(:,:,ik1)    * zrfact2 * tmask(:,:,1)
275         trc2d(:,:  ,jp_pcs0_2d + 6)  = sinkfer (:,:,ik1)    * zrfact2 * tmask(:,:,1)
276         trc2d(:,:  ,jp_pcs0_2d + 7)  = sinksil (:,:,ik1)    * zrfact2 * tmask(:,:,1)
277         trc2d(:,:  ,jp_pcs0_2d + 8)  = sinkcal (:,:,ik1)    * zrfact2 * tmask(:,:,1)
278         trc3d(:,:,:,jp_pcs0_3d + 11) = sinking (:,:,:)      * zrfact2 * tmask(:,:,:)
279         trc3d(:,:,:,jp_pcs0_3d + 12) = sinking2(:,:,:)      * zrfact2 * tmask(:,:,:)
280         trc3d(:,:,:,jp_pcs0_3d + 13) = sinksil (:,:,:)      * zrfact2 * tmask(:,:,:)
281         trc3d(:,:,:,jp_pcs0_3d + 14) = sinkcal (:,:,:)      * zrfact2 * tmask(:,:,:)
282         trc3d(:,:,:,jp_pcs0_3d + 15) = znum3d  (:,:,:)                * tmask(:,:,:)
283         trc3d(:,:,:,jp_pcs0_3d + 16) = wsbio3  (:,:,:)                * tmask(:,:,:)
284         trc3d(:,:,:,jp_pcs0_3d + 17) = wsbio4  (:,:,:)                * tmask(:,:,:)
285# endif
286        !
287      ENDIF
288      !
289      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
290         WRITE(charout, FMT="('sink')")
291         CALL prt_ctl_trc_info(charout)
292         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
293      ENDIF
294      !
295      CALL wrk_alloc( jpi, jpj, jpk, znum3d )
296      !
297   END SUBROUTINE p4z_sink
298
299
300   SUBROUTINE p4z_sink_init
301      !!----------------------------------------------------------------------
302      !!                  ***  ROUTINE p4z_sink_init  ***
303      !!
304      !! ** Purpose :   Initialization of sinking parameters
305      !!                Kriest parameterization only
306      !!
307      !! ** Method  :   Read the nampiskrs namelist and check the parameters
308      !!      called at the first timestep
309      !!
310      !! ** input   :   Namelist nampiskrs
311      !!----------------------------------------------------------------------
312      INTEGER  ::   jk, jn, kiter
313      REAL(wp) ::   znum, zdiv
314      REAL(wp) ::   zws, zwr, zwl,wmax, znummax
315      REAL(wp) ::   zmin, zmax, zl, zr, xacc
316      !
317      NAMELIST/nampiskrs/ xkr_sfact, xkr_stick ,  &
318         &                xkr_nnano, xkr_ndiat, xkr_nmeso, xkr_naggr
319      !!----------------------------------------------------------------------
320      !
321      REWIND( numnatp )                     ! read nampiskrs
322      READ  ( numnatp, nampiskrs )
323
324      IF(lwp) THEN
325         WRITE(numout,*)
326         WRITE(numout,*) ' Namelist : nampiskrs'
327         WRITE(numout,*) '    Sinking factor                           xkr_sfact    = ', xkr_sfact
328         WRITE(numout,*) '    Stickiness                               xkr_stick    = ', xkr_stick
329         WRITE(numout,*) '    Nbr of cell in nano size class           xkr_nnano    = ', xkr_nnano
330         WRITE(numout,*) '    Nbr of cell in diatoms size class        xkr_ndiat    = ', xkr_ndiat
331         WRITE(numout,*) '    Nbr of cell in mesozoo size class        xkr_nmeso    = ', xkr_nmeso
332         WRITE(numout,*) '    Nbr of cell in aggregates size class     xkr_naggr    = ', xkr_naggr
333      ENDIF
334
335
336      ! max and min vertical particle speed
337      xkr_wsbio_min = xkr_sfact * xkr_mass_min**xkr_eta
338      xkr_wsbio_max = xkr_sfact * xkr_mass_max**xkr_eta
339      WRITE(numout,*) ' max and min vertical particle speed ', xkr_wsbio_min, xkr_wsbio_max
340
341      !
342      !    effect of the sizes of the different living pools on particle numbers
343      !    nano = 2um-20um -> mean size=6.32 um -> ws=2.596 -> xnum=xnnano=2.337
344      !    diat and microzoo = 10um-200um -> 44.7 -> 8.732 -> xnum=xndiat=3.718
345      !    mesozoo = 200um-2mm -> 632.45 -> 45.14 -> xnum=xnmeso=7.147
346      !    aggregates = 200um-10mm -> 1414 -> 74.34 -> xnum=xnaggr=9.877
347      !    doc aggregates = 1um
348      ! ----------------------------------------------------------
349
350      xkr_dnano = 1. / ( xkr_massp * xkr_nnano )
351      xkr_ddiat = 1. / ( xkr_massp * xkr_ndiat )
352      xkr_dmeso = 1. / ( xkr_massp * xkr_nmeso )
353      xkr_daggr = 1. / ( xkr_massp * xkr_naggr )
354
355      !!---------------------------------------------------------------------
356      !!    'key_kriest'                                                  ???
357      !!---------------------------------------------------------------------
358      !  COMPUTATION OF THE VERTICAL PROFILE OF MAXIMUM SINKING SPEED
359      !  Search of the maximum number of particles in aggregates for each k-level.
360      !  Bissection Method
361      !--------------------------------------------------------------------
362      WRITE(numout,*)
363      WRITE(numout,*)'    kriest : Compute maximum number of particles in aggregates'
364
365      xacc     =  0.001_wp
366      kiter    = 50
367      zmin     =  1.10_wp
368      zmax     = xkr_mass_max / xkr_mass_min
369      xkr_frac = zmax
370
371      DO jk = 1,jpk
372         zl = zmin
373         zr = zmax
374         wmax = 0.5 * fse3t(1,1,jk) * rday / rfact2
375         zdiv = xkr_zeta + xkr_eta - xkr_eta * zl
376         znum = zl - 1.
377         zwl =  xkr_wsbio_min * xkr_zeta / zdiv &
378            & - ( xkr_wsbio_max * xkr_eta * znum * &
379            &     xkr_frac**( -xkr_zeta / znum ) / zdiv ) &
380            & - wmax
381
382         zdiv = xkr_zeta + xkr_eta - xkr_eta * zr
383         znum = zr - 1.
384         zwr =  xkr_wsbio_min * xkr_zeta / zdiv &
385            & - ( xkr_wsbio_max * xkr_eta * znum * &
386            &     xkr_frac**( -xkr_zeta / znum ) / zdiv ) &
387            & - wmax
388iflag:   DO jn = 1, kiter
389            IF    ( zwl == 0._wp ) THEN   ;   znummax = zl
390            ELSEIF( zwr == 0._wp ) THEN   ;   znummax = zr
391            ELSE
392               znummax = ( zr + zl ) / 2.
393               zdiv = xkr_zeta + xkr_eta - xkr_eta * znummax
394               znum = znummax - 1.
395               zws =  xkr_wsbio_min * xkr_zeta / zdiv &
396                  & - ( xkr_wsbio_max * xkr_eta * znum * &
397                  &     xkr_frac**( -xkr_zeta / znum ) / zdiv ) &
398                  & - wmax
399               IF( zws * zwl < 0. ) THEN   ;   zr = znummax
400               ELSE                        ;   zl = znummax
401               ENDIF
402               zdiv = xkr_zeta + xkr_eta - xkr_eta * zl
403               znum = zl - 1.
404               zwl =  xkr_wsbio_min * xkr_zeta / zdiv &
405                  & - ( xkr_wsbio_max * xkr_eta * znum * &
406                  &     xkr_frac**( -xkr_zeta / znum ) / zdiv ) &
407                  & - wmax
408
409               zdiv = xkr_zeta + xkr_eta - xkr_eta * zr
410               znum = zr - 1.
411               zwr =  xkr_wsbio_min * xkr_zeta / zdiv &
412                  & - ( xkr_wsbio_max * xkr_eta * znum * &
413                  &     xkr_frac**( -xkr_zeta / znum ) / zdiv ) &
414                  & - wmax
415               !
416               IF ( ABS ( zws )  <= xacc ) EXIT iflag
417               !
418            ENDIF
419            !
420         END DO iflag
421
422         xnumm(jk) = znummax
423         WRITE(numout,*) '       jk = ', jk, ' wmax = ', wmax,' xnum max = ', xnumm(jk)
424         !
425      END DO
426      !
427  END SUBROUTINE p4z_sink_init
428
429#else
430
431   SUBROUTINE p4z_sink ( kt, jnt )
432      !!---------------------------------------------------------------------
433      !!                     ***  ROUTINE p4z_sink  ***
434      !!
435      !! ** Purpose :   Compute vertical flux of particulate matter due to
436      !!                gravitational sinking
437      !!
438      !! ** Method  : - ???
439      !!---------------------------------------------------------------------
440      INTEGER, INTENT(in) :: kt, jnt
441      INTEGER  ::   ji, jj, jk
442      REAL(wp) ::   zagg1, zagg2, zagg3, zagg4
443      REAL(wp) ::   zagg , zaggfe, zaggdoc, zaggdoc2, zaggdoc3
444      REAL(wp) ::   zfact, zwsmax, zmax, zstep
445      REAL(wp) ::   zrfact2
446      INTEGER  ::   ik1
447      CHARACTER (len=25) :: charout
448      !!---------------------------------------------------------------------
449
450      !    Sinking speeds of detritus is increased with depth as shown
451      !    by data and from the coagulation theory
452      !    -----------------------------------------------------------
453      DO jk = 1, jpkm1
454         DO jj = 1, jpj
455            DO ji = 1,jpi
456      !         zmax  = MAX( heup(ji,jj), hmld(ji,jj) )
457      !         zfact = MAX( 0., fsdepw(ji,jj,jk+1) - zmax ) / 5000._wp
458               zmax = hmld(ji,jj)
459               zfact = MAX( 0., fsdepw(ji,jj,jk+1) - zmax ) / 4000._wp
460               wsbio4(ji,jj,jk) = wsbio2 + ( 200.- wsbio2 ) * zfact
461            END DO
462         END DO
463      END DO
464
465      ! limit the values of the sinking speeds to avoid numerical instabilities 
466      wsbio3(:,:,:) = wsbio
467      !
468      ! OA Below, this is garbage. the ideal would be to find a time-splitting
469      ! OA algorithm that does not increase the computing cost by too much
470      ! OA In ROMS, I have included a time-splitting procedure. But it is
471      ! OA too expensive as the loop is computed globally. Thus, a small e3t
472      ! OA at one place determines the number of subtimesteps globally
473      ! OA AWFULLY EXPENSIVE !! Not able to find a better approach. Damned !!
474
475      DO jk = 1,jpkm1
476         DO jj = 1, jpj
477            DO ji = 1, jpi
478               zwsmax = 0.8 * fse3t(ji,jj,jk) / xstep
479               wsbio4(ji,jj,jk) = MIN( wsbio4(ji,jj,jk), zwsmax )
480               wsbio3(ji,jj,jk) = MIN( wsbio3(ji,jj,jk), zwsmax )
481            END DO
482         END DO
483      END DO
484
485      wscal(:,:,:) = wsbio4(:,:,:)
486
487      !  Initializa to zero all the sinking arrays
488      !   -----------------------------------------
489
490      sinking (:,:,:) = 0.e0
491      sinking2(:,:,:) = 0.e0
492      sinkcal (:,:,:) = 0.e0
493      sinkfer (:,:,:) = 0.e0
494      sinksil (:,:,:) = 0.e0
495      sinkfer2(:,:,:) = 0.e0
496
497      !   Compute the sedimentation term using p4zsink2 for all the sinking particles
498      !   -----------------------------------------------------
499
500      CALL p4z_sink2( wsbio3, sinking , jppoc )
501      CALL p4z_sink2( wsbio3, sinkfer , jpsfe )
502      CALL p4z_sink2( wsbio4, sinking2, jpgoc )
503      CALL p4z_sink2( wsbio4, sinkfer2, jpbfe )
504      CALL p4z_sink2( wsbio4, sinksil , jpdsi )
505      CALL p4z_sink2( wscal , sinkcal , jpcal )
506
507      !  Exchange between organic matter compartments due to coagulation/disaggregation
508      !  ---------------------------------------------------
509
510      DO jk = 1, jpkm1
511         DO jj = 1, jpj
512            DO ji = 1, jpi
513               !
514               zstep = xstep 
515# if defined key_degrad
516               zstep = zstep * facvol(ji,jj,jk)
517# endif
518               zfact = zstep * xdiss(ji,jj,jk)
519               !  Part I : Coagulation dependent on turbulence
520               zagg1 = 354.  * zfact * trn(ji,jj,jk,jppoc) * trn(ji,jj,jk,jppoc)
521               zagg2 = 4452. * zfact * trn(ji,jj,jk,jppoc) * trn(ji,jj,jk,jpgoc)
522
523               ! Part II : Differential settling
524
525               !  Aggregation of small into large particles
526               zagg3 =  4.7 * zstep * trn(ji,jj,jk,jppoc) * trn(ji,jj,jk,jpgoc)
527               zagg4 =  0.4 * zstep * trn(ji,jj,jk,jppoc) * trn(ji,jj,jk,jppoc)
528
529               zagg   = zagg1 + zagg2 + zagg3 + zagg4
530               zaggfe = zagg * trn(ji,jj,jk,jpsfe) / ( trn(ji,jj,jk,jppoc) + rtrn )
531
532               ! Aggregation of DOC to small particles
533               zaggdoc  = ( 0.83 * trn(ji,jj,jk,jpdoc) + 271. * trn(ji,jj,jk,jppoc) ) * zfact * trn(ji,jj,jk,jpdoc)
534               zaggdoc2 = 1.07e4 * zfact * trn(ji,jj,jk,jpgoc) * trn(ji,jj,jk,jpdoc)
535               zaggdoc3 =   0.02 * ( 16706. * trn(ji,jj,jk,jppoc) + 231. * trn(ji,jj,jk,jpdoc) ) * zstep * trn(ji,jj,jk,jpdoc)
536
537               !  Update the trends
538               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) - zagg + zaggdoc + zaggdoc3
539               tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) + zagg + zaggdoc2
540               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) - zaggfe
541               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + zaggfe
542               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) - zaggdoc - zaggdoc2 - zaggdoc3
543               !
544            END DO
545         END DO
546      END DO
547
548      IF( ln_diatrc ) THEN
549         zrfact2 = 1.e3 * rfact2r
550         ik1  = iksed + 1
551         IF( lk_iomput ) THEN
552           IF( jnt == nrdttrc ) THEN
553              CALL iom_put( "EPC100"  , ( sinking(:,:,ik1) + sinking2(:,:,ik1) ) * zrfact2 * tmask(:,:,1) ) ! Export of carbon at 100m
554              CALL iom_put( "EPFE100" , ( sinkfer(:,:,ik1) + sinkfer2(:,:,ik1) ) * zrfact2 * tmask(:,:,1) ) ! Export of iron at 100m
555              CALL iom_put( "EPCAL100",   sinkcal(:,:,ik1)                       * zrfact2 * tmask(:,:,1) ) ! Export of calcite  at 100m
556              CALL iom_put( "EPSI100" ,   sinksil(:,:,ik1)                       * zrfact2 * tmask(:,:,1) ) ! Export of biogenic silica at 100m
557           ENDIF
558         ELSE
559           trc2d(:,:,jp_pcs0_2d + 4) = sinking (:,:,ik1) * zrfact2 * tmask(:,:,1)
560           trc2d(:,:,jp_pcs0_2d + 5) = sinking2(:,:,ik1) * zrfact2 * tmask(:,:,1)
561           trc2d(:,:,jp_pcs0_2d + 6) = sinkfer (:,:,ik1) * zrfact2 * tmask(:,:,1)
562           trc2d(:,:,jp_pcs0_2d + 7) = sinkfer2(:,:,ik1) * zrfact2 * tmask(:,:,1)
563           trc2d(:,:,jp_pcs0_2d + 8) = sinksil (:,:,ik1) * zrfact2 * tmask(:,:,1)
564           trc2d(:,:,jp_pcs0_2d + 9) = sinkcal (:,:,ik1) * zrfact2 * tmask(:,:,1)
565         ENDIF
566      ENDIF
567      !
568      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
569         WRITE(charout, FMT="('sink')")
570         CALL prt_ctl_trc_info(charout)
571         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
572      ENDIF
573      !
574   END SUBROUTINE p4z_sink
575
576   SUBROUTINE p4z_sink_init
577      !!----------------------------------------------------------------------
578      !!                  ***  ROUTINE p4z_sink_init  ***
579      !!----------------------------------------------------------------------
580   END SUBROUTINE p4z_sink_init
581
582#endif
583
584
585
586   SUBROUTINE p4z_sink2( pwsink, psinkflx, jp_tra )
587      !!---------------------------------------------------------------------
588      !!                     ***  ROUTINE p4z_sink2  ***
589      !!
590      !! ** Purpose :   Compute the sedimentation terms for the various sinking
591      !!     particles. The scheme used to compute the trends is based
592      !!     on MUSCL.
593      !!
594      !! ** Method  : - this ROUTINE compute not exactly the advection but the
595      !!      transport term, i.e.  div(u*tra).
596      !!---------------------------------------------------------------------
597      !
598      INTEGER , INTENT(in   )                         ::   jp_tra    ! tracer index index     
599      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj,jpk) ::   pwsink    ! sinking speed
600      REAL(wp), INTENT(inout), DIMENSION(jpi,jpj,jpk) ::   psinkflx  ! sinking fluxe
601      !!
602      INTEGER  ::   ji, jj, jk, jn
603      REAL(wp) ::   zigma,zew,zign, zflx, zstep
604      REAL(wp), POINTER, DIMENSION(:,:,:) :: ztraz, zakz, zwsink2 
605      !!---------------------------------------------------------------------
606
607      ! Allocate temporary workspace
608      CALL wrk_alloc( jpi, jpj, jpk, ztraz, zakz, zwsink2 )
609
610      zstep = rfact2 / 2.
611
612      ztraz(:,:,:) = 0.e0
613      zakz (:,:,:) = 0.e0
614
615      DO jk = 1, jpkm1
616         zwsink2(:,:,jk+1) = -pwsink(:,:,jk) / rday * tmask(:,:,jk+1) 
617      END DO
618      zwsink2(:,:,1) = 0.e0
619      IF( lk_degrad ) THEN
620         zwsink2(:,:,:) = zwsink2(:,:,:) * facvol(:,:,:)
621      ENDIF
622
623
624      ! Vertical advective flux
625      DO jn = 1, 2
626         !  first guess of the slopes interior values
627         DO jk = 2, jpkm1
628            ztraz(:,:,jk) = ( trn(:,:,jk-1,jp_tra) - trn(:,:,jk,jp_tra) ) * tmask(:,:,jk)
629         END DO
630         ztraz(:,:,1  ) = 0.0
631         ztraz(:,:,jpk) = 0.0
632
633         ! slopes
634         DO jk = 2, jpkm1
635            DO jj = 1,jpj
636               DO ji = 1, jpi
637                  zign = 0.25 + SIGN( 0.25, ztraz(ji,jj,jk) * ztraz(ji,jj,jk+1) )
638                  zakz(ji,jj,jk) = ( ztraz(ji,jj,jk) + ztraz(ji,jj,jk+1) ) * zign
639               END DO
640            END DO
641         END DO
642         
643         ! Slopes limitation
644         DO jk = 2, jpkm1
645            DO jj = 1, jpj
646               DO ji = 1, jpi
647                  zakz(ji,jj,jk) = SIGN( 1., zakz(ji,jj,jk) ) *        &
648                     &             MIN( ABS( zakz(ji,jj,jk) ), 2. * ABS(ztraz(ji,jj,jk+1)), 2. * ABS(ztraz(ji,jj,jk) ) )
649               END DO
650            END DO
651         END DO
652         
653         ! vertical advective flux
654         DO jk = 1, jpkm1
655            DO jj = 1, jpj     
656               DO ji = 1, jpi   
657                  zigma = zwsink2(ji,jj,jk+1) * zstep / fse3w(ji,jj,jk+1)
658                  zew   = zwsink2(ji,jj,jk+1)
659                  psinkflx(ji,jj,jk+1) = -zew * ( trn(ji,jj,jk,jp_tra) - 0.5 * ( 1 + zigma ) * zakz(ji,jj,jk) ) * zstep
660               END DO
661            END DO
662         END DO
663         !
664         ! Boundary conditions
665         psinkflx(:,:,1  ) = 0.e0
666         psinkflx(:,:,jpk) = 0.e0
667         
668         DO jk=1,jpkm1
669            DO jj = 1,jpj
670               DO ji = 1, jpi
671                  zflx = ( psinkflx(ji,jj,jk) - psinkflx(ji,jj,jk+1) ) / fse3t(ji,jj,jk)
672                  trn(ji,jj,jk,jp_tra) = trn(ji,jj,jk,jp_tra) + zflx
673               END DO
674            END DO
675         END DO
676
677      ENDDO
678
679      DO jk=1,jpkm1
680         DO jj = 1,jpj
681            DO ji = 1, jpi
682               zflx = ( psinkflx(ji,jj,jk) - psinkflx(ji,jj,jk+1) ) / fse3t(ji,jj,jk)
683               trb(ji,jj,jk,jp_tra) = trb(ji,jj,jk,jp_tra) + 2. * zflx
684            END DO
685         END DO
686      END DO
687
688      trn     (:,:,:,jp_tra) = trb(:,:,:,jp_tra)
689      psinkflx(:,:,:)        = 2. * psinkflx(:,:,:)
690      !
691      CALL wrk_dealloc( jpi, jpj, jpk, ztraz, zakz, zwsink2 )
692      !
693   END SUBROUTINE p4z_sink2
694
695
696   INTEGER FUNCTION p4z_sink_alloc()
697      !!----------------------------------------------------------------------
698      !!                     ***  ROUTINE p4z_sink_alloc  ***
699      !!----------------------------------------------------------------------
700      ALLOCATE( wsbio3 (jpi,jpj,jpk) , wsbio4  (jpi,jpj,jpk) , wscal(jpi,jpj,jpk) ,     &
701         &      sinking(jpi,jpj,jpk) , sinking2(jpi,jpj,jpk)                      ,     &               
702         &      sinkcal(jpi,jpj,jpk) , sinksil (jpi,jpj,jpk)                      ,     &               
703#if defined key_kriest
704         &      xnumm(jpk)                                                        ,     &               
705#else
706         &      sinkfer2(jpi,jpj,jpk)                                             ,     &               
707#endif
708         &      sinkfer(jpi,jpj,jpk)                                              , STAT=p4z_sink_alloc )               
709         !
710      IF( p4z_sink_alloc /= 0 ) CALL ctl_warn('p4z_sink_alloc : failed to allocate arrays.')
711      !
712   END FUNCTION p4z_sink_alloc
713   
714#else
715   !!======================================================================
716   !!  Dummy module :                                   No PISCES bio-model
717   !!======================================================================
718CONTAINS
719   SUBROUTINE p4z_sink                    ! Empty routine
720   END SUBROUTINE p4z_sink
721#endif 
722
723   !!======================================================================
724END MODULE  p4zsink
Note: See TracBrowser for help on using the repository browser.