New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zflx.F90 in branches/2011/dev_r2787_LOCEAN3_TRA_TRP/NEMOGCM/NEMO/TOP_SRC/PISCES – NEMO

source: branches/2011/dev_r2787_LOCEAN3_TRA_TRP/NEMOGCM/NEMO/TOP_SRC/PISCES/p4zflx.F90 @ 2819

Last change on this file since 2819 was 2819, checked in by cetlod, 13 years ago

Improvment of branch dev_r2787_LOCEAN3_TRA_TRP
  • Property svn:keywords set to Id
File size: 11.6 KB
Line 
1MODULE p4zflx
2   !!======================================================================
3   !!                         ***  MODULE p4zflx  ***
4   !! TOP :   PISCES CALCULATES GAS EXCHANGE AND CHEMISTRY AT SEA SURFACE
5   !!======================================================================
6   !! History :    -   !  1988-07  (E. MAIER-REIMER) Original code
7   !!              -   !  1998     (O. Aumont) additions
8   !!              -   !  1999     (C. Le Quere) modifications
9   !!             1.0  !  2004     (O. Aumont) modifications
10   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
11   !!----------------------------------------------------------------------
12#if defined key_pisces
13   !!----------------------------------------------------------------------
14   !!   'key_pisces'                                       PISCES bio-model
15   !!----------------------------------------------------------------------
16   !!   p4z_flx       :   CALCULATES GAS EXCHANGE AND CHEMISTRY AT SEA SURFACE
17   !!   p4z_flx_init  :   Read the namelist
18   !!----------------------------------------------------------------------
19   USE oce_trc                      !  shared variables between ocean and passive tracers
20   USE trc                          !  passive tracers common variables
21   USE sms_pisces                   !  PISCES Source Minus Sink variables
22   USE p4zche                       !  Chemical model
23   USE prtctl_trc                   !  print control for debugging
24   USE iom                          !  I/O manager
25#if defined key_cpl_carbon_cycle
26   USE sbc_oce, ONLY :  atm_co2     !  atmospheric pCO2               
27#endif
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   p4z_flx 
33   PUBLIC   p4z_flx_init 
34   PUBLIC   p4z_flx_alloc 
35
36   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: oce_co2   !: ocean carbon flux
37   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: satmco2   !: atmospheric pco2
38
39   REAL(wp) ::  t_oce_co2_flx               !: Total ocean carbon flux
40   REAL(wp) ::  t_atm_co2_flx               !: global mean of atmospheric pco2
41   REAL(wp) ::  area                        !: ocean surface
42   REAL(wp) ::  atcco2 = 278._wp            !: pre-industrial atmospheric [co2] (ppm) 
43   REAL(wp) ::  atcox  = 0.20946_wp         !:
44   REAL(wp) ::  xconv  = 0.01_wp / 3600._wp !: coefficients for conversion
45
46   !!* Substitution
47#  include "top_substitute.h90"
48   !!----------------------------------------------------------------------
49   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
50   !! $Id$
51   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
52   !!----------------------------------------------------------------------
53CONTAINS
54
55   SUBROUTINE p4z_flx ( kt )
56      !!---------------------------------------------------------------------
57      !!                     ***  ROUTINE p4z_flx  ***
58      !!
59      !! ** Purpose :   CALCULATES GAS EXCHANGE AND CHEMISTRY AT SEA SURFACE
60      !!
61      !! ** Method  : - ???
62      !!---------------------------------------------------------------------
63      USE wrk_nemo, ONLY:   wrk_in_use, wrk_not_released
64      USE wrk_nemo, ONLY:   zkgco2 => wrk_2d_1 , zkgo2 => wrk_2d_2 , zh2co3 => wrk_2d_3 
65      USE wrk_nemo, ONLY:   zoflx  => wrk_2d_4 , zkg   => wrk_2d_5
66      USE wrk_nemo, ONLY:   zdpco2 => wrk_2d_6 , zdpo2 => wrk_2d_7
67      !
68      INTEGER, INTENT(in) ::   kt   !
69      !
70      INTEGER  ::   ji, jj, jrorr
71      REAL(wp) ::   ztc, ztc2, ztc3, zws, zkgwan
72      REAL(wp) ::   zfld, zflu, zfld16, zflu16, zfact
73      REAL(wp) ::   zph, zah2, zbot, zdic, zalk, zsch_o2, zalka, zsch_co2
74      CHARACTER (len=25) :: charout
75      !!---------------------------------------------------------------------
76
77      IF( wrk_in_use(2, 1,2,3,4,5,6,7) ) THEN
78         CALL ctl_stop('p4z_flx: requested workspace arrays unavailable')   ;   RETURN
79      ENDIF
80
81      ! SURFACE CHEMISTRY (PCO2 AND [H+] IN
82      !     SURFACE LAYER); THE RESULT OF THIS CALCULATION
83      !     IS USED TO COMPUTE AIR-SEA FLUX OF CO2
84
85#if defined key_cpl_carbon_cycle
86      satmco2(:,:) = atm_co2(:,:)
87#endif
88
89      DO jrorr = 1, 10
90
91!CDIR NOVERRCHK
92         DO jj = 1, jpj
93!CDIR NOVERRCHK
94            DO ji = 1, jpi
95
96               ! DUMMY VARIABLES FOR DIC, H+, AND BORATE
97               zbot  = borat(ji,jj,1)
98               zfact = rhop(ji,jj,1) / 1000. + rtrn
99               zdic  = trn(ji,jj,1,jpdic) / zfact
100               zph   = MAX( hi(ji,jj,1), 1.e-10 ) / zfact
101               zalka = trn(ji,jj,1,jptal) / zfact
102
103               ! CALCULATE [ALK]([CO3--], [HCO3-])
104               zalk  = zalka - (  akw3(ji,jj,1) / zph - zph + zbot / ( 1.+ zph / akb3(ji,jj,1) )  )
105
106               ! CALCULATE [H+] AND [H2CO3]
107               zah2   = SQRT(  (zdic-zalk)**2 + 4.* ( zalk * ak23(ji,jj,1)   &
108                  &                                        / ak13(ji,jj,1) ) * ( 2.* zdic - zalk )  )
109               zah2   = 0.5 * ak13(ji,jj,1) / zalk * ( ( zdic - zalk ) + zah2 )
110               zh2co3(ji,jj) = ( 2.* zdic - zalk ) / ( 2.+ ak13(ji,jj,1) / zah2 ) * zfact
111               hi(ji,jj,1)   = zah2 * zfact
112            END DO
113         END DO
114      END DO
115
116
117      ! --------------
118      ! COMPUTE FLUXES
119      ! --------------
120
121      ! FIRST COMPUTE GAS EXCHANGE COEFFICIENTS
122      ! -------------------------------------------
123
124!CDIR NOVERRCHK
125      DO jj = 1, jpj
126!CDIR NOVERRCHK
127         DO ji = 1, jpi
128            ztc  = MIN( 35., tsn(ji,jj,1,jp_tem) )
129            ztc2 = ztc * ztc
130            ztc3 = ztc * ztc2 
131            ! Compute the schmidt Number both O2 and CO2
132            zsch_co2 = 2073.1 - 125.62 * ztc + 3.6276 * ztc2 - 0.043126 * ztc3
133            zsch_o2  = 1953.4 - 128.0  * ztc + 3.9918 * ztc2 - 0.050091 * ztc3
134            !  wind speed
135            zws  = wndm(ji,jj) * wndm(ji,jj)
136            ! Compute the piston velocity for O2 and CO2
137            zkgwan = 0.3 * zws  + 2.5 * ( 0.5246 + 0.016256 * ztc + 0.00049946  * ztc2 )
138            zkgwan = zkgwan * xconv * ( 1.- fr_i(ji,jj) ) * tmask(ji,jj,1)
139# if defined key_degrad
140            zkgwan = zkgwan * facvol(ji,jj,1)
141#endif 
142            ! compute gas exchange for CO2 and O2
143            zkgco2(ji,jj) = zkgwan * SQRT( 660./ zsch_co2 )
144            zkgo2 (ji,jj) = zkgwan * SQRT( 660./ zsch_o2 )
145         END DO
146      END DO
147
148      DO jj = 1, jpj
149         DO ji = 1, jpi
150            ! Compute CO2 flux for the sea and air
151            zfld = satmco2(ji,jj) * tmask(ji,jj,1) * chemc(ji,jj,1) * zkgco2(ji,jj)
152            zflu = zh2co3(ji,jj) * tmask(ji,jj,1) * zkgco2(ji,jj)
153            oce_co2(ji,jj) = ( zfld - zflu ) * rfact * e1e2t(ji,jj) * tmask(ji,jj,1) * 1000.
154            ! compute the trend
155            tra(ji,jj,1,jpdic) = tra(ji,jj,1,jpdic) + ( zfld - zflu ) / fse3t(ji,jj,1)
156
157            ! Compute O2 flux
158            zfld16 = atcox * chemc(ji,jj,2) * tmask(ji,jj,1) * zkgo2(ji,jj)
159            zflu16 = trn(ji,jj,1,jpoxy) * tmask(ji,jj,1) * zkgo2(ji,jj)
160            tra(ji,jj,1,jpoxy) = tra(ji,jj,1,jpoxy) + ( zfld16 - zflu16 ) / fse3t(ji,jj,1)
161#if defined key_iomput
162            zoflx(ji,jj) = ( zfld16 - zflu16 ) * 1000. * tmask(ji,jj,1)
163            zkg  (ji,jj) = zkgco2(ji,jj) * tmask(ji,jj,1)
164            zdpco2(ji,jj) = ( satmco2(ji,jj) - zh2co3(ji,jj) / ( chemc(ji,jj,1) + rtrn ) ) * tmask(ji,jj,1)
165            zdpo2 (ji,jj) = ( atcox  - trn(ji,jj,1,jpoxy)    / ( chemc(ji,jj,2) + rtrn ) ) * tmask(ji,jj,1)
166# else
167            zfact = 1. / e1e2t(ji,jj) / rfact
168            trc2d(ji,jj,jp_pcs0_2d    ) = oce_co2(ji,jj) * zfact
169            trc2d(ji,jj,jp_pcs0_2d + 1) = ( zfld16 - zflu16 ) * 1000. * tmask(ji,jj,1)
170            trc2d(ji,jj,jp_pcs0_2d + 2) = zkgco2(ji,jj) * tmask(ji,jj,1)
171            trc2d(ji,jj,jp_pcs0_2d + 3) = ( satmco2(ji,jj) - zh2co3(ji,jj) / ( chemc(ji,jj,1) + rtrn ) ) * tmask(ji,jj,1)
172# endif
173         END DO
174      END DO
175
176      t_oce_co2_flx = t_oce_co2_flx + glob_sum( oce_co2(:,:) )            ! Cumulative Total Flux of Carbon
177      IF( kt == nitend ) THEN
178         t_atm_co2_flx = glob_sum( satmco2(:,:) * e1e2t(:,:) )            ! Total atmospheric pCO2
179         !
180         t_oce_co2_flx = (-1.) * t_oce_co2_flx  * 12. / 1.e15             ! Conversion in PgC ; negative for out of the ocean
181         t_atm_co2_flx = t_atm_co2_flx  / area                            ! global mean of atmospheric pCO2
182         !
183         IF( lwp) THEN
184            WRITE(numout,*)
185            WRITE(numout,*) ' Global mean of atmospheric pCO2 (ppm) at it= ', kt, ' date= ', ndastp
186            WRITE(numout,*) '------------------------------------------------------- :  ',t_atm_co2_flx
187            WRITE(numout,*)
188            WRITE(numout,*) ' Cumulative total Flux of Carbon out of the ocean (PgC) :'
189            WRITE(numout,*) '-------------------------------------------------------  ',t_oce_co2_flx
190         ENDIF
191         !
192      ENDIF
193
194      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
195         WRITE(charout, FMT="('flx ')")
196         CALL prt_ctl_trc_info(charout)
197         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
198      ENDIF
199
200      IF( ln_diatrc ) THEN
201         CALL iom_put( "Cflx" , oce_co2(:,:) / e1e2t(:,:) / rfact ) 
202         CALL iom_put( "Oflx" , zoflx  )
203         CALL iom_put( "Kg"   , zkg    )
204         CALL iom_put( "Dpco2", zdpco2 )
205         CALL iom_put( "Dpo2" , zdpo2  )
206      ENDIF
207      !
208      IF( wrk_not_released(2, 1,2,3,4,5,6,7) )   CALL ctl_stop('p4z_flx: failed to release workspace arrays')
209      !
210   END SUBROUTINE p4z_flx
211
212
213   SUBROUTINE p4z_flx_init
214      !!----------------------------------------------------------------------
215      !!                  ***  ROUTINE p4z_flx_init  ***
216      !!
217      !! ** Purpose :   Initialization of atmospheric conditions
218      !!
219      !! ** Method  :   Read the nampisext namelist and check the parameters
220      !!      called at the first timestep (nit000)
221      !! ** input   :   Namelist nampisext
222      !!----------------------------------------------------------------------
223      NAMELIST/nampisext/ atcco2
224      !!----------------------------------------------------------------------
225      !
226      REWIND( numnatp )                     ! read numnatp
227      READ  ( numnatp, nampisext )
228      !
229      IF(lwp) THEN                         ! control print
230         WRITE(numout,*) ' '
231         WRITE(numout,*) ' Namelist parameters for air-sea exchange, nampisext'
232         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
233         WRITE(numout,*) '    Atmospheric pCO2      atcco2      =', atcco2
234      ENDIF
235      !
236      area = glob_sum( e1e2t(:,:) )        ! interior global domain surface
237      !
238      oce_co2(:,:)  = 0._wp                ! Initialization of Flux of Carbon
239      t_atm_co2_flx = 0._wp
240      !
241      satmco2(:,:)  = atcco2      ! Initialisation of atmospheric pco2
242      t_oce_co2_flx = 0._wp
243      !
244   END SUBROUTINE p4z_flx_init
245
246
247   INTEGER FUNCTION p4z_flx_alloc()
248      !!----------------------------------------------------------------------
249      !!                     ***  ROUTINE p4z_flx_alloc  ***
250      !!----------------------------------------------------------------------
251      ALLOCATE( oce_co2(jpi,jpj), satmco2(jpi,jpj), STAT=p4z_flx_alloc )
252      !
253      IF( p4z_flx_alloc /= 0 )   CALL ctl_warn('p4z_flx_alloc : failed to allocate arrays')
254      !
255   END FUNCTION p4z_flx_alloc
256
257#else
258   !!======================================================================
259   !!  Dummy module :                                   No PISCES bio-model
260   !!======================================================================
261CONTAINS
262   SUBROUTINE p4z_flx( kt )                   ! Empty routine
263      INTEGER, INTENT( in ) ::   kt
264      WRITE(*,*) 'p4z_flx: You should not have seen this print! error?', kt
265   END SUBROUTINE p4z_flx
266#endif 
267
268   !!======================================================================
269END MODULE  p4zflx
Note: See TracBrowser for help on using the repository browser.