| 1 | MODULE sbcrnf |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE sbcrnf *** |
|---|
| 4 | !! Ocean forcing: river runoff |
|---|
| 5 | !!===================================================================== |
|---|
| 6 | !! History : OPA ! 2000-11 (R. Hordoir, E. Durand) NetCDF FORMAT |
|---|
| 7 | !! NEMO 1.0 ! 2002-09 (G. Madec) F90: Free form and module |
|---|
| 8 | !! 3.0 ! 2006-07 (G. Madec) Surface module |
|---|
| 9 | !! 3.2 ! 2009-04 (B. Lemaire) Introduce iom_put |
|---|
| 10 | !! 3.3 ! 2010-10 (R. Furner, G. Madec) runoff distributed over ocean levels |
|---|
| 11 | !!---------------------------------------------------------------------- |
|---|
| 12 | |
|---|
| 13 | !!---------------------------------------------------------------------- |
|---|
| 14 | !! sbc_rnf : monthly runoffs read in a NetCDF file |
|---|
| 15 | !! sbc_rnf_init : runoffs initialisation |
|---|
| 16 | !! rnf_mouth : set river mouth mask |
|---|
| 17 | !!---------------------------------------------------------------------- |
|---|
| 18 | USE dom_oce ! ocean space and time domain |
|---|
| 19 | USE phycst ! physical constants |
|---|
| 20 | USE sbc_oce ! surface boundary condition variables |
|---|
| 21 | USE closea ! closed seas |
|---|
| 22 | USE fldread ! read input field at current time step |
|---|
| 23 | USE in_out_manager ! I/O manager |
|---|
| 24 | USE iom ! I/O module |
|---|
| 25 | USE lib_mpp ! MPP library |
|---|
| 26 | |
|---|
| 27 | IMPLICIT NONE |
|---|
| 28 | PRIVATE |
|---|
| 29 | |
|---|
| 30 | PUBLIC sbc_rnf ! routine call in sbcmod module |
|---|
| 31 | PUBLIC sbc_rnf_div ! routine called in sshwzv module |
|---|
| 32 | PUBLIC sbc_rnf_alloc ! routine call in sbcmod module |
|---|
| 33 | |
|---|
| 34 | ! !!* namsbc_rnf namelist * |
|---|
| 35 | CHARACTER(len=100), PUBLIC :: cn_dir = './' !: Root directory for location of ssr files |
|---|
| 36 | LOGICAL , PUBLIC :: ln_rnf_depth = .false. !: depth river runoffs attribute specified in a file |
|---|
| 37 | LOGICAL , PUBLIC :: ln_rnf_tem = .false. !: temperature river runoffs attribute specified in a file |
|---|
| 38 | LOGICAL , PUBLIC :: ln_rnf_sal = .false. !: salinity river runoffs attribute specified in a file |
|---|
| 39 | LOGICAL , PUBLIC :: ln_rnf_emp = .false. !: runoffs into a file to be read or already into precipitation |
|---|
| 40 | TYPE(FLD_N) , PUBLIC :: sn_rnf !: information about the runoff file to be read |
|---|
| 41 | TYPE(FLD_N) , PUBLIC :: sn_cnf !: information about the runoff mouth file to be read |
|---|
| 42 | TYPE(FLD_N) :: sn_s_rnf !: information about the salinities of runoff file to be read |
|---|
| 43 | TYPE(FLD_N) :: sn_t_rnf !: information about the temperatures of runoff file to be read |
|---|
| 44 | TYPE(FLD_N) :: sn_dep_rnf !: information about the depth which river inflow affects |
|---|
| 45 | LOGICAL , PUBLIC :: ln_rnf_mouth = .false. !: specific treatment in mouths vicinity |
|---|
| 46 | REAL(wp) , PUBLIC :: rn_hrnf = 0._wp !: runoffs, depth over which enhanced vertical mixing is used |
|---|
| 47 | REAL(wp) , PUBLIC :: rn_avt_rnf = 0._wp !: runoffs, value of the additional vertical mixing coef. [m2/s] |
|---|
| 48 | REAL(wp) , PUBLIC :: rn_rfact = 1._wp !: multiplicative factor for runoff |
|---|
| 49 | |
|---|
| 50 | INTEGER , PUBLIC :: nkrnf = 0 !: nb of levels over which Kz is increased at river mouths |
|---|
| 51 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: rnfmsk !: river mouth mask (hori.) |
|---|
| 52 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:) :: rnfmsk_z !: river mouth mask (vert.) |
|---|
| 53 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: h_rnf !: depth of runoff in m |
|---|
| 54 | INTEGER, PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: nk_rnf !: depth of runoff in model levels |
|---|
| 55 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: rnf_tsc_b, rnf_tsc !: before and now T & S runoff contents [K.m/s & PSU.m/s] |
|---|
| 56 | |
|---|
| 57 | REAL(wp) :: r1_rau0 ! = 1 / rau0 |
|---|
| 58 | |
|---|
| 59 | TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_rnf ! structure: river runoff (file information, fields read) |
|---|
| 60 | TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_s_rnf ! structure: river runoff salinity (file information, fields read) |
|---|
| 61 | TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_t_rnf ! structure: river runoff temperature (file information, fields read) |
|---|
| 62 | |
|---|
| 63 | !! * Substitutions |
|---|
| 64 | # include "domzgr_substitute.h90" |
|---|
| 65 | !!---------------------------------------------------------------------- |
|---|
| 66 | !! NEMO/OPA 3.3 , NEMO Consortium (2010) |
|---|
| 67 | !! $Id$ |
|---|
| 68 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 69 | !!---------------------------------------------------------------------- |
|---|
| 70 | CONTAINS |
|---|
| 71 | |
|---|
| 72 | INTEGER FUNCTION sbc_rnf_alloc() |
|---|
| 73 | !!---------------------------------------------------------------------- |
|---|
| 74 | !! *** ROUTINE sbc_rnf_alloc *** |
|---|
| 75 | !!---------------------------------------------------------------------- |
|---|
| 76 | ALLOCATE( rnfmsk(jpi,jpj) , rnfmsk_z(jpk) , & |
|---|
| 77 | & h_rnf (jpi,jpj) , nk_rnf (jpi,jpj) , & |
|---|
| 78 | & rnf_tsc_b(jpi,jpj,jpts) , rnf_tsc (jpi,jpj,jpts) , STAT=sbc_rnf_alloc ) |
|---|
| 79 | ! |
|---|
| 80 | IF( lk_mpp ) CALL mpp_sum ( sbc_rnf_alloc ) |
|---|
| 81 | IF( sbc_rnf_alloc > 0 ) CALL ctl_warn('sbc_rnf_alloc: allocation of arrays failed') |
|---|
| 82 | END FUNCTION sbc_rnf_alloc |
|---|
| 83 | |
|---|
| 84 | SUBROUTINE sbc_rnf( kt ) |
|---|
| 85 | !!---------------------------------------------------------------------- |
|---|
| 86 | !! *** ROUTINE sbc_rnf *** |
|---|
| 87 | !! |
|---|
| 88 | !! ** Purpose : Introduce a climatological run off forcing |
|---|
| 89 | !! |
|---|
| 90 | !! ** Method : Set each river mouth with a monthly climatology |
|---|
| 91 | !! provided from different data. |
|---|
| 92 | !! CAUTION : upward water flux, runoff forced to be < 0 |
|---|
| 93 | !! |
|---|
| 94 | !! ** Action : runoff updated runoff field at time-step kt |
|---|
| 95 | !!---------------------------------------------------------------------- |
|---|
| 96 | INTEGER, INTENT(in) :: kt ! ocean time step |
|---|
| 97 | !! |
|---|
| 98 | INTEGER :: ji, jj ! dummy loop indices |
|---|
| 99 | !!---------------------------------------------------------------------- |
|---|
| 100 | ! |
|---|
| 101 | IF( kt == nit000 ) CALL sbc_rnf_init ! Read namelist and allocate structures |
|---|
| 102 | |
|---|
| 103 | ! ! ---------------------------------------- ! |
|---|
| 104 | IF( kt /= nit000 ) THEN ! Swap of forcing fields ! |
|---|
| 105 | ! ! ---------------------------------------- ! |
|---|
| 106 | rnf_b (:,: ) = rnf (:,: ) ! Swap the ocean forcing fields except at nit000 |
|---|
| 107 | rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:) ! where before fields are set at the end of the routine |
|---|
| 108 | ! |
|---|
| 109 | ENDIF |
|---|
| 110 | |
|---|
| 111 | ! !-------------------! |
|---|
| 112 | IF( .NOT. ln_rnf_emp ) THEN ! Update runoff ! |
|---|
| 113 | ! !-------------------! |
|---|
| 114 | ! |
|---|
| 115 | CALL fld_read ( kt, nn_fsbc, sf_rnf ) ! Read Runoffs data and provide it at kt |
|---|
| 116 | IF( ln_rnf_tem ) CALL fld_read ( kt, nn_fsbc, sf_t_rnf ) ! idem for runoffs temperature if required |
|---|
| 117 | IF( ln_rnf_sal ) CALL fld_read ( kt, nn_fsbc, sf_s_rnf ) ! idem for runoffs salinity if required |
|---|
| 118 | ! |
|---|
| 119 | ! Runoff reduction only associated to the ORCA2_LIM configuration |
|---|
| 120 | ! when reading the NetCDF file runoff_1m_nomask.nc |
|---|
| 121 | IF( cp_cfg == 'orca' .AND. jp_cfg == 2 ) THEN |
|---|
| 122 | WHERE( 40._wp < gphit(:,:) .AND. gphit(:,:) < 65._wp ) |
|---|
| 123 | sf_rnf(1)%fnow(:,:,1) = 0.85 * sf_rnf(1)%fnow(:,:,1) |
|---|
| 124 | END WHERE |
|---|
| 125 | ENDIF |
|---|
| 126 | ! |
|---|
| 127 | IF( MOD( kt - 1, nn_fsbc ) == 0 ) THEN |
|---|
| 128 | rnf(:,:) = rn_rfact * ( sf_rnf(1)%fnow(:,:,1) ) |
|---|
| 129 | ! |
|---|
| 130 | r1_rau0 = 1._wp / rau0 |
|---|
| 131 | ! ! set temperature & salinity content of runoffs |
|---|
| 132 | IF( ln_rnf_tem ) THEN ! use runoffs temperature data |
|---|
| 133 | rnf_tsc(:,:,jp_tem) = ( sf_t_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rau0 |
|---|
| 134 | WHERE( sf_t_rnf(1)%fnow(:,:,1) == -999 ) ! if missing data value use SST as runoffs temperature |
|---|
| 135 | rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * r1_rau0 |
|---|
| 136 | END WHERE |
|---|
| 137 | ELSE ! use SST as runoffs temperature |
|---|
| 138 | rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * r1_rau0 |
|---|
| 139 | ENDIF |
|---|
| 140 | ! ! use runoffs salinity data |
|---|
| 141 | IF( ln_rnf_sal ) rnf_tsc(:,:,jp_sal) = ( sf_s_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rau0 |
|---|
| 142 | ! ! else use S=0 for runoffs (done one for all in the init) |
|---|
| 143 | ! |
|---|
| 144 | IF( ln_rnf_tem .OR. ln_rnf_sal ) THEN ! runoffs as outflow: use ocean SST and SSS |
|---|
| 145 | WHERE( rnf(:,:) < 0._wp ) ! example baltic model when flow is out of domain |
|---|
| 146 | rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * r1_rau0 |
|---|
| 147 | rnf_tsc(:,:,jp_sal) = sss_m(:,:) * rnf(:,:) * r1_rau0 |
|---|
| 148 | END WHERE |
|---|
| 149 | ENDIF |
|---|
| 150 | ! |
|---|
| 151 | CALL iom_put( "runoffs", rnf ) ! output runoffs arrays |
|---|
| 152 | ENDIF |
|---|
| 153 | ! |
|---|
| 154 | ENDIF |
|---|
| 155 | ! |
|---|
| 156 | IF( kt == nit000 ) THEN ! set the forcing field at nit000 - 1 ! |
|---|
| 157 | ! ! ---------------------------------------- ! |
|---|
| 158 | IF( ln_rstart .AND. & !* Restart: read in restart file |
|---|
| 159 | & iom_varid( numror, 'rnf_b', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 160 | IF(lwp) WRITE(numout,*) ' nit000-1 runoff forcing fields red in the restart file' |
|---|
| 161 | CALL iom_get( numror, jpdom_autoglo, 'rnf_b', rnf_b ) ! before runoff |
|---|
| 162 | CALL iom_get( numror, jpdom_autoglo, 'rnf_hc_b', rnf_tsc_b(:,:,jp_tem) ) ! before heat content of runoff |
|---|
| 163 | CALL iom_get( numror, jpdom_autoglo, 'rnf_sc_b', rnf_tsc_b(:,:,jp_sal) ) ! before salinity content of runoff |
|---|
| 164 | ELSE !* no restart: set from nit000 values |
|---|
| 165 | IF(lwp) WRITE(numout,*) ' nit000-1 runoff forcing fields set to nit000' |
|---|
| 166 | rnf_b (:,: ) = rnf (:,: ) |
|---|
| 167 | rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:) |
|---|
| 168 | ENDIF |
|---|
| 169 | ENDIF |
|---|
| 170 | ! ! ---------------------------------------- ! |
|---|
| 171 | IF( lrst_oce ) THEN ! Write in the ocean restart file ! |
|---|
| 172 | ! ! ---------------------------------------- ! |
|---|
| 173 | IF(lwp) WRITE(numout,*) |
|---|
| 174 | IF(lwp) WRITE(numout,*) 'sbcrnf : runoff forcing fields written in ocean restart file ', & |
|---|
| 175 | & 'at it= ', kt,' date= ', ndastp |
|---|
| 176 | IF(lwp) WRITE(numout,*) '~~~~' |
|---|
| 177 | CALL iom_rstput( kt, nitrst, numrow, 'rnf_b' , rnf ) |
|---|
| 178 | CALL iom_rstput( kt, nitrst, numrow, 'rnf_hc_b', rnf_tsc(:,:,jp_tem) ) |
|---|
| 179 | CALL iom_rstput( kt, nitrst, numrow, 'rnf_sc_b', rnf_tsc(:,:,jp_sal) ) |
|---|
| 180 | ENDIF |
|---|
| 181 | ! |
|---|
| 182 | END SUBROUTINE sbc_rnf |
|---|
| 183 | |
|---|
| 184 | |
|---|
| 185 | SUBROUTINE sbc_rnf_div( phdivn ) |
|---|
| 186 | !!---------------------------------------------------------------------- |
|---|
| 187 | !! *** ROUTINE sbc_rnf *** |
|---|
| 188 | !! |
|---|
| 189 | !! ** Purpose : update the horizontal divergence with the runoff inflow |
|---|
| 190 | !! |
|---|
| 191 | !! ** Method : |
|---|
| 192 | !! CAUTION : rnf is positive (inflow) decreasing the |
|---|
| 193 | !! divergence and expressed in m/s |
|---|
| 194 | !! |
|---|
| 195 | !! ** Action : phdivn decreased by the runoff inflow |
|---|
| 196 | !!---------------------------------------------------------------------- |
|---|
| 197 | REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: phdivn ! horizontal divergence |
|---|
| 198 | !! |
|---|
| 199 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 200 | REAL(wp) :: r1_rau0 ! local scalar |
|---|
| 201 | REAL(wp) :: zfact ! local scalar |
|---|
| 202 | !!---------------------------------------------------------------------- |
|---|
| 203 | ! |
|---|
| 204 | zfact = 0.5_wp |
|---|
| 205 | ! |
|---|
| 206 | r1_rau0 = 1._wp / rau0 |
|---|
| 207 | IF( ln_rnf_depth ) THEN !== runoff distributed over several levels ==! |
|---|
| 208 | IF( lk_vvl ) THEN ! variable volume case |
|---|
| 209 | DO jj = 1, jpj ! update the depth over which runoffs are distributed |
|---|
| 210 | DO ji = 1, jpi |
|---|
| 211 | h_rnf(ji,jj) = 0._wp |
|---|
| 212 | DO jk = 1, nk_rnf(ji,jj) ! recalculates h_rnf to be the depth in metres |
|---|
| 213 | h_rnf(ji,jj) = h_rnf(ji,jj) + fse3t(ji,jj,jk) ! to the bottom of the relevant grid box |
|---|
| 214 | END DO |
|---|
| 215 | ! ! apply the runoff input flow |
|---|
| 216 | DO jk = 1, nk_rnf(ji,jj) |
|---|
| 217 | phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rau0 / h_rnf(ji,jj) |
|---|
| 218 | END DO |
|---|
| 219 | END DO |
|---|
| 220 | END DO |
|---|
| 221 | ELSE ! constant volume case : just apply the runoff input flow |
|---|
| 222 | DO jj = 1, jpj |
|---|
| 223 | DO ji = 1, jpi |
|---|
| 224 | DO jk = 1, nk_rnf(ji,jj) |
|---|
| 225 | phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rau0 / h_rnf(ji,jj) |
|---|
| 226 | END DO |
|---|
| 227 | END DO |
|---|
| 228 | END DO |
|---|
| 229 | ENDIF |
|---|
| 230 | ELSE !== runoff put only at the surface ==! |
|---|
| 231 | IF( lk_vvl ) THEN ! variable volume case |
|---|
| 232 | h_rnf(:,:) = fse3t(:,:,1) ! recalculate h_rnf to be depth of top box |
|---|
| 233 | ENDIF |
|---|
| 234 | phdivn(:,:,1) = phdivn(:,:,1) - ( rnf(:,:) + rnf_b(:,:) ) * zfact * r1_rau0 / fse3t(:,:,1) |
|---|
| 235 | ENDIF |
|---|
| 236 | ! |
|---|
| 237 | END SUBROUTINE sbc_rnf_div |
|---|
| 238 | |
|---|
| 239 | |
|---|
| 240 | SUBROUTINE sbc_rnf_init |
|---|
| 241 | !!---------------------------------------------------------------------- |
|---|
| 242 | !! *** ROUTINE sbc_rnf_init *** |
|---|
| 243 | !! |
|---|
| 244 | !! ** Purpose : Initialisation of the runoffs if (ln_rnf=T) |
|---|
| 245 | !! |
|---|
| 246 | !! ** Method : - read the runoff namsbc_rnf namelist |
|---|
| 247 | !! |
|---|
| 248 | !! ** Action : - read parameters |
|---|
| 249 | !!---------------------------------------------------------------------- |
|---|
| 250 | CHARACTER(len=32) :: rn_dep_file ! runoff file name |
|---|
| 251 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 252 | INTEGER :: ierror, inum ! temporary integer |
|---|
| 253 | !! |
|---|
| 254 | NAMELIST/namsbc_rnf/ cn_dir, ln_rnf_emp, ln_rnf_depth, ln_rnf_tem, ln_rnf_sal, & |
|---|
| 255 | & sn_rnf, sn_cnf , sn_s_rnf , sn_t_rnf , sn_dep_rnf, & |
|---|
| 256 | & ln_rnf_mouth , rn_hrnf , rn_avt_rnf, rn_rfact |
|---|
| 257 | !!---------------------------------------------------------------------- |
|---|
| 258 | |
|---|
| 259 | ! ! ============ |
|---|
| 260 | ! ! Namelist |
|---|
| 261 | ! ! ============ |
|---|
| 262 | ! (NB: frequency positive => hours, negative => months) |
|---|
| 263 | ! ! file ! frequency ! variable ! time intep ! clim ! 'yearly' or ! weights ! rotation ! |
|---|
| 264 | ! ! name ! (hours) ! name ! (T/F) ! (T/F) ! 'monthly' ! filename ! pairs ! |
|---|
| 265 | sn_rnf = FLD_N( 'runoffs', -1 , 'sorunoff' , .TRUE. , .true. , 'yearly' , '' , '' ) |
|---|
| 266 | sn_cnf = FLD_N( 'runoffs', 0 , 'sorunoff' , .FALSE. , .true. , 'yearly' , '' , '' ) |
|---|
| 267 | |
|---|
| 268 | sn_s_rnf = FLD_N( 'runoffs', 24. , 'rosaline' , .TRUE. , .true. , 'yearly' , '' , '' ) |
|---|
| 269 | sn_t_rnf = FLD_N( 'runoffs', 24. , 'rotemper' , .TRUE. , .true. , 'yearly' , '' , '' ) |
|---|
| 270 | sn_dep_rnf = FLD_N( 'runoffs', 0. , 'rodepth' , .FALSE. , .true. , 'yearly' , '' , '' ) |
|---|
| 271 | ! |
|---|
| 272 | REWIND ( numnam ) ! Read Namelist namsbc_rnf |
|---|
| 273 | READ ( numnam, namsbc_rnf ) |
|---|
| 274 | |
|---|
| 275 | ! ! Control print |
|---|
| 276 | IF(lwp) THEN |
|---|
| 277 | WRITE(numout,*) |
|---|
| 278 | WRITE(numout,*) 'sbc_rnf : runoff ' |
|---|
| 279 | WRITE(numout,*) '~~~~~~~ ' |
|---|
| 280 | WRITE(numout,*) ' Namelist namsbc_rnf' |
|---|
| 281 | WRITE(numout,*) ' runoff in a file to be read ln_rnf_emp = ', ln_rnf_emp |
|---|
| 282 | WRITE(numout,*) ' specific river mouths treatment ln_rnf_mouth = ', ln_rnf_mouth |
|---|
| 283 | WRITE(numout,*) ' river mouth additional Kz rn_avt_rnf = ', rn_avt_rnf |
|---|
| 284 | WRITE(numout,*) ' depth of river mouth additional mixing rn_hrnf = ', rn_hrnf |
|---|
| 285 | WRITE(numout,*) ' multiplicative factor for runoff rn_rfact = ', rn_rfact |
|---|
| 286 | ENDIF |
|---|
| 287 | |
|---|
| 288 | ! ! ================== |
|---|
| 289 | ! ! Type of runoff |
|---|
| 290 | ! ! ================== |
|---|
| 291 | ! !== allocate runoff arrays |
|---|
| 292 | IF( sbc_rnf_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'sbc_rnf_alloc : unable to allocate arrays' ) |
|---|
| 293 | ! |
|---|
| 294 | IF( ln_rnf_emp ) THEN !== runoffs directly provided in the precipitations ==! |
|---|
| 295 | IF(lwp) WRITE(numout,*) |
|---|
| 296 | IF(lwp) WRITE(numout,*) ' runoffs directly provided in the precipitations' |
|---|
| 297 | IF( ln_rnf_depth .OR. ln_rnf_tem .OR. ln_rnf_sal ) THEN |
|---|
| 298 | CALL ctl_warn( 'runoffs already included in precipitations, so runoff (T,S, depth) attributes will not be used' ) |
|---|
| 299 | ln_rnf_depth = .FALSE. ; ln_rnf_tem = .FALSE. ; ln_rnf_sal = .FALSE. |
|---|
| 300 | ENDIF |
|---|
| 301 | ! |
|---|
| 302 | ELSE !== runoffs read in a file : set sf_rnf structure ==! |
|---|
| 303 | ! |
|---|
| 304 | ALLOCATE( sf_rnf(1), STAT=ierror ) ! Create sf_rnf structure (runoff inflow) |
|---|
| 305 | IF(lwp) WRITE(numout,*) |
|---|
| 306 | IF(lwp) WRITE(numout,*) ' runoffs inflow read in a file' |
|---|
| 307 | IF( ierror > 0 ) THEN |
|---|
| 308 | CALL ctl_stop( 'sbc_rnf: unable to allocate sf_rnf structure' ) ; RETURN |
|---|
| 309 | ENDIF |
|---|
| 310 | ALLOCATE( sf_rnf(1)%fnow(jpi,jpj,1) ) |
|---|
| 311 | IF( sn_rnf%ln_tint ) ALLOCATE( sf_rnf(1)%fdta(jpi,jpj,1,2) ) |
|---|
| 312 | ! ! fill sf_rnf with the namelist (sn_rnf) and control print |
|---|
| 313 | CALL fld_fill( sf_rnf, (/ sn_rnf /), cn_dir, 'sbc_rnf_init', 'read runoffs data', 'namsbc_rnf' ) |
|---|
| 314 | ! |
|---|
| 315 | IF( ln_rnf_tem ) THEN ! Create (if required) sf_t_rnf structure |
|---|
| 316 | IF(lwp) WRITE(numout,*) |
|---|
| 317 | IF(lwp) WRITE(numout,*) ' runoffs temperatures read in a file' |
|---|
| 318 | ALLOCATE( sf_t_rnf(1), STAT=ierror ) |
|---|
| 319 | IF( ierror > 0 ) THEN |
|---|
| 320 | CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_t_rnf structure' ) ; RETURN |
|---|
| 321 | ENDIF |
|---|
| 322 | ALLOCATE( sf_t_rnf(1)%fnow(jpi,jpj,1) ) |
|---|
| 323 | IF( sn_t_rnf%ln_tint ) ALLOCATE( sf_t_rnf(1)%fdta(jpi,jpj,1,2) ) |
|---|
| 324 | CALL fld_fill (sf_t_rnf, (/ sn_t_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff temperature data', 'namsbc_rnf' ) |
|---|
| 325 | ENDIF |
|---|
| 326 | ! |
|---|
| 327 | IF( ln_rnf_sal ) THEN ! Create (if required) sf_s_rnf and sf_t_rnf structures |
|---|
| 328 | IF(lwp) WRITE(numout,*) |
|---|
| 329 | IF(lwp) WRITE(numout,*) ' runoffs salinities read in a file' |
|---|
| 330 | ALLOCATE( sf_s_rnf(1), STAT=ierror ) |
|---|
| 331 | IF( ierror > 0 ) THEN |
|---|
| 332 | CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_s_rnf structure' ) ; RETURN |
|---|
| 333 | ENDIF |
|---|
| 334 | ALLOCATE( sf_s_rnf(1)%fnow(jpi,jpj,1) ) |
|---|
| 335 | IF( sn_s_rnf%ln_tint ) ALLOCATE( sf_s_rnf(1)%fdta(jpi,jpj,1,2) ) |
|---|
| 336 | CALL fld_fill (sf_s_rnf, (/ sn_s_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff salinity data', 'namsbc_rnf' ) |
|---|
| 337 | ENDIF |
|---|
| 338 | ! |
|---|
| 339 | IF( ln_rnf_depth ) THEN ! depth of runoffs set from a file |
|---|
| 340 | IF(lwp) WRITE(numout,*) |
|---|
| 341 | IF(lwp) WRITE(numout,*) ' runoffs depth read in a file' |
|---|
| 342 | rn_dep_file = TRIM( cn_dir )//TRIM( sn_dep_rnf%clname ) |
|---|
| 343 | CALL iom_open ( rn_dep_file, inum ) ! open file |
|---|
| 344 | CALL iom_get ( inum, jpdom_data, sn_dep_rnf%clvar, h_rnf ) ! read the river mouth array |
|---|
| 345 | CALL iom_close( inum ) ! close file |
|---|
| 346 | ! |
|---|
| 347 | nk_rnf(:,:) = 0 ! set the number of level over which river runoffs are applied |
|---|
| 348 | DO jj = 1, jpj |
|---|
| 349 | DO ji = 1, jpi |
|---|
| 350 | IF( h_rnf(ji,jj) > 0._wp ) THEN |
|---|
| 351 | jk = 2 |
|---|
| 352 | DO WHILE ( jk /= mbkt(ji,jj) .AND. fsdept(ji,jj,jk) < h_rnf(ji,jj) ) ; jk = jk + 1 ; END DO |
|---|
| 353 | nk_rnf(ji,jj) = jk |
|---|
| 354 | ELSEIF( h_rnf(ji,jj) == -1 ) THEN ; nk_rnf(ji,jj) = 1 |
|---|
| 355 | ELSEIF( h_rnf(ji,jj) == -999 ) THEN ; nk_rnf(ji,jj) = mbkt(ji,jj) |
|---|
| 356 | ELSEIF( h_rnf(ji,jj) /= 0 ) THEN |
|---|
| 357 | CALL ctl_stop( 'runoff depth not positive, and not -999 or -1, rnf value in file fort.999' ) |
|---|
| 358 | WRITE(999,*) 'ji, jj, rnf(ji,jj) :', ji, jj, rnf(ji,jj) |
|---|
| 359 | ENDIF |
|---|
| 360 | END DO |
|---|
| 361 | END DO |
|---|
| 362 | DO jj = 1, jpj ! set the associated depth |
|---|
| 363 | DO ji = 1, jpi |
|---|
| 364 | h_rnf(ji,jj) = 0._wp |
|---|
| 365 | DO jk = 1, nk_rnf(ji,jj) |
|---|
| 366 | h_rnf(ji,jj) = h_rnf(ji,jj) + fse3t(ji,jj,jk) |
|---|
| 367 | END DO |
|---|
| 368 | END DO |
|---|
| 369 | END DO |
|---|
| 370 | ELSE ! runoffs applied at the surface |
|---|
| 371 | nk_rnf(:,:) = 1 |
|---|
| 372 | h_rnf (:,:) = fse3t(:,:,1) |
|---|
| 373 | ENDIF |
|---|
| 374 | ! |
|---|
| 375 | ENDIF |
|---|
| 376 | ! |
|---|
| 377 | rnf(:,:) = 0._wp ! runoff initialisation |
|---|
| 378 | rnf_tsc(:,:,:) = 0._wp ! runoffs temperature & salinty contents initilisation |
|---|
| 379 | ! |
|---|
| 380 | ! ! ======================== |
|---|
| 381 | ! ! River mouth vicinity |
|---|
| 382 | ! ! ======================== |
|---|
| 383 | ! |
|---|
| 384 | IF( ln_rnf_mouth ) THEN ! Specific treatment in vicinity of river mouths : |
|---|
| 385 | ! ! - Increase Kz in surface layers ( rn_hrnf > 0 ) |
|---|
| 386 | ! ! - set to zero SSS damping (ln_ssr=T) |
|---|
| 387 | ! ! - mixed upstream-centered (ln_traadv_cen2=T) |
|---|
| 388 | ! |
|---|
| 389 | IF ( ln_rnf_depth ) CALL ctl_warn( 'sbc_rnf_init: increased mixing turned on but effects may already', & |
|---|
| 390 | & 'be spread through depth by ln_rnf_depth' ) |
|---|
| 391 | ! |
|---|
| 392 | nkrnf = 0 ! Number of level over which Kz increase |
|---|
| 393 | IF( rn_hrnf > 0._wp ) THEN |
|---|
| 394 | nkrnf = 2 |
|---|
| 395 | DO WHILE( nkrnf /= jpkm1 .AND. gdepw_0(nkrnf+1) < rn_hrnf ) ; nkrnf = nkrnf + 1 ; END DO |
|---|
| 396 | IF( ln_sco ) & |
|---|
| 397 | CALL ctl_warn( 'sbc_rnf: number of levels over which Kz is increased is computed for zco...' ) |
|---|
| 398 | ENDIF |
|---|
| 399 | IF(lwp) WRITE(numout,*) |
|---|
| 400 | IF(lwp) WRITE(numout,*) ' Specific treatment used in vicinity of river mouths :' |
|---|
| 401 | IF(lwp) WRITE(numout,*) ' - Increase Kz in surface layers (if rn_hrnf > 0 )' |
|---|
| 402 | IF(lwp) WRITE(numout,*) ' by ', rn_avt_rnf,' m2/s over ', nkrnf, ' w-levels' |
|---|
| 403 | IF(lwp) WRITE(numout,*) ' - set to zero SSS damping (if ln_ssr=T)' |
|---|
| 404 | IF(lwp) WRITE(numout,*) ' - mixed upstream-centered (if ln_traadv_cen2=T)' |
|---|
| 405 | ! |
|---|
| 406 | CALL rnf_mouth ! set river mouth mask |
|---|
| 407 | ! |
|---|
| 408 | ELSE ! No treatment at river mouths |
|---|
| 409 | IF(lwp) WRITE(numout,*) |
|---|
| 410 | IF(lwp) WRITE(numout,*) ' No specific treatment at river mouths' |
|---|
| 411 | rnfmsk (:,:) = 0._wp |
|---|
| 412 | rnfmsk_z(:) = 0._wp |
|---|
| 413 | nkrnf = 0 |
|---|
| 414 | ENDIF |
|---|
| 415 | |
|---|
| 416 | END SUBROUTINE sbc_rnf_init |
|---|
| 417 | |
|---|
| 418 | |
|---|
| 419 | SUBROUTINE rnf_mouth |
|---|
| 420 | !!---------------------------------------------------------------------- |
|---|
| 421 | !! *** ROUTINE rnf_mouth *** |
|---|
| 422 | !! |
|---|
| 423 | !! ** Purpose : define the river mouths mask |
|---|
| 424 | !! |
|---|
| 425 | !! ** Method : read the river mouth mask (=0/1) in the river runoff |
|---|
| 426 | !! climatological file. Defined a given vertical structure. |
|---|
| 427 | !! CAUTION, the vertical structure is hard coded on the |
|---|
| 428 | !! first 5 levels. |
|---|
| 429 | !! This fields can be used to: |
|---|
| 430 | !! - set an upstream advection scheme |
|---|
| 431 | !! (ln_rnf_mouth=T and ln_traadv_cen2=T) |
|---|
| 432 | !! - increase vertical on the top nn_krnf vertical levels |
|---|
| 433 | !! at river runoff input grid point (nn_krnf>=2, see step.F90) |
|---|
| 434 | !! - set to zero SSS restoring flux at river mouth grid points |
|---|
| 435 | !! |
|---|
| 436 | !! ** Action : rnfmsk set to 1 at river runoff input, 0 elsewhere |
|---|
| 437 | !! rnfmsk_z vertical structure |
|---|
| 438 | !!---------------------------------------------------------------------- |
|---|
| 439 | ! |
|---|
| 440 | INTEGER :: inum ! temporary integers |
|---|
| 441 | CHARACTER(len=140) :: cl_rnfile ! runoff file name |
|---|
| 442 | !!---------------------------------------------------------------------- |
|---|
| 443 | ! |
|---|
| 444 | IF(lwp) WRITE(numout,*) |
|---|
| 445 | IF(lwp) WRITE(numout,*) 'rnf_mouth : river mouth mask' |
|---|
| 446 | IF(lwp) WRITE(numout,*) '~~~~~~~~~ ' |
|---|
| 447 | |
|---|
| 448 | cl_rnfile = TRIM( cn_dir )//TRIM( sn_cnf%clname ) |
|---|
| 449 | IF( .NOT. sn_cnf%ln_clim ) THEN ; WRITE(cl_rnfile, '(a,"_y",i4)' ) TRIM( cl_rnfile ), nyear ! add year |
|---|
| 450 | IF( sn_cnf%cltype == 'monthly' ) WRITE(cl_rnfile, '(a,"m",i2)' ) TRIM( cl_rnfile ), nmonth ! add month |
|---|
| 451 | ENDIF |
|---|
| 452 | |
|---|
| 453 | ! horizontal mask (read in NetCDF file) |
|---|
| 454 | CALL iom_open ( cl_rnfile, inum ) ! open file |
|---|
| 455 | CALL iom_get ( inum, jpdom_data, sn_cnf%clvar, rnfmsk ) ! read the river mouth array |
|---|
| 456 | CALL iom_close( inum ) ! close file |
|---|
| 457 | |
|---|
| 458 | IF( nn_closea == 1 ) CALL clo_rnf( rnfmsk ) ! closed sea inflow set as ruver mouth |
|---|
| 459 | |
|---|
| 460 | rnfmsk_z(:) = 0._wp ! vertical structure |
|---|
| 461 | rnfmsk_z(1) = 1.0 |
|---|
| 462 | rnfmsk_z(2) = 1.0 ! ********** |
|---|
| 463 | rnfmsk_z(3) = 0.5 ! HARD CODED on the 5 first levels |
|---|
| 464 | rnfmsk_z(4) = 0.25 ! ********** |
|---|
| 465 | rnfmsk_z(5) = 0.125 |
|---|
| 466 | ! |
|---|
| 467 | END SUBROUTINE rnf_mouth |
|---|
| 468 | |
|---|
| 469 | !!====================================================================== |
|---|
| 470 | END MODULE sbcrnf |
|---|
