New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
daymod.F90 in branches/2012/dev_LOCEAN_2012/NEMOGCM/NEMO/OPA_SRC/DOM – NEMO

source: branches/2012/dev_LOCEAN_2012/NEMOGCM/NEMO/OPA_SRC/DOM/daymod.F90 @ 3648

Last change on this file since 3648 was 3648, checked in by smasson, 11 years ago

enable "mini restart", see ticket:1019

  • Property svn:keywords set to Id
File size: 17.6 KB
Line 
1MODULE daymod
2   !!======================================================================
3   !!                       ***  MODULE  daymod  ***
4   !! Ocean        :  calendar
5   !!=====================================================================
6   !! History :  OPA  ! 1994-09  (M. Pontaud M. Imbard)  Original code
7   !!                 ! 1997-03  (O. Marti)
8   !!                 ! 1997-05  (G. Madec)
9   !!                 ! 1997-08  (M. Imbard)
10   !!   NEMO     1.0  ! 2003-09  (G. Madec)  F90 + nyear, nmonth, nday
11   !!                 ! 2004-01  (A.M. Treguier) new calculation based on adatrj
12   !!                 ! 2006-08  (G. Madec)  surface module major update
13   !!----------------------------------------------------------------------     
14
15   !!----------------------------------------------------------------------
16   !!   day        : calendar
17   !! 
18   !!           -------------------------------
19   !!           ----------- WARNING -----------
20   !!
21   !!   we suppose that the time step is deviding the number of second of in a day
22   !!             ---> MOD( rday, rdttra(1) ) == 0
23   !!
24   !!           ----------- WARNING -----------
25   !!           -------------------------------
26   !! 
27   !!----------------------------------------------------------------------
28   USE dom_oce         ! ocean space and time domain
29   USE phycst          ! physical constants
30   USE in_out_manager  ! I/O manager
31   USE iom             !
32   USE ioipsl, ONLY :   ymds2ju   ! for calendar
33   USE prtctl          ! Print control
34   USE trc_oce, ONLY : lk_offline ! offline flag
35   USE timing          ! Timing
36
37   IMPLICIT NONE
38   PRIVATE
39
40   PUBLIC   day        ! called by step.F90
41   PUBLIC   day_init   ! called by istate.F90
42
43   INTEGER ::   nsecd, nsecd05, ndt, ndt05
44
45   !!----------------------------------------------------------------------
46   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
47   !! $Id$
48   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
49   !!----------------------------------------------------------------------
50CONTAINS
51
52   SUBROUTINE day_init
53      !!----------------------------------------------------------------------
54      !!                   ***  ROUTINE day_init  ***
55      !!
56      !! ** Purpose :   Initialization of the calendar values to their values 1 time step before nit000
57      !!                because day will be called at the beginning of step
58      !!
59      !! ** Action  : - nyear        : current year
60      !!              - nmonth       : current month of the year nyear
61      !!              - nday         : current day of the month nmonth
62      !!              - nday_year    : current day of the year nyear
63      !!              - nsec_year    : current time step counted in second since 00h jan 1st of the current year
64      !!              - nsec_month   : current time step counted in second since 00h 1st day of the current month
65      !!              - nsec_day     : current time step counted in second since 00h of the current day
66      !!              - nsec1jan000  : second since Jan. 1st 00h of nit000 year and Jan. 1st 00h of the current year
67      !!              - nmonth_len, nyear_len, nmonth_half, nmonth_end through day_mth
68      !!----------------------------------------------------------------------
69      INTEGER  ::   inbday, idweek
70      REAL(wp) ::   zjul
71      !!----------------------------------------------------------------------
72      !
73      ! all calendar staff is based on the fact that MOD( rday, rdttra(1) ) == 0
74      IF( MOD( rday     , rdttra(1) ) /= 0. )   CALL ctl_stop( 'the time step must devide the number of second of in a day' )
75      IF( MOD( rday     , 2.        ) /= 0. )   CALL ctl_stop( 'the number of second of in a day must be an even number'    )
76      IF( MOD( rdttra(1), 2.        ) /= 0. )   CALL ctl_stop( 'the time step (in second) must be an even number'           )
77      nsecd   = NINT(rday           )
78      nsecd05 = NINT(0.5 * rday     )
79      ndt     = NINT(      rdttra(1))
80      ndt05   = NINT(0.5 * rdttra(1))
81
82      IF( .NOT. lk_offline ) CALL day_rst( nit000, 'READ' ) 
83
84      ! set the calandar from ndastp (read in restart file and namelist)
85
86      nyear   =   ndastp / 10000
87      nmonth  = ( ndastp - (nyear * 10000) ) / 100
88      nday    =   ndastp - (nyear * 10000) - ( nmonth * 100 ) 
89
90      CALL ymds2ju( nyear, nmonth, nday, 0.0, fjulday )  ! we assume that we start run at 00:00
91      IF( ABS(fjulday - REAL(NINT(fjulday),wp)) < 0.1 / rday )   fjulday = REAL(NINT(fjulday),wp)   ! avoid truncation error
92      fjulday = fjulday + 1.                             ! move back to the day at nit000 (and not at nit000 - 1)
93
94      nsec1jan000 = 0
95      CALL day_mth
96     
97      IF ( nday == 0 ) THEN     !   for ex if ndastp = ndate0 - 1
98         nmonth = nmonth - 1 
99         nday = nmonth_len(nmonth)
100      ENDIF
101      IF ( nmonth == 0 ) THEN   ! go at the end of previous year
102         nmonth = 12
103         nyear = nyear - 1
104         nsec1jan000 = nsec1jan000 - nsecd * nyear_len(0)
105         IF( nleapy == 1 )   CALL day_mth
106      ENDIF
107     
108      ! day since january 1st
109      nday_year = nday + SUM( nmonth_len(1:nmonth - 1) )
110
111      !compute number of days between last monday and today     
112      CALL ymds2ju( 1900, 01, 01, 0.0, zjul )  ! compute julian day value of 01.01.1900 (our reference that was a Monday)
113      inbday = NINT(fjulday - zjul)            ! compute nb day between  01.01.1900 and current day 
114      idweek = MOD(inbday, 7)                  ! compute nb day between last monday and current day 
115
116      ! number of seconds since the beginning of current year/month/week/day at the middle of the time-step
117      nsec_year  = nday_year * nsecd - ndt05   ! 1 time step before the middle of the first time step
118      nsec_month = nday      * nsecd - ndt05   ! because day will be called at the beginning of step
119      nsec_week  = idweek    * nsecd - ndt05
120      nsec_day   =             nsecd - ndt05
121
122      ! control print
123      IF(lwp) WRITE(numout,'(a,i6,a,i2,a,i2,a,i6)')' ==============>> 1/2 time step before the start of the run DATE Y/M/D = ',   &
124           &                   nyear, '/', nmonth, '/', nday, '  nsec_day:', nsec_day, '  nsec_week:', nsec_week
125
126      ! Up to now, calendar parameters are related to the end of previous run (nit000-1)
127      ! call day to set the calendar parameters at the begining of the current simulaton. needed by iom_init
128      CALL day( nit000 )
129      !
130   END SUBROUTINE day_init
131
132
133   SUBROUTINE day_mth
134      !!----------------------------------------------------------------------
135      !!                   ***  ROUTINE day_init  ***
136      !!
137      !! ** Purpose :   calendar values related to the months
138      !!
139      !! ** Action  : - nmonth_len    : length in days of the months of the current year
140      !!              - nyear_len     : length in days of the previous/current year
141      !!              - nmonth_half   : second since the beginning of the year and the halft of the months
142      !!              - nmonth_end    : second since the beginning of the year and the end of the months
143      !!----------------------------------------------------------------------
144      INTEGER  ::   jm               ! dummy loop indice
145      !!----------------------------------------------------------------------
146
147      ! length of the month of the current year (from nleapy, read in namelist)
148      IF ( nleapy < 2 ) THEN
149         nmonth_len(:) = (/ 31, 31, 28, 31, 30, 31, 30, 31, 31, 30, 31, 30, 31, 31 /)
150         nyear_len(:) = 365
151         IF ( nleapy == 1 ) THEN   ! we are using calandar with leap years
152            IF ( MOD(nyear-1, 4) == 0 .AND. ( MOD(nyear-1, 400) == 0 .OR. MOD(nyear-1, 100) /= 0 ) ) THEN
153               nyear_len(0) = 366
154            ENDIF
155            IF ( MOD(nyear, 4) == 0 .AND. ( MOD(nyear, 400) == 0 .OR. MOD(nyear, 100) /= 0 ) ) THEN
156               nmonth_len(2) = 29
157               nyear_len(1) = 366
158            ENDIF
159         ENDIF
160      ELSE
161         nmonth_len(:) = nleapy   ! all months with nleapy days per year
162         nyear_len(:) = 12 * nleapy
163      ENDIF
164
165      ! half month in second since the begining of the year:
166      ! time since Jan 1st   0     1     2    ...    11    12    13
167      !          ---------*--|--*--|--*--| ... |--*--|--*--|--*--|--------------------------------------
168      !                 <---> <---> <--->  ...  <---> <---> <--->       
169      ! month number      0     1     2    ...    11    12    13
170      !
171      ! nmonth_half(jm) = rday * REAL( 0.5 * nmonth_len(jm) + SUM(nmonth_len(1:jm-1)) )
172      nmonth_half(0) = - nsecd05 * nmonth_len(0)
173      DO jm = 1, 13
174         nmonth_half(jm) = nmonth_half(jm-1) + nsecd05 * ( nmonth_len(jm-1) + nmonth_len(jm) )
175      END DO
176
177      nmonth_end(0) = 0
178      DO jm = 1, 13
179         nmonth_end(jm) = nmonth_end(jm-1) + nsecd * nmonth_len(jm)
180      END DO
181      !           
182   END SUBROUTINE
183
184
185   SUBROUTINE day( kt )
186      !!----------------------------------------------------------------------
187      !!                      ***  ROUTINE day  ***
188      !!
189      !! ** Purpose :   Compute the date with a day iteration IF necessary.
190      !!
191      !! ** Method  : - ???
192      !!
193      !! ** Action  : - nyear     : current year
194      !!              - nmonth    : current month of the year nyear
195      !!              - nday      : current day of the month nmonth
196      !!              - nday_year : current day of the year nyear
197      !!              - ndastp    : = nyear*10000 + nmonth*100 + nday
198      !!              - adatrj    : date in days since the beginning of the run
199      !!              - nsec_year : current time of the year (in second since 00h, jan 1st)
200      !!----------------------------------------------------------------------     
201      INTEGER, INTENT(in) ::   kt        ! ocean time-step indices
202      !
203      CHARACTER (len=25) ::   charout
204      REAL(wp)           ::   zprec      ! fraction of day corresponding to 0.1 second
205      !!----------------------------------------------------------------------
206      !
207      IF( nn_timing == 1 )  CALL timing_start('day')
208      !
209      zprec = 0.1 / rday
210      !                                                 ! New time-step
211      nsec_year  = nsec_year  + ndt 
212      nsec_month = nsec_month + ndt                 
213      nsec_week  = nsec_week  + ndt
214      nsec_day   = nsec_day   + ndt               
215      adatrj  = adatrj  + rdttra(1) / rday
216      fjulday = fjulday + rdttra(1) / rday
217      IF( ABS(fjulday - REAL(NINT(fjulday),wp)) < zprec )   fjulday = REAL(NINT(fjulday),wp)   ! avoid truncation error
218      IF( ABS(adatrj  - REAL(NINT(adatrj ),wp)) < zprec )   adatrj  = REAL(NINT(adatrj ),wp)   ! avoid truncation error
219     
220      IF( nsec_day > nsecd ) THEN                       ! New day
221         !
222         nday      = nday + 1
223         nday_year = nday_year + 1
224         nsec_day  = ndt05
225         !
226         IF( nday == nmonth_len(nmonth) + 1 ) THEN      ! New month
227            nday   = 1
228            nmonth = nmonth + 1
229            nsec_month = ndt05
230            IF( nmonth == 13 ) THEN                     ! New year
231               nyear     = nyear + 1
232               nmonth    = 1
233               nday_year = 1
234               nsec_year = ndt05
235               nsec1jan000 = nsec1jan000 + nsecd * nyear_len(1)
236               IF( nleapy == 1 )   CALL day_mth
237            ENDIF
238         ENDIF
239         !
240         ndastp = nyear * 10000 + nmonth * 100 + nday   ! New date
241         !
242         !compute first day of the year in julian days
243         CALL ymds2ju( nyear, 01, 01, 0.0, fjulstartyear )
244         !
245         IF(lwp) WRITE(numout,'(a,i8,a,i4.4,a,i2.2,a,i2.2,a,i3.3)') '======>> time-step =', kt,   &
246              &   '      New day, DATE Y/M/D = ', nyear, '/', nmonth, '/', nday, '      nday_year = ', nday_year
247         IF(lwp) WRITE(numout,'(a,i8,a,i7,a,i5)') '         nsec_year = ', nsec_year,   &
248              &   '   nsec_month = ', nsec_month, '   nsec_day = ', nsec_day, '   nsec_week = ', nsec_week
249      ENDIF
250
251      IF( nsec_week > 7*nsecd )   nsec_week = ndt05     ! New week
252     
253      IF(ln_ctl) THEN
254         WRITE(charout,FMT="('kt =', I4,'  d/m/y =',I2,I2,I4)") kt, nday, nmonth, nyear
255         CALL prt_ctl_info(charout)
256      ENDIF
257
258      IF( .NOT. lk_offline ) CALL rst_opn( kt )               ! Open the restart file if needed and control lrst_oce
259      IF( lrst_oce         ) CALL day_rst( kt, 'WRITE' )      ! write day restart information
260      !
261      IF( nn_timing == 1 )  CALL timing_stop('day')
262      !
263   END SUBROUTINE day
264
265
266   SUBROUTINE day_rst( kt, cdrw )
267      !!---------------------------------------------------------------------
268      !!                   ***  ROUTINE ts_rst  ***
269      !!
270      !!  ** Purpose : Read or write calendar in restart file:
271      !!
272      !!  WRITE(READ) mode:
273      !!       kt        : number of time step since the begining of the experiment at the
274      !!                   end of the current(previous) run
275      !!       adatrj(0) : number of elapsed days since the begining of the experiment at the
276      !!                   end of the current(previous) run (REAL -> keep fractions of day)
277      !!       ndastp    : date at the end of the current(previous) run (coded as yyyymmdd integer)
278      !!
279      !!   According to namelist parameter nrstdt,
280      !!       nrstdt = 0  no control on the date (nit000 is  arbitrary).
281      !!       nrstdt = 1  we verify that nit000 is equal to the last
282      !!                   time step of previous run + 1.
283      !!       In both those options, the  exact duration of the experiment
284      !!       since the beginning (cumulated duration of all previous restart runs)
285      !!       is not stored in the restart and is assumed to be (nit000-1)*rdt.
286      !!       This is valid is the time step has remained constant.
287      !!
288      !!       nrstdt = 2  the duration of the experiment in days (adatrj)
289      !!                    has been stored in the restart file.
290      !!----------------------------------------------------------------------
291      INTEGER         , INTENT(in) ::   kt         ! ocean time-step
292      CHARACTER(len=*), INTENT(in) ::   cdrw       ! "READ"/"WRITE" flag
293      !
294      REAL(wp) ::   zkt, zndastp
295      !!----------------------------------------------------------------------
296     
297      IF( TRIM(cdrw) == 'READ' ) THEN
298
299         IF( iom_varid( numror, 'kt', ldstop = .FALSE. ) > 0 ) THEN
300            ! Get Calendar informations
301            CALL iom_get( numror, 'kt', zkt )   ! last time-step of previous run
302            IF(lwp) THEN
303               WRITE(numout,*) ' *** Info read in restart : '
304               WRITE(numout,*) '   previous time-step                               : ', NINT( zkt )
305               WRITE(numout,*) ' *** restart option'
306               SELECT CASE ( nrstdt )
307               CASE ( 0 )   ;   WRITE(numout,*) ' nrstdt = 0 : no control of nit000'
308               CASE ( 1 )   ;   WRITE(numout,*) ' nrstdt = 1 : no control the date at nit000 (use ndate0 read in the namelist)'
309               CASE ( 2 )   ;   WRITE(numout,*) ' nrstdt = 2 : calendar parameters read in restart'
310               END SELECT
311               WRITE(numout,*)
312            ENDIF
313            ! Control of date
314            IF( nit000 - NINT( zkt ) /= 1 .AND. nrstdt /= 0 )                                         & 
315                 &   CALL ctl_stop( ' ===>>>> : problem with nit000 for the restart',                 & 
316                 &                  ' verify the restart file or rerun with nrstdt = 0 (namelist)' )
317            ! define ndastp and adatrj
318            IF ( nrstdt == 2 ) THEN 
319               ! read the parameters correspondting to nit000 - 1 (last time step of previous run)
320               CALL iom_get( numror, 'ndastp', zndastp )
321               ndastp = NINT( zndastp )
322               CALL iom_get( numror, 'adatrj', adatrj  )
323            ELSE 
324               ! parameters correspondting to nit000 - 1 (as we start the step loop with a call to day)
325               ndastp = ndate0 - 1     ! ndate0 read in the namelist in dom_nam, we assume that we start run at 00:00
326               adatrj = ( REAL( nit000-1, wp ) * rdttra(1) ) / rday 
327               ! note this is wrong if time step has changed during run
328            ENDIF
329         ELSE
330            ! parameters correspondting to nit000 - 1 (as we start the step loop with a call to day)
331            ndastp = ndate0 - 1        ! ndate0 read in the namelist in dom_nam, we assume that we start run at 00:00
332            adatrj = ( REAL( nit000-1, wp ) * rdttra(1) ) / rday 
333         ENDIF
334         IF( ABS(adatrj  - REAL(NINT(adatrj),wp)) < 0.1 / rday )   adatrj = REAL(NINT(adatrj),wp)   ! avoid truncation error
335         !
336         IF(lwp) THEN
337            WRITE(numout,*) ' *** Info used values : '
338            WRITE(numout,*) '   date ndastp                                      : ', ndastp
339            WRITE(numout,*) '   number of elapsed days since the begining of run : ', adatrj
340            WRITE(numout,*)
341         ENDIF
342         !
343      ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN
344         !
345         IF( kt == nitrst ) THEN
346            IF(lwp) WRITE(numout,*)
347            IF(lwp) WRITE(numout,*) 'rst_write : write oce restart file  kt =', kt
348            IF(lwp) WRITE(numout,*) '~~~~~~~'         
349         ENDIF
350         ! calendar control
351         CALL iom_rstput( kt, nitrst, numrow, 'kt'     , REAL( kt    , wp) )   ! time-step
352         CALL iom_rstput( kt, nitrst, numrow, 'ndastp' , REAL( ndastp, wp) )   ! date
353         CALL iom_rstput( kt, nitrst, numrow, 'adatrj' , adatrj            )   ! number of elapsed days since
354         !                                                                     ! the begining of the run [s]
355      ENDIF
356      !
357   END SUBROUTINE day_rst
358
359   !!======================================================================
360END MODULE daymod
Note: See TracBrowser for help on using the repository browser.