New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zlim.F90 in branches/2011/dev_r2787_PISCES_improvment/NEMOGCM/NEMO/TOP_SRC/PISCES – NEMO

source: branches/2011/dev_r2787_PISCES_improvment/NEMOGCM/NEMO/TOP_SRC/PISCES/p4zlim.F90 @ 2823

Last change on this file since 2823 was 2823, checked in by cetlod, 13 years ago

Add new parameterisation in PISCES, see ticket #854
  • Property svn:keywords set to Id
File size: 12.6 KB
Line 
1MODULE p4zlim
2   !!======================================================================
3   !!                         ***  MODULE p4zlim  ***
4   !! TOP :   PISCES
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-04  (O. Aumont, C. Ethe) Limitation for iron modelled in quota
9   !!----------------------------------------------------------------------
10#if defined key_pisces
11   !!----------------------------------------------------------------------
12   !!   'key_pisces'                                       PISCES bio-model
13   !!----------------------------------------------------------------------
14   !!   p4z_lim        :   Compute the nutrients limitation terms
15   !!   p4z_lim_init   :   Read the namelist
16   !!----------------------------------------------------------------------
17   USE oce_trc         ! Shared ocean-passive tracers variables
18   USE trc             ! Tracers defined
19   USE sms_pisces      ! PISCES variables
20   USE p4zopt          ! Optical
21
22   IMPLICIT NONE
23   PRIVATE
24
25   PUBLIC p4z_lim   
26   PUBLIC p4z_lim_init   
27
28   !! * Shared module variables
29   REAL(wp), PUBLIC ::  conc0     = 2.e-6_wp      !:  NO3, PO4 half saturation   
30   REAL(wp), PUBLIC ::  conc1     = 8.e-6_wp      !:  Phosphate half saturation for diatoms 
31   REAL(wp), PUBLIC ::  conc2     = 1.e-9_wp      !:  Iron half saturation for nanophyto
32   REAL(wp), PUBLIC ::  conc2m    = 3.e-9_wp      !:  Max iron half saturation for nanophyto
33   REAL(wp), PUBLIC ::  conc3     = 2.e-9_wp      !:  Iron half saturation for diatoms 
34   REAL(wp), PUBLIC ::  conc3m    = 8.e-9_wp      !:  Max iron half saturation for diatoms
35   REAL(wp), PUBLIC ::  concnnh4  = 1.e-7_wp      !:  NH4 half saturation for phyto 
36   REAL(wp), PUBLIC ::  concdnh4  = 4.e-7_wp      !:  NH4 half saturation for diatoms
37   REAL(wp), PUBLIC ::  xksi1     = 2.E-6_wp      !:  half saturation constant for Si uptake
38   REAL(wp), PUBLIC ::  xksi2     = 3.33e-6_wp    !:  half saturation constant for Si/C
39   REAL(wp), PUBLIC ::  xkdoc     = 417.e-6_wp    !:  2nd half-sat. of DOC remineralization 
40   REAL(wp), PUBLIC ::  concfebac = 1.E-11_wp     !:  Fe half saturation for bacteria
41   REAL(wp), PUBLIC ::  qnfelim   = 7.E-6_wp      !:  optimal Fe quota for nanophyto
42   REAL(wp), PUBLIC ::  qdfelim   = 7.E-6_wp      !:  optimal Fe quota for diatoms
43   REAL(wp), PUBLIC ::  caco3r    = 0.16_wp       !:  mean rainratio
44
45   ! Coefficient for iron limitation
46!   REAL(wp) ::  xcoef1   = 0.0016
47!   REAL(wp) ::  xcoef2   = 1.21E-5 * 1.5
48!   REAL(wp) ::  xcoef3   = 1.15E-4 / 7.625 /  55.85
49   REAL(wp) ::  xcoef1   = 0.0016  / 55.85 
50   REAL(wp) ::  xcoef2   = 1.21E-5 * 14. / 55.85 / 7.625 * 0.5 * 1.5
51   REAL(wp) ::  xcoef3   = 1.15E-4 * 14. / 55.85 / 7.625 * 0.5 
52   !!* Substitution
53#  include "top_substitute.h90"
54   !!----------------------------------------------------------------------
55   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
56   !! $Id$
57   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
58   !!----------------------------------------------------------------------
59
60CONTAINS
61
62   SUBROUTINE p4z_lim( kt )
63      !!---------------------------------------------------------------------
64      !!                     ***  ROUTINE p4z_lim  ***
65      !!
66      !! ** Purpose :   Compute the co-limitations by the various nutrients
67      !!              for the various phytoplankton species
68      !!
69      !! ** Method  : - ???
70      !!---------------------------------------------------------------------
71      !
72      INTEGER, INTENT(in)  :: kt
73      !
74      INTEGER  ::   ji, jj, jk
75      REAL(wp) ::   zlim1, zlim2, zlim3, zlim4, zno3, zferlim
76      REAL(wp) ::   zconcd, zconcd2, zconcn, zconcn2
77      REAL(wp) ::   z1_trndia, z1_trnphy, ztem1, ztem2, zetot1, zetot2
78      REAL(wp) ::   zdenom, zratio, zironmin
79      REAL(wp) ::   zconc1d, zconc1dnh4, zconc0n, zconc0nnh4   
80      !!---------------------------------------------------------------------
81
82      DO jk = 1, jpkm1
83         DO jj = 1, jpj
84            DO ji = 1, jpi
85               
86               ! Tuning of the iron concentration to a minimum level that is set to the detection limit
87               !-------------------------------------
88               zno3    = trn(ji,jj,jk,jpno3) / 40.e-6
89               zferlim = MAX( 2e-11 * zno3 * zno3, 5e-12 )
90               zferlim = MIN( zferlim, 3e-11 )
91               trn(ji,jj,jk,jpfer) = MAX( trn(ji,jj,jk,jpfer), zferlim )
92
93               ! Computation of a variable Ks for iron on diatoms taking into account
94               ! that increasing biomass is made of generally bigger cells
95               !------------------------------------------------
96               zconcd   = MAX( 0.e0 , trn(ji,jj,jk,jpdia) - 5.e-7 )
97               zconcd2  = trn(ji,jj,jk,jpdia) - zconcd
98               zconcn   = MAX( 0.e0 , trn(ji,jj,jk,jpphy) - 1.e-6 )
99               zconcn2  = trn(ji,jj,jk,jpphy) - zconcn
100               z1_trnphy   = 1. / ( trn(ji,jj,jk,jpphy) + rtrn )
101               z1_trndia   = 1. / ( trn(ji,jj,jk,jpdia) + rtrn )
102
103               concdfe(ji,jj,jk) = MAX( conc3       , ( zconcd2 *      conc3    + conc3m        * zconcd ) * z1_trndia )
104               zconc1d           = MAX( 2.* conc0   , ( zconcd2 * 2. * conc0    + conc1         * zconcd ) * z1_trndia )
105               zconc1dnh4        = MAX( 2.* concnnh4, ( zconcd2 * 2. * concnnh4 + concdnh4      * zconcd ) * z1_trndia )
106
107               concnfe(ji,jj,jk) = MAX( conc2       , ( zconcn2 * conc2         + conc2m        * zconcn ) * z1_trnphy )
108               zconc0n           = MAX( conc0       , ( zconcn2 * conc0         + 2. * conc0    * zconcn ) * z1_trnphy )
109               zconc0nnh4        = MAX( concnnh4    , ( zconcn2 * concnnh4      + 2. * concnnh4 * zconcn ) * z1_trnphy )
110
111               ! Michaelis-Menten Limitation term for nutrients Small flagellates
112               ! -----------------------------------------------
113               zdenom = 1. /  ( zconc0n * zconc0nnh4 + zconc0nnh4 * trn(ji,jj,jk,jpno3) + zconc0n * trn(ji,jj,jk,jpnh4) )
114               xnanono3(ji,jj,jk) = trn(ji,jj,jk,jpno3) * zconc0nnh4 * zdenom
115               xnanonh4(ji,jj,jk) = trn(ji,jj,jk,jpnh4) * zconc0n    * zdenom
116               !
117               zlim1    = xnanono3(ji,jj,jk) + xnanonh4(ji,jj,jk)
118               zlim2    = trn(ji,jj,jk,jppo4) / ( trn(ji,jj,jk,jppo4) + zconc0nnh4 )
119               zratio   = trn(ji,jj,jk,jpnfe) * z1_trnphy 
120               zironmin = xcoef1 * trn(ji,jj,jk,jpnch) * z1_trnphy + xcoef2 * zlim1 + xcoef3 * xnanono3(ji,jj,jk)
121               zlim3    = MAX( 0.,( zratio - zironmin ) / qnfelim )
122               xlimnfe(ji,jj,jk) = MIN( 1., zlim3 )
123               xlimphy(ji,jj,jk) = MIN( zlim1, zlim2, zlim3 )
124               !
125               zlim1    = trn(ji,jj,jk,jpnh4) / ( concnnh4 + trn(ji,jj,jk,jpnh4) )
126               zlim3    = trn(ji,jj,jk,jpfer) / ( concfebac+ trn(ji,jj,jk,jpfer) )
127               zlim4    = trn(ji,jj,jk,jpdoc) / ( xkdoc   + trn(ji,jj,jk,jpdoc) )
128               xlimbac(ji,jj,jk) = MIN( zlim1, zlim2, zlim3 ) * zlim4
129
130               !   Michaelis-Menten Limitation term for nutrients Diatoms
131               !   ----------------------------------------------
132               zdenom   = 1. / ( zconc1d * zconc1dnh4 + zconc1dnh4 * trn(ji,jj,jk,jpno3) + zconc1d * trn(ji,jj,jk,jpnh4) )
133               xdiatno3(ji,jj,jk) = trn(ji,jj,jk,jpno3) * zconc1dnh4 * zdenom
134               xdiatnh4(ji,jj,jk) = trn(ji,jj,jk,jpnh4) * zconc1d    * zdenom
135               !
136               zlim1    = xdiatno3(ji,jj,jk) + xdiatnh4(ji,jj,jk)
137               zlim2    = trn(ji,jj,jk,jppo4) / ( trn(ji,jj,jk,jppo4) + zconc1dnh4  )
138               zlim3    = trn(ji,jj,jk,jpsil) / ( trn(ji,jj,jk,jpsil) + xksi(ji,jj) )
139               zratio   = trn(ji,jj,jk,jpdfe)/(trn(ji,jj,jk,jpdia)+rtrn)
140               zironmin = xcoef1 * trn(ji,jj,jk,jpdch) * z1_trndia + xcoef2 * zlim1 + xcoef3 * xdiatno3(ji,jj,jk)
141               zlim4    = MAX( 0., ( zratio - zironmin ) / qdfelim )
142               xlimdfe(ji,jj,jk) = MIN( 1., zlim4 )
143               xlimdia(ji,jj,jk) = MIN( zlim1, zlim2, zlim3, zlim4 )
144               xlimsi(ji,jj,jk)  = MIN( zlim1, zlim2, zlim4 )
145           END DO
146         END DO
147      END DO
148
149      ! Compute the fraction of nanophytoplankton that is made of calcifiers
150      ! --------------------------------------------------------------------
151      DO jk = 1, jpkm1
152         DO jj = 1, jpj
153            DO ji = 1, jpi
154               zlim1 =  ( trn(ji,jj,jk,jpno3) * concnnh4 + trn(ji,jj,jk,jpnh4) * conc0 )    &
155                  &   / ( conc0 * concnnh4 + concnnh4 * trn(ji,jj,jk,jpno3)  + conc0 * trn(ji,jj,jk,jpnh4) ) 
156               zlim2  = trn(ji,jj,jk,jppo4) / ( trn(ji,jj,jk,jppo4) + concnnh4 )
157               zlim3  = trn(ji,jj,jk,jpfer) / ( trn(ji,jj,jk,jpfer) + concfebac )
158               ztem1  = MAX( 0., tsn(ji,jj,jk,jp_tem) )
159               ztem2  = tsn(ji,jj,jk,jp_tem) - 10.
160               zetot1 = MAX( 0., etot(ji,jj,jk) - 1.) / ( 4. + etot(ji,jj,jk) ) 
161               zetot2 = 1. / ( 30. + etot(ji,jj,jk) ) 
162
163               xfracal(ji,jj,jk) = caco3r * MIN( zlim1, zlim2, zlim3 )                  &
164                  &                       * ztem1 / ( 0.1 + ztem1 )                     &
165                  &                       * MAX( 1., trn(ji,jj,jk,jpphy) * 1.e6 / 2. )  &
166                  &                       * 2.325 * zetot1 * 30. * zetot2               &
167                  &                       * ( 1. + EXP(-ztem2 * ztem2 / 25. ) )         &
168                  &                       * MIN( 1., 50. / ( hmld(ji,jj) + rtrn ) )
169               xfracal(ji,jj,jk) = MIN( 0.8 , xfracal(ji,jj,jk) )
170               xfracal(ji,jj,jk) = MAX( 0.02, xfracal(ji,jj,jk) )
171            END DO
172         END DO
173      END DO
174      !
175   END SUBROUTINE p4z_lim
176
177   SUBROUTINE p4z_lim_init
178
179      !!----------------------------------------------------------------------
180      !!                  ***  ROUTINE p4z_lim_init  ***
181      !!
182      !! ** Purpose :   Initialization of nutrient limitation parameters
183      !!
184      !! ** Method  :   Read the nampislim namelist and check the parameters
185      !!      called at the first timestep (nit000)
186      !!
187      !! ** input   :   Namelist nampislim
188      !!
189      !!----------------------------------------------------------------------
190
191      NAMELIST/nampislim/ conc0, conc1, conc2, conc2m, conc3, conc3m,   &
192         &                concnnh4, concdnh4, xksi1, xksi2, xkdoc,      &
193         &                concfebac, qnfelim, qdfelim, caco3r
194
195      REWIND( numnatp )                     ! read numnat
196      READ  ( numnatp, nampislim )
197
198      IF(lwp) THEN                         ! control print
199         WRITE(numout,*) ' '
200         WRITE(numout,*) ' Namelist parameters for nutrient limitations, nampislim'
201         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
202         WRITE(numout,*) '    mean rainratio                            caco3r    =', caco3r
203         WRITE(numout,*) '    NO3, PO4 half saturation                  conc0     =', conc0
204         WRITE(numout,*) '    half saturation constant for Si uptake    xksi1     =', xksi1
205         WRITE(numout,*) '    half saturation constant for Si/C         xksi2     =', xksi2
206         WRITE(numout,*) '    2nd half-sat. of DOC remineralization     xkdoc     =', xkdoc
207         WRITE(numout,*) '    Phosphate half saturation for diatoms     conc1     =', conc1
208         WRITE(numout,*) '    Iron half saturation for phyto            conc2     =', conc2
209         WRITE(numout,*) '    Max iron half saturation for phyto        conc2m    =', conc2m
210         WRITE(numout,*) '    Iron half saturation for diatoms          conc3     =', conc3
211         WRITE(numout,*) '    Maxi iron half saturation for diatoms     conc3m    =', conc3m
212         WRITE(numout,*) '    NH4 half saturation for phyto             concnnh4  =', concnnh4
213         WRITE(numout,*) '    NH4 half saturation for diatoms           concdnh4  =', concdnh4
214         WRITE(numout,*) '    Fe half saturation for bacteria           concfebac =', concfebac
215         WRITE(numout,*) '    optimal Fe quota for nano.                qnfelim   =', qnfelim
216         WRITE(numout,*) '    Optimal Fe quota for diatoms              qdfelim   =', qdfelim
217      ENDIF
218
219   END SUBROUTINE p4z_lim_init
220
221#else
222   !!======================================================================
223   !!  Dummy module :                                   No PISCES bio-model
224   !!======================================================================
225CONTAINS
226   SUBROUTINE p4z_lim                   ! Empty routine
227   END SUBROUTINE p4z_lim
228#endif 
229
230   !!======================================================================
231END MODULE  p4zlim
Note: See TracBrowser for help on using the repository browser.