source: branches/2011/dev_r2739_LOCEAN8_ZTC/NEMOGCM/NEMO/TOP_SRC/trcwri.F90 @ 4361

MODULE trcwri
   !!===================================================================================
   !!                       *** MODULE trcwri ***
   !!    TOP :   Output of passive tracers
   !!====================================================================================
   !! History :   1.0  !  2009-05 (C. Ethe)  Original code
   !!----------------------------------------------------------------------
#if defined key_top &&  defined key_iomput
   !!----------------------------------------------------------------------
   !!   'key_top' && 'key_iomput'                              TOP models
   !!----------------------------------------------------------------------
   !! trc_wri_trc   :  outputs of concentration fields
   !!----------------------------------------------------------------------
   USE dom_oce         ! ocean space and time domain variables
   USE oce_trc
   USE trc
   USE iom
   USE dianam

   IMPLICIT NONE
   PRIVATE

   PUBLIC trc_wri      

   !! * Substitutions
#  include "top_substitute.h90"

CONTAINS

   SUBROUTINE trc_wri( kt )
      !!---------------------------------------------------------------------
      !!                     ***  ROUTINE trc_wri  ***
      !! 
      !! ** Purpose :   output passive tracers fields and dynamical trends
      !!---------------------------------------------------------------------
      INTEGER, INTENT( in ) :: kt
      !!---------------------------------------------------------------------

      !
      CALL iom_setkt  ( kt + nn_dttrc - 1 )       ! set the passive tracer time step
      CALL trc_wri_trc( kt              )       ! outputs for tracer concentration
      CALL iom_setkt  ( kt              )       ! set the model time step
      !
   END SUBROUTINE trc_wri

   SUBROUTINE trc_wri_trc( kt )  
      !!---------------------------------------------------------------------
      !!                     ***  ROUTINE trc_wri_trc  ***
      !!
      !! ** Purpose :   output passive tracers fields 
      !!---------------------------------------------------------------------
      INTEGER, INTENT( in ) :: kt       ! ocean time-step
      INTEGER               :: jn
      CHARACTER (len=20)    :: cltra
      CHARACTER (len=40) :: clhstnam
      INTEGER ::   inum = 11            ! temporary logical unit
      !!---------------------------------------------------------------------
 
      IF( lk_offline .AND. kt == nit000 .AND. lwp ) THEN    ! WRITE root name in date.file for use by postpro
         CALL dia_nam( clhstnam, nn_writetrc,' ' )
         CALL ctl_opn( inum, 'date.file', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea )
         WRITE(inum,*) clhstnam
         CLOSE(inum)
      ENDIF
      ! write the tracer concentrations in the file
      ! ---------------------------------------
      DO jn = 1, jptra
         cltra = TRIM( ctrcnm(jn) )                  ! short title for tracer
         IF( lk_vvl ) THEN
            CALL iom_put( cltra, trn(:,:,:,jn) * fse3t_n(:,:,:) )
         ELSE
            CALL iom_put( cltra, trn(:,:,:,jn) )
         END IF
      END DO
      !
   END SUBROUTINE trc_wri_trc

#else
   !!----------------------------------------------------------------------
   !!  Dummy module :                                     No passive tracer
   !!----------------------------------------------------------------------
   PUBLIC trc_wri
CONTAINS
   SUBROUTINE trc_wri( kt )                     ! Empty routine   
   INTEGER, INTENT(in) :: kt
   END SUBROUTINE trc_wri
#endif

   !!----------------------------------------------------------------------
   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
   !! $Id$ 
   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
   !!======================================================================
END MODULE trcwri