New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zsink.F90 in branches/2011/dev_r2787_LOCEAN3_TRA_TRP/NEMOGCM/NEMO/TOP_SRC/PISCES – NEMO

source: branches/2011/dev_r2787_LOCEAN3_TRA_TRP/NEMOGCM/NEMO/TOP_SRC/PISCES/p4zsink.F90 @ 2819

Last change on this file since 2819 was 2819, checked in by cetlod, 13 years ago

Improvment of branch dev_r2787_LOCEAN3_TRA_TRP
  • Property svn:keywords set to Id
File size: 32.1 KB
Line 
1MODULE p4zsink
2   !!======================================================================
3   !!                         ***  MODULE p4zsink  ***
4   !! TOP :  PISCES  vertical flux of particulate matter due to gravitational sinking
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8#if defined key_pisces
9   !!----------------------------------------------------------------------
10   !!   p4z_sink       :  Compute vertical flux of particulate matter due to gravitational sinking
11   !!   p4z_sink_init  :  Unitialisation of sinking speed parameters
12   !!   p4z_sink_alloc :  Allocate sinking speed variables
13   !!----------------------------------------------------------------------
14   USE oce_trc         !  shared variables between ocean and passive tracers
15   USE trc             !  passive tracers common variables
16   USE sms_pisces      !  PISCES Source Minus Sink variables
17   USE prtctl_trc      !  print control for debugging
18   USE iom             !  I/O manager
19
20   IMPLICIT NONE
21   PRIVATE
22
23   PUBLIC   p4z_sink         ! called in p4zbio.F90
24   PUBLIC   p4z_sink_init    ! called in trcsms_pisces.F90
25   PUBLIC   p4z_sink_alloc
26
27   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   wsbio3   !: POC sinking speed
28   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   wsbio4   !: GOC sinking speed
29   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   wscal    !: Calcite and BSi sinking speeds
30
31   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinking, sinking2  !: POC sinking fluxes
32   !                                                          !  (different meanings depending on the parameterization)
33   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinkcal, sinksil   !: CaCO3 and BSi sinking fluxes
34   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinkfer            !: Small BFe sinking fluxes
35#if ! defined key_kriest
36   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinkfer2           !: Big iron sinking fluxes
37#endif
38
39   INTEGER  :: iksed  = 10
40
41#if  defined key_kriest
42   REAL(wp) ::  xkr_sfact    = 250.     !: Sinking factor
43   REAL(wp) ::  xkr_stick    = 0.2      !: Stickiness
44   REAL(wp) ::  xkr_nnano    = 2.337    !: Nbr of cell in nano size class
45   REAL(wp) ::  xkr_ndiat    = 3.718    !: Nbr of cell in diatoms size class
46   REAL(wp) ::  xkr_nmeso    = 7.147    !: Nbr of cell in mesozoo  size class
47   REAL(wp) ::  xkr_naggr    = 9.877    !: Nbr of cell in aggregates  size class
48
49   REAL(wp) ::  xkr_frac 
50
51   REAL(wp), PUBLIC ::  xkr_dnano       !: Size of particles in nano pool
52   REAL(wp), PUBLIC ::  xkr_ddiat       !: Size of particles in diatoms pool
53   REAL(wp), PUBLIC ::  xkr_dmeso       !: Size of particles in mesozoo pool
54   REAL(wp), PUBLIC ::  xkr_daggr       !: Size of particles in aggregates pool
55   REAL(wp), PUBLIC ::  xkr_wsbio_min   !: min vertical particle speed
56   REAL(wp), PUBLIC ::  xkr_wsbio_max   !: max vertical particle speed
57
58   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:) ::   xnumm   !:  maximum number of particles in aggregates
59#endif
60
61   !!* Substitution
62#  include "top_substitute.h90"
63   !!----------------------------------------------------------------------
64   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
65   !! $Id$
66   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
67   !!----------------------------------------------------------------------
68CONTAINS
69
70#if defined key_kriest
71   !!----------------------------------------------------------------------
72   !!   'key_kriest'                                                    ???
73   !!----------------------------------------------------------------------
74
75   SUBROUTINE p4z_sink ( kt, jnt )
76      !!---------------------------------------------------------------------
77      !!                ***  ROUTINE p4z_sink  ***
78      !!
79      !! ** Purpose :   Compute vertical flux of particulate matter due to
80      !!              gravitational sinking - Kriest parameterization
81      !!
82      !! ** Method  : - ???
83      !!---------------------------------------------------------------------
84      USE wrk_nemo, ONLY:   wrk_in_use, wrk_not_released
85      USE wrk_nemo, ONLY:   znum3d => wrk_3d_2
86      !
87      INTEGER, INTENT(in) :: kt, jnt
88      !
89      INTEGER  :: ji, jj, jk
90      REAL(wp) :: zagg1, zagg2, zagg3, zagg4, zagg5, zaggsi, zaggsh
91      REAL(wp) :: zagg , zaggdoc, znumdoc
92      REAL(wp) :: znum , zeps, zfm, zgm, zsm
93      REAL(wp) :: zdiv , zdiv1, zdiv2, zdiv3, zdiv4, zdiv5
94      REAL(wp) :: zval1, zval2, zval3, zval4
95      REAL(wp) :: zrfact2
96      INTEGER  :: ik1
97      CHARACTER (len=25) :: charout
98      !!---------------------------------------------------------------------
99      !
100      IF( wrk_in_use(3, 2 ) ) THEN
101         CALL ctl_stop('p4z_sink: requested workspace arrays unavailable')   ;   RETURN
102      ENDIF
103     
104      !     Initialisation of variables used to compute Sinking Speed
105      !     ---------------------------------------------------------
106
107      znum3d(:,:,:) = 0.e0
108      zval1 = 1. + xkr_zeta
109      zval2 = 1. + xkr_zeta + xkr_eta
110      zval3 = 1. + xkr_eta
111
112      !     Computation of the vertical sinking speed : Kriest et Evans, 2000
113      !     -----------------------------------------------------------------
114
115      DO jk = 1, jpkm1
116         DO jj = 1, jpj
117            DO ji = 1, jpi
118               IF( tmask(ji,jj,jk) /= 0.e0 ) THEN
119                  znum = trn(ji,jj,jk,jppoc) / ( trn(ji,jj,jk,jpnum) + rtrn ) / xkr_massp
120                  ! -------------- To avoid sinking speed over 50 m/day -------
121                  znum  = MIN( xnumm(jk), znum )
122                  znum  = MAX( 1.1      , znum )
123                  znum3d(ji,jj,jk) = znum
124                  !------------------------------------------------------------
125                  zeps  = ( zval1 * znum - 1. )/ ( znum - 1. )
126                  zfm   = xkr_frac**( 1. - zeps )
127                  zgm   = xkr_frac**( zval1 - zeps )
128                  zdiv  = MAX( 1.e-4, ABS( zeps - zval2 ) ) * SIGN( 1., ( zeps - zval2 ) )
129                  zdiv1 = zeps - zval3
130                  wsbio3(ji,jj,jk) = xkr_wsbio_min * ( zeps - zval1 ) / zdiv    &
131                     &             - xkr_wsbio_max *   zgm * xkr_eta  / zdiv
132                  wsbio4(ji,jj,jk) = xkr_wsbio_min *   ( zeps-1. )    / zdiv1   &
133                     &             - xkr_wsbio_max *   zfm * xkr_eta  / zdiv1
134                  IF( znum == 1.1)   wsbio3(ji,jj,jk) = wsbio4(ji,jj,jk)
135               ENDIF
136            END DO
137         END DO
138      END DO
139
140      wscal(:,:,:) = MAX( wsbio3(:,:,:), 50._wp )
141
142      !   INITIALIZE TO ZERO ALL THE SINKING ARRAYS
143      !   -----------------------------------------
144
145      sinking (:,:,:) = 0.e0
146      sinking2(:,:,:) = 0.e0
147      sinkcal (:,:,:) = 0.e0
148      sinkfer (:,:,:) = 0.e0
149      sinksil (:,:,:) = 0.e0
150
151     !   Compute the sedimentation term using p4zsink2 for all the sinking particles
152     !   -----------------------------------------------------
153
154      CALL p4z_sink2( wsbio3, sinking , jppoc )
155      CALL p4z_sink2( wsbio4, sinking2, jpnum )
156      CALL p4z_sink2( wsbio3, sinkfer , jpsfe )
157      CALL p4z_sink2( wscal , sinksil , jpdsi )
158      CALL p4z_sink2( wscal , sinkcal , jpcal )
159
160     !  Exchange between organic matter compartments due to coagulation/disaggregation
161     !  ---------------------------------------------------
162
163      zval1 = 1. + xkr_zeta
164      zval2 = 1. + xkr_eta
165      zval3 = 3. + xkr_eta
166      zval4 = 4. + xkr_eta
167
168      DO jk = 1,jpkm1
169         DO jj = 1,jpj
170            DO ji = 1,jpi
171               IF( tmask(ji,jj,jk) /= 0.e0 ) THEN
172
173                  znum = trn(ji,jj,jk,jppoc)/(trn(ji,jj,jk,jpnum)+rtrn) / xkr_massp
174                  !-------------- To avoid sinking speed over 50 m/day -------
175                  znum  = min(xnumm(jk),znum)
176                  znum  = MAX( 1.1,znum)
177                  !------------------------------------------------------------
178                  zeps  = ( zval1 * znum - 1.) / ( znum - 1.)
179                  zdiv  = MAX( 1.e-4, ABS( zeps - zval3) ) * SIGN( 1., zeps - zval3 )
180                  zdiv1 = MAX( 1.e-4, ABS( zeps - 4.   ) ) * SIGN( 1., zeps - 4.    )
181                  zdiv2 = zeps - 2.
182                  zdiv3 = zeps - 3.
183                  zdiv4 = zeps - zval2
184                  zdiv5 = 2.* zeps - zval4
185                  zfm   = xkr_frac**( 1.- zeps )
186                  zsm   = xkr_frac**xkr_eta
187
188                  !    Part I : Coagulation dependant on turbulence
189                  !    ----------------------------------------------
190
191                  zagg1 = ( 0.163 * trn(ji,jj,jk,jpnum)**2               &
192                     &            * 2.*( (zfm-1.)*(zfm*xkr_mass_max**3-xkr_mass_min**3)    &
193                     &            * (zeps-1)/zdiv1 + 3.*(zfm*xkr_mass_max-xkr_mass_min)    &
194                     &            * (zfm*xkr_mass_max**2-xkr_mass_min**2)                  &
195                     &            * (zeps-1.)**2/(zdiv2*zdiv3))           ) 
196
197                  zagg2 = (  2*0.163*trn(ji,jj,jk,jpnum)**2*zfm*                       &
198                     &                   ((xkr_mass_max**3+3.*(xkr_mass_max**2          &
199                     &                    *xkr_mass_min*(zeps-1.)/zdiv2                 &
200                     &                    +xkr_mass_max*xkr_mass_min**2*(zeps-1.)/zdiv3)    &
201                     &                    +xkr_mass_min**3*(zeps-1)/zdiv1)                  &
202                     &                    -zfm*xkr_mass_max**3*(1.+3.*((zeps-1.)/           &
203                     &                    (zeps-2.)+(zeps-1.)/zdiv3)+(zeps-1.)/zdiv1))  ) 
204
205                  zagg3 = (  0.163*trn(ji,jj,jk,jpnum)**2*zfm**2*8. * xkr_mass_max**3 ) 
206
207                  IF( lk_degrad ) THEN
208                     zagg1 = zagg1 * facvol(ji,jj,jk)
209                     zagg2 = zagg2 * facvol(ji,jj,jk)
210                     zagg3 = zagg3 * facvol(ji,jj,jk)
211                  ENDIF
212                  zaggsh = ( zagg1 + zagg2 + zagg3 ) * rfact2 * xdiss(ji,jj,jk) / 1000.
213
214                 !    Aggregation of small into large particles
215                 !    Part II : Differential settling
216                 !    ----------------------------------------------
217
218                  zagg4 = (  2.*3.141*0.125*trn(ji,jj,jk,jpnum)**2*                       &
219                     &                 xkr_wsbio_min*(zeps-1.)**2                         &
220                     &                 *(xkr_mass_min**2*((1.-zsm*zfm)/(zdiv3*zdiv4)      &
221                     &                 -(1.-zfm)/(zdiv*(zeps-1.)))-                       &
222                     &                 ((zfm*zfm*xkr_mass_max**2*zsm-xkr_mass_min**2)     &
223                     &                 *xkr_eta)/(zdiv*zdiv3*zdiv5) )  ) 
224
225                  zagg5 = (  2.*3.141*0.125*trn(ji,jj,jk,jpnum)**2                         &
226                     &                 *(zeps-1.)*zfm*xkr_wsbio_min                        &
227                     &                 *(zsm*(xkr_mass_min**2-zfm*xkr_mass_max**2)         &
228                     &                 /zdiv3-(xkr_mass_min**2-zfm*zsm*xkr_mass_max**2)    &
229                     &                 /zdiv)    ) 
230# if defined key_degrad
231                  zagg4 = zagg4 * facvol(ji,jj,jk)
232                  zagg5 = zagg5 * facvol(ji,jj,jk)
233# endif
234                  zaggsi = ( zagg4 + zagg5 ) * xstep / 10.
235
236                  zagg = 0.5 * xkr_stick * ( zaggsh + zaggsi )
237
238                  !     Aggregation of DOC to small particles
239                  !     --------------------------------------
240
241                  zaggdoc = ( 0.4 * trn(ji,jj,jk,jpdoc)               &
242                     &        + 1018.  * trn(ji,jj,jk,jppoc)  ) * xstep    &
243# if defined key_degrad
244                     &        * facvol(ji,jj,jk)
245# endif
246                     &        * xdiss(ji,jj,jk) * trn(ji,jj,jk,jpdoc)
247
248                  znumdoc = trn(ji,jj,jk,jpnum) / ( trn(ji,jj,jk,jppoc) + rtrn )
249                  tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zaggdoc
250                  tra(ji,jj,jk,jpnum) = tra(ji,jj,jk,jpnum) + zaggdoc * znumdoc - zagg
251                  tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) - zaggdoc
252
253               ENDIF
254            END DO
255         END DO
256      END DO
257
258      IF( ln_diatrc ) THEN
259         !
260         ik1 = iksed + 1
261         zrfact2 = 1.e3 * rfact2r
262         IF( jnt == nrdttrc ) THEN
263           CALL iom_put( "POCFlx"  , sinking (:,:,:)      * zrfact2 * tmask(:,:,:) )  ! POC export
264           CALL iom_put( "NumFlx"  , sinking2 (:,:,:)     * zrfact2 * tmask(:,:,:) )  ! Num export
265           CALL iom_put( "SiFlx"   , sinksil (:,:,:)      * zrfact2 * tmask(:,:,:) )  ! Silica export
266           CALL iom_put( "CaCO3Flx", sinkcal (:,:,:)      * zrfact2 * tmask(:,:,:) )  ! Calcite export
267           CALL iom_put( "xnum"    , znum3d  (:,:,:)                * tmask(:,:,:) )  ! Number of particles in aggregats
268           CALL iom_put( "W1"      , wsbio3  (:,:,:)                * tmask(:,:,:) )  ! sinking speed of POC
269           CALL iom_put( "W2"      , wsbio4  (:,:,:)                * tmask(:,:,:) )  ! sinking speed of aggregats
270           CALL iom_put( "PMO"     , sinking (:,:,ik1)    * zrfact2 * tmask(:,:,1) )  ! POC export at 100m
271           CALL iom_put( "PMO2"    , sinking2(:,:,ik1)    * zrfact2 * tmask(:,:,1) )  ! Num export at 100m
272           CALL iom_put( "ExpFe1"  , sinkfer (:,:,ik1)    * zrfact2 * tmask(:,:,1) )  ! Export of iron at 100m
273           CALL iom_put( "ExpSi"   , sinksil (:,:,ik1)    * zrfact2 * tmask(:,:,1) )  ! export of silica at 100m
274           CALL iom_put( "ExpCaCO3", sinkcal (:,:,ik1)    * zrfact2 * tmask(:,:,1) )  ! export of calcite at 100m
275         ENDIF
276# if ! defined key_iomput
277         trc2d(:,:  ,jp_pcs0_2d + 4)  = sinking (:,:,ik1)    * zrfact2 * tmask(:,:,1)
278         trc2d(:,:  ,jp_pcs0_2d + 5)  = sinking2(:,:,ik1)    * zrfact2 * tmask(:,:,1)
279         trc2d(:,:  ,jp_pcs0_2d + 6)  = sinkfer (:,:,ik1)    * zrfact2 * tmask(:,:,1)
280         trc2d(:,:  ,jp_pcs0_2d + 7)  = sinksil (:,:,ik1)    * zrfact2 * tmask(:,:,1)
281         trc2d(:,:  ,jp_pcs0_2d + 8)  = sinkcal (:,:,ik1)    * zrfact2 * tmask(:,:,1)
282         trc3d(:,:,:,jp_pcs0_3d + 11) = sinking (:,:,:)      * zrfact2 * tmask(:,:,:)
283         trc3d(:,:,:,jp_pcs0_3d + 12) = sinking2(:,:,:)      * zrfact2 * tmask(:,:,:)
284         trc3d(:,:,:,jp_pcs0_3d + 13) = sinksil (:,:,:)      * zrfact2 * tmask(:,:,:)
285         trc3d(:,:,:,jp_pcs0_3d + 14) = sinkcal (:,:,:)      * zrfact2 * tmask(:,:,:)
286         trc3d(:,:,:,jp_pcs0_3d + 15) = znum3d  (:,:,:)                * tmask(:,:,:)
287         trc3d(:,:,:,jp_pcs0_3d + 16) = wsbio3  (:,:,:)                * tmask(:,:,:)
288         trc3d(:,:,:,jp_pcs0_3d + 17) = wsbio4  (:,:,:)                * tmask(:,:,:)
289# endif
290        !
291      ENDIF
292      !
293      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
294         WRITE(charout, FMT="('sink')")
295         CALL prt_ctl_trc_info(charout)
296         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
297      ENDIF
298      !
299      IF( wrk_not_released(3, 2 ) )   CALL ctl_stop('p4z_sink: failed to release workspace arrays')
300      !
301   END SUBROUTINE p4z_sink
302
303
304   SUBROUTINE p4z_sink_init
305      !!----------------------------------------------------------------------
306      !!                  ***  ROUTINE p4z_sink_init  ***
307      !!
308      !! ** Purpose :   Initialization of sinking parameters
309      !!                Kriest parameterization only
310      !!
311      !! ** Method  :   Read the nampiskrs namelist and check the parameters
312      !!      called at the first timestep
313      !!
314      !! ** input   :   Namelist nampiskrs
315      !!----------------------------------------------------------------------
316      INTEGER  ::   jk, jn, kiter
317      REAL(wp) ::   znum, zdiv
318      REAL(wp) ::   zws, zwr, zwl,wmax, znummax
319      REAL(wp) ::   zmin, zmax, zl, zr, xacc
320      !
321      NAMELIST/nampiskrs/ xkr_sfact, xkr_stick ,  &
322         &                xkr_nnano, xkr_ndiat, xkr_nmeso, xkr_naggr
323      !!----------------------------------------------------------------------
324      !
325      REWIND( numnatp )                     ! read nampiskrs
326      READ  ( numnatp, nampiskrs )
327
328      IF(lwp) THEN
329         WRITE(numout,*)
330         WRITE(numout,*) ' Namelist : nampiskrs'
331         WRITE(numout,*) '    Sinking factor                           xkr_sfact    = ', xkr_sfact
332         WRITE(numout,*) '    Stickiness                               xkr_stick    = ', xkr_stick
333         WRITE(numout,*) '    Nbr of cell in nano size class           xkr_nnano    = ', xkr_nnano
334         WRITE(numout,*) '    Nbr of cell in diatoms size class        xkr_ndiat    = ', xkr_ndiat
335         WRITE(numout,*) '    Nbr of cell in mesozoo size class        xkr_nmeso    = ', xkr_nmeso
336         WRITE(numout,*) '    Nbr of cell in aggregates size class     xkr_naggr    = ', xkr_naggr
337      ENDIF
338
339
340      ! max and min vertical particle speed
341      xkr_wsbio_min = xkr_sfact * xkr_mass_min**xkr_eta
342      xkr_wsbio_max = xkr_sfact * xkr_mass_max**xkr_eta
343      WRITE(numout,*) ' max and min vertical particle speed ', xkr_wsbio_min, xkr_wsbio_max
344
345      !
346      !    effect of the sizes of the different living pools on particle numbers
347      !    nano = 2um-20um -> mean size=6.32 um -> ws=2.596 -> xnum=xnnano=2.337
348      !    diat and microzoo = 10um-200um -> 44.7 -> 8.732 -> xnum=xndiat=3.718
349      !    mesozoo = 200um-2mm -> 632.45 -> 45.14 -> xnum=xnmeso=7.147
350      !    aggregates = 200um-10mm -> 1414 -> 74.34 -> xnum=xnaggr=9.877
351      !    doc aggregates = 1um
352      ! ----------------------------------------------------------
353
354      xkr_dnano = 1. / ( xkr_massp * xkr_nnano )
355      xkr_ddiat = 1. / ( xkr_massp * xkr_ndiat )
356      xkr_dmeso = 1. / ( xkr_massp * xkr_nmeso )
357      xkr_daggr = 1. / ( xkr_massp * xkr_naggr )
358
359      !!---------------------------------------------------------------------
360      !!    'key_kriest'                                                  ???
361      !!---------------------------------------------------------------------
362      !  COMPUTATION OF THE VERTICAL PROFILE OF MAXIMUM SINKING SPEED
363      !  Search of the maximum number of particles in aggregates for each k-level.
364      !  Bissection Method
365      !--------------------------------------------------------------------
366      WRITE(numout,*)
367      WRITE(numout,*)'    kriest : Compute maximum number of particles in aggregates'
368
369      xacc     =  0.001_wp
370      kiter    = 50
371      zmin     =  1.10_wp
372      zmax     = xkr_mass_max / xkr_mass_min
373      xkr_frac = zmax
374
375      DO jk = 1,jpk
376         zl = zmin
377         zr = zmax
378         wmax = 0.5 * fse3t(1,1,jk) * rday / rfact2
379         zdiv = xkr_zeta + xkr_eta - xkr_eta * zl
380         znum = zl - 1.
381         zwl =  xkr_wsbio_min * xkr_zeta / zdiv &
382            & - ( xkr_wsbio_max * xkr_eta * znum * &
383            &     xkr_frac**( -xkr_zeta / znum ) / zdiv ) &
384            & - wmax
385
386         zdiv = xkr_zeta + xkr_eta - xkr_eta * zr
387         znum = zr - 1.
388         zwr =  xkr_wsbio_min * xkr_zeta / zdiv &
389            & - ( xkr_wsbio_max * xkr_eta * znum * &
390            &     xkr_frac**( -xkr_zeta / znum ) / zdiv ) &
391            & - wmax
392iflag:   DO jn = 1, kiter
393            IF    ( zwl == 0._wp ) THEN   ;   znummax = zl
394            ELSEIF( zwr == 0._wp ) THEN   ;   znummax = zr
395            ELSE
396               znummax = ( zr + zl ) / 2.
397               zdiv = xkr_zeta + xkr_eta - xkr_eta * znummax
398               znum = znummax - 1.
399               zws =  xkr_wsbio_min * xkr_zeta / zdiv &
400                  & - ( xkr_wsbio_max * xkr_eta * znum * &
401                  &     xkr_frac**( -xkr_zeta / znum ) / zdiv ) &
402                  & - wmax
403               IF( zws * zwl < 0. ) THEN   ;   zr = znummax
404               ELSE                        ;   zl = znummax
405               ENDIF
406               zdiv = xkr_zeta + xkr_eta - xkr_eta * zl
407               znum = zl - 1.
408               zwl =  xkr_wsbio_min * xkr_zeta / zdiv &
409                  & - ( xkr_wsbio_max * xkr_eta * znum * &
410                  &     xkr_frac**( -xkr_zeta / znum ) / zdiv ) &
411                  & - wmax
412
413               zdiv = xkr_zeta + xkr_eta - xkr_eta * zr
414               znum = zr - 1.
415               zwr =  xkr_wsbio_min * xkr_zeta / zdiv &
416                  & - ( xkr_wsbio_max * xkr_eta * znum * &
417                  &     xkr_frac**( -xkr_zeta / znum ) / zdiv ) &
418                  & - wmax
419               !
420               IF ( ABS ( zws )  <= xacc ) EXIT iflag
421               !
422            ENDIF
423            !
424         END DO iflag
425
426         xnumm(jk) = znummax
427         WRITE(numout,*) '       jk = ', jk, ' wmax = ', wmax,' xnum max = ', xnumm(jk)
428         !
429      END DO
430      !
431  END SUBROUTINE p4z_sink_init
432
433#else
434
435   SUBROUTINE p4z_sink ( kt, jnt )
436      !!---------------------------------------------------------------------
437      !!                     ***  ROUTINE p4z_sink  ***
438      !!
439      !! ** Purpose :   Compute vertical flux of particulate matter due to
440      !!                gravitational sinking
441      !!
442      !! ** Method  : - ???
443      !!---------------------------------------------------------------------
444      INTEGER, INTENT(in) :: kt, jnt
445      INTEGER  ::   ji, jj, jk
446      REAL(wp) ::   zagg1, zagg2, zagg3, zagg4
447      REAL(wp) ::   zagg , zaggfe, zaggdoc, zaggdoc2
448      REAL(wp) ::   zfact, zwsmax, zstep
449      REAL(wp) ::   zrfact2
450      INTEGER  ::   ik1
451      CHARACTER (len=25) :: charout
452      !!---------------------------------------------------------------------
453
454      !    Sinking speeds of detritus is increased with depth as shown
455      !    by data and from the coagulation theory
456      !    -----------------------------------------------------------
457      DO jk = 1, jpkm1
458         DO jj = 1, jpj
459            DO ji=1,jpi
460               zfact = MAX( 0., fsdepw(ji,jj,jk+1) - hmld(ji,jj) ) / 4000._wp
461               wsbio4(ji,jj,jk) = wsbio2 + ( 200.- wsbio2 ) * zfact
462            END DO
463         END DO
464      END DO
465
466      ! limit the values of the sinking speeds to avoid numerical instabilities 
467      wsbio3(:,:,:) = wsbio
468      !
469      ! OA Below, this is garbage. the ideal would be to find a time-splitting
470      ! OA algorithm that does not increase the computing cost by too much
471      ! OA In ROMS, I have included a time-splitting procedure. But it is
472      ! OA too expensive as the loop is computed globally. Thus, a small e3t
473      ! OA at one place determines the number of subtimesteps globally
474      ! OA AWFULLY EXPENSIVE !! Not able to find a better approach. Damned !!
475
476      DO jk = 1,jpkm1
477         DO jj = 1, jpj
478            DO ji = 1, jpi
479               zwsmax = 0.8 * fse3t(ji,jj,jk) / xstep
480               wsbio4(ji,jj,jk) = MIN( wsbio4(ji,jj,jk), zwsmax )
481               wsbio3(ji,jj,jk) = MIN( wsbio3(ji,jj,jk), zwsmax )
482            END DO
483         END DO
484      END DO
485
486      wscal(:,:,:) = wsbio4(:,:,:)
487
488      !  Initializa to zero all the sinking arrays
489      !   -----------------------------------------
490
491      sinking (:,:,:) = 0.e0
492      sinking2(:,:,:) = 0.e0
493      sinkcal (:,:,:) = 0.e0
494      sinkfer (:,:,:) = 0.e0
495      sinksil (:,:,:) = 0.e0
496      sinkfer2(:,:,:) = 0.e0
497
498      !   Compute the sedimentation term using p4zsink2 for all the sinking particles
499      !   -----------------------------------------------------
500
501      CALL p4z_sink2( wsbio3, sinking , jppoc )
502      CALL p4z_sink2( wsbio3, sinkfer , jpsfe )
503      CALL p4z_sink2( wsbio4, sinking2, jpgoc )
504      CALL p4z_sink2( wsbio4, sinkfer2, jpbfe )
505      CALL p4z_sink2( wsbio4, sinksil , jpdsi )
506      CALL p4z_sink2( wscal , sinkcal , jpcal )
507
508      !  Exchange between organic matter compartments due to coagulation/disaggregation
509      !  ---------------------------------------------------
510
511      DO jk = 1, jpkm1
512         DO jj = 1, jpj
513            DO ji = 1, jpi
514               !
515               zstep = xstep 
516# if defined key_degrad
517               zstep = zstep * facvol(ji,jj,jk)
518# endif
519               zfact = zstep * xdiss(ji,jj,jk)
520               !  Part I : Coagulation dependent on turbulence
521               zagg1 = 940.* zfact * trn(ji,jj,jk,jppoc) * trn(ji,jj,jk,jppoc)
522               zagg2 = 1.054e4 * zfact * trn(ji,jj,jk,jppoc) * trn(ji,jj,jk,jpgoc)
523
524               ! Part II : Differential settling
525
526               !  Aggregation of small into large particles
527               zagg3 = 0.66 * zstep * trn(ji,jj,jk,jppoc) * trn(ji,jj,jk,jpgoc)
528               zagg4 = 0.e0 * zstep * trn(ji,jj,jk,jppoc) * trn(ji,jj,jk,jppoc)
529
530               zagg   = zagg1 + zagg2 + zagg3 + zagg4
531               zaggfe = zagg * trn(ji,jj,jk,jpsfe) / ( trn(ji,jj,jk,jppoc) + rtrn )
532
533               ! Aggregation of DOC to small particles
534               zaggdoc = ( 80.* trn(ji,jj,jk,jpdoc) + 698. * trn(ji,jj,jk,jppoc) ) *  zfact * trn(ji,jj,jk,jpdoc) 
535               zaggdoc2 = 1.05e4 * zfact * trn(ji,jj,jk,jpgoc) * trn(ji,jj,jk,jpdoc)
536
537               !  Update the trends
538               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) - zagg + zaggdoc
539               tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) + zagg + zaggdoc2
540               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) - zaggfe
541               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + zaggfe
542               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) - zaggdoc - zaggdoc2
543               !
544            END DO
545         END DO
546      END DO
547
548      IF( ln_diatrc ) THEN
549         !
550         zrfact2 = 1.e3 * rfact2r
551         ik1  = iksed + 1
552         IF( jnt == nrdttrc ) THEN
553            CALL iom_put( "EPC100"  , ( sinking(:,:,ik1) + sinking2(:,:,ik1) ) * zrfact2 * tmask(:,:,1) ) ! Export of carbon at 100m
554            CALL iom_put( "EPFE100" , ( sinkfer(:,:,ik1) + sinkfer2(:,:,ik1) ) * zrfact2 * tmask(:,:,1) ) ! Export of iron at 100m
555            CALL iom_put( "EPCAL100",   sinkcal(:,:,ik1)                       * zrfact2 * tmask(:,:,1) ) ! Export of calcite  at 100m
556            CALL iom_put( "EPSI100" ,   sinksil(:,:,ik1)                       * zrfact2 * tmask(:,:,1) ) ! Export of biogenic silica at 100m
557         ENDIF
558# if ! defined key_iomput
559         trc2d(:,:,jp_pcs0_2d + 4) = sinking (:,:,ik1) * zrfact2 * tmask(:,:,1)
560         trc2d(:,:,jp_pcs0_2d + 5) = sinking2(:,:,ik1) * zrfact2 * tmask(:,:,1)
561         trc2d(:,:,jp_pcs0_2d + 6) = sinkfer (:,:,ik1) * zrfact2 * tmask(:,:,1)
562         trc2d(:,:,jp_pcs0_2d + 7) = sinkfer2(:,:,ik1) * zrfact2 * tmask(:,:,1)
563         trc2d(:,:,jp_pcs0_2d + 8) = sinksil (:,:,ik1) * zrfact2 * tmask(:,:,1)
564         trc2d(:,:,jp_pcs0_2d + 9) = sinkcal (:,:,ik1) * zrfact2 * tmask(:,:,1)
565# endif
566         !
567      ENDIF
568      !
569      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
570         WRITE(charout, FMT="('sink')")
571         CALL prt_ctl_trc_info(charout)
572         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
573      ENDIF
574      !
575   END SUBROUTINE p4z_sink
576
577
578   SUBROUTINE p4z_sink_init
579      !!----------------------------------------------------------------------
580      !!                  ***  ROUTINE p4z_sink_init  ***
581      !!----------------------------------------------------------------------
582   END SUBROUTINE p4z_sink_init
583
584#endif
585
586   SUBROUTINE p4z_sink2( pwsink, psinkflx, jp_tra )
587      !!---------------------------------------------------------------------
588      !!                     ***  ROUTINE p4z_sink2  ***
589      !!
590      !! ** Purpose :   Compute the sedimentation terms for the various sinking
591      !!     particles. The scheme used to compute the trends is based
592      !!     on MUSCL.
593      !!
594      !! ** Method  : - this ROUTINE compute not exactly the advection but the
595      !!      transport term, i.e.  div(u*tra).
596      !!---------------------------------------------------------------------
597      USE wrk_nemo, ONLY: wrk_in_use, wrk_not_released
598      USE wrk_nemo, ONLY: ztraz => wrk_3d_2, zakz => wrk_3d_3, zwsink2 => wrk_3d_4
599      !
600      INTEGER , INTENT(in   )                         ::   jp_tra    ! tracer index index     
601      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj,jpk) ::   pwsink    ! sinking speed
602      REAL(wp), INTENT(inout), DIMENSION(jpi,jpj,jpk) ::   psinkflx  ! sinking fluxe
603      !!
604      INTEGER  ::   ji, jj, jk, jn
605      REAL(wp) ::   zigma,zew,zign, zflx, zstep
606      !!---------------------------------------------------------------------
607
608      IF(  wrk_in_use(3, 2,3,4 ) ) THEN
609         CALL ctl_stop('p4z_sink2: requested workspace arrays unavailable')
610         RETURN
611      END IF
612
613      zstep = rfact2 / 2.
614
615      ztraz(:,:,:) = 0.e0
616      zakz (:,:,:) = 0.e0
617
618      DO jk = 1, jpkm1
619         zwsink2(:,:,jk+1) = -pwsink(:,:,jk) / rday * tmask(:,:,jk+1) 
620      END DO
621      zwsink2(:,:,1) = 0.e0
622      IF( lk_degrad ) THEN
623         zwsink2(:,:,:) = zwsink2(:,:,:) * facvol(:,:,:)
624      ENDIF
625
626
627      ! Vertical advective flux
628      DO jn = 1, 2
629         !  first guess of the slopes interior values
630         DO jk = 2, jpkm1
631            ztraz(:,:,jk) = ( trn(:,:,jk-1,jp_tra) - trn(:,:,jk,jp_tra) ) * tmask(:,:,jk)
632         END DO
633         ztraz(:,:,1  ) = 0.0
634         ztraz(:,:,jpk) = 0.0
635
636         ! slopes
637         DO jk = 2, jpkm1
638            DO jj = 1,jpj
639               DO ji = 1, jpi
640                  zign = 0.25 + SIGN( 0.25, ztraz(ji,jj,jk) * ztraz(ji,jj,jk+1) )
641                  zakz(ji,jj,jk) = ( ztraz(ji,jj,jk) + ztraz(ji,jj,jk+1) ) * zign
642               END DO
643            END DO
644         END DO
645         
646         ! Slopes limitation
647         DO jk = 2, jpkm1
648            DO jj = 1, jpj
649               DO ji = 1, jpi
650                  zakz(ji,jj,jk) = SIGN( 1., zakz(ji,jj,jk) ) *        &
651                     &             MIN( ABS( zakz(ji,jj,jk) ), 2. * ABS(ztraz(ji,jj,jk+1)), 2. * ABS(ztraz(ji,jj,jk) ) )
652               END DO
653            END DO
654         END DO
655         
656         ! vertical advective flux
657         DO jk = 1, jpkm1
658            DO jj = 1, jpj     
659               DO ji = 1, jpi   
660                  zigma = zwsink2(ji,jj,jk+1) * zstep / fse3w(ji,jj,jk+1)
661                  zew   = zwsink2(ji,jj,jk+1)
662                  psinkflx(ji,jj,jk+1) = -zew * ( trn(ji,jj,jk,jp_tra) - 0.5 * ( 1 + zigma ) * zakz(ji,jj,jk) ) * zstep
663               END DO
664            END DO
665         END DO
666         !
667         ! Boundary conditions
668         psinkflx(:,:,1  ) = 0.e0
669         psinkflx(:,:,jpk) = 0.e0
670         
671         DO jk=1,jpkm1
672            DO jj = 1,jpj
673               DO ji = 1, jpi
674                  zflx = ( psinkflx(ji,jj,jk) - psinkflx(ji,jj,jk+1) ) / fse3t(ji,jj,jk)
675                  trn(ji,jj,jk,jp_tra) = trn(ji,jj,jk,jp_tra) + zflx
676               END DO
677            END DO
678         END DO
679
680      ENDDO
681
682      DO jk=1,jpkm1
683         DO jj = 1,jpj
684            DO ji = 1, jpi
685               zflx = ( psinkflx(ji,jj,jk) - psinkflx(ji,jj,jk+1) ) / fse3t(ji,jj,jk)
686               trb(ji,jj,jk,jp_tra) = trb(ji,jj,jk,jp_tra) + 2. * zflx
687            END DO
688         END DO
689      END DO
690
691      trn     (:,:,:,jp_tra) = trb(:,:,:,jp_tra)
692      psinkflx(:,:,:)        = 2. * psinkflx(:,:,:)
693      !
694      IF( wrk_not_released(3, 2,3,4) )   CALL ctl_stop('p4z_sink2: failed to release workspace arrays')
695      !
696   END SUBROUTINE p4z_sink2
697
698
699   INTEGER FUNCTION p4z_sink_alloc()
700      !!----------------------------------------------------------------------
701      !!                     ***  ROUTINE p4z_sink_alloc  ***
702      !!----------------------------------------------------------------------
703      ALLOCATE( wsbio3 (jpi,jpj,jpk) , wsbio4  (jpi,jpj,jpk) , wscal(jpi,jpj,jpk) ,     &
704         &      sinking(jpi,jpj,jpk) , sinking2(jpi,jpj,jpk)                      ,     &               
705         &      sinkcal(jpi,jpj,jpk) , sinksil (jpi,jpj,jpk)                      ,     &               
706#if defined key_kriest
707         &      xnumm(jpk)                                                        ,     &               
708#else
709         &      sinkfer2(jpi,jpj,jpk)                                             ,     &               
710#endif
711         &      sinkfer(jpi,jpj,jpk)                                              , STAT=p4z_sink_alloc )               
712         !
713      IF( p4z_sink_alloc /= 0 ) CALL ctl_warn('p4z_sink_alloc : failed to allocate arrays.')
714      !
715   END FUNCTION p4z_sink_alloc
716   
717#else
718   !!======================================================================
719   !!  Dummy module :                                   No PISCES bio-model
720   !!======================================================================
721CONTAINS
722   SUBROUTINE p4z_sink                    ! Empty routine
723   END SUBROUTINE p4z_sink
724#endif 
725
726   !!======================================================================
727END MODULE  p4zsink
Note: See TracBrowser for help on using the repository browser.