1 | MODULE dynldf_bilap |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE dynldf_bilap *** |
---|
4 | !! Ocean dynamics: lateral viscosity trend |
---|
5 | !!====================================================================== |
---|
6 | !! History : OPA ! 1990-09 (G. Madec) Original code |
---|
7 | !! 4.0 ! 1993-03 (M. Guyon) symetrical conditions (M. Guyon) |
---|
8 | !! 6.0 ! 1996-01 (G. Madec) statement function for e3 |
---|
9 | !! 8.0 ! 1997-07 (G. Madec) lbc calls |
---|
10 | !! NEMO 1.0 ! 2002-08 (G. Madec) F90: Free form and module |
---|
11 | !! 2.0 ! 2004-08 (C. Talandier) New trends organization |
---|
12 | !!---------------------------------------------------------------------- |
---|
13 | |
---|
14 | !!---------------------------------------------------------------------- |
---|
15 | !! dyn_ldf_bilap : update the momentum trend with the lateral diffusion |
---|
16 | !! using an iso-level bilaplacian operator |
---|
17 | !!---------------------------------------------------------------------- |
---|
18 | USE oce ! ocean dynamics and tracers |
---|
19 | USE dom_oce ! ocean space and time domain |
---|
20 | USE ldfdyn_oce ! ocean dynamics: lateral physics |
---|
21 | USE in_out_manager ! I/O manager |
---|
22 | USE trdmod ! ocean dynamics trends |
---|
23 | USE trdmod_oce ! ocean variables trends |
---|
24 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
---|
25 | |
---|
26 | IMPLICIT NONE |
---|
27 | PRIVATE |
---|
28 | |
---|
29 | PUBLIC dyn_ldf_bilap ! called by step.F90 |
---|
30 | |
---|
31 | !! * Substitutions |
---|
32 | # include "domzgr_substitute.h90" |
---|
33 | # include "ldfdyn_substitute.h90" |
---|
34 | # include "vectopt_loop_substitute.h90" |
---|
35 | !!---------------------------------------------------------------------- |
---|
36 | !! NEMO/OPA 3.3 , NEMO Consortium (2010) |
---|
37 | !! $Id$ |
---|
38 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
---|
39 | !!---------------------------------------------------------------------- |
---|
40 | CONTAINS |
---|
41 | |
---|
42 | SUBROUTINE dyn_ldf_bilap( kt ) |
---|
43 | !!---------------------------------------------------------------------- |
---|
44 | !! *** ROUTINE dyn_ldf_bilap *** |
---|
45 | !! |
---|
46 | !! ** Purpose : Compute the before trend of the lateral momentum |
---|
47 | !! diffusion and add it to the general trend of momentum equation. |
---|
48 | !! |
---|
49 | !! ** Method : The before horizontal momentum diffusion trend is a |
---|
50 | !! bi-harmonic operator (bilaplacian type) which separates the |
---|
51 | !! divergent and rotational parts of the flow. |
---|
52 | !! Its horizontal components are computed as follow: |
---|
53 | !! laplacian: |
---|
54 | !! zlu = 1/e1u di[ hdivb ] - 1/(e2u*e3u) dj-1[ e3f rotb ] |
---|
55 | !! zlv = 1/e2v dj[ hdivb ] + 1/(e1v*e3v) di-1[ e3f rotb ] |
---|
56 | !! third derivative: |
---|
57 | !! * multiply by the eddy viscosity coef. at u-, v-point, resp. |
---|
58 | !! zlu = ahmu * zlu |
---|
59 | !! zlv = ahmv * zlv |
---|
60 | !! * curl and divergence of the laplacian |
---|
61 | !! zuf = 1/(e1f*e2f) ( di[e2v zlv] - dj[e1u zlu] ) |
---|
62 | !! zut = 1/(e1t*e2t*e3t) ( di[e2u*e3u zlu] + dj[e1v*e3v zlv] ) |
---|
63 | !! bilaplacian: |
---|
64 | !! diffu = 1/e1u di[ zut ] - 1/(e2u*e3u) dj-1[ e3f zuf ] |
---|
65 | !! diffv = 1/e2v dj[ zut ] + 1/(e1v*e3v) di-1[ e3f zuf ] |
---|
66 | !! If ln_sco=F and ln_zps=F, the vertical scale factors in the |
---|
67 | !! rotational part of the diffusion are simplified |
---|
68 | !! Add this before trend to the general trend (ua,va): |
---|
69 | !! (ua,va) = (ua,va) + (diffu,diffv) |
---|
70 | !! 'key_trddyn' defined: the two components of the horizontal |
---|
71 | !! diffusion trend are saved. |
---|
72 | !! |
---|
73 | !! ** Action : - Update (ua,va) with the before iso-level biharmonic |
---|
74 | !! mixing trend. |
---|
75 | !!---------------------------------------------------------------------- |
---|
76 | USE wrk_nemo, ONLY: wrk_in_use, wrk_not_released |
---|
77 | USE wrk_nemo, ONLY: zcu => wrk_2d_1 , zcv => wrk_2d_2 ! 3D workspace |
---|
78 | USE wrk_nemo, ONLY: zuf => wrk_3d_3 , zut => wrk_3d_4 ! 3D workspace |
---|
79 | USE wrk_nemo, ONLY: zlu => wrk_3d_5 , zlv => wrk_3d_6 |
---|
80 | ! |
---|
81 | INTEGER, INTENT(in) :: kt ! ocean time-step index |
---|
82 | ! |
---|
83 | INTEGER :: ji, jj, jk ! dummy loop indices |
---|
84 | REAL(wp) :: zua, zva, zbt, ze2u, ze2v ! temporary scalar |
---|
85 | !!---------------------------------------------------------------------- |
---|
86 | |
---|
87 | IF( wrk_in_use(2, 1,2) .OR. wrk_in_use(3, 3,4,5,6) ) THEN |
---|
88 | CALL ctl_stop('dyn_ldf_bilap : requested workspace arrays unavailable') ; RETURN |
---|
89 | ENDIF |
---|
90 | |
---|
91 | IF( kt == nit000 .AND. lwp ) THEN |
---|
92 | WRITE(numout,*) |
---|
93 | WRITE(numout,*) 'dyn_ldf_bilap : iso-level bilaplacian operator' |
---|
94 | WRITE(numout,*) '~~~~~~~~~~~~~' |
---|
95 | ENDIF |
---|
96 | |
---|
97 | !!bug gm this should be enough |
---|
98 | !!$ zuf(:,:,jpk) = 0.e0 |
---|
99 | !!$ zut(:,:,jpk) = 0.e0 |
---|
100 | !!$ zlu(:,:,jpk) = 0.e0 |
---|
101 | !!$ zlv(:,:,jpk) = 0.e0 |
---|
102 | zuf(:,:,:) = 0._wp |
---|
103 | zut(:,:,:) = 0._wp |
---|
104 | zlu(:,:,:) = 0._wp |
---|
105 | zlv(:,:,:) = 0._wp |
---|
106 | |
---|
107 | ! ! =============== |
---|
108 | DO jk = 1, jpkm1 ! Horizontal slab |
---|
109 | ! ! =============== |
---|
110 | ! Laplacian |
---|
111 | ! --------- |
---|
112 | |
---|
113 | IF( ln_sco .OR. ln_zps ) THEN ! s-coordinate or z-coordinate with partial steps |
---|
114 | zuf(:,:,jk) = rotb(:,:,jk) * fse3f(:,:,jk) |
---|
115 | DO jj = 2, jpjm1 |
---|
116 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
117 | zlu(ji,jj,jk) = - ( zuf(ji,jj,jk) - zuf(ji,jj-1,jk) ) / ( e2u(ji,jj) * fse3u(ji,jj,jk) ) & |
---|
118 | & + ( hdivb(ji+1,jj,jk) - hdivb(ji,jj,jk) ) / e1u(ji,jj) |
---|
119 | |
---|
120 | zlv(ji,jj,jk) = + ( zuf(ji,jj,jk) - zuf(ji-1,jj,jk) ) / ( e1v(ji,jj) * fse3v(ji,jj,jk) ) & |
---|
121 | & + ( hdivb(ji,jj+1,jk) - hdivb(ji,jj,jk) ) / e2v(ji,jj) |
---|
122 | END DO |
---|
123 | END DO |
---|
124 | ELSE ! z-coordinate - full step |
---|
125 | DO jj = 2, jpjm1 |
---|
126 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
127 | zlu(ji,jj,jk) = - ( rotb (ji ,jj,jk) - rotb (ji,jj-1,jk) ) / e2u(ji,jj) & |
---|
128 | & + ( hdivb(ji+1,jj,jk) - hdivb(ji,jj ,jk) ) / e1u(ji,jj) |
---|
129 | |
---|
130 | zlv(ji,jj,jk) = + ( rotb (ji,jj ,jk) - rotb (ji-1,jj,jk) ) / e1v(ji,jj) & |
---|
131 | & + ( hdivb(ji,jj+1,jk) - hdivb(ji ,jj,jk) ) / e2v(ji,jj) |
---|
132 | END DO |
---|
133 | END DO |
---|
134 | ENDIF |
---|
135 | END DO |
---|
136 | CALL lbc_lnk( zlu, 'U', -1. ) ; CALL lbc_lnk( zlv, 'V', -1. ) ! Boundary conditions |
---|
137 | |
---|
138 | |
---|
139 | DO jk = 1, jpkm1 |
---|
140 | |
---|
141 | ! Third derivative |
---|
142 | ! ---------------- |
---|
143 | |
---|
144 | ! Multiply by the eddy viscosity coef. (at u- and v-points) |
---|
145 | zlu(:,:,jk) = zlu(:,:,jk) * fsahmu(:,:,jk) |
---|
146 | zlv(:,:,jk) = zlv(:,:,jk) * fsahmv(:,:,jk) |
---|
147 | |
---|
148 | ! Contravariant "laplacian" |
---|
149 | zcu(:,:) = e1u(:,:) * zlu(:,:,jk) |
---|
150 | zcv(:,:) = e2v(:,:) * zlv(:,:,jk) |
---|
151 | |
---|
152 | ! Laplacian curl ( * e3f if s-coordinates or z-coordinate with partial steps) |
---|
153 | DO jj = 1, jpjm1 |
---|
154 | DO ji = 1, fs_jpim1 ! vector opt. |
---|
155 | zuf(ji,jj,jk) = fmask(ji,jj,jk) * ( zcv(ji+1,jj ) - zcv(ji,jj) & |
---|
156 | & - zcu(ji ,jj+1) + zcu(ji,jj) ) & |
---|
157 | & * fse3f(ji,jj,jk) / ( e1f(ji,jj)*e2f(ji,jj) ) |
---|
158 | END DO |
---|
159 | END DO |
---|
160 | |
---|
161 | ! Laplacian Horizontal fluxes |
---|
162 | DO jj = 1, jpjm1 |
---|
163 | DO ji = 1, fs_jpim1 ! vector opt. |
---|
164 | zlu(ji,jj,jk) = e2u(ji,jj) * fse3u(ji,jj,jk) * zlu(ji,jj,jk) |
---|
165 | zlv(ji,jj,jk) = e1v(ji,jj) * fse3v(ji,jj,jk) * zlv(ji,jj,jk) |
---|
166 | END DO |
---|
167 | END DO |
---|
168 | |
---|
169 | ! Laplacian divergence |
---|
170 | DO jj = 2, jpj |
---|
171 | DO ji = fs_2, jpi ! vector opt. |
---|
172 | zbt = e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) |
---|
173 | zut(ji,jj,jk) = ( zlu(ji,jj,jk) - zlu(ji-1,jj ,jk) & |
---|
174 | & + zlv(ji,jj,jk) - zlv(ji ,jj-1,jk) ) / zbt |
---|
175 | END DO |
---|
176 | END DO |
---|
177 | END DO |
---|
178 | |
---|
179 | |
---|
180 | ! boundary conditions on the laplacian curl and div (zuf,zut) |
---|
181 | !!bug gm no need to do this 2 following lbc... |
---|
182 | CALL lbc_lnk( zuf, 'F', 1. ) |
---|
183 | CALL lbc_lnk( zut, 'T', 1. ) |
---|
184 | |
---|
185 | DO jk = 1, jpkm1 |
---|
186 | |
---|
187 | ! Bilaplacian |
---|
188 | ! ----------- |
---|
189 | |
---|
190 | DO jj = 2, jpjm1 |
---|
191 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
192 | ze2u = e2u(ji,jj) * fse3u(ji,jj,jk) |
---|
193 | ze2v = e1v(ji,jj) * fse3v(ji,jj,jk) |
---|
194 | ! horizontal biharmonic diffusive trends |
---|
195 | zua = - ( zuf(ji ,jj,jk) - zuf(ji,jj-1,jk) ) / ze2u & |
---|
196 | & + ( zut(ji+1,jj,jk) - zut(ji,jj ,jk) ) / e1u(ji,jj) |
---|
197 | |
---|
198 | zva = + ( zuf(ji,jj ,jk) - zuf(ji-1,jj,jk) ) / ze2v & |
---|
199 | & + ( zut(ji,jj+1,jk) - zut(ji ,jj,jk) ) / e2v(ji,jj) |
---|
200 | ! add it to the general momentum trends |
---|
201 | ua(ji,jj,jk) = ua(ji,jj,jk) + zua |
---|
202 | va(ji,jj,jk) = va(ji,jj,jk) + zva |
---|
203 | END DO |
---|
204 | END DO |
---|
205 | |
---|
206 | ! ! =============== |
---|
207 | END DO ! End of slab |
---|
208 | ! ! =============== |
---|
209 | IF( wrk_not_released(2, 1,2) .OR. & |
---|
210 | wrk_not_released(3, 3,4,5,6) ) CALL ctl_stop('dyn_ldf_bilap: failed to release workspace arrays') |
---|
211 | ! |
---|
212 | END SUBROUTINE dyn_ldf_bilap |
---|
213 | |
---|
214 | !!====================================================================== |
---|
215 | END MODULE dynldf_bilap |
---|