New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_iso.F90 in branches/2011/dev_r2802_TOP_substepping/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2011/dev_r2802_TOP_substepping/NEMOGCM/NEMO/OPA_SRC/TRA/traldf_iso.F90 @ 2830

Last change on this file since 2830 was 2830, checked in by kpedwards, 13 years ago

Updates to average physics variables for TOP substepping.
  • Property svn:keywords set to Id
File size: 16.1 KB
Line 
1MODULE traldf_iso
2   !!======================================================================
3   !!                   ***  MODULE  traldf_iso  ***
4   !! Ocean  tracers:  horizontal component of the lateral tracer mixing trend
5   !!======================================================================
6   !! History :  OPA  !  1994-08  (G. Madec, M. Imbard)
7   !!            8.0  !  1997-05  (G. Madec)  split into traldf and trazdf
8   !!            NEMO !  2002-08  (G. Madec)  Free form, F90
9   !!            1.0  !  2005-11  (G. Madec)  merge traldf and trazdf :-)
10   !!            3.3  !  2010-09  (C. Ethe, G. Madec) Merge TRA-TRC
11   !!----------------------------------------------------------------------
12#if   defined key_ldfslp   ||   defined key_esopa
13   !!----------------------------------------------------------------------
14   !!   'key_ldfslp'               slope of the lateral diffusive direction
15   !!----------------------------------------------------------------------
16   !!   tra_ldf_iso  : update the tracer trend with the horizontal
17   !!                  component of a iso-neutral laplacian operator
18   !!                  and with the vertical part of
19   !!                  the isopycnal or geopotential s-coord. operator
20   !!----------------------------------------------------------------------
21   USE oce             ! ocean dynamics and active tracers
22   USE dom_oce         ! ocean space and time domain
23   USE trc_oce         ! share passive tracers/Ocean variables
24   USE zdf_oce         ! ocean vertical physics
25   USE ldftra_oce      ! ocean active tracers: lateral physics
26   USE ldfslp          ! iso-neutral slopes
27   USE diaptr          ! poleward transport diagnostics
28   USE in_out_manager  ! I/O manager
29   USE iom             ! I/O library
30#if defined key_diaar5
31   USE phycst          ! physical constants
32   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
33#endif
34#if defined key_top
35   USE trc, ONLY: nittrc000  !get first time step for passive tracers
36#endif
37
38   IMPLICIT NONE
39   PRIVATE
40
41   PUBLIC   tra_ldf_iso   ! routine called by step.F90
42
43   !! * Substitutions
44#  include "domzgr_substitute.h90"
45#  include "ldftra_substitute.h90"
46#  include "vectopt_loop_substitute.h90"
47   !!----------------------------------------------------------------------
48   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
49   !! $Id$
50   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
51   !!----------------------------------------------------------------------
52CONTAINS
53
54   SUBROUTINE tra_ldf_iso( kt, cdtype, pgu, pgv,              &
55      &                                ptb, pta, kjpt, pahtb0 )
56      !!----------------------------------------------------------------------
57      !!                  ***  ROUTINE tra_ldf_iso  ***
58      !!
59      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
60      !!      trend for a laplacian tensor (ezxcept the dz[ dz[.] ] term) and
61      !!      add it to the general trend of tracer equation.
62      !!
63      !! ** Method  :   The horizontal component of the lateral diffusive trends
64      !!      is provided by a 2nd order operator rotated along neural or geopo-
65      !!      tential surfaces to which an eddy induced advection can be added
66      !!      It is computed using before fields (forward in time) and isopyc-
67      !!      nal or geopotential slopes computed in routine ldfslp.
68      !!
69      !!      1st part :  masked horizontal derivative of T  ( di[ t ] )
70      !!      ========    with partial cell update if ln_zps=T.
71      !!
72      !!      2nd part :  horizontal fluxes of the lateral mixing operator
73      !!      ========   
74      !!         zftu = (aht+ahtb0) e2u*e3u/e1u di[ tb ]
75      !!               - aht       e2u*uslp    dk[ mi(mk(tb)) ]
76      !!         zftv = (aht+ahtb0) e1v*e3v/e2v dj[ tb ]
77      !!               - aht       e2u*vslp    dk[ mj(mk(tb)) ]
78      !!      take the horizontal divergence of the fluxes:
79      !!         difft = 1/(e1t*e2t*e3t) {  di-1[ zftu ] +  dj-1[ zftv ]  }
80      !!      Add this trend to the general trend (ta,sa):
81      !!         ta = ta + difft
82      !!
83      !!      3rd part: vertical trends of the lateral mixing operator
84      !!      ========  (excluding the vertical flux proportional to dk[t] )
85      !!      vertical fluxes associated with the rotated lateral mixing:
86      !!         zftw =-aht {  e2t*wslpi di[ mi(mk(tb)) ]
87      !!                     + e1t*wslpj dj[ mj(mk(tb)) ]  }
88      !!      take the horizontal divergence of the fluxes:
89      !!         difft = 1/(e1t*e2t*e3t) dk[ zftw ]
90      !!      Add this trend to the general trend (ta,sa):
91      !!         pta = pta + difft
92      !!
93      !! ** Action :   Update pta arrays with the before rotated diffusion
94      !!----------------------------------------------------------------------
95      USE wrk_nemo, ONLY:   wrk_in_use, wrk_not_released
96      USE oce     , ONLY:   zftu => ua       , zftv  => va         ! (ua,va) used as workspace
97      USE wrk_nemo, ONLY:   zdkt => wrk_2d_1 , zdk1t => wrk_2d_2 , z2d  => wrk_2d_3   ! 2D workspace
98      USE wrk_nemo, ONLY:   zdit => wrk_3d_6 , zdjt  => wrk_3d_7 , ztfw => wrk_3d_8   ! 3D workspace
99      !
100      INTEGER                              , INTENT(in   ) ::   kt         ! ocean time-step index
101      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
102      INTEGER                              , INTENT(in   ) ::   kjpt       ! number of tracers
103      REAL(wp), DIMENSION(jpi,jpj    ,kjpt), INTENT(in   ) ::   pgu, pgv   ! tracer gradient at pstep levels
104      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb        ! before and now tracer fields
105      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta        ! tracer trend
106      REAL(wp)                             , INTENT(in   ) ::   pahtb0     ! background diffusion coef
107      !
108      INTEGER  ::  ji, jj, jk, jn   ! dummy loop indices
109      REAL(wp) ::  zmsku, zabe1, zcof1, zcoef3   ! local scalars
110      REAL(wp) ::  zmskv, zabe2, zcof2, zcoef4   !   -      -
111      REAL(wp) ::  zcoef0, zbtr, ztra            !   -      -
112#if defined key_diaar5
113      REAL(wp)                         ::   zztmp               ! local scalar
114#endif
115      !!----------------------------------------------------------------------
116
117      IF( wrk_in_use(3, 6,7,8) .OR. wrk_in_use(2, 1,2,3) ) THEN
118          CALL ctl_stop('tra_ldf_iso : requested workspace array unavailable')   ;   RETURN
119      ENDIF
120
121      IF( kt == nit000 )  THEN
122         IF(lwp) WRITE(numout,*)
123         IF(lwp) WRITE(numout,*) 'tra_ldf_iso : rotated laplacian diffusion operator on ', cdtype
124         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
125      ENDIF
126#if defined key_top
127      IF( kt == nittrc000 .AND. cdtype == 'TRC' )  THEN
128         IF(lwp) WRITE(numout,*)
129         IF(lwp) WRITE(numout,*) 'tra_ldf_iso : rotated laplacian diffusion operator on ', cdtype
130         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
131      ENDIF
132#endif
133      !
134      !                                                          ! ===========
135      DO jn = 1, kjpt                                            ! tracer loop
136         !                                                       ! ===========
137         !                                               
138         !!----------------------------------------------------------------------
139         !!   I - masked horizontal derivative
140         !!----------------------------------------------------------------------
141         !!bug ajout.... why?   ( 1,jpj,:) and (jpi,1,:) should be sufficient....
142         zdit (1,:,:) = 0.e0     ;     zdit (jpi,:,:) = 0.e0
143         zdjt (1,:,:) = 0.e0     ;     zdjt (jpi,:,:) = 0.e0
144         !!end
145
146         ! Horizontal tracer gradient
147         DO jk = 1, jpkm1
148            DO jj = 1, jpjm1
149               DO ji = 1, fs_jpim1   ! vector opt.
150                  zdit(ji,jj,jk) = ( ptb(ji+1,jj  ,jk,jn) - ptb(ji,jj,jk,jn) ) * umask(ji,jj,jk)
151                  zdjt(ji,jj,jk) = ( ptb(ji  ,jj+1,jk,jn) - ptb(ji,jj,jk,jn) ) * vmask(ji,jj,jk)
152               END DO
153            END DO
154         END DO
155         IF( ln_zps ) THEN      ! partial steps correction at the last ocean level
156            DO jj = 1, jpjm1
157               DO ji = 1, fs_jpim1   ! vector opt.
158                  zdit(ji,jj,mbku(ji,jj)) = pgu(ji,jj,jn)         
159                  zdjt(ji,jj,mbkv(ji,jj)) = pgv(ji,jj,jn)     
160               END DO
161            END DO
162         ENDIF
163
164         !!----------------------------------------------------------------------
165         !!   II - horizontal trend  (full)
166         !!----------------------------------------------------------------------
167!CDIR PARALLEL DO PRIVATE( zdk1t )
168         !                                                ! ===============
169         DO jk = 1, jpkm1                                 ! Horizontal slab
170            !                                             ! ===============
171            ! 1. Vertical tracer gradient at level jk and jk+1
172            ! ------------------------------------------------
173            ! surface boundary condition: zdkt(jk=1)=zdkt(jk=2)
174            zdk1t(:,:) = ( ptb(:,:,jk,jn) - ptb(:,:,jk+1,jn) ) * tmask(:,:,jk+1)
175            !
176            IF( jk == 1 ) THEN   ;   zdkt(:,:) = zdk1t(:,:)
177            ELSE                 ;   zdkt(:,:) = ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) ) * tmask(:,:,jk)
178            ENDIF
179
180            ! 2. Horizontal fluxes
181            ! --------------------   
182            DO jj = 1 , jpjm1
183               DO ji = 1, fs_jpim1   ! vector opt.
184                  zabe1 = ( fsahtu(ji,jj,jk) + pahtb0 ) * e2u(ji,jj) * fse3u(ji,jj,jk) / e1u(ji,jj)
185                  zabe2 = ( fsahtv(ji,jj,jk) + pahtb0 ) * e1v(ji,jj) * fse3v(ji,jj,jk) / e2v(ji,jj)
186                  !
187                  zmsku = 1. / MAX(  tmask(ji+1,jj,jk  ) + tmask(ji,jj,jk+1)   &
188                     &             + tmask(ji+1,jj,jk+1) + tmask(ji,jj,jk  ), 1. )
189                  !
190                  zmskv = 1. / MAX(  tmask(ji,jj+1,jk  ) + tmask(ji,jj,jk+1)   &
191                     &             + tmask(ji,jj+1,jk+1) + tmask(ji,jj,jk  ), 1. )
192                  !
193                  zcof1 = - fsahtu(ji,jj,jk) * e2u(ji,jj) * uslp(ji,jj,jk) * zmsku
194                  zcof2 = - fsahtv(ji,jj,jk) * e1v(ji,jj) * vslp(ji,jj,jk) * zmskv
195                  !
196                  zftu(ji,jj,jk ) = (  zabe1 * zdit(ji,jj,jk)   &
197                     &              + zcof1 * (  zdkt (ji+1,jj) + zdk1t(ji,jj)      &
198                     &                         + zdk1t(ji+1,jj) + zdkt (ji,jj)  )  ) * umask(ji,jj,jk)
199                  zftv(ji,jj,jk) = (  zabe2 * zdjt(ji,jj,jk)   &
200                     &              + zcof2 * (  zdkt (ji,jj+1) + zdk1t(ji,jj)      &
201                     &                         + zdk1t(ji,jj+1) + zdkt (ji,jj)  )  ) * vmask(ji,jj,jk)                 
202               END DO
203            END DO
204
205            ! II.4 Second derivative (divergence) and add to the general trend
206            ! ----------------------------------------------------------------
207            DO jj = 2 , jpjm1
208               DO ji = fs_2, fs_jpim1   ! vector opt.
209                  zbtr = 1.0 / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
210                  ztra = zbtr * ( zftu(ji,jj,jk) - zftu(ji-1,jj,jk) + zftv(ji,jj,jk) - zftv(ji,jj-1,jk)  )
211                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
212               END DO
213            END DO
214            !                                          ! ===============
215         END DO                                        !   End of slab 
216         !                                             ! ===============
217         !
218         ! "Poleward" diffusive heat or salt transports (T-S case only)
219         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN
220            IF( jn == jp_tem)   htr_ldf(:) = ptr_vj( zftv(:,:,:) )
221            IF( jn == jp_sal)   str_ldf(:) = ptr_vj( zftv(:,:,:) )
222         ENDIF
223 
224#if defined key_diaar5
225         IF( cdtype == 'TRA' .AND. jn == jp_tem  ) THEN
226            z2d(:,:) = 0._wp 
227            zztmp = rau0 * rcp 
228            DO jk = 1, jpkm1
229               DO jj = 2, jpjm1
230                  DO ji = fs_2, fs_jpim1   ! vector opt.
231                     z2d(ji,jj) = z2d(ji,jj) + zftu(ji,jj,jk) 
232                  END DO
233               END DO
234            END DO
235            z2d(:,:) = zztmp * z2d(:,:)
236            CALL lbc_lnk( z2d, 'U', -1. )
237            CALL iom_put( "udiff_heattr", z2d )                  ! heat transport in i-direction
238            z2d(:,:) = 0._wp 
239            DO jk = 1, jpkm1
240               DO jj = 2, jpjm1
241                  DO ji = fs_2, fs_jpim1   ! vector opt.
242                     z2d(ji,jj) = z2d(ji,jj) + zftv(ji,jj,jk) 
243                  END DO
244               END DO
245            END DO
246            z2d(:,:) = zztmp * z2d(:,:)
247            CALL lbc_lnk( z2d, 'V', -1. )
248            CALL iom_put( "vdiff_heattr", z2d )                  !  heat transport in i-direction
249         END IF
250#endif
251
252         !!----------------------------------------------------------------------
253         !!   III - vertical trend of T & S (extra diagonal terms only)
254         !!----------------------------------------------------------------------
255         
256         ! Local constant initialization
257         ! -----------------------------
258         ztfw(1,:,:) = 0.e0     ;     ztfw(jpi,:,:) = 0.e0
259         
260         ! Vertical fluxes
261         ! ---------------
262         
263         ! Surface and bottom vertical fluxes set to zero
264         ztfw(:,:, 1 ) = 0.e0      ;      ztfw(:,:,jpk) = 0.e0
265         
266         ! interior (2=<jk=<jpk-1)
267         DO jk = 2, jpkm1
268            DO jj = 2, jpjm1
269               DO ji = fs_2, fs_jpim1   ! vector opt.
270                  zcoef0 = - fsahtw(ji,jj,jk) * tmask(ji,jj,jk)
271                  !
272                  zmsku = 1./MAX(   umask(ji  ,jj,jk-1) + umask(ji-1,jj,jk)      &
273                     &            + umask(ji-1,jj,jk-1) + umask(ji  ,jj,jk), 1.  )
274                  zmskv = 1./MAX(   vmask(ji,jj  ,jk-1) + vmask(ji,jj-1,jk)      &
275                     &            + vmask(ji,jj-1,jk-1) + vmask(ji,jj  ,jk), 1.  )
276                  !
277                  zcoef3 = zcoef0 * e2t(ji,jj) * zmsku * wslpi (ji,jj,jk)
278                  zcoef4 = zcoef0 * e1t(ji,jj) * zmskv * wslpj (ji,jj,jk)
279                  !
280                  ztfw(ji,jj,jk) = zcoef3 * (   zdit(ji  ,jj  ,jk-1) + zdit(ji-1,jj  ,jk)      &
281                     &                        + zdit(ji-1,jj  ,jk-1) + zdit(ji  ,jj  ,jk)  )   &
282                     &           + zcoef4 * (   zdjt(ji  ,jj  ,jk-1) + zdjt(ji  ,jj-1,jk)      &
283                     &                        + zdjt(ji  ,jj-1,jk-1) + zdjt(ji  ,jj  ,jk)  )
284               END DO
285            END DO
286         END DO
287         
288         
289         ! I.5 Divergence of vertical fluxes added to the general tracer trend
290         ! -------------------------------------------------------------------
291         DO jk = 1, jpkm1
292            DO jj = 2, jpjm1
293               DO ji = fs_2, fs_jpim1   ! vector opt.
294                  zbtr = 1.0 / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
295                  ztra = (  ztfw(ji,jj,jk) - ztfw(ji,jj,jk+1)  ) * zbtr
296                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
297               END DO
298            END DO
299         END DO
300         !
301      END DO
302      !
303      IF( wrk_not_released(3, 6,7,8) .OR.   &
304          wrk_not_released(2, 1,2,3) )   CALL ctl_stop('tra_ldf_iso: failed to release workspace arrays')
305      !
306   END SUBROUTINE tra_ldf_iso
307
308#else
309   !!----------------------------------------------------------------------
310   !!   default option :   Dummy code   NO rotation of the diffusive tensor
311   !!----------------------------------------------------------------------
312CONTAINS
313   SUBROUTINE tra_ldf_iso( kt, cdtype, pgu, pgv, ptb, pta, kjpt, pahtb0 )      ! Empty routine
314      CHARACTER(len=3) ::   cdtype
315      REAL, DIMENSION(:,:,:) ::   pgu, pgv   ! tracer gradient at pstep levels
316      REAL, DIMENSION(:,:,:,:) ::   ptb, pta
317      WRITE(*,*) 'tra_ldf_iso: You should not have seen this print! error?', kt, cdtype, pgu(1,1,1), pgv(1,1,1),   &
318         &                                                             ptb(1,1,1,1), pta(1,1,1,1), kjpt, pahtb0
319   END SUBROUTINE tra_ldf_iso
320#endif
321
322   !!==============================================================================
323END MODULE traldf_iso
Note: See TracBrowser for help on using the repository browser.