New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_lap.F90 in branches/2011/dev_r2739_LOCEAN8_ZTC/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2011/dev_r2739_LOCEAN8_ZTC/NEMOGCM/NEMO/OPA_SRC/TRA/traldf_lap.F90 @ 2970

Last change on this file since 2970 was 2905, checked in by mlelod, 13 years ago

first commit, compilation ok, see ticket/863?
  • Property svn:keywords set to Id
File size: 7.4 KB
Line 
1MODULE traldf_lap
2   !!==============================================================================
3   !!                       ***  MODULE  traldf_lap  ***
4   !! Ocean  tracers:  horizontal component of the lateral tracer mixing trend
5   !!==============================================================================
6   !! History :  OPA  !  87-06  (P. Andrich, D. L Hostis)  Original code
7   !!                 !  91-11  (G. Madec)
8   !!                 !  95-11  (G. Madec)  suppress volumetric scale factors
9   !!                 !  96-01  (G. Madec)  statement function for e3
10   !!            NEMO !  02-06  (G. Madec)  F90: Free form and module
11   !!            1.0  !  04-08  (C. Talandier) New trends organization
12   !!                 !  05-11  (G. Madec)  add zps case
13   !!            3.0  !  10-06  (C. Ethe, G. Madec) Merge TRA-TRC
14   !!----------------------------------------------------------------------
15
16   !!----------------------------------------------------------------------
17   !!   tra_ldf_lap  : update the tracer trend with the horizontal diffusion
18   !!                 using a iso-level harmonic (laplacien) operator.
19   !!----------------------------------------------------------------------
20   USE oce             ! ocean dynamics and active tracers
21   USE dom_oce         ! ocean space and time domain
22   USE ldftra_oce      ! ocean active tracers: lateral physics
23   USE in_out_manager  ! I/O manager
24   USE diaptr          ! poleward transport diagnostics
25   USE trc_oce         ! share passive tracers/Ocean variables
26   USE lib_mpp         ! MPP library
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC   tra_ldf_lap   ! routine called by step.F90
32
33   !! * Substitutions
34#  include "domzgr_substitute.h90"
35#  include "ldftra_substitute.h90"
36#  include "vectopt_loop_substitute.h90"
37   !!----------------------------------------------------------------------
38   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
39   !! $Id$
40   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
41   !!----------------------------------------------------------------------
42CONTAINS
43
44   SUBROUTINE tra_ldf_lap( kt, cdtype, pgu, pgv,      &
45      &                                ptb, pta, kjpt ) 
46      !!----------------------------------------------------------------------
47      !!                  ***  ROUTINE tra_ldf_lap  ***
48      !!                   
49      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
50      !!      trend and add it to the general trend of tracer equation.
51      !!
52      !! ** Method  :   Second order diffusive operator evaluated using before
53      !!      fields (forward time scheme). The horizontal diffusive trends of
54      !!      the tracer is given by:
55      !!          difft = 1/(e1t*e2t*e3t) {  di-1[ aht e2u*e3u/e1u di(tb) ]
56      !!                                   + dj-1[ aht e1v*e3v/e2v dj(tb) ] }
57      !!      Add this trend to the general tracer trend pta :
58      !!          pta = pta + difft
59      !!
60      !! ** Action  : - Update pta arrays with the before iso-level
61      !!                harmonic mixing trend.
62      !!----------------------------------------------------------------------
63      USE oce, ONLY:   ztu => ua , ztv => va  ! (ua,va) used as workspace
64      !
65      INTEGER                              , INTENT(in   ) ::   kt         ! ocean time-step index
66      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
67      INTEGER                              , INTENT(in   ) ::   kjpt       ! number of tracers
68      REAL(wp), DIMENSION(jpi,jpj    ,kjpt), INTENT(in   ) ::   pgu, pgv   ! tracer gradient at pstep levels
69      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb        ! before and now tracer fields
70      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta        ! tracer trend
71      !
72      INTEGER  ::   ji, jj, jk, jn       ! dummy loop indices
73      INTEGER  ::   iku, ikv, ierr       ! local integers
74      REAL(wp) ::   zabe1, zabe2, zbtr   ! local scalars
75      !!----------------------------------------------------------------------
76     
77      IF( kt == nit000 )  THEN
78         IF(lwp) WRITE(numout,*)
79         IF(lwp) WRITE(numout,*) 'tra_ldf_lap : iso-level laplacian diffusion on ', cdtype
80         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ '
81      ENDIF
82
83      !                                                          ! =========== !
84      DO jn = 1, kjpt                                            ! tracer loop !
85         !                                                       ! =========== !   
86         DO jk = 1, jpkm1                                            ! slab loop
87            !                                           
88            ! 1. First derivative (gradient)
89            ! -------------------
90            DO jj = 1, jpjm1
91               DO ji = 1, fs_jpim1   ! vector opt.
92                  zabe1 = fsahtu(ji,jj,jk) * umask(ji,jj,jk) * e1ur(ji,jj) * fse3u_n(ji,jj,jk)
93                  zabe2 = fsahtv(ji,jj,jk) * vmask(ji,jj,jk) * e2vr(ji,jj) * fse3v_n(ji,jj,jk)
94                  ztu(ji,jj,jk) = zabe1 * ( ptb(ji+1,jj  ,jk,jn) - ptb(ji,jj,jk,jn) )
95                  ztv(ji,jj,jk) = zabe2 * ( ptb(ji  ,jj+1,jk,jn) - ptb(ji,jj,jk,jn) )
96               END DO
97            END DO
98            IF( ln_zps ) THEN      ! set gradient at partial step level
99               DO jj = 1, jpjm1
100                  DO ji = 1, fs_jpim1   ! vector opt.
101                     ! last level
102                     iku = mbku(ji,jj)
103                     ikv = mbkv(ji,jj)
104                     IF( iku == jk ) THEN
105                        zabe1 = fsahtu(ji,jj,iku) * umask(ji,jj,iku) * e1ur(ji,jj) * fse3u_n(ji,jj,iku)
106                        ztu(ji,jj,jk) = zabe1 * pgu(ji,jj,jn)
107                     ENDIF
108                     IF( ikv == jk ) THEN
109                        zabe2 = fsahtv(ji,jj,ikv) * vmask(ji,jj,ikv) * e2vr(ji,jj) * fse3v_n(ji,jj,ikv)
110                        ztv(ji,jj,jk) = zabe2 * pgv(ji,jj,jn)
111                     ENDIF
112                  END DO
113               END DO
114            ENDIF
115         
116         
117            ! 2. Second derivative (divergence) added to the general tracer trends
118            ! ---------------------------------------------------------------------
119            DO jj = 2, jpjm1
120               DO ji = fs_2, fs_jpim1   ! vector opt.
121                  zbtr = 1._wp / ( e1t(ji,jj) *e2t(ji,jj) * fse3t_n(ji,jj,jk) )
122                  ! horizontal diffusive trends added to the general tracer trends
123                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + zbtr * (  ztu(ji,jj,jk) - ztu(ji-1,jj,jk)   &
124                     &                                          + ztv(ji,jj,jk) - ztv(ji,jj-1,jk)  )
125               END DO
126            END DO
127            !
128         END DO                                             !  End of slab 
129         !
130         ! "Poleward" diffusive heat or salt transports
131         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN
132            IF( jn  == jp_tem)   htr_ldf(:) = ptr_vj( ztv(:,:,:) )
133            IF( jn  == jp_sal)   str_ldf(:) = ptr_vj( ztv(:,:,:) )
134         ENDIF
135         !                                                  ! ==================
136      END DO                                                ! end of tracer loop
137      !                                                     ! ==================
138   END SUBROUTINE tra_ldf_lap
139
140   !!==============================================================================
141END MODULE traldf_lap
Note: See TracBrowser for help on using the repository browser.