New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcrad.F90 in branches/2011/dev_NEMO_MERGE_2011/NEMOGCM/NEMO/TOP_SRC/TRP – NEMO

source: branches/2011/dev_NEMO_MERGE_2011/NEMOGCM/NEMO/TOP_SRC/TRP/trcrad.F90 @ 3116

Last change on this file since 3116 was 3116, checked in by cetlod, 12 years ago

dev_NEMO_MERGE_2011: add in changes dev_NOC_UKMO_MERGE developments
  • Property svn:keywords set to Id
File size: 9.6 KB
Line 
1MODULE trcrad
2   !!======================================================================
3   !!                       ***  MODULE  trcrad  ***
4   !! Ocean passive tracers:  correction of negative concentrations
5   !!======================================================================
6   !! History :   -   !  01-01  (O. Aumont & E. Kestenare)  Original code
7   !!            1.0  !  04-03  (C. Ethe)  free form F90
8   !!----------------------------------------------------------------------
9#if defined key_top
10   !!----------------------------------------------------------------------
11   !!   'key_top'                                                TOP models
12   !!----------------------------------------------------------------------
13   !!   trc_rad    : correction of negative concentrations
14   !!----------------------------------------------------------------------
15   USE oce_trc             ! ocean dynamics and tracers variables
16   USE trc                 ! ocean passive tracers variables
17   USE trdmod_oce
18   USE trdtra
19   USE prtctl_trc          ! Print control for debbuging
20
21   IMPLICIT NONE
22   PRIVATE
23
24   PUBLIC trc_rad         ! routine called by trcstp.F90
25
26   !! * Substitutions
27#  include "top_substitute.h90"
28   !!----------------------------------------------------------------------
29   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
30   !! $Id$
31   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
32   !!----------------------------------------------------------------------
33   
34CONTAINS
35
36   SUBROUTINE trc_rad( kt )
37      !!----------------------------------------------------------------------
38      !!                  ***  ROUTINE trc_rad  ***
39      !!
40      !! ** Purpose :   "crappy" routine to correct artificial negative
41      !!              concentrations due to isopycnal scheme
42      !!
43      !! ** Method  : - PISCES or LOBSTER: Set negative concentrations to zero
44      !!                while computing the corresponding tracer content that
45      !!                is added to the tracers. Then, adjust the tracer
46      !!                concentration using a multiplicative factor so that
47      !!                the total tracer concentration is preserved.
48      !!              - CFC: simply set to zero the negative CFC concentration
49      !!                (the total CFC content is not strictly preserved)
50      !!----------------------------------------------------------------------
51      INTEGER, INTENT( in ) ::   kt   ! ocean time-step index     
52      CHARACTER (len=22) :: charout
53      !!----------------------------------------------------------------------
54
55      IF( kt == nittrc000 ) THEN
56         IF(lwp) WRITE(numout,*)
57         IF(lwp) WRITE(numout,*) 'trc_rad : Correct artificial negative concentrations '
58         IF(lwp) WRITE(numout,*) '~~~~~~~ '
59      ENDIF
60
61      IF( lk_cfc     )   CALL trc_rad_sms( kt, trb, trn, jp_cfc0 , jp_cfc1               )  ! CFC model
62      IF( lk_c14b    )   CALL trc_rad_sms( kt, trb, trn, jp_c14b0, jp_c14b1              )  ! bomb C14
63      IF( lk_lobster )   CALL trc_rad_sms( kt, trb, trn, jp_lob0 , jp_lob1, cpreserv='Y' )  ! LOBSTER model
64      IF( lk_pisces  )   CALL trc_rad_sms( kt, trb, trn, jp_pcs0 , jp_pcs1, cpreserv='Y' )  ! PISCES model
65      IF( lk_my_trc  )   CALL trc_rad_sms( kt, trb, trn, jp_myt0 , jp_myt1               )  ! MY_TRC model
66
67
68      !
69      IF(ln_ctl) THEN      ! print mean trends (used for debugging)
70         WRITE(charout, FMT="('rad')")
71         CALL prt_ctl_trc_info( charout )
72         CALL prt_ctl_trc( tab4d=trn, mask=tmask, clinfo=ctrcnm )
73      ENDIF
74      !
75   END SUBROUTINE trc_rad
76
77   SUBROUTINE trc_rad_sms( kt, ptrb, ptrn, jp_sms0, jp_sms1, cpreserv )
78      !!-----------------------------------------------------------------------------
79      !!                  ***  ROUTINE trc_rad_sms  ***
80      !!
81      !! ** Purpose :   "crappy" routine to correct artificial negative
82      !!              concentrations due to isopycnal scheme
83      !!
84      !! ** Method  : 2 cases :
85      !!                - Set negative concentrations to zero while computing
86      !!                  the corresponding tracer content that is added to the
87      !!                  tracers. Then, adjust the tracer concentration using
88      !!                  a multiplicative factor so that the total tracer
89      !!                  concentration is preserved.
90      !!                - simply set to zero the negative CFC concentration
91      !!                  (the total content of concentration is not strictly preserved)
92      !!--------------------------------------------------------------------------------
93      !! Arguments
94      INTEGER, INTENT( in ) ::   kt   ! ocean time-step index
95      INTEGER  , INTENT( in ) ::  &
96         jp_sms0, &       !: First index of the passive tracer model
97         jp_sms1          !: Last  index of  the passive tracer model
98
99      REAL(wp), DIMENSION (jpi,jpj,jpk,jptra), INTENT( inout )  :: &
100         ptrb, ptrn       !: before and now traceur concentration
101
102      CHARACTER( len = 1) , INTENT(in), OPTIONAL  :: &
103         cpreserv          !: flag to preserve content or not
104     
105      ! Local declarations
106      INTEGER  :: ji, jj, jk, jn     ! dummy loop indices
107      REAL(wp) :: ztrcorb, ztrmasb   ! temporary scalars
108      REAL(wp) :: zcoef, ztrcorn, ztrmasn   !    "         "
109      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrtrdb  ! workspace arrays
110      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrtrdn  ! workspace arrays
111      REAL(wp) :: zs2rdt
112      LOGICAL ::   lldebug = .FALSE.
113
114      !!----------------------------------------------------------------------
115
116      IF( l_trdtrc ) THEN
117        !
118        ALLOCATE( ztrtrdb(jpi,jpj,jpk) )
119        ALLOCATE( ztrtrdn(jpi,jpj,jpk) )
120        !
121      ENDIF
122     
123      IF( PRESENT( cpreserv )  ) THEN   !  total tracer concentration is preserved
124     
125         DO jn = jp_sms0, jp_sms1
126            !                                                        ! ===========
127            ztrcorb = 0.e0   ;   ztrmasb = 0.e0
128            ztrcorn = 0.e0   ;   ztrmasn = 0.e0
129
130            IF( l_trdtrc ) THEN
131               ztrtrdb(:,:,:) = ptrb(:,:,:,jn)                        ! save input trb for trend computation
132               ztrtrdn(:,:,:) = ptrn(:,:,:,jn)                        ! save input trn for trend computation
133            ENDIF
134            !                                                         ! sum over the global domain
135            ztrcorb = glob_sum( MIN( 0., ptrb(:,:,:,jn) ) * cvol(:,:,:) )
136            ztrcorn = glob_sum( MIN( 0., ptrn(:,:,:,jn) ) * cvol(:,:,:) )
137
138            ztrmasb = glob_sum( MAX( 0., ptrb(:,:,:,jn) ) * cvol(:,:,:) )
139            ztrmasn = glob_sum( MAX( 0., ptrn(:,:,:,jn) ) * cvol(:,:,:) )
140
141            IF( ztrcorb /= 0 ) THEN
142               zcoef = 1. + ztrcorb / ztrmasb
143               DO jk = 1, jpkm1
144                  ptrb(:,:,jk,jn) = MAX( 0., ptrb(:,:,jk,jn) )
145                  ptrb(:,:,jk,jn) = ptrb(:,:,jk,jn) * zcoef * tmask(:,:,jk)
146               END DO
147            ENDIF
148
149            IF( ztrcorn /= 0 ) THEN
150               zcoef = 1. + ztrcorn / ztrmasn
151               DO jk = 1, jpkm1
152                  ptrn(:,:,jk,jn) = MAX( 0., ptrn(:,:,jk,jn) )
153                  ptrn(:,:,jk,jn) = ptrn(:,:,jk,jn) * zcoef * tmask(:,:,jk)
154               END DO
155            ENDIF
156            !
157            IF( l_trdtrc ) THEN
158               !
159               zs2rdt = 1. / ( 2. * rdt )
160               ztrtrdb(:,:,:) = ( ptrb(:,:,:,jn) - ztrtrdb(:,:,:) ) * zs2rdt
161               ztrtrdn(:,:,:) = ( ptrn(:,:,:,jn) - ztrtrdn(:,:,:) ) * zs2rdt 
162               CALL trd_tra( kt, 'TRC', jn, jptra_trd_radb, ztrtrdb )       ! Asselin-like trend handling
163               CALL trd_tra( kt, 'TRC', jn, jptra_trd_radn, ztrtrdn )       ! standard     trend handling
164              !
165            ENDIF
166
167         END DO
168         !
169         !
170      ELSE  ! total CFC content is not strictly preserved
171
172         DO jn = jp_sms0, jp_sms1 
173
174           IF( l_trdtrc ) THEN
175              ztrtrdb(:,:,:) = ptrb(:,:,:,jn)                        ! save input trb for trend computation
176              ztrtrdn(:,:,:) = ptrn(:,:,:,jn)                        ! save input trn for trend computation
177           ENDIF
178
179            DO jk = 1, jpkm1
180               DO jj = 1, jpj
181                  DO ji = 1, jpi
182                     ptrn(ji,jj,jk,jn) = MAX( 0. , ptrn(ji,jj,jk,jn) )
183                     ptrb(ji,jj,jk,jn) = MAX( 0. , ptrb(ji,jj,jk,jn) )
184                  END DO
185               END DO
186            END DO
187         
188            IF( l_trdtrc ) THEN
189               !
190               zs2rdt = 1. / ( 2. * rdt * FLOAT(nn_dttrc) )
191               ztrtrdb(:,:,:) = ( ptrb(:,:,:,jn) - ztrtrdb(:,:,:) ) * zs2rdt
192               ztrtrdn(:,:,:) = ( ptrn(:,:,:,jn) - ztrtrdn(:,:,:) ) * zs2rdt 
193               CALL trd_tra( kt, 'TRC', jn, jptra_trd_radb, ztrtrdb )       ! Asselin-like trend handling
194               CALL trd_tra( kt, 'TRC', jn, jptra_trd_radn, ztrtrdn )       ! standard     trend handling
195              !
196            ENDIF
197            !
198         ENDDO
199
200      ENDIF
201
202      IF( l_trdtrc )   DEALLOCATE( ztrtrdb, ztrtrdn )
203
204   END SUBROUTINE trc_rad_sms
205#else
206   !!----------------------------------------------------------------------
207   !!   Dummy module :                                         NO TOP model
208   !!----------------------------------------------------------------------
209CONTAINS
210   SUBROUTINE trc_rad( kt )              ! Empty routine
211      INTEGER, INTENT(in) ::   kt
212      WRITE(*,*) 'trc_rad: You should not have seen this print! error?', kt
213   END SUBROUTINE trc_rad
214#endif
215   
216   !!======================================================================
217END MODULE trcrad
Note: See TracBrowser for help on using the repository browser.