New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_tvd.F90 in branches/2011/dev_r2802_TOP_substepping/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2011/dev_r2802_TOP_substepping/NEMOGCM/NEMO/OPA_SRC/TRA/traadv_tvd.F90 @ 2830

Last change on this file since 2830 was 2830, checked in by kpedwards, 13 years ago

Updates to average physics variables for TOP substepping.
  • Property svn:keywords set to Id
File size: 18.2 KB
Line 
1MODULE traadv_tvd
2   !!==============================================================================
3   !!                       ***  MODULE  traadv_tvd  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend
5   !!==============================================================================
6   !! History :  OPA  !  1995-12  (L. Mortier)  Original code
7   !!                 !  2000-01  (H. Loukos)  adapted to ORCA
8   !!                 !  2000-10  (MA Foujols E.Kestenare)  include file not routine
9   !!                 !  2000-12  (E. Kestenare M. Levy)  fix bug in trtrd indexes
10   !!                 !  2001-07  (E. Durand G. Madec)  adaptation to ORCA config
11   !!            8.5  !  2002-06  (G. Madec)  F90: Free form and module
12   !!    NEMO    1.0  !  2004-01  (A. de Miranda, G. Madec, J.M. Molines ): advective bbl
13   !!            2.0  !  2008-04  (S. Cravatte) add the i-, j- & k- trends computation
14   !!             -   !  2009-11  (V. Garnier) Surface pressure gradient organization
15   !!            3.3  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
16   !!----------------------------------------------------------------------
17
18   !!----------------------------------------------------------------------
19   !!   tra_adv_tvd  : update the tracer trend with the horizontal
20   !!                  and vertical advection trends using a TVD scheme
21   !!   nonosc       : compute monotonic tracer fluxes by a nonoscillatory
22   !!                  algorithm
23   !!----------------------------------------------------------------------
24   USE oce             ! ocean dynamics and active tracers
25   USE dom_oce         ! ocean space and time domain
26   USE trdmod_oce      ! tracers trends
27   USE trdtra          ! tracers trends
28   USE in_out_manager  ! I/O manager
29   USE dynspg_oce      ! choice/control of key cpp for surface pressure gradient
30   USE lib_mpp         ! MPP library
31   USE lbclnk          ! ocean lateral boundary condition (or mpp link)
32   USE diaptr          ! poleward transport diagnostics
33   USE trc_oce         ! share passive tracers/Ocean variables
34#if defined key_top
35   USE trc, ONLY: nittrc000  !get first time step for passive tracers
36#endif
37
38
39   IMPLICIT NONE
40   PRIVATE
41
42   PUBLIC   tra_adv_tvd    ! routine called by step.F90
43
44   LOGICAL ::   l_trd   ! flag to compute trends
45
46   !! * Substitutions
47#  include "domzgr_substitute.h90"
48#  include "vectopt_loop_substitute.h90"
49   !!----------------------------------------------------------------------
50   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
51   !! $Id$
52   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
53   !!----------------------------------------------------------------------
54CONTAINS
55
56   SUBROUTINE tra_adv_tvd ( kt, cdtype, p2dt, pun, pvn, pwn,      &
57      &                                       ptb, ptn, pta, kjpt )
58      !!----------------------------------------------------------------------
59      !!                  ***  ROUTINE tra_adv_tvd  ***
60      !!
61      !! **  Purpose :   Compute the now trend due to total advection of
62      !!       tracers and add it to the general trend of tracer equations
63      !!
64      !! **  Method  :   TVD scheme, i.e. 2nd order centered scheme with
65      !!       corrected flux (monotonic correction)
66      !!       note: - this advection scheme needs a leap-frog time scheme
67      !!
68      !! ** Action : - update (pta) with the now advective tracer trends
69      !!             - save the trends
70      !!----------------------------------------------------------------------
71      USE wrk_nemo, ONLY:   wrk_in_use, wrk_not_released
72      USE oce     , ONLY:   zwx => ua        , zwy => va          ! (ua,va) used as workspace
73      USE wrk_nemo, ONLY:   zwi => wrk_3d_12 , zwz => wrk_3d_13   ! 3D workspace
74      !
75      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
76      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
77      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
78      REAL(wp), DIMENSION(        jpk     ), INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
79      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
80      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb, ptn        ! before and now tracer fields
81      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
82      !
83      INTEGER  ::   ji, jj, jk, jn           ! dummy loop indices 
84      REAL(wp) ::   z2dtt, zbtr, ztra        ! local scalar
85      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk   !   -      -
86      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk   !   -      -
87      REAL(wp), DIMENSION (:,:,:), ALLOCATABLE ::   ztrdx, ztrdy, ztrdz
88      !!----------------------------------------------------------------------
89
90      IF( wrk_in_use(3, 12,13) ) THEN
91         CALL ctl_stop('tra_adv_tvd: requested workspace arrays unavailable')   ;   RETURN
92      ENDIF
93
94#if defined key_top
95      IF( kt == nit000 .OR. (kt == nittrc000 .AND. cdtype == 'TRC'))  THEN
96#else
97      IF( kt == nit000 )  THEN
98#endif
99         IF(lwp) WRITE(numout,*)
100         IF(lwp) WRITE(numout,*) 'tra_adv_tvd : TVD advection scheme on ', cdtype
101         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
102         !
103         l_trd = .FALSE.
104         IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) ) l_trd = .TRUE.
105      ENDIF
106      !
107      IF( l_trd )  THEN
108        ALLOCATE( ztrdx(jpi,jpj,jpk) )      ;      ztrdx(:,:,:) = 0.e0
109        ALLOCATE( ztrdy(jpi,jpj,jpk) )      ;      ztrdy(:,:,:) = 0.e0
110        ALLOCATE( ztrdz(jpi,jpj,jpk) )      ;      ztrdz(:,:,:) = 0.e0
111      END IF
112      !
113      zwi(:,:,:) = 0.e0
114      !
115      !                                                          ! ===========
116      DO jn = 1, kjpt                                            ! tracer loop
117         !                                                       ! ===========
118         ! 1. Bottom value : flux set to zero
119         ! ----------------------------------
120         zwx(:,:,jpk) = 0.e0    ;    zwz(:,:,jpk) = 0.e0
121         zwy(:,:,jpk) = 0.e0    ;    zwi(:,:,jpk) = 0.e0
122
123         ! 2. upstream advection with initial mass fluxes & intermediate update
124         ! --------------------------------------------------------------------
125         ! upstream tracer flux in the i and j direction
126         DO jk = 1, jpkm1
127            DO jj = 1, jpjm1
128               DO ji = 1, fs_jpim1   ! vector opt.
129                  ! upstream scheme
130                  zfp_ui = pun(ji,jj,jk) + ABS( pun(ji,jj,jk) )
131                  zfm_ui = pun(ji,jj,jk) - ABS( pun(ji,jj,jk) )
132                  zfp_vj = pvn(ji,jj,jk) + ABS( pvn(ji,jj,jk) )
133                  zfm_vj = pvn(ji,jj,jk) - ABS( pvn(ji,jj,jk) )
134                  zwx(ji,jj,jk) = 0.5 * ( zfp_ui * ptb(ji,jj,jk,jn) + zfm_ui * ptb(ji+1,jj  ,jk,jn) )
135                  zwy(ji,jj,jk) = 0.5 * ( zfp_vj * ptb(ji,jj,jk,jn) + zfm_vj * ptb(ji  ,jj+1,jk,jn) )
136               END DO
137            END DO
138         END DO
139
140         ! upstream tracer flux in the k direction
141         ! Surface value
142         IF( lk_vvl ) THEN   ;   zwz(:,:, 1 ) = 0.e0                         ! volume variable
143         ELSE                ;   zwz(:,:, 1 ) = pwn(:,:,1) * ptb(:,:,1,jn)   ! linear free surface
144         ENDIF
145         ! Interior value
146         DO jk = 2, jpkm1
147            DO jj = 1, jpj
148               DO ji = 1, jpi
149                  zfp_wk = pwn(ji,jj,jk) + ABS( pwn(ji,jj,jk) )
150                  zfm_wk = pwn(ji,jj,jk) - ABS( pwn(ji,jj,jk) )
151                  zwz(ji,jj,jk) = 0.5 * ( zfp_wk * ptb(ji,jj,jk,jn) + zfm_wk * ptb(ji,jj,jk-1,jn) )
152               END DO
153            END DO
154         END DO
155
156         ! total advective trend
157         DO jk = 1, jpkm1
158            z2dtt = p2dt(jk)
159            DO jj = 2, jpjm1
160               DO ji = fs_2, fs_jpim1   ! vector opt.
161                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
162                  ! total intermediate advective trends
163                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
164                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
165                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
166                  ! update and guess with monotonic sheme
167                  pta(ji,jj,jk,jn) =   pta(ji,jj,jk,jn)         + ztra
168                  zwi(ji,jj,jk)    = ( ptb(ji,jj,jk,jn) + z2dtt * ztra ) * tmask(ji,jj,jk)
169               END DO
170            END DO
171         END DO
172         !                             ! Lateral boundary conditions on zwi  (unchanged sign)
173         CALL lbc_lnk( zwi, 'T', 1. ) 
174
175         !                                 ! trend diagnostics (contribution of upstream fluxes)
176         IF( l_trd )  THEN 
177            ! store intermediate advective trends
178            ztrdx(:,:,:) = zwx(:,:,:)   ;    ztrdy(:,:,:) = zwy(:,:,:)  ;   ztrdz(:,:,:) = zwz(:,:,:)
179         END IF
180         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
181         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN 
182           IF( jn == jp_tem )  htr_adv(:) = ptr_vj( zwy(:,:,:) )
183           IF( jn == jp_sal )  str_adv(:) = ptr_vj( zwy(:,:,:) )
184         ENDIF
185
186         ! 3. antidiffusive flux : high order minus low order
187         ! --------------------------------------------------
188         ! antidiffusive flux on i and j
189         DO jk = 1, jpkm1
190            DO jj = 1, jpjm1
191               DO ji = 1, fs_jpim1   ! vector opt.
192                  zwx(ji,jj,jk) = 0.5 * pun(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj,jk,jn) ) - zwx(ji,jj,jk)
193                  zwy(ji,jj,jk) = 0.5 * pvn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj+1,jk,jn) ) - zwy(ji,jj,jk)
194               END DO
195            END DO
196         END DO
197     
198         ! antidiffusive flux on k
199         zwz(:,:,1) = 0.e0         ! Surface value
200         !
201         DO jk = 2, jpkm1          ! Interior value
202            DO jj = 1, jpj
203               DO ji = 1, jpi
204                  zwz(ji,jj,jk) = 0.5 * pwn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj,jk-1,jn) ) - zwz(ji,jj,jk)
205               END DO
206            END DO
207         END DO
208         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )         ! Lateral bondary conditions
209         CALL lbc_lnk( zwz, 'W',  1. )
210
211         ! 4. monotonicity algorithm
212         ! -------------------------
213         CALL nonosc( ptb(:,:,:,jn), zwx, zwy, zwz, zwi, p2dt )
214
215
216         ! 5. final trend with corrected fluxes
217         ! ------------------------------------
218         DO jk = 1, jpkm1
219            DO jj = 2, jpjm1
220               DO ji = fs_2, fs_jpim1   ! vector opt. 
221                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
222                  ! total advective trends
223                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
224                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
225                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
226                  ! add them to the general tracer trends
227                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
228               END DO
229            END DO
230         END DO
231
232         !                                 ! trend diagnostics (contribution of upstream fluxes)
233         IF( l_trd )  THEN
234            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< Add to previously computed
235            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  ! <<< Add to previously computed
236            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  ! <<< Add to previously computed
237           
238            CALL trd_tra( kt, cdtype, jn, jptra_trd_xad, ztrdx, pun, ptn(:,:,:,jn) )   
239            CALL trd_tra( kt, cdtype, jn, jptra_trd_yad, ztrdy, pvn, ptn(:,:,:,jn) ) 
240            CALL trd_tra( kt, cdtype, jn, jptra_trd_zad, ztrdz, pwn, ptn(:,:,:,jn) ) 
241         END IF
242         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
243         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN 
244           IF( jn == jp_tem )  htr_adv(:) = ptr_vj( zwy(:,:,:) ) + htr_adv(:)
245           IF( jn == jp_sal )  str_adv(:) = ptr_vj( zwy(:,:,:) ) + str_adv(:)
246         ENDIF
247         !
248      END DO
249      !
250      IF( l_trd )  THEN
251        DEALLOCATE( ztrdx )     ;     DEALLOCATE( ztrdy )     ;      DEALLOCATE( ztrdz ) 
252      END IF
253      !
254      IF( wrk_not_released(3, 12,13) )   CALL ctl_stop('tra_adv_tvd: failed to release workspace arrays')
255      !
256   END SUBROUTINE tra_adv_tvd
257
258
259   SUBROUTINE nonosc( pbef, paa, pbb, pcc, paft, p2dt )
260      !!---------------------------------------------------------------------
261      !!                    ***  ROUTINE nonosc  ***
262      !!     
263      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
264      !!       scheme and the before field by a nonoscillatory algorithm
265      !!
266      !! **  Method  :   ... ???
267      !!       warning : pbef and paft must be masked, but the boundaries
268      !!       conditions on the fluxes are not necessary zalezak (1979)
269      !!       drange (1995) multi-dimensional forward-in-time and upstream-
270      !!       in-space based differencing for fluid
271      !!----------------------------------------------------------------------
272      USE wrk_nemo, ONLY:   wrk_in_use, wrk_not_released
273      USE wrk_nemo, ONLY:   zbetup => wrk_3d_8  , zbetdo => wrk_3d_9    ! 3D workspace
274      USE wrk_nemo, ONLY:   zbup   => wrk_3d_10 , zbdo   => wrk_3d_11   !  -     -
275      !
276      REAL(wp), DIMENSION(jpk)         , INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
277      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(in   ) ::   pbef, paft      ! before & after field
278      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(inout) ::   paa, pbb, pcc   ! monotonic fluxes in the 3 directions
279      !
280      INTEGER ::   ji, jj, jk   ! dummy loop indices
281      INTEGER ::   ikm1         ! local integer
282      REAL(wp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn, z2dtt   ! local scalars
283      REAL(wp) ::   zau, zbu, zcu, zav, zbv, zcv, zup, zdo            !   -      -
284      !!----------------------------------------------------------------------
285
286      IF( wrk_in_use(3, 8,9,10,11) ) THEN
287         CALL ctl_stop('nonosc: requested workspace array unavailable')   ;   RETURN
288      ENDIF
289
290      zbig  = 1.e+40_wp
291      zrtrn = 1.e-15_wp
292      zbetup(:,:,jpk) = 0._wp   ;   zbetdo(:,:,jpk) = 0._wp
293
294
295      ! Search local extrema
296      ! --------------------
297      ! max/min of pbef & paft with large negative/positive value (-/+zbig) inside land
298      zbup = MAX( pbef * tmask - zbig * ( 1.e0 - tmask ),   &
299         &        paft * tmask - zbig * ( 1.e0 - tmask )  )
300      zbdo = MIN( pbef * tmask + zbig * ( 1.e0 - tmask ),   &
301         &        paft * tmask + zbig * ( 1.e0 - tmask )  )
302
303      DO jk = 1, jpkm1
304         ikm1 = MAX(jk-1,1)
305         z2dtt = p2dt(jk)
306         DO jj = 2, jpjm1
307            DO ji = fs_2, fs_jpim1   ! vector opt.
308
309               ! search maximum in neighbourhood
310               zup = MAX(  zbup(ji  ,jj  ,jk  ),   &
311                  &        zbup(ji-1,jj  ,jk  ), zbup(ji+1,jj  ,jk  ),   &
312                  &        zbup(ji  ,jj-1,jk  ), zbup(ji  ,jj+1,jk  ),   &
313                  &        zbup(ji  ,jj  ,ikm1), zbup(ji  ,jj  ,jk+1)  )
314
315               ! search minimum in neighbourhood
316               zdo = MIN(  zbdo(ji  ,jj  ,jk  ),   &
317                  &        zbdo(ji-1,jj  ,jk  ), zbdo(ji+1,jj  ,jk  ),   &
318                  &        zbdo(ji  ,jj-1,jk  ), zbdo(ji  ,jj+1,jk  ),   &
319                  &        zbdo(ji  ,jj  ,ikm1), zbdo(ji  ,jj  ,jk+1)  )
320
321               ! positive part of the flux
322               zpos = MAX( 0., paa(ji-1,jj  ,jk  ) ) - MIN( 0., paa(ji  ,jj  ,jk  ) )   &
323                  & + MAX( 0., pbb(ji  ,jj-1,jk  ) ) - MIN( 0., pbb(ji  ,jj  ,jk  ) )   &
324                  & + MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
325
326               ! negative part of the flux
327               zneg = MAX( 0., paa(ji  ,jj  ,jk  ) ) - MIN( 0., paa(ji-1,jj  ,jk  ) )   &
328                  & + MAX( 0., pbb(ji  ,jj  ,jk  ) ) - MIN( 0., pbb(ji  ,jj-1,jk  ) )   &
329                  & + MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
330
331               ! up & down beta terms
332               zbt = e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) / z2dtt
333               zbetup(ji,jj,jk) = ( zup            - paft(ji,jj,jk) ) / ( zpos + zrtrn ) * zbt
334               zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zdo            ) / ( zneg + zrtrn ) * zbt
335            END DO
336         END DO
337      END DO
338      CALL lbc_lnk( zbetup, 'T', 1. )   ;   CALL lbc_lnk( zbetdo, 'T', 1. )   ! lateral boundary cond. (unchanged sign)
339
340
341
342      ! 3. monotonic flux in the i & j direction (paa & pbb)
343      ! ----------------------------------------
344      DO jk = 1, jpkm1
345         DO jj = 2, jpjm1
346            DO ji = fs_2, fs_jpim1   ! vector opt.
347               zau = MIN( 1.e0, zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) )
348               zbu = MIN( 1.e0, zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) )
349               zcu =       ( 0.5  + SIGN( 0.5 , paa(ji,jj,jk) ) )
350               paa(ji,jj,jk) = paa(ji,jj,jk) * ( zcu * zau + ( 1.e0 - zcu) * zbu )
351
352               zav = MIN( 1.e0, zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) )
353               zbv = MIN( 1.e0, zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) )
354               zcv =       ( 0.5  + SIGN( 0.5 , pbb(ji,jj,jk) ) )
355               pbb(ji,jj,jk) = pbb(ji,jj,jk) * ( zcv * zav + ( 1.e0 - zcv) * zbv )
356
357      ! monotonic flux in the k direction, i.e. pcc
358      ! -------------------------------------------
359               za = MIN( 1., zbetdo(ji,jj,jk+1), zbetup(ji,jj,jk) )
360               zb = MIN( 1., zbetup(ji,jj,jk+1), zbetdo(ji,jj,jk) )
361               zc =       ( 0.5  + SIGN( 0.5 , pcc(ji,jj,jk+1) ) )
362               pcc(ji,jj,jk+1) = pcc(ji,jj,jk+1) * ( zc * za + ( 1.e0 - zc) * zb )
363            END DO
364         END DO
365      END DO
366      CALL lbc_lnk( paa, 'U', -1. )   ;   CALL lbc_lnk( pbb, 'V', -1. )   ! lateral boundary condition (changed sign)
367      !
368      IF( wrk_not_released(3, 8,9,10,11) )   CALL ctl_stop('nonosc: failed to release workspace arrays')
369      !
370   END SUBROUTINE nonosc
371
372   !!======================================================================
373END MODULE traadv_tvd
Note: See TracBrowser for help on using the repository browser.