New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_iso_grif.F90 in branches/2011/dev_NOC_2011_MERGE/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2011/dev_NOC_2011_MERGE/NEMOGCM/NEMO/OPA_SRC/TRA/traldf_iso_grif.F90 @ 3008

Last change on this file since 3008 was 2980, checked in by acc, 13 years ago

Branch dev_NOC_2011_MERGE. #874. Step 2: Add changes from the 2011/dev_r2782_NOCS_Griffies branch
  • Property svn:keywords set to Id
File size: 21.2 KB
Line 
1MODULE traldf_iso_grif
2   !!======================================================================
3   !!                   ***  MODULE  traldf_iso_grif  ***
4   !! Ocean  tracers:  horizontal component of the lateral tracer mixing trend
5   !!======================================================================
6   !! History : 3.3  ! 2010-10  (G. Nurser, C. Harris, G. Madec)
7   !!                !          Griffies operator version adapted from traldf_iso.F90
8   !!----------------------------------------------------------------------
9#if   defined key_ldfslp   ||   defined key_esopa
10   !!----------------------------------------------------------------------
11   !!   'key_ldfslp'               slope of the lateral diffusive direction
12   !!----------------------------------------------------------------------
13   !!   tra_ldf_iso_grif  : update the tracer trend with the horizontal component
14   !!                       of the Griffies iso-neutral laplacian operator
15   !!----------------------------------------------------------------------
16   USE oce             ! ocean dynamics and active tracers
17   USE dom_oce         ! ocean space and time domain
18   USE phycst          ! physical constants
19   USE trc_oce         ! share passive tracers/Ocean variables
20   USE zdf_oce         ! ocean vertical physics
21   USE ldftra_oce      ! ocean active tracers: lateral physics
22   USE ldfslp          ! iso-neutral slopes
23   USE diaptr          ! poleward transport diagnostics
24   USE in_out_manager  ! I/O manager
25   USE iom             ! I/O library
26   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
27   USE lib_mpp         ! MPP library
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   tra_ldf_iso_grif   ! routine called by traldf.F90
33
34   REAL(wp), PUBLIC, DIMENSION(:,:,:), ALLOCATABLE, SAVE ::   psix_eiv, psiy_eiv   !: eiv stream function (diag only)
35   REAL(wp), PUBLIC, DIMENSION(:,:,:), ALLOCATABLE, SAVE ::   ah_wslp2             !: aeiv*w-slope^2
36   REAL(wp),         DIMENSION(:,:,:), ALLOCATABLE, SAVE ::   zdkt3d               !: vertical tracer gradient at 2 levels
37
38   !! * Substitutions
39#  include "domzgr_substitute.h90"
40#  include "ldftra_substitute.h90"
41#  include "vectopt_loop_substitute.h90"
42#  include "ldfeiv_substitute.h90"
43   !!----------------------------------------------------------------------
44   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
45   !! $Id$
46   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
47   !!----------------------------------------------------------------------
48CONTAINS
49
50  SUBROUTINE tra_ldf_iso_grif( kt, cdtype, pgu, pgv,              &
51       &                                   ptb, pta, kjpt, pahtb0 )
52      !!----------------------------------------------------------------------
53      !!                  ***  ROUTINE tra_ldf_iso_grif  ***
54      !!
55      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
56      !!      trend for a laplacian tensor (ezxcept the dz[ dz[.] ] term) and
57      !!      add it to the general trend of tracer equation.
58      !!
59      !! ** Method  :   The horizontal component of the lateral diffusive trends
60      !!      is provided by a 2nd order operator rotated along neural or geopo-
61      !!      tential surfaces to which an eddy induced advection can be added
62      !!      It is computed using before fields (forward in time) and isopyc-
63      !!      nal or geopotential slopes computed in routine ldfslp.
64      !!
65      !!      1st part :  masked horizontal derivative of T  ( di[ t ] )
66      !!      ========    with partial cell update if ln_zps=T.
67      !!
68      !!      2nd part :  horizontal fluxes of the lateral mixing operator
69      !!      ========
70      !!         zftu = (aht+ahtb0) e2u*e3u/e1u di[ tb ]
71      !!               - aht       e2u*uslp    dk[ mi(mk(tb)) ]
72      !!         zftv = (aht+ahtb0) e1v*e3v/e2v dj[ tb ]
73      !!               - aht       e2u*vslp    dk[ mj(mk(tb)) ]
74      !!      take the horizontal divergence of the fluxes:
75      !!         difft = 1/(e1t*e2t*e3t) {  di-1[ zftu ] +  dj-1[ zftv ]  }
76      !!      Add this trend to the general trend (ta,sa):
77      !!         ta = ta + difft
78      !!
79      !!      3rd part: vertical trends of the lateral mixing operator
80      !!      ========  (excluding the vertical flux proportional to dk[t] )
81      !!      vertical fluxes associated with the rotated lateral mixing:
82      !!         zftw =-aht {  e2t*wslpi di[ mi(mk(tb)) ]
83      !!                     + e1t*wslpj dj[ mj(mk(tb)) ]  }
84      !!      take the horizontal divergence of the fluxes:
85      !!         difft = 1/(e1t*e2t*e3t) dk[ zftw ]
86      !!      Add this trend to the general trend (ta,sa):
87      !!         pta = pta + difft
88      !!
89      !! ** Action :   Update pta arrays with the before rotated diffusion
90      !!----------------------------------------------------------------------
91      USE wrk_nemo, ONLY:   wrk_in_use, wrk_not_released
92      USE oce     , ONLY:   zftu => ua       , zftv => va            ! (ua,va) used as 3D workspace
93      USE wrk_nemo, ONLY:   zdit => wrk_3d_6 , zdjt => wrk_3d_7 , ztfw => wrk_3d_8   ! 3D workspace
94      USE wrk_nemo, ONLY:   z2d  => wrk_2d_1                                         ! 2D workspace
95      !
96      INTEGER                              , INTENT(in   ) ::   kt         ! ocean time-step index
97      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
98      INTEGER                              , INTENT(in   ) ::   kjpt       ! number of tracers
99      REAL(wp), DIMENSION(jpi,jpj    ,kjpt), INTENT(in   ) ::   pgu, pgv   ! tracer gradient at pstep levels
100      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb        ! before and now tracer fields
101      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta        ! tracer trend
102      REAL(wp)                             , INTENT(in   ) ::   pahtb0     ! background diffusion coef
103      !
104      INTEGER  ::  ji, jj, jk,jn   ! dummy loop indices
105      INTEGER  ::  ip,jp,kp        ! dummy loop indices
106      INTEGER  ::  ierr            ! temporary integer
107      REAL(wp) ::  zmsku, zabe1, zcof1, zcoef3   ! local scalars
108      REAL(wp) ::  zmskv, zabe2, zcof2, zcoef4   !   -      -
109      REAL(wp) ::  zcoef0, zbtr                  !   -      -
110      !
111      REAL(wp) ::   zslope_skew, zslope_iso, zslope2, zbu, zbv
112      REAL(wp) ::   ze1ur, zdxt, ze2vr, ze3wr, zdyt, zdzt
113      REAL(wp) ::   zah, zah_slp, zaei_slp
114#if defined key_diaar5
115      REAL(wp) ::   zztmp              ! local scalar
116#endif
117      !!----------------------------------------------------------------------
118
119      IF( wrk_in_use(3, 6,7,8) .OR. wrk_in_use(2, 1) ) THEN
120         CALL ctl_stop('tra_ldf_iso_grif: requested workspace arrays unavailable.')   ;   RETURN
121      ENDIF
122
123      IF( kt == nit000.AND..NOT.ALLOCATED(ah_wslp2) )  THEN
124         IF(lwp) WRITE(numout,*)
125         IF(lwp) WRITE(numout,*) 'tra_ldf_iso_grif : rotated laplacian diffusion operator on ', cdtype
126         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
127         ALLOCATE( ah_wslp2(jpi,jpj,jpk) , zdkt3d(jpi,jpj,0:1), STAT=ierr )
128         IF( lk_mpp   )   CALL mpp_sum ( ierr )
129         IF( ierr > 0 )   CALL ctl_stop('STOP', 'tra_ldf_iso_grif: unable to allocate arrays')
130         IF( ln_traldf_gdia ) THEN
131            ALLOCATE( psix_eiv(jpi,jpj,jpk) , psiy_eiv(jpi,jpj,jpk) , STAT=ierr )
132            IF( lk_mpp   )   CALL mpp_sum ( ierr )
133            IF( ierr > 0 )   CALL ctl_stop('STOP', 'tra_ldf_iso_grif: unable to allocate diagnostics')
134         ENDIF
135      ENDIF
136
137      !!----------------------------------------------------------------------
138      !!   0 - calculate  ah_wslp2, psix_eiv, psiy_eiv
139      !!----------------------------------------------------------------------
140
141      !!gm Future development: consider using Ah defined at T-points and attached to the 4 t-point triads
142
143      ah_wslp2(:,:,:) = 0._wp
144      IF( ln_traldf_gdia ) THEN
145         psix_eiv(:,:,:) = 0._wp
146         psiy_eiv(:,:,:) = 0._wp
147      ENDIF
148
149      DO ip = 0, 1
150         DO kp = 0, 1
151            DO jk = 1, jpkm1
152               DO jj = 1, jpjm1
153                  DO ji = 1, fs_jpim1
154                     ze1ur = 1._wp / e1u(ji,jj)
155                     ze3wr = 1._wp / fse3w(ji+ip,jj,jk+kp)
156                     zbu   = 0.25_wp * e1u(ji,jj) * e2u(ji,jj) * fse3u(ji,jj,jk)
157                     zah   = fsahtu(ji,jj,jk)                                  ! fsaht(ji+ip,jj,jk)
158                     zslope_skew = triadi_g(ji+ip,jj,jk,1-ip,kp)
159                     ! Subtract s-coordinate slope at t-points to give slope rel to s surfaces
160                     ! (do this by *adding* gradient of depth)
161                     zslope2 = zslope_skew + ( fsdept(ji+1,jj,jk) - fsdept(ji ,jj ,jk) ) * ze1ur * umask(ji,jj,jk+kp)
162                     zslope2 = zslope2 *zslope2
163                     ah_wslp2(ji+ip,jj,jk+kp) = ah_wslp2(ji+ip,jj,jk+kp)    &
164                        &                     + zah * ( zbu * ze3wr / ( e1t(ji+ip,jj) * e2t(ji+ip,jj) ) ) * zslope2
165                     IF( ln_traldf_gdia ) THEN
166                        zaei_slp = fsaeiw(ji+ip,jj,jk) * zslope_skew           ! fsaeit(ji+ip,jj,jk)*zslope_skew
167                        psix_eiv(ji,jj,jk+kp) = psix_eiv(ji,jj,jk+kp) + 0.25_wp * zaei_slp
168                     ENDIF
169                  END DO
170               END DO
171            END DO
172         END DO
173      END DO
174      !
175      DO jp = 0, 1
176         DO kp = 0, 1
177            DO jk = 1, jpkm1
178               DO jj = 1, jpjm1
179                  DO ji=1,fs_jpim1
180                     ze2vr = 1._wp / e2v(ji,jj)
181                     ze3wr = 1.0_wp / fse3w(ji,jj+jp,jk+kp)
182                     zbv   = 0.25_wp * e1v(ji,jj) * e2v(ji,jj) * fse3v(ji,jj,jk)
183                     zah   = fsahtv(ji,jj,jk)                                  ! fsaht(ji,jj+jp,jk)
184                     zslope_skew = triadj_g(ji,jj+jp,jk,1-jp,kp)
185                     ! Subtract s-coordinate slope at t-points to give slope rel to s surfaces
186                     !    (do this by *adding* gradient of depth)
187                     zslope2 = zslope_skew + ( fsdept(ji,jj+1,jk) - fsdept(ji,jj,jk) ) * ze2vr * vmask(ji,jj,jk+kp)
188                     zslope2 = zslope2 * zslope2
189                     ah_wslp2(ji,jj+jp,jk+kp) = ah_wslp2(ji,jj+jp,jk+kp)   &
190                        &                     + zah * ( zbv * ze3wr / ( e1t(ji,jj+jp) * e2t(ji,jj+jp) ) ) * zslope2
191                     IF( ln_traldf_gdia ) THEN
192                        zaei_slp = fsaeiw(ji,jj+jp,jk) * zslope_skew           ! fsaeit(ji,jj+jp,jk)*zslope_skew
193                        psiy_eiv(ji,jj,jk+kp) = psiy_eiv(ji,jj,jk+kp) + 0.25_wp * zaei_slp
194                     ENDIF
195                  END DO
196               END DO
197            END DO
198         END DO
199      END DO
200      !
201      !                                                          ! ===========
202      DO jn = 1, kjpt                                            ! tracer loop
203         !                                                       ! ===========
204         ! Zero fluxes for each tracer
205         ztfw(:,:,:) = 0._wp
206         zftu(:,:,:) = 0._wp
207         zftv(:,:,:) = 0._wp
208         !
209         DO jk = 1, jpkm1                          !==  before lateral T & S gradients at T-level jk  ==!
210            DO jj = 1, jpjm1
211               DO ji = 1, fs_jpim1   ! vector opt.
212                  zdit(ji,jj,jk) = ( ptb(ji+1,jj  ,jk,jn) - ptb(ji,jj,jk,jn) ) * umask(ji,jj,jk)
213                  zdjt(ji,jj,jk) = ( ptb(ji  ,jj+1,jk,jn) - ptb(ji,jj,jk,jn) ) * vmask(ji,jj,jk)
214               END DO
215            END DO
216         END DO
217         IF( ln_zps.and.l_grad_zps ) THEN              ! partial steps: correction at the last level
218# if defined key_vectopt_loop
219            DO jj = 1, 1
220               DO ji = 1, jpij-jpi   ! vector opt. (forced unrolling)
221# else
222            DO jj = 1, jpjm1
223               DO ji = 1, jpim1
224# endif
225                  zdit(ji,jj,mbku(ji,jj)) = pgu(ji,jj,jn)
226                  zdjt(ji,jj,mbkv(ji,jj)) = pgv(ji,jj,jn)
227               END DO
228            END DO
229         ENDIF
230
231         !!----------------------------------------------------------------------
232         !!   II - horizontal trend  (full)
233         !!----------------------------------------------------------------------
234         !
235         DO jk = 1, jpkm1
236            !
237            !                    !==  Vertical tracer gradient at level jk and jk+1
238            zdkt3d(:,:,1) = ( ptb(:,:,jk,jn) - ptb(:,:,jk+1,jn) ) * tmask(:,:,jk+1)
239            !
240            !                    ! surface boundary condition: zdkt3d(jk=0)=zdkt3d(jk=1)
241            IF( jk == 1 ) THEN   ;   zdkt3d(:,:,0) = zdkt3d(:,:,1)
242            ELSE                 ;   zdkt3d(:,:,0) = ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) ) * tmask(:,:,jk)
243            ENDIF
244
245
246            IF (ln_botmix_grif) THEN
247               DO ip = 0, 1              !==  Horizontal & vertical fluxes
248                  DO kp = 0, 1
249                     DO jj = 1, jpjm1
250                        DO ji = 1, fs_jpim1
251                           ze1ur = 1._wp / e1u(ji,jj)
252                           zdxt  = zdit(ji,jj,jk) * ze1ur
253                           ze3wr = 1._wp / fse3w(ji+ip,jj,jk+kp)
254                           zdzt  = zdkt3d(ji+ip,jj,kp) * ze3wr
255                           zslope_skew = triadi_g(ji+ip,jj,jk,1-ip,kp)
256                           zslope_iso  = triadi(ji+ip,jj,jk,1-ip,kp)
257
258                           zbu = 0.25_wp * e1u(ji,jj) * e2u(ji,jj) * fse3u(ji,jj,jk)
259                           ! ln_botmix_grif is .T. don't mask zah for bottom half cells
260                           zah = fsahtu(ji,jj,jk)   !*umask(ji,jj,jk+kp)         !fsaht(ji+ip,jj,jk)           ===>>  ????
261                           zah_slp  = zah * zslope_iso
262                           zaei_slp = fsaeiw(ji+ip,jj,jk) * zslope_skew    !fsaeit(ji+ip,jj,jk)*zslope_skew
263                           zftu(ji,jj,jk) = zftu(ji,jj,jk) - ( zah * zdxt + (zah_slp - zaei_slp) * zdzt ) * zbu * ze1ur
264                           ztfw(ji+ip,jj,jk+kp) = ztfw(ji+ip,jj,jk+kp) - (zah_slp + zaei_slp) * zdxt * zbu * ze3wr
265                        END DO
266                     END DO
267                  END DO
268               END DO
269
270               DO jp = 0, 1
271                  DO kp = 0, 1
272                     DO jj = 1, jpjm1
273                        DO ji = 1, fs_jpim1
274                           ze2vr = 1._wp / e2v(ji,jj)
275                           zdyt  = zdjt(ji,jj,jk) * ze2vr
276                           ze3wr = 1._wp / fse3w(ji,jj+jp,jk+kp)
277                           zdzt  = zdkt3d(ji,jj+jp,kp) * ze3wr
278                           zslope_skew = triadj_g(ji,jj+jp,jk,1-jp,kp)
279                           zslope_iso  = triadj(ji,jj+jp,jk,1-jp,kp)
280                           zbv = 0.25_wp * e1v(ji,jj) * e2v(ji,jj) * fse3v(ji,jj,jk)
281                           ! ln_botmix_grif is .T. don't mask zah for bottom half cells
282                           zah = fsahtv(ji,jj,jk)        !*vmask(ji,jj,jk+kp)  ! fsaht(ji,jj+jp,jk)
283                           zah_slp = zah * zslope_iso
284                           zaei_slp = fsaeiw(ji,jj+jp,jk) * zslope_skew        ! fsaeit(ji,jj+jp,jk)*zslope_skew
285                           zftv(ji,jj,jk) = zftv(ji,jj,jk) - ( zah * zdyt + (zah_slp - zaei_slp) * zdzt ) * zbv * ze2vr
286                           ztfw(ji,jj+jp,jk+kp) = ztfw(ji,jj+jp,jk+kp) - (zah_slp + zaei_slp) * zdyt * zbv * ze3wr
287                        END DO
288                     END DO
289                  END DO
290               END DO
291            ELSE
292               DO ip = 0, 1              !==  Horizontal & vertical fluxes
293                  DO kp = 0, 1
294                     DO jj = 1, jpjm1
295                        DO ji = 1, fs_jpim1
296                           ze1ur = 1._wp / e1u(ji,jj)
297                           zdxt  = zdit(ji,jj,jk) * ze1ur
298                           ze3wr = 1._wp / fse3w(ji+ip,jj,jk+kp)
299                           zdzt  = zdkt3d(ji+ip,jj,kp) * ze3wr
300                           zslope_skew = triadi_g(ji+ip,jj,jk,1-ip,kp)
301                           zslope_iso  = triadi(ji+ip,jj,jk,1-ip,kp)
302
303                           zbu = 0.25_wp * e1u(ji,jj) * e2u(ji,jj) * fse3u(ji,jj,jk)
304                           ! ln_botmix_grif is .F. mask zah for bottom half cells
305                           zah = fsahtu(ji,jj,jk) * umask(ji,jj,jk+kp)         ! fsaht(ji+ip,jj,jk)   ===>>  ????
306                           zah_slp  = zah * zslope_iso
307                           zaei_slp = fsaeiw(ji+ip,jj,jk) * zslope_skew        ! fsaeit(ji+ip,jj,jk)*zslope_skew
308                           zftu(ji,jj,jk) = zftu(ji,jj,jk) - ( zah * zdxt + (zah_slp - zaei_slp) * zdzt ) * zbu * ze1ur
309                           ztfw(ji+ip,jj,jk+kp) = ztfw(ji+ip,jj,jk+kp) - (zah_slp + zaei_slp) * zdxt * zbu * ze3wr
310                        END DO
311                     END DO
312                  END DO
313               END DO
314
315               DO jp = 0, 1
316                  DO kp = 0, 1
317                     DO jj = 1, jpjm1
318                        DO ji = 1, fs_jpim1
319                           ze2vr = 1._wp / e2v(ji,jj)
320                           zdyt  = zdjt(ji,jj,jk) * ze2vr
321                           ze3wr = 1._wp / fse3w(ji,jj+jp,jk+kp)
322                           zdzt  = zdkt3d(ji,jj+jp,kp) * ze3wr
323                           zslope_skew = triadj_g(ji,jj+jp,jk,1-jp,kp)
324                           zslope_iso  = triadj(ji,jj+jp,jk,1-jp,kp)
325                           zbv = 0.25_wp * e1v(ji,jj) * e2v(ji,jj) * fse3v(ji,jj,jk)
326                           ! ln_botmix_grif is .F. mask zah for bottom half cells
327                           zah = fsahtv(ji,jj,jk) * vmask(ji,jj,jk+kp)         ! fsaht(ji,jj+jp,jk)
328                           zah_slp = zah * zslope_iso
329                           zaei_slp = fsaeiw(ji,jj+jp,jk) * zslope_skew        ! fsaeit(ji,jj+jp,jk)*zslope_skew
330                           zftv(ji,jj,jk) = zftv(ji,jj,jk) - ( zah * zdyt + (zah_slp - zaei_slp) * zdzt ) * zbv * ze2vr
331                           ztfw(ji,jj+jp,jk+kp) = ztfw(ji,jj+jp,jk+kp) - (zah_slp + zaei_slp) * zdyt * zbv * ze3wr
332                        END DO
333                     END DO
334                  END DO
335               END DO
336            END IF
337            !                          !==  divergence and add to the general trend  ==!
338            DO jj = 2 , jpjm1
339               DO ji = fs_2, fs_jpim1  ! vector opt.
340                  zbtr = 1._wp / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
341                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + zbtr * (   zftu(ji-1,jj,jk) - zftu(ji,jj,jk)   &
342                     &                                           + zftv(ji,jj-1,jk) - zftv(ji,jj,jk)   )
343               END DO
344            END DO
345            !
346         END DO
347         !
348         DO jk = 1, jpkm1              !== Divergence of vertical fluxes added to the general tracer trend
349            DO jj = 2, jpjm1
350               DO ji = fs_2, fs_jpim1  ! vector opt.
351                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + (  ztfw(ji,jj,jk+1) - ztfw(ji,jj,jk)  )   &
352                     &                                / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
353               END DO
354            END DO
355         END DO
356         !
357         !                             ! "Poleward" diffusive heat or salt transports (T-S case only)
358         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN
359            IF( jn == jp_tem)   htr_ldf(:) = ptr_vj( zftv(:,:,:) )        ! 3.3  names
360            IF( jn == jp_sal)   str_ldf(:) = ptr_vj( zftv(:,:,:) )
361         ENDIF
362
363#if defined key_diaar5
364         IF( cdtype == 'TRA' .AND. jn == jp_tem  ) THEN
365            z2d(:,:) = 0._wp
366            zztmp = rau0 * rcp
367            DO jk = 1, jpkm1
368               DO jj = 2, jpjm1
369                  DO ji = fs_2, fs_jpim1   ! vector opt.
370                     z2d(ji,jj) = z2d(ji,jj) + zftu(ji,jj,jk)
371                  END DO
372               END DO
373            END DO
374            z2d(:,:) = zztmp * z2d(:,:)
375            CALL lbc_lnk( z2d, 'U', -1. )
376            CALL iom_put( "udiff_heattr", z2d )                  ! heat transport in i-direction
377            z2d(:,:) = 0._wp
378            DO jk = 1, jpkm1
379               DO jj = 2, jpjm1
380                  DO ji = fs_2, fs_jpim1   ! vector opt.
381                     z2d(ji,jj) = z2d(ji,jj) + zftv(ji,jj,jk)
382                  END DO
383               END DO
384            END DO
385            z2d(:,:) = zztmp * z2d(:,:)
386            CALL lbc_lnk( z2d, 'V', -1. )
387            CALL iom_put( "vdiff_heattr", z2d )                  !  heat transport in j-direction
388         END IF
389#endif
390         !
391      END DO
392      !
393      IF( wrk_not_released(3, 6,7,8) .OR.   &
394          wrk_not_released(2, 1)       )   CALL ctl_stop('tra_ldf_iso_grif: failed to release workspace arrays')
395      !
396  END SUBROUTINE tra_ldf_iso_grif
397
398#else
399   !!----------------------------------------------------------------------
400   !!   default option :   Dummy code   NO rotation of the diffusive tensor
401   !!----------------------------------------------------------------------
402CONTAINS
403   SUBROUTINE tra_ldf_iso_grif( kt, cdtype, pgu, pgv, ptb, pta, kjpt, pahtb0 )      ! Empty routine
404      CHARACTER(len=3) ::   cdtype
405      REAL, DIMENSION(:,:,:) ::   pgu, pgv   ! tracer gradient at pstep levels
406      REAL, DIMENSION(:,:,:,:) ::   ptb, pta
407      WRITE(*,*) 'tra_ldf_iso_grif: You should not have seen this print! error?', kt, cdtype,    &
408         &                  pgu(1,1,1), pgv(1,1,1), ptb(1,1,1,1), pta(1,1,1,1), kjpt, pahtb0
409   END SUBROUTINE tra_ldf_iso_grif
410#endif
411
412   !!==============================================================================
413END MODULE traldf_iso_grif
Note: See TracBrowser for help on using the repository browser.