New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcini.F90 in branches/2011/dev_NEMO_MERGE_2011/NEMOGCM/NEMO/TOP_SRC – NEMO

source: branches/2011/dev_NEMO_MERGE_2011/NEMOGCM/NEMO/TOP_SRC/trcini.F90 @ 3192

Last change on this file since 3192 was 3192, checked in by cetlod, 12 years ago

Perform the initialisation phase of PISCES at nit000 rather than nittrc000
  • Property svn:keywords set to Id
File size: 9.6 KB
Line 
1MODULE trcini
2   !!======================================================================
3   !!                         ***  MODULE trcini  ***
4   !! TOP :   Manage the passive tracer initialization
5   !!======================================================================
6   !! History :   -   ! 1991-03 (O. Marti)  original code
7   !!            1.0  ! 2005-03 (O. Aumont, A. El Moussaoui) F90
8   !!            2.0  ! 2005-10 (C. Ethe, G. Madec) revised architecture
9   !!            4.0  ! 2011-01 (A. R. Porter, STFC Daresbury) dynamical allocation
10   !!----------------------------------------------------------------------
11#if defined key_top
12   !!----------------------------------------------------------------------
13   !!   'key_top'                                                TOP models
14   !!----------------------------------------------------------------------
15   !!   trc_init  :   Initialization for passive tracer
16   !!   top_alloc :   allocate the TOP arrays
17   !!----------------------------------------------------------------------
18   USE oce_trc         ! shared variables between ocean and passive tracers
19   USE trc             ! passive tracers common variables
20   USE trcrst          ! passive tracers restart
21   USE trcnam          ! Namelist read
22   USE trcini_cfc      ! CFC      initialisation
23   USE trcini_lobster  ! LOBSTER  initialisation
24   USE trcini_pisces   ! PISCES   initialisation
25   USE trcini_c14b     ! C14 bomb initialisation
26   USE trcini_my_trc   ! MY_TRC   initialisation
27   USE trcdta          ! initialisation form files
28   USE daymod          ! calendar manager
29   USE zpshde          ! partial step: hor. derivative   (zps_hde routine)
30   USE prtctl_trc      ! Print control passive tracers (prt_ctl_trc_init routine)
31   USE trcsub       ! variables to substep passive tracers
32   
33   IMPLICIT NONE
34   PRIVATE
35   
36   PUBLIC   trc_init   ! called by opa
37
38    !! * Substitutions
39#  include "domzgr_substitute.h90"
40   !!----------------------------------------------------------------------
41   !! NEMO/TOP 4.0 , NEMO Consortium (2011)
42   !! $Id$
43   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
44   !!----------------------------------------------------------------------
45CONTAINS
46   
47   SUBROUTINE trc_init
48      !!---------------------------------------------------------------------
49      !!                     ***  ROUTINE trc_init  ***
50      !!
51      !! ** Purpose :   Initialization of the passive tracer fields
52      !!
53      !! ** Method  : - read namelist
54      !!              - control the consistancy
55      !!              - compute specific initialisations
56      !!              - set initial tracer fields (either read restart
57      !!                or read data or analytical formulation
58      !!---------------------------------------------------------------------
59      INTEGER ::   jk, jn, jl    ! dummy loop indices
60      CHARACTER (len=25) :: charout
61      REAL(wp), POINTER, DIMENSION(:,:,:,:) ::  ztrcdta   ! 4D  workspace
62      !!---------------------------------------------------------------------
63      !
64      IF( nn_timing == 1 )   CALL timing_start('trc_init')
65      !
66      IF(lwp) WRITE(numout,*)
67      IF(lwp) WRITE(numout,*) 'trc_init : initial set up of the passive tracers'
68      IF(lwp) WRITE(numout,*) '~~~~~~~'
69
70      CALL top_alloc()              ! allocate TOP arrays
71
72      IF( ln_dm2dc .AND. ( lk_pisces .OR. lk_lobster ) )    &
73         &  CALL ctl_stop( ' The diurnal cycle is not compatible with PISCES or LOBSTER  ' )
74
75      IF( nn_cla == 1 )   &
76         &  CALL ctl_stop( ' Cross Land Advection not yet implemented with passive tracer ; nn_cla must be 0' )
77
78      CALL trc_nam                  ! read passive tracers namelists
79      !                                                              ! masked grid volume
80      DO jk = 1, jpk
81         cvol(:,:,jk) = e1e2t(:,:) * fse3t(:,:,jk) * tmask(:,:,jk)
82      END DO
83      IF( lk_degrad ) cvol(:,:,:) = cvol(:,:,:) * facvol(:,:,:)      ! degrad option: reduction by facvol
84      !                                                              ! total volume of the ocean
85      areatot = glob_sum( cvol(:,:,:) )
86
87      IF( lk_lobster ) THEN   ;   CALL trc_ini_lobster      ! LOBSTER bio-model
88      ELSE                    ;   IF(lwp) WRITE(numout,*) '          LOBSTER not used'
89      ENDIF
90     
91      IF( lk_pisces  ) THEN   ;   CALL trc_ini_pisces       ! PISCES  bio-model
92      ELSE                    ;   IF(lwp) WRITE(numout,*) '          PISCES not used'
93      ENDIF
94     
95      IF( lk_cfc     ) THEN   ;   CALL trc_ini_cfc          ! CFC     tracers
96      ELSE                    ;   IF(lwp) WRITE(numout,*) '          CFC not used'
97      ENDIF
98
99      IF( lk_c14b    ) THEN   ;   CALL trc_ini_c14b         ! C14 bomb  tracer
100      ELSE                    ;   IF(lwp) WRITE(numout,*) '          C14 not used'
101      ENDIF
102     
103      IF( lk_my_trc  ) THEN   ;   CALL trc_ini_my_trc       ! MY_TRC  tracers
104      ELSE                    ;   IF(lwp) WRITE(numout,*) '          MY_TRC not used'
105      ENDIF
106
107      IF( lwp ) THEN
108         !
109         CALL ctl_opn( numstr, 'tracer.stat', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
110         !
111      ENDIF
112
113      IF( ln_trcdta )             CALL trc_dta_init
114
115      IF( ln_rsttr ) THEN
116        !
117        IF( lk_offline )  neuler = 1   ! Set time-step indicator at nit000 (leap-frog)
118        CALL trc_rst_read              ! restart from a file
119        !
120      ELSE
121        IF( lk_offline )  THEN
122           neuler = 0                  ! Set time-step indicator at nit000 (euler)
123           CALL day_init               ! set calendar
124        ENDIF
125        IF( ln_trcdta .AND. nb_trcdta > 0 ) THEN  ! Initialisation of tracer from a file that may also be used for damping
126            !
127            CALL wrk_alloc( jpi, jpj, jpk, nb_trcdta, ztrcdta )    ! Memory allocation
128            !
129            CALL trc_dta( nit000, ztrcdta )   ! read tracer data at nit000
130            !
131            DO jn = 1, jptra
132               IF( ln_trc_ini(jn) ) THEN      ! update passive tracers arrays with input data read from file
133                  jl = n_trc_index(jn) 
134                  trn(:,:,:,jn) = ztrcdta(:,:,:,jl) * tmask(:,:,:) 
135               ENDIF
136            ENDDO
137            CALL wrk_dealloc( jpi, jpj, jpk, nb_trcdta, ztrcdta )
138        ENDIF
139        !
140        trb(:,:,:,:) = trn(:,:,:,:)
141        !
142      ENDIF
143 
144      tra(:,:,:,:) = 0._wp
145     
146      IF( ln_zps .AND. .NOT. lk_c1d )   &              ! Partial steps: before horizontal gradient of passive
147        &    CALL zps_hde( nit000, jptra, trn, gtru, gtrv )       ! tracers at the bottom ocean level
148
149      !
150      IF( nn_dttrc /= 1 )        CALL trc_sub_ini      ! Initialize variables for substepping passive tracers
151      !
152
153      trai(:) = 0._wp                                                   ! initial content of all tracers
154      DO jn = 1, jptra
155         trai(jn) = trai(jn) + glob_sum( trn(:,:,:,jn) * cvol(:,:,:)   )
156      END DO
157
158      IF(lwp) THEN               ! control print
159         WRITE(numout,*)
160         WRITE(numout,*)
161         WRITE(numout,*) '          *** Total number of passive tracer jptra = ', jptra
162         WRITE(numout,*) '          *** Total volume of ocean                = ', areatot
163         WRITE(numout,*) '          *** Total inital content of all tracers '
164         WRITE(numout,*)
165         DO jn = 1, jptra
166            WRITE(numout,9000) jn, TRIM( ctrcnm(jn) ), trai(jn)
167         ENDDO
168         WRITE(numout,*)
169      ENDIF
170      WRITE(numout,*)
171      IF(ln_ctl) THEN            ! print mean trends (used for debugging)
172         CALL prt_ctl_trc_init
173         WRITE(charout, FMT="('ini ')")
174         CALL prt_ctl_trc_info( charout )
175         CALL prt_ctl_trc( tab4d=trn, mask=tmask, clinfo=ctrcnm )
176      ENDIF
1779000  FORMAT(' tracer nb : ',i2,'      name :',a10,'      initial content :',e18.10)
178      !
179      IF( nn_timing == 1 )   CALL timing_stop('trc_init')
180      !
181   END SUBROUTINE trc_init
182
183
184   SUBROUTINE top_alloc
185      !!----------------------------------------------------------------------
186      !!                     ***  ROUTINE top_alloc  ***
187      !!
188      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
189      !!----------------------------------------------------------------------
190      USE trcadv        , ONLY:   trc_adv_alloc          ! TOP-related alloc routines...
191      USE trc           , ONLY:   trc_alloc
192      USE trcnxt        , ONLY:   trc_nxt_alloc
193      USE trczdf        , ONLY:   trc_zdf_alloc
194      USE trdmod_trc_oce, ONLY:   trd_mod_trc_oce_alloc
195#if defined key_trdmld_trc 
196      USE trdmld_trc    , ONLY:   trd_mld_trc_alloc
197#endif
198      !
199      INTEGER :: ierr
200      !!----------------------------------------------------------------------
201      !
202      ierr =        trc_adv_alloc()          ! Start of TOP-related alloc routines...
203      ierr = ierr + trc_alloc    ()
204      ierr = ierr + trc_nxt_alloc()
205      ierr = ierr + trc_zdf_alloc()
206      ierr = ierr + trd_mod_trc_oce_alloc()
207#if defined key_trdmld_trc 
208      ierr = ierr + trd_mld_trc_alloc()
209#endif
210      !
211      IF( lk_mpp    )   CALL mpp_sum( ierr )
212      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'top_alloc : unable to allocate standard ocean arrays' )
213      !
214   END SUBROUTINE top_alloc
215
216#else
217   !!----------------------------------------------------------------------
218   !!  Empty module :                                     No passive tracer
219   !!----------------------------------------------------------------------
220CONTAINS
221   SUBROUTINE trc_init                      ! Dummy routine   
222   END SUBROUTINE trc_init
223#endif
224
225   !!======================================================================
226END MODULE trcini
Note: See TracBrowser for help on using the repository browser.