New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
zdfgls.F90 in branches/2012/dev_LOCEAN_2012/NEMOGCM/NEMO/OPA_SRC/ZDF – NEMO

source: branches/2012/dev_LOCEAN_2012/NEMOGCM/NEMO/OPA_SRC/ZDF/zdfgls.F90 @ 3648

Last change on this file since 3648 was 3648, checked in by smasson, 11 years ago

enable "mini restart", see ticket:1019
  • Property svn:keywords set to Id
File size: 59.7 KB
Line 
1MODULE zdfgls
2   !!======================================================================
3   !!                       ***  MODULE  zdfgls  ***
4   !! Ocean physics:  vertical mixing coefficient computed from the gls
5   !!                 turbulent closure parameterization
6   !!======================================================================
7   !! History :   3.0  !  2009-09  (G. Reffray)  Original code
8   !!             3.3  !  2010-10  (C. Bricaud)  Add in the reference
9   !!----------------------------------------------------------------------
10#if defined key_zdfgls   ||   defined key_esopa
11   !!----------------------------------------------------------------------
12   !!   'key_zdfgls'                 Generic Length Scale vertical physics
13   !!----------------------------------------------------------------------
14   !!   zdf_gls      : update momentum and tracer Kz from a gls scheme
15   !!   zdf_gls_init : initialization, namelist read, and parameters control
16   !!   gls_rst      : read/write gls restart in ocean restart file
17   !!----------------------------------------------------------------------
18   USE oce            ! ocean dynamics and active tracers
19   USE dom_oce        ! ocean space and time domain
20   USE domvvl         ! ocean space and time domain : variable volume layer
21   USE zdf_oce        ! ocean vertical physics
22   USE sbc_oce        ! surface boundary condition: ocean
23   USE phycst         ! physical constants
24   USE zdfmxl         ! mixed layer
25   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
26   USE lib_mpp        ! MPP manager
27   USE wrk_nemo       ! work arrays
28   USE prtctl         ! Print control
29   USE in_out_manager ! I/O manager
30   USE iom            ! I/O manager library
31   USE timing         ! Timing
32
33   IMPLICIT NONE
34   PRIVATE
35
36   PUBLIC   zdf_gls        ! routine called in step module
37   PUBLIC   zdf_gls_init   ! routine called in opa module
38   PUBLIC   gls_rst        ! routine called in step module
39
40   LOGICAL , PUBLIC, PARAMETER ::   lk_zdfgls = .TRUE.   !: TKE vertical mixing flag
41   !
42   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   en      !: now turbulent kinetic energy
43   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   mxln    !: now mixing length
44   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   zwall   !: wall function
45   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   ustars2 !: Squared surface velocity scale at T-points
46   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   ustarb2 !: Squared bottom  velocity scale at T-points
47
48   !                                         !!! ** Namelist  namzdf_gls  **
49   LOGICAL  ::   ln_crban      = .FALSE.      ! =T use Craig and Banner scheme
50   LOGICAL  ::   ln_length_lim = .FALSE.      ! use limit on the dissipation rate under stable stratification (Galperin et al. 1988)
51   LOGICAL  ::   ln_sigpsi     = .FALSE.      ! Activate Burchard (2003) modification for k-eps closure & wave breaking mixing
52   INTEGER  ::   nn_tkebc_surf = 0            ! TKE surface boundary condition (=0/1)
53   INTEGER  ::   nn_tkebc_bot  = 0            ! TKE bottom boundary condition (=0/1)
54   INTEGER  ::   nn_psibc_surf = 0            ! PSI surface boundary condition (=0/1)
55   INTEGER  ::   nn_psibc_bot  = 0            ! PSI bottom boundary condition (=0/1)
56   INTEGER  ::   nn_stab_func  = 0            ! stability functions G88, KC or Canuto (=0/1/2)
57   INTEGER  ::   nn_clos       = 0            ! closure 0/1/2/3 MY82/k-eps/k-w/gen
58   REAL(wp) ::   rn_clim_galp  = 0.53_wp      ! Holt 2008 value for k-eps: 0.267
59   REAL(wp) ::   rn_epsmin     = 1.e-12_wp    ! minimum value of dissipation (m2/s3)
60   REAL(wp) ::   rn_emin       = 1.e-6_wp     ! minimum value of TKE (m2/s2)
61   REAL(wp) ::   rn_charn      = 2.e+5_wp     ! Charnock constant for surface breaking waves mixing : 1400. (standard) or 2.e5 (Stacey value)
62   REAL(wp) ::   rn_crban      = 100._wp      ! Craig and Banner constant for surface breaking waves mixing
63
64   REAL(wp) ::   hsro          =  0.003_wp    ! Minimum surface roughness
65   REAL(wp) ::   hbro          =  0.003_wp    ! Bottom roughness (m)
66   REAL(wp) ::   rcm_sf        =  0.73_wp     ! Shear free turbulence parameters
67   REAL(wp) ::   ra_sf         = -2.0_wp      ! Must be negative -2 < ra_sf < -1
68   REAL(wp) ::   rl_sf         =  0.2_wp      ! 0 <rl_sf<vkarmn   
69   REAL(wp) ::   rghmin        = -0.28_wp
70   REAL(wp) ::   rgh0          =  0.0329_wp
71   REAL(wp) ::   rghcri        =  0.03_wp
72   REAL(wp) ::   ra1           =  0.92_wp
73   REAL(wp) ::   ra2           =  0.74_wp
74   REAL(wp) ::   rb1           = 16.60_wp
75   REAL(wp) ::   rb2           = 10.10_wp         
76   REAL(wp) ::   re2           =  1.33_wp         
77   REAL(wp) ::   rl1           =  0.107_wp
78   REAL(wp) ::   rl2           =  0.0032_wp
79   REAL(wp) ::   rl3           =  0.0864_wp
80   REAL(wp) ::   rl4           =  0.12_wp
81   REAL(wp) ::   rl5           = 11.9_wp
82   REAL(wp) ::   rl6           =  0.4_wp
83   REAL(wp) ::   rl7           =  0.0_wp
84   REAL(wp) ::   rl8           =  0.48_wp
85   REAL(wp) ::   rm1           =  0.127_wp
86   REAL(wp) ::   rm2           =  0.00336_wp
87   REAL(wp) ::   rm3           =  0.0906_wp
88   REAL(wp) ::   rm4           =  0.101_wp
89   REAL(wp) ::   rm5           = 11.2_wp
90   REAL(wp) ::   rm6           =  0.4_wp
91   REAL(wp) ::   rm7           =  0.0_wp
92   REAL(wp) ::   rm8           =  0.318_wp
93   
94   REAL(wp) ::   rc02, rc02r, rc03, rc04                          ! coefficients deduced from above parameters
95   REAL(wp) ::   rc03_sqrt2_galp                                  !     -           -           -        -
96   REAL(wp) ::   rsbc_tke1, rsbc_tke2, rsbc_tke3, rfact_tke       !     -           -           -        -
97   REAL(wp) ::   rsbc_psi1, rsbc_psi2, rsbc_psi3, rfact_psi       !     -           -           -        -
98   REAL(wp) ::   rsbc_mb  , rsbc_std , rsbc_zs                    !     -           -           -        -
99   REAL(wp) ::   rc0, rc2, rc3, rf6, rcff, rc_diff                !     -           -           -        -
100   REAL(wp) ::   rs0, rs1, rs2, rs4, rs5, rs6                     !     -           -           -        -
101   REAL(wp) ::   rd0, rd1, rd2, rd3, rd4, rd5                     !     -           -           -        -
102   REAL(wp) ::   rsc_tke, rsc_psi, rpsi1, rpsi2, rpsi3, rsc_psi0  !     -           -           -        -
103   REAL(wp) ::   rpsi3m, rpsi3p, rpp, rmm, rnn                    !     -           -           -        -
104
105   !! * Substitutions
106#  include "domzgr_substitute.h90"
107#  include "vectopt_loop_substitute.h90"
108   !!----------------------------------------------------------------------
109   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
110   !! $Id$
111   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
112   !!----------------------------------------------------------------------
113CONTAINS
114
115   INTEGER FUNCTION zdf_gls_alloc()
116      !!----------------------------------------------------------------------
117      !!                ***  FUNCTION zdf_gls_alloc  ***
118      !!----------------------------------------------------------------------
119      ALLOCATE( en(jpi,jpj,jpk),  mxln(jpi,jpj,jpk), zwall(jpi,jpj,jpk) ,     &
120         &      ustars2(jpi,jpj), ustarb2(jpi,jpj)                      , STAT= zdf_gls_alloc )
121         !
122      IF( lk_mpp             )   CALL mpp_sum ( zdf_gls_alloc )
123      IF( zdf_gls_alloc /= 0 )   CALL ctl_warn('zdf_gls_alloc: failed to allocate arrays')
124   END FUNCTION zdf_gls_alloc
125
126
127   SUBROUTINE zdf_gls( kt )
128      !!----------------------------------------------------------------------
129      !!                   ***  ROUTINE zdf_gls  ***
130      !!
131      !! ** Purpose :   Compute the vertical eddy viscosity and diffusivity
132      !!              coefficients using the GLS turbulent closure scheme.
133      !!----------------------------------------------------------------------
134      INTEGER, INTENT(in) ::   kt ! ocean time step
135      INTEGER  ::   ji, jj, jk, ibot, ibotm1, dir  ! dummy loop arguments
136      REAL(wp) ::   zesh2, zsigpsi, zcoef, zex1, zex2   ! local scalars
137      REAL(wp) ::   ztx2, zty2, zup, zdown, zcof        !   -      -
138      REAL(wp) ::   zratio, zrn2, zflxb, sh             !   -      -
139      REAL(wp) ::   prod, buoy, diss, zdiss, sm         !   -      -
140      REAL(wp) ::   gh, gm, shr, dif, zsqen, zav        !   -      -
141      REAL(wp), POINTER, DIMENSION(:,:  ) ::   zdep
142      REAL(wp), POINTER, DIMENSION(:,:  ) ::   zflxs       ! Turbulence fluxed induced by internal waves
143      REAL(wp), POINTER, DIMENSION(:,:  ) ::   zhsro       ! Surface roughness (surface waves)
144      REAL(wp), POINTER, DIMENSION(:,:,:) ::   eb          ! tke at time before
145      REAL(wp), POINTER, DIMENSION(:,:,:) ::   mxlb        ! mixing length at time before
146      REAL(wp), POINTER, DIMENSION(:,:,:) ::   shear       ! vertical shear
147      REAL(wp), POINTER, DIMENSION(:,:,:) ::   eps         ! dissipation rate
148      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zwall_psi   ! Wall function use in the wb case (ln_sigpsi.AND.ln_crban=T)
149      REAL(wp), POINTER, DIMENSION(:,:,:) ::   z_elem_a, z_elem_b, z_elem_c, psi
150      !!--------------------------------------------------------------------
151      !
152      IF( nn_timing == 1 )  CALL timing_start('zdf_gls')
153      !
154      CALL wrk_alloc( jpi,jpj, zdep, zflxs, zhsro )
155      CALL wrk_alloc( jpi,jpj,jpk, eb, mxlb, shear, eps, zwall_psi, z_elem_a, z_elem_b, z_elem_c, psi )
156
157      ! Preliminary computing
158
159      ustars2 = 0._wp   ;   ustarb2 = 0._wp   ;   psi  = 0._wp   ;   zwall_psi = 0._wp
160
161      ! Compute surface and bottom friction at T-points
162!CDIR NOVERRCHK
163      DO jj = 2, jpjm1
164!CDIR NOVERRCHK
165         DO ji = fs_2, fs_jpim1   ! vector opt.
166            !
167            ! surface friction
168            ustars2(ji,jj) = rau0r * taum(ji,jj) * tmask(ji,jj,1)
169            !
170            ! bottom friction (explicit before friction)
171            ! Note that we chose here not to bound the friction as in dynbfr)
172            ztx2 = (  bfrua(ji,jj)  * ub(ji,jj,mbku(ji,jj)) + bfrua(ji-1,jj) * ub(ji-1,jj,mbku(ji-1,jj))  )   &
173               & * ( 1._wp - 0.5_wp * umask(ji,jj,1) * umask(ji-1,jj,1)  )
174            zty2 = (  bfrva(ji,jj)  * vb(ji,jj,mbkv(ji,jj)) + bfrva(ji,jj-1) * vb(ji,jj-1,mbkv(ji,jj-1))  )   &
175               & * ( 1._wp - 0.5_wp * vmask(ji,jj,1) * vmask(ji,jj-1,1)  )
176            ustarb2(ji,jj) = SQRT( ztx2 * ztx2 + zty2 * zty2 ) * tmask(ji,jj,1)
177         END DO
178      END DO 
179
180      ! In case of breaking surface waves mixing,
181      ! Compute surface roughness length according to Charnock formula:
182      IF( ln_crban ) THEN   ;   zhsro(:,:) = MAX(rsbc_zs * ustars2(:,:), hsro)
183      ELSE                  ;   zhsro(:,:) = hsro
184      ENDIF
185
186      ! Compute shear and dissipation rate
187      DO jk = 2, jpkm1
188         DO jj = 2, jpjm1
189            DO ji = fs_2, fs_jpim1   ! vector opt.
190               avmu(ji,jj,jk) = avmu(ji,jj,jk) * ( un(ji,jj,jk-1) - un(ji,jj,jk) )   &
191                  &                            * ( ub(ji,jj,jk-1) - ub(ji,jj,jk) )   &
192                  &                            / (  fse3uw_n(ji,jj,jk)               &
193                  &                            *    fse3uw_b(ji,jj,jk) )
194               avmv(ji,jj,jk) = avmv(ji,jj,jk) * ( vn(ji,jj,jk-1) - vn(ji,jj,jk) )   &
195                  &                            * ( vb(ji,jj,jk-1) - vb(ji,jj,jk) )   &
196                  &                            / (  fse3vw_n(ji,jj,jk)               &
197                  &                            *    fse3vw_b(ji,jj,jk) )
198               eps(ji,jj,jk)  = rc03 * en(ji,jj,jk) * SQRT(en(ji,jj,jk)) / mxln(ji,jj,jk)
199            END DO
200         END DO
201      END DO
202      !
203      ! Lateral boundary conditions (avmu,avmv) (sign unchanged)
204      CALL lbc_lnk( avmu, 'U', 1. )   ;   CALL lbc_lnk( avmv, 'V', 1. )
205
206      ! Save tke at before time step
207      eb  (:,:,:) = en  (:,:,:)
208      mxlb(:,:,:) = mxln(:,:,:)
209
210      IF( nn_clos == 0 ) THEN    ! Mellor-Yamada
211         DO jk = 2, jpkm1
212            DO jj = 2, jpjm1 
213               DO ji = fs_2, fs_jpim1   ! vector opt.
214                  zup   = mxln(ji,jj,jk) * fsdepw(ji,jj,mbkt(ji,jj)+1)
215                  zdown = vkarmn * fsdepw(ji,jj,jk) * ( -fsdepw(ji,jj,jk) + fsdepw(ji,jj,mbkt(ji,jj)+1) )
216                  zcoef = ( zup / MAX( zdown, rsmall ) )
217                  zwall (ji,jj,jk) = ( 1._wp + re2 * zcoef*zcoef ) * tmask(ji,jj,jk)
218               END DO
219            END DO
220         END DO
221      ENDIF
222
223      !!---------------------------------!!
224      !!   Equation to prognostic k      !!
225      !!---------------------------------!!
226      !
227      ! Now Turbulent kinetic energy (output in en)
228      ! -------------------------------
229      ! Resolution of a tridiagonal linear system by a "methode de chasse"
230      ! computation from level 2 to jpkm1  (e(1) computed after and e(jpk)=0 ).
231      ! The surface boundary condition are set after
232      ! The bottom boundary condition are also set after. In standard e(bottom)=0.
233      ! z_elem_b : diagonal z_elem_c : upper diagonal z_elem_a : lower diagonal
234      ! Warning : after this step, en : right hand side of the matrix
235
236      DO jk = 2, jpkm1
237         DO jj = 2, jpjm1
238            DO ji = fs_2, fs_jpim1   ! vector opt.
239               !
240               ! shear prod. at w-point weightened by mask
241               shear(ji,jj,jk) =  ( avmu(ji-1,jj,jk) + avmu(ji,jj,jk) ) / MAX( 1.e0 , umask(ji-1,jj,jk) + umask(ji,jj,jk) )   &
242                  &             + ( avmv(ji,jj-1,jk) + avmv(ji,jj,jk) ) / MAX( 1.e0 , vmask(ji,jj-1,jk) + vmask(ji,jj,jk) )
243               !
244               ! stratif. destruction
245               buoy = - avt(ji,jj,jk) * rn2(ji,jj,jk)
246               !
247               ! shear prod. - stratif. destruction
248               diss = eps(ji,jj,jk)
249               !
250               dir = 0.5_wp + SIGN( 0.5_wp, shear(ji,jj,jk) + buoy )   ! dir =1(=0) if shear(ji,jj,jk)+buoy >0(<0)
251               !
252               zesh2 = dir*(shear(ji,jj,jk)+buoy)+(1._wp-dir)*shear(ji,jj,jk)          ! production term
253               zdiss = dir*(diss/en(ji,jj,jk))   +(1._wp-dir)*(diss-buoy)/en(ji,jj,jk) ! dissipation term
254               !
255               ! Compute a wall function from 1. to rsc_psi*zwall/rsc_psi0
256               ! Note that as long that Dirichlet boundary conditions are NOT set at the first and last levels (GOTM style)
257               ! there is no need to set a boundary condition for zwall_psi at the top and bottom boundaries.
258               ! Otherwise, this should be rsc_psi/rsc_psi0
259               IF( ln_sigpsi ) THEN
260                  zsigpsi = MIN( 1._wp, zesh2 / eps(ji,jj,jk) )     ! 0. <= zsigpsi <= 1.
261                  zwall_psi(ji,jj,jk) = rsc_psi /   & 
262                     &     (  zsigpsi * rsc_psi + (1._wp-zsigpsi) * rsc_psi0 / MAX( zwall(ji,jj,jk), 1._wp )  )
263               ELSE
264                  zwall_psi(ji,jj,jk) = 1._wp
265               ENDIF
266               !
267               ! building the matrix
268               zcof = rfact_tke * tmask(ji,jj,jk)
269               !
270               ! lower diagonal
271               z_elem_a(ji,jj,jk) = zcof * ( avm  (ji,jj,jk  ) + avm  (ji,jj,jk-1) )   &
272                  &                      / ( fse3t(ji,jj,jk-1) * fse3w(ji,jj,jk  ) )
273               !
274               ! upper diagonal
275               z_elem_c(ji,jj,jk) = zcof * ( avm  (ji,jj,jk+1) + avm  (ji,jj,jk  ) )   &
276                  &                      / ( fse3t(ji,jj,jk  ) * fse3w(ji,jj,jk) )
277               !
278               ! diagonal
279               z_elem_b(ji,jj,jk) = 1._wp - z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk)  &
280                  &                       + rdt * zdiss * tmask(ji,jj,jk) 
281               !
282               ! right hand side in en
283               en(ji,jj,jk) = en(ji,jj,jk) + rdt * zesh2 * tmask(ji,jj,jk)
284            END DO
285         END DO
286      END DO
287      !
288      z_elem_b(:,:,jpk) = 1._wp
289      !
290      ! Set surface condition on zwall_psi (1 at the bottom)
291      IF( ln_sigpsi ) THEN
292         zcoef = rsc_psi / rsc_psi0
293         DO jj = 2, jpjm1
294            DO ji = fs_2, fs_jpim1   ! vector opt.
295               zwall_psi(ji,jj,1) = zcoef
296            END DO
297         END DO
298      ENDIF
299
300      ! Surface boundary condition on tke
301      ! ---------------------------------
302      !
303      SELECT CASE ( nn_tkebc_surf )
304      !
305      CASE ( 0 )             ! Dirichlet case
306         !
307         IF (ln_crban) THEN     ! Wave induced mixing case
308            !                      ! en(1) = q2(1) = 0.5 * (15.8 * Ccb)^(2/3) * u*^2
309            !                      ! balance between the production and the dissipation terms including the wave effect
310            en(:,:,1) = MAX( rsbc_tke1 * ustars2(:,:), rn_emin )
311            z_elem_a(:,:,1) = en(:,:,1)
312            z_elem_c(:,:,1) = 0._wp
313            z_elem_b(:,:,1) = 1._wp
314            !
315            ! one level below
316            en(:,:,2) = MAX( rsbc_tke1 * ustars2(:,:) * ( (zhsro(:,:)+fsdepw(:,:,2))/zhsro(:,:) )**ra_sf, rn_emin )
317            z_elem_a(:,:,2) = 0._wp
318            z_elem_c(:,:,2) = 0._wp
319            z_elem_b(:,:,2) = 1._wp
320            !
321         ELSE                   ! No wave induced mixing case
322            !                      ! en(1) = u*^2/C0^2  &  l(1)  = K*zs
323            !                      ! balance between the production and the dissipation terms
324            en(:,:,1) = MAX( rc02r * ustars2(:,:), rn_emin )
325            z_elem_a(:,:,1) = en(:,:,1) 
326            z_elem_c(:,:,1) = 0._wp
327            z_elem_b(:,:,1) = 1._wp
328            !
329            ! one level below
330            en(:,:,2) = MAX( rc02r * ustars2(:,:), rn_emin )
331            z_elem_a(:,:,2) = 0._wp
332            z_elem_c(:,:,2) = 0._wp
333            z_elem_b(:,:,2) = 1._wp
334            !
335         ENDIF
336         !
337      CASE ( 1 )             ! Neumann boundary condition on d(e)/dz
338         !
339         IF (ln_crban) THEN ! Shear free case: d(e)/dz= Fw
340            !
341            ! Dirichlet conditions at k=1 (Cosmetic)
342            en(:,:,1) = MAX( rsbc_tke1 * ustars2(:,:), rn_emin )
343            z_elem_a(:,:,1) = en(:,:,1)
344            z_elem_c(:,:,1) = 0._wp
345            z_elem_b(:,:,1) = 1._wp
346            ! at k=2, set de/dz=Fw
347            z_elem_b(:,:,2) = z_elem_b(:,:,2) +  z_elem_a(:,:,2) ! Remove z_elem_a from z_elem_b
348            z_elem_a(:,:,2) = 0._wp       
349            zflxs(:,:) = rsbc_tke3 * ustars2(:,:)**1.5_wp * ( (zhsro(:,:)+fsdept(:,:,1) ) / zhsro(:,:) )**(1.5*ra_sf)
350            en(:,:,2) = en(:,:,2) + zflxs(:,:) / fse3w(:,:,2)
351            !
352         ELSE                   ! No wave induced mixing case: d(e)/dz=0.
353            !
354            ! Dirichlet conditions at k=1 (Cosmetic)
355            en(:,:,1) = MAX( rc02r * ustars2(:,:), rn_emin )
356            z_elem_a(:,:,1) = en(:,:,1)
357            z_elem_c(:,:,1) = 0._wp
358            z_elem_b(:,:,1) = 1._wp
359            ! at k=2 set de/dz=0.:
360            z_elem_b(:,:,2) = z_elem_b(:,:,2) +  z_elem_a(:,:,2)  ! Remove z_elem_a from z_elem_b
361            z_elem_a(:,:,2) = 0._wp
362            !
363         ENDIF
364         !
365      END SELECT
366
367      ! Bottom boundary condition on tke
368      ! --------------------------------
369      !
370      SELECT CASE ( nn_tkebc_bot )
371      !
372      CASE ( 0 )             ! Dirichlet
373         !                      ! en(ibot) = u*^2 / Co2 and mxln(ibot) = rn_lmin
374         !                      ! Balance between the production and the dissipation terms
375!CDIR NOVERRCHK
376         DO jj = 2, jpjm1
377!CDIR NOVERRCHK
378            DO ji = fs_2, fs_jpim1   ! vector opt.
379               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
380               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
381               !
382               ! Bottom level Dirichlet condition:
383               z_elem_a(ji,jj,ibot  ) = 0._wp
384               z_elem_c(ji,jj,ibot  ) = 0._wp
385               z_elem_b(ji,jj,ibot  ) = 1._wp
386               en(ji,jj,ibot  ) = MAX( rc02r * ustarb2(ji,jj), rn_emin )
387               !
388               ! Just above last level, Dirichlet condition again
389               z_elem_a(ji,jj,ibotm1) = 0._wp
390               z_elem_c(ji,jj,ibotm1) = 0._wp
391               z_elem_b(ji,jj,ibotm1) = 1._wp
392               en(ji,jj,ibotm1) = MAX( rc02r * ustarb2(ji,jj), rn_emin ) 
393            END DO
394         END DO
395         !
396      CASE ( 1 )             ! Neumman boundary condition
397         !                     
398!CDIR NOVERRCHK
399         DO jj = 2, jpjm1
400!CDIR NOVERRCHK
401            DO ji = fs_2, fs_jpim1   ! vector opt.
402               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
403               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
404               !
405               ! Bottom level Dirichlet condition:
406               z_elem_a(ji,jj,ibot) = 0._wp
407               z_elem_c(ji,jj,ibot) = 0._wp
408               z_elem_b(ji,jj,ibot) = 1._wp
409               en(ji,jj,ibot) = MAX( rc02r * ustarb2(ji,jj), rn_emin )
410               !
411               ! Just above last level: Neumann condition
412               z_elem_b(ji,jj,ibotm1) = z_elem_b(ji,jj,ibotm1) + z_elem_c(ji,jj,ibotm1)   ! Remove z_elem_c from z_elem_b
413               z_elem_c(ji,jj,ibotm1) = 0._wp
414            END DO
415         END DO
416         !
417      END SELECT
418
419      ! Matrix inversion (en prescribed at surface and the bottom)
420      ! ----------------------------------------------------------
421      !
422      DO jk = 2, jpkm1                             ! First recurrence : Dk = Dk - Lk * Uk-1 / Dk-1
423         DO jj = 2, jpjm1
424            DO ji = fs_2, fs_jpim1    ! vector opt.
425               z_elem_b(ji,jj,jk) = z_elem_b(ji,jj,jk) - z_elem_a(ji,jj,jk) * z_elem_c(ji,jj,jk-1) / z_elem_b(ji,jj,jk-1)
426            END DO
427         END DO
428      END DO
429      DO jk = 2, jpk                               ! Second recurrence : Lk = RHSk - Lk / Dk-1 * Lk-1
430         DO jj = 2, jpjm1
431            DO ji = fs_2, fs_jpim1    ! vector opt.
432               z_elem_a(ji,jj,jk) = en(ji,jj,jk) - z_elem_a(ji,jj,jk) / z_elem_b(ji,jj,jk-1) * z_elem_a(ji,jj,jk-1)
433            END DO
434         END DO
435      END DO
436      DO jk = jpk-1, 2, -1                         ! thrid recurrence : Ek = ( Lk - Uk * Ek+1 ) / Dk
437         DO jj = 2, jpjm1
438            DO ji = fs_2, fs_jpim1    ! vector opt.
439               en(ji,jj,jk) = ( z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk) * en(ji,jj,jk+1) ) / z_elem_b(ji,jj,jk)
440            END DO
441         END DO
442      END DO
443      !                                            ! set the minimum value of tke
444      en(:,:,:) = MAX( en(:,:,:), rn_emin )
445     
446      !!----------------------------------------!!
447      !!   Solve prognostic equation for psi    !!
448      !!----------------------------------------!!
449
450      ! Set psi to previous time step value
451      !
452      SELECT CASE ( nn_clos )
453      !
454      CASE( 0 )               ! k-kl  (Mellor-Yamada)
455         DO jk = 2, jpkm1
456            DO jj = 2, jpjm1
457               DO ji = fs_2, fs_jpim1   ! vector opt.
458                  psi(ji,jj,jk)  = eb(ji,jj,jk) * mxlb(ji,jj,jk)
459               END DO
460            END DO
461         END DO
462         !
463      CASE( 1 )               ! k-eps
464         DO jk = 2, jpkm1
465            DO jj = 2, jpjm1
466               DO ji = fs_2, fs_jpim1   ! vector opt.
467                  psi(ji,jj,jk)  = eps(ji,jj,jk)
468               END DO
469            END DO
470         END DO
471         !
472      CASE( 2 )               ! k-w
473         DO jk = 2, jpkm1
474            DO jj = 2, jpjm1
475               DO ji = fs_2, fs_jpim1   ! vector opt.
476                  psi(ji,jj,jk)  = SQRT( eb(ji,jj,jk) ) / ( rc0 * mxlb(ji,jj,jk) )
477               END DO
478            END DO
479         END DO
480         !
481      CASE( 3 )               ! generic
482         DO jk = 2, jpkm1
483            DO jj = 2, jpjm1
484               DO ji = fs_2, fs_jpim1   ! vector opt.
485                  psi(ji,jj,jk)  = rc02 * eb(ji,jj,jk) * mxlb(ji,jj,jk)**rnn 
486               END DO
487            END DO
488         END DO
489         !
490      END SELECT
491      !
492      ! Now gls (output in psi)
493      ! -------------------------------
494      ! Resolution of a tridiagonal linear system by a "methode de chasse"
495      ! computation from level 2 to jpkm1  (e(1) already computed and e(jpk)=0 ).
496      ! z_elem_b : diagonal z_elem_c : upper diagonal z_elem_a : lower diagonal
497      ! Warning : after this step, en : right hand side of the matrix
498
499      DO jk = 2, jpkm1
500         DO jj = 2, jpjm1
501            DO ji = fs_2, fs_jpim1   ! vector opt.
502               !
503               ! psi / k
504               zratio = psi(ji,jj,jk) / eb(ji,jj,jk) 
505               !
506               ! psi3+ : stable : B=-KhN²<0 => N²>0 if rn2>0 dir = 1 (stable) otherwise dir = 0 (unstable)
507               dir = 0.5_wp + SIGN( 0.5_wp, rn2(ji,jj,jk) )
508               !
509               rpsi3 = dir * rpsi3m + ( 1._wp - dir ) * rpsi3p
510               !
511               ! shear prod. - stratif. destruction
512               prod = rpsi1 * zratio * shear(ji,jj,jk)
513               !
514               ! stratif. destruction
515               buoy = rpsi3 * zratio * (- avt(ji,jj,jk) * rn2(ji,jj,jk) )
516               !
517               ! shear prod. - stratif. destruction
518               diss = rpsi2 * zratio * zwall(ji,jj,jk) * eps(ji,jj,jk)
519               !
520               dir = 0.5_wp + SIGN( 0.5_wp, prod + buoy )   ! dir =1(=0) if shear(ji,jj,jk)+buoy >0(<0)
521               !
522               zesh2 = dir * ( prod + buoy )          + (1._wp - dir ) * prod                        ! production term
523               zdiss = dir * ( diss / psi(ji,jj,jk) ) + (1._wp - dir ) * (diss-buoy) / psi(ji,jj,jk) ! dissipation term
524               !                                                       
525               ! building the matrix
526               zcof = rfact_psi * zwall_psi(ji,jj,jk) * tmask(ji,jj,jk)
527               ! lower diagonal
528               z_elem_a(ji,jj,jk) = zcof * ( avm  (ji,jj,jk  ) + avm  (ji,jj,jk-1) )   &
529                  &                      / ( fse3t(ji,jj,jk-1) * fse3w(ji,jj,jk  ) )
530               ! upper diagonal
531               z_elem_c(ji,jj,jk) = zcof * ( avm  (ji,jj,jk+1) + avm  (ji,jj,jk  ) )   &
532                  &                      / ( fse3t(ji,jj,jk  ) * fse3w(ji,jj,jk) )
533               ! diagonal
534               z_elem_b(ji,jj,jk) = 1._wp - z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk)  &
535                  &                       + rdt * zdiss * tmask(ji,jj,jk)
536               !
537               ! right hand side in psi
538               psi(ji,jj,jk) = psi(ji,jj,jk) + rdt * zesh2 * tmask(ji,jj,jk)
539            END DO
540         END DO
541      END DO
542      !
543      z_elem_b(:,:,jpk) = 1._wp
544
545      ! Surface boundary condition on psi
546      ! ---------------------------------
547      !
548      SELECT CASE ( nn_psibc_surf )
549      !
550      CASE ( 0 )             ! Dirichlet boundary conditions
551         !
552         IF( ln_crban ) THEN       ! Wave induced mixing case
553            !                      ! en(1) = q2(1) = 0.5 * (15.8 * Ccb)^(2/3) * u*^2
554            !                      ! balance between the production and the dissipation terms including the wave effect
555            zdep(:,:) = rl_sf * zhsro(:,:)
556            psi (:,:,1) = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
557            z_elem_a(:,:,1) = psi(:,:,1)
558            z_elem_c(:,:,1) = 0._wp
559            z_elem_b(:,:,1) = 1._wp
560            !
561            ! one level below
562            zex1 = (rmm*ra_sf+rnn)
563            zex2 = (rmm*ra_sf)
564            zdep(:,:) = ( (zhsro(:,:) + fsdepw(:,:,2))**zex1 ) / zhsro(:,:)**zex2
565            psi (:,:,2) = rsbc_psi1 * ustars2(:,:)**rmm * zdep(:,:) * tmask(:,:,1)
566            z_elem_a(:,:,2) = 0._wp
567            z_elem_c(:,:,2) = 0._wp
568            z_elem_b(:,:,2) = 1._wp
569            !
570         ELSE                   ! No wave induced mixing case
571            !                      ! en(1) = u*^2/C0^2  &  l(1)  = K*zs
572            !                      ! balance between the production and the dissipation terms
573            !
574            zdep(:,:) = vkarmn * zhsro(:,:)
575            psi (:,:,1) = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
576            z_elem_a(:,:,1) = psi(:,:,1)
577            z_elem_c(:,:,1) = 0._wp
578            z_elem_b(:,:,1) = 1._wp
579            !
580            ! one level below
581            zdep(:,:) = vkarmn * ( zhsro(:,:) + fsdepw(:,:,2) )
582            psi (:,:,2) = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
583            z_elem_a(:,:,2) = 0._wp
584            z_elem_c(:,:,2) = 0._wp
585            z_elem_b(:,:,2) = 1.
586            !
587         ENDIF
588         !
589      CASE ( 1 )             ! Neumann boundary condition on d(psi)/dz
590         !
591         IF( ln_crban ) THEN     ! Wave induced mixing case
592            !
593            zdep(:,:) = rl_sf * zhsro(:,:)
594            psi (:,:,1) = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
595            z_elem_a(:,:,1) = psi(:,:,1)
596            z_elem_c(:,:,1) = 0._wp
597            z_elem_b(:,:,1) = 1._wp
598            !
599            ! Neumann condition at k=2
600            z_elem_b(:,:,2) = z_elem_b(:,:,2) +  z_elem_a(:,:,2) ! Remove z_elem_a from z_elem_b
601            z_elem_a(:,:,2) = 0._wp
602            !
603            ! Set psi vertical flux at the surface:
604            zdep(:,:) = (zhsro(:,:) + fsdept(:,:,1))**(rmm*ra_sf+rnn-1._wp) / zhsro(:,:)**(rmm*ra_sf)
605            zflxs(:,:) = rsbc_psi3 * ( zwall_psi(:,:,1)*avm(:,:,1) + zwall_psi(:,:,2)*avm(:,:,2) ) & 
606               &                   * en(:,:,1)**rmm * zdep         
607            psi(:,:,2) = psi(:,:,2) + zflxs(:,:) / fse3w(:,:,2)
608            !
609      ELSE                   ! No wave induced mixing
610            !
611            zdep(:,:) = vkarmn * zhsro(:,:)
612            psi (:,:,1) = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
613            z_elem_a(:,:,1) = psi(:,:,1)
614            z_elem_c(:,:,1) = 0._wp
615            z_elem_b(:,:,1) = 1._wp
616            !
617            ! Neumann condition at k=2
618            z_elem_b(:,:,2) = z_elem_b(:,:,2) +  z_elem_a(:,:,2) ! Remove z_elem_a from z_elem_b
619            z_elem_a(ji,jj,2) = 0._wp
620            !
621            ! Set psi vertical flux at the surface:
622            zdep(:,:)  = zhsro(:,:) + fsdept(:,:,1)
623            zflxs(:,:) = rsbc_psi2 * ( avm(:,:,1) + avm(:,:,2) ) * en(:,:,1)**rmm * zdep**(rnn-1._wp)
624            psi(:,:,2) = psi(:,:,2) + zflxs(:,:) / fse3w(:,:,2)
625            !     
626         ENDIF
627         !
628      END SELECT
629
630      ! Bottom boundary condition on psi
631      ! --------------------------------
632      !
633      SELECT CASE ( nn_psibc_bot )
634      !
635      CASE ( 0 )             ! Dirichlet
636         !                      ! en(ibot) = u*^2 / Co2 and mxln(ibot) = vkarmn * hbro
637         !                      ! Balance between the production and the dissipation terms
638!CDIR NOVERRCHK
639         DO jj = 2, jpjm1
640!CDIR NOVERRCHK
641            DO ji = fs_2, fs_jpim1   ! vector opt.
642               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
643               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
644               zdep(ji,jj) = vkarmn * hbro
645               psi (ji,jj,ibot) = rc0**rpp * en(ji,jj,ibot)**rmm * zdep(ji,jj)**rnn
646               z_elem_a(ji,jj,ibot) = 0._wp
647               z_elem_c(ji,jj,ibot) = 0._wp
648               z_elem_b(ji,jj,ibot) = 1._wp
649               !
650               ! Just above last level, Dirichlet condition again (GOTM like)
651               zdep(ji,jj) = vkarmn * ( hbro + fse3t(ji,jj,ibotm1) )
652               psi (ji,jj,ibotm1) = rc0**rpp * en(ji,jj,ibot  )**rmm * zdep(ji,jj)**rnn
653               z_elem_a(ji,jj,ibotm1) = 0._wp
654               z_elem_c(ji,jj,ibotm1) = 0._wp
655               z_elem_b(ji,jj,ibotm1) = 1._wp
656            END DO
657         END DO
658         !
659      CASE ( 1 )             ! Neumman boundary condition
660         !                     
661!CDIR NOVERRCHK
662         DO jj = 2, jpjm1
663!CDIR NOVERRCHK
664            DO ji = fs_2, fs_jpim1   ! vector opt.
665               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
666               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
667               !
668               ! Bottom level Dirichlet condition:
669               zdep(ji,jj) = vkarmn * hbro
670               psi (ji,jj,ibot) = rc0**rpp * en(ji,jj,ibot)**rmm * zdep(ji,jj)**rnn
671               !
672               z_elem_a(ji,jj,ibot) = 0._wp
673               z_elem_c(ji,jj,ibot) = 0._wp
674               z_elem_b(ji,jj,ibot) = 1._wp
675               !
676               ! Just above last level: Neumann condition with flux injection
677               z_elem_b(ji,jj,ibotm1) = z_elem_b(ji,jj,ibotm1) + z_elem_c(ji,jj,ibotm1) ! Remove z_elem_c from z_elem_b
678               z_elem_c(ji,jj,ibotm1) = 0.
679               !
680               ! Set psi vertical flux at the bottom:
681               zdep(ji,jj) = hbro + 0.5_wp*fse3t(ji,jj,ibotm1)
682               zflxb = rsbc_psi2 * ( avm(ji,jj,ibot) + avm(ji,jj,ibotm1) )   &
683                  &  * (0.5_wp*(en(ji,jj,ibot)+en(ji,jj,ibotm1)))**rmm * zdep(ji,jj)**(rnn-1._wp)
684               psi(ji,jj,ibotm1) = psi(ji,jj,ibotm1) + zflxb / fse3w(ji,jj,ibotm1)
685            END DO
686         END DO
687         !
688      END SELECT
689
690      ! Matrix inversion
691      ! ----------------
692      !
693      DO jk = 2, jpkm1                             ! First recurrence : Dk = Dk - Lk * Uk-1 / Dk-1
694         DO jj = 2, jpjm1
695            DO ji = fs_2, fs_jpim1    ! vector opt.
696               z_elem_b(ji,jj,jk) = z_elem_b(ji,jj,jk) - z_elem_a(ji,jj,jk) * z_elem_c(ji,jj,jk-1) / z_elem_b(ji,jj,jk-1)
697            END DO
698         END DO
699      END DO
700      DO jk = 2, jpk                               ! Second recurrence : Lk = RHSk - Lk / Dk-1 * Lk-1
701         DO jj = 2, jpjm1
702            DO ji = fs_2, fs_jpim1    ! vector opt.
703               z_elem_a(ji,jj,jk) = psi(ji,jj,jk) - z_elem_a(ji,jj,jk) / z_elem_b(ji,jj,jk-1) * z_elem_a(ji,jj,jk-1)
704            END DO
705         END DO
706      END DO
707      DO jk = jpk-1, 2, -1                         ! Third recurrence : Ek = ( Lk - Uk * Ek+1 ) / Dk
708         DO jj = 2, jpjm1
709            DO ji = fs_2, fs_jpim1    ! vector opt.
710               psi(ji,jj,jk) = ( z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk) * psi(ji,jj,jk+1) ) / z_elem_b(ji,jj,jk)
711            END DO
712         END DO
713      END DO
714
715      ! Set dissipation
716      !----------------
717
718      SELECT CASE ( nn_clos )
719      !
720      CASE( 0 )               ! k-kl  (Mellor-Yamada)
721         DO jk = 1, jpkm1
722            DO jj = 2, jpjm1
723               DO ji = fs_2, fs_jpim1   ! vector opt.
724                  eps(ji,jj,jk) = rc03 * en(ji,jj,jk) * en(ji,jj,jk) * SQRT( en(ji,jj,jk) ) / psi(ji,jj,jk)
725               END DO
726            END DO
727         END DO
728         !
729      CASE( 1 )               ! k-eps
730         DO jk = 1, jpkm1
731            DO jj = 2, jpjm1
732               DO ji = fs_2, fs_jpim1   ! vector opt.
733                  eps(ji,jj,jk) = psi(ji,jj,jk)
734               END DO
735            END DO
736         END DO
737         !
738      CASE( 2 )               ! k-w
739         DO jk = 1, jpkm1
740            DO jj = 2, jpjm1
741               DO ji = fs_2, fs_jpim1   ! vector opt.
742                  eps(ji,jj,jk) = rc04 * en(ji,jj,jk) * psi(ji,jj,jk) 
743               END DO
744            END DO
745         END DO
746         !
747      CASE( 3 )               ! generic
748         zcoef = rc0**( 3._wp  + rpp/rnn )
749         zex1  =      ( 1.5_wp + rmm/rnn )
750         zex2  = -1._wp / rnn
751         DO jk = 1, jpkm1
752            DO jj = 2, jpjm1
753               DO ji = fs_2, fs_jpim1   ! vector opt.
754                  eps(ji,jj,jk) = zcoef * en(ji,jj,jk)**zex1 * psi(ji,jj,jk)**zex2
755               END DO
756            END DO
757         END DO
758         !
759      END SELECT
760
761      ! Limit dissipation rate under stable stratification
762      ! --------------------------------------------------
763      DO jk = 1, jpkm1 ! Note that this set boundary conditions on mxln at the same time
764         DO jj = 2, jpjm1
765            DO ji = fs_2, fs_jpim1    ! vector opt.
766               ! limitation
767               eps(ji,jj,jk)  = MAX( eps(ji,jj,jk), rn_epsmin )
768               mxln(ji,jj,jk)  = rc03 * en(ji,jj,jk) * SQRT( en(ji,jj,jk) ) / eps(ji,jj,jk)
769               ! Galperin criterium (NOTE : Not required if the proper value of C3 in stable cases is calculated)
770               zrn2 = MAX( rn2(ji,jj,jk), rsmall )
771               mxln(ji,jj,jk) = MIN(  rn_clim_galp * SQRT( 2._wp * en(ji,jj,jk) / zrn2 ), mxln(ji,jj,jk)  )
772            END DO
773         END DO
774      END DO 
775
776      !
777      ! Stability function and vertical viscosity and diffusivity
778      ! ---------------------------------------------------------
779      !
780      SELECT CASE ( nn_stab_func )
781      !
782      CASE ( 0 , 1 )             ! Galperin or Kantha-Clayson stability functions
783         DO jk = 2, jpkm1
784            DO jj = 2, jpjm1
785               DO ji = fs_2, fs_jpim1   ! vector opt.
786                  ! zcof =  l²/q²
787                  zcof = mxlb(ji,jj,jk) * mxlb(ji,jj,jk) / ( 2._wp*eb(ji,jj,jk) )
788                  ! Gh = -N²l²/q²
789                  gh = - rn2(ji,jj,jk) * zcof
790                  gh = MIN( gh, rgh0   )
791                  gh = MAX( gh, rghmin )
792                  ! Stability functions from Kantha and Clayson (if C2=C3=0 => Galperin)
793                  sh = ra2*( 1._wp-6._wp*ra1/rb1 ) / ( 1.-3.*ra2*gh*(6.*ra1+rb2*( 1._wp-rc3 ) ) )
794                  sm = ( rb1**(-1._wp/3._wp) + ( 18._wp*ra1*ra1 + 9._wp*ra1*ra2*(1._wp-rc2) )*sh*gh ) / (1._wp-9._wp*ra1*ra2*gh)
795                  !
796                  ! Store stability function in avmu and avmv
797                  avmu(ji,jj,jk) = rc_diff * sh * tmask(ji,jj,jk)
798                  avmv(ji,jj,jk) = rc_diff * sm * tmask(ji,jj,jk)
799               END DO
800            END DO
801         END DO
802         !
803      CASE ( 2, 3 )               ! Canuto stability functions
804         DO jk = 2, jpkm1
805            DO jj = 2, jpjm1
806               DO ji = fs_2, fs_jpim1   ! vector opt.
807                  ! zcof =  l²/q²
808                  zcof = mxlb(ji,jj,jk)*mxlb(ji,jj,jk) / ( 2._wp * eb(ji,jj,jk) )
809                  ! Gh = -N²l²/q²
810                  gh = - rn2(ji,jj,jk) * zcof
811                  gh = MIN( gh, rgh0   )
812                  gh = MAX( gh, rghmin )
813                  gh = gh * rf6
814                  ! Gm =  M²l²/q² Shear number
815                  shr = shear(ji,jj,jk) / MAX( avm(ji,jj,jk), rsmall )
816                  gm = MAX( shr * zcof , 1.e-10 )
817                  gm = gm * rf6
818                  gm = MIN ( (rd0 - rd1*gh + rd3*gh*gh) / (rd2-rd4*gh) , gm )
819                  ! Stability functions from Canuto
820                  rcff = rd0 - rd1*gh +rd2*gm + rd3*gh*gh - rd4*gh*gm + rd5*gm*gm
821                  sm = (rs0 - rs1*gh + rs2*gm) / rcff
822                  sh = (rs4 - rs5*gh + rs6*gm) / rcff
823                  !
824                  ! Store stability function in avmu and avmv
825                  avmu(ji,jj,jk) = rc_diff * sh * tmask(ji,jj,jk)
826                  avmv(ji,jj,jk) = rc_diff * sm * tmask(ji,jj,jk)
827               END DO
828            END DO
829         END DO
830         !
831      END SELECT
832
833      ! Boundary conditions on stability functions for momentum (Neumann):
834      ! Lines below are useless if GOTM style Dirichlet conditions are used
835      zcoef = rcm_sf / SQRT( 2._wp )
836      DO jj = 2, jpjm1
837         DO ji = fs_2, fs_jpim1   ! vector opt.
838            avmv(ji,jj,1) = zcoef
839         END DO
840      END DO
841      zcoef = rc0 / SQRT( 2._wp )
842      DO jj = 2, jpjm1
843         DO ji = fs_2, fs_jpim1   ! vector opt.
844            avmv(ji,jj,mbkt(ji,jj)+1) = zcoef
845         END DO
846      END DO
847
848      ! Compute diffusivities/viscosities
849      ! The computation below could be restrained to jk=2 to jpkm1 if GOTM style Dirichlet conditions are used
850      DO jk = 1, jpk
851         DO jj = 2, jpjm1
852            DO ji = fs_2, fs_jpim1   ! vector opt.
853               zsqen         = SQRT( 2._wp * en(ji,jj,jk) ) * mxln(ji,jj,jk)
854               zav           = zsqen * avmu(ji,jj,jk)
855               avt(ji,jj,jk) = MAX( zav, avtb(jk) )*tmask(ji,jj,jk) ! apply mask for zdfmxl routine
856               zav           = zsqen * avmv(ji,jj,jk)
857               avm(ji,jj,jk) = MAX( zav, avmb(jk) ) ! Note that avm is not masked at the surface and the bottom
858            END DO
859         END DO
860      END DO
861      !
862      ! Lateral boundary conditions (sign unchanged)
863      avt(:,:,1)  = 0._wp
864      CALL lbc_lnk( avm, 'W', 1. )   ;   CALL lbc_lnk( avt, 'W', 1. )
865
866      DO jk = 2, jpkm1            !* vertical eddy viscosity at u- and v-points
867         DO jj = 2, jpjm1
868            DO ji = fs_2, fs_jpim1   ! vector opt.
869               avmu(ji,jj,jk) = 0.5 * ( avm(ji,jj,jk) + avm(ji+1,jj  ,jk) ) * umask(ji,jj,jk)
870               avmv(ji,jj,jk) = 0.5 * ( avm(ji,jj,jk) + avm(ji  ,jj+1,jk) ) * vmask(ji,jj,jk)
871            END DO
872         END DO
873      END DO
874      avmu(:,:,1) = 0._wp             ;   avmv(:,:,1) = 0._wp                 ! set surface to zero
875      CALL lbc_lnk( avmu, 'U', 1. )   ;   CALL lbc_lnk( avmv, 'V', 1. )       ! Lateral boundary conditions
876
877      IF(ln_ctl) THEN
878         CALL prt_ctl( tab3d_1=en  , clinfo1=' gls  - e: ', tab3d_2=avt, clinfo2=' t: ', ovlap=1, kdim=jpk)
879         CALL prt_ctl( tab3d_1=avmu, clinfo1=' gls  - u: ', mask1=umask,                   &
880            &          tab3d_2=avmv, clinfo2=       ' v: ', mask2=vmask, ovlap=1, kdim=jpk )
881      ENDIF
882      !
883      CALL wrk_dealloc( jpi,jpj, zdep, zflxs, zhsro )
884      CALL wrk_dealloc( jpi,jpj,jpk, eb, mxlb, shear, eps, zwall_psi, z_elem_a, z_elem_b, z_elem_c, psi )
885      !
886      IF( nn_timing == 1 )  CALL timing_stop('zdf_gls')
887      !
888      !
889   END SUBROUTINE zdf_gls
890
891
892   SUBROUTINE zdf_gls_init
893      !!----------------------------------------------------------------------
894      !!                  ***  ROUTINE zdf_gls_init  ***
895      !!                     
896      !! ** Purpose :   Initialization of the vertical eddy diffivity and
897      !!      viscosity when using a gls turbulent closure scheme
898      !!
899      !! ** Method  :   Read the namzdf_gls namelist and check the parameters
900      !!      called at the first timestep (nit000)
901      !!
902      !! ** input   :   Namlist namzdf_gls
903      !!
904      !! ** Action  :   Increase by 1 the nstop flag is setting problem encounter
905      !!
906      !!----------------------------------------------------------------------
907      USE dynzdf_exp
908      USE trazdf_exp
909      !
910      INTEGER ::   jk    ! dummy loop indices
911      REAL(wp)::   zcr   ! local scalar
912      !!
913      NAMELIST/namzdf_gls/rn_emin, rn_epsmin, ln_length_lim, &
914         &            rn_clim_galp, ln_crban, ln_sigpsi,     &
915         &            rn_crban, rn_charn,                    &
916         &            nn_tkebc_surf, nn_tkebc_bot,           &
917         &            nn_psibc_surf, nn_psibc_bot,           &
918         &            nn_stab_func, nn_clos
919      !!----------------------------------------------------------
920      !
921      IF( nn_timing == 1 )  CALL timing_start('zdf_gls_init')
922      !
923      REWIND( numnam )                 !* Read Namelist namzdf_gls
924      READ  ( numnam, namzdf_gls )
925
926      IF(lwp) THEN                     !* Control print
927         WRITE(numout,*)
928         WRITE(numout,*) 'zdf_gls_init : gls turbulent closure scheme'
929         WRITE(numout,*) '~~~~~~~~~~~~'
930         WRITE(numout,*) '   Namelist namzdf_gls : set gls mixing parameters'
931         WRITE(numout,*) '      minimum value of en                           rn_emin       = ', rn_emin
932         WRITE(numout,*) '      minimum value of eps                          rn_epsmin     = ', rn_epsmin
933         WRITE(numout,*) '      Limit dissipation rate under stable stratif.  ln_length_lim = ', ln_length_lim
934         WRITE(numout,*) '      Galperin limit (Standard: 0.53, Holt: 0.26)   rn_clim_galp  = ', rn_clim_galp
935         WRITE(numout,*) '      TKE Surface boundary condition                nn_tkebc_surf = ', nn_tkebc_surf
936         WRITE(numout,*) '      TKE Bottom boundary condition                 nn_tkebc_bot  = ', nn_tkebc_bot
937         WRITE(numout,*) '      PSI Surface boundary condition                nn_psibc_surf = ', nn_psibc_surf
938         WRITE(numout,*) '      PSI Bottom boundary condition                 nn_psibc_bot  = ', nn_psibc_bot
939         WRITE(numout,*) '      Craig and Banner scheme                       ln_crban      = ', ln_crban
940         WRITE(numout,*) '      Modify psi Schmidt number (wb case)           ln_sigpsi     = ', ln_sigpsi
941         WRITE(numout,*) '      Craig and Banner coefficient                  rn_crban       = ', rn_crban
942         WRITE(numout,*) '      Charnock coefficient                          rn_charn       = ', rn_charn
943         WRITE(numout,*) '      Stability functions                           nn_stab_func   = ', nn_stab_func
944         WRITE(numout,*) '      Type of closure                               nn_clos        = ', nn_clos
945         WRITE(numout,*) '   Hard coded parameters'
946         WRITE(numout,*) '      Surface roughness (m)                         hsro          = ', hsro
947         WRITE(numout,*) '      Bottom roughness (m)                          hbro          = ', hbro
948      ENDIF
949
950      !                                !* allocate gls arrays
951      IF( zdf_gls_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'zdf_gls_init : unable to allocate arrays' )
952
953      !                                !* Check of some namelist values
954      IF( nn_tkebc_surf < 0 .OR. nn_tkebc_surf > 1 ) CALL ctl_stop( 'bad flag: nn_tkebc_surf is 0 or 1' )
955      IF( nn_psibc_surf < 0 .OR. nn_psibc_surf > 1 ) CALL ctl_stop( 'bad flag: nn_psibc_surf is 0 or 1' )
956      IF( nn_tkebc_bot  < 0 .OR. nn_tkebc_bot  > 1 ) CALL ctl_stop( 'bad flag: nn_tkebc_bot is 0 or 1' )
957      IF( nn_psibc_bot  < 0 .OR. nn_psibc_bot  > 1 ) CALL ctl_stop( 'bad flag: nn_psibc_bot is 0 or 1' )
958      IF( nn_stab_func  < 0 .OR. nn_stab_func  > 3 ) CALL ctl_stop( 'bad flag: nn_stab_func is 0, 1, 2 and 3' )
959      IF( nn_clos       < 0 .OR. nn_clos       > 3 ) CALL ctl_stop( 'bad flag: nn_clos is 0, 1, 2 or 3' )
960
961      SELECT CASE ( nn_clos )          !* set the parameters for the chosen closure
962      !
963      CASE( 0 )                              ! k-kl  (Mellor-Yamada)
964         !
965         IF(lwp) WRITE(numout,*) 'The choosen closure is k-kl closed to the classical Mellor-Yamada'
966         rpp     = 0._wp
967         rmm     = 1._wp
968         rnn     = 1._wp
969         rsc_tke = 1.96_wp
970         rsc_psi = 1.96_wp
971         rpsi1   = 0.9_wp
972         rpsi3p  = 1._wp
973         rpsi2   = 0.5_wp
974         !
975         SELECT CASE ( nn_stab_func )
976         CASE( 0, 1 )   ;   rpsi3m = 2.53_wp       ! G88 or KC stability functions
977         CASE( 2 )      ;   rpsi3m = 2.38_wp       ! Canuto A stability functions
978         CASE( 3 )      ;   rpsi3m = 2.38          ! Canuto B stability functions (caution : constant not identified)
979         END SELECT
980         !
981      CASE( 1 )                              ! k-eps
982         !
983         IF(lwp) WRITE(numout,*) 'The choosen closure is k-eps'
984         rpp     =  3._wp
985         rmm     =  1.5_wp
986         rnn     = -1._wp
987         rsc_tke =  1._wp
988         rsc_psi =  1.3_wp  ! Schmidt number for psi
989         rpsi1   =  1.44_wp
990         rpsi3p  =  1._wp
991         rpsi2   =  1.92_wp
992         !
993         SELECT CASE ( nn_stab_func )
994         CASE( 0, 1 )   ;   rpsi3m = -0.52_wp      ! G88 or KC stability functions
995         CASE( 2 )      ;   rpsi3m = -0.629_wp     ! Canuto A stability functions
996         CASE( 3 )      ;   rpsi3m = -0.566        ! Canuto B stability functions
997         END SELECT
998         !
999      CASE( 2 )                              ! k-omega
1000         !
1001         IF(lwp) WRITE(numout,*) 'The choosen closure is k-omega'
1002         rpp     = -1._wp
1003         rmm     =  0.5_wp
1004         rnn     = -1._wp
1005         rsc_tke =  2._wp
1006         rsc_psi =  2._wp
1007         rpsi1   =  0.555_wp
1008         rpsi3p  =  1._wp
1009         rpsi2   =  0.833_wp
1010         !
1011         SELECT CASE ( nn_stab_func )
1012         CASE( 0, 1 )   ;   rpsi3m = -0.58_wp       ! G88 or KC stability functions
1013         CASE( 2 )      ;   rpsi3m = -0.64_wp       ! Canuto A stability functions
1014         CASE( 3 )      ;   rpsi3m = -0.64_wp       ! Canuto B stability functions caution : constant not identified)
1015         END SELECT
1016         !
1017      CASE( 3 )                              ! generic
1018         !
1019         IF(lwp) WRITE(numout,*) 'The choosen closure is generic'
1020         rpp     = 2._wp
1021         rmm     = 1._wp
1022         rnn     = -0.67_wp
1023         rsc_tke = 0.8_wp
1024         rsc_psi = 1.07_wp
1025         rpsi1   = 1._wp
1026         rpsi3p  = 1._wp
1027         rpsi2   = 1.22_wp
1028         !
1029         SELECT CASE ( nn_stab_func )
1030         CASE( 0, 1 )   ;   rpsi3m = 0.1_wp         ! G88 or KC stability functions
1031         CASE( 2 )      ;   rpsi3m = 0.05_wp        ! Canuto A stability functions
1032         CASE( 3 )      ;   rpsi3m = 0.05_wp        ! Canuto B stability functions caution : constant not identified)
1033         END SELECT
1034         !
1035      END SELECT
1036
1037      !
1038      SELECT CASE ( nn_stab_func )     !* set the parameters of the stability functions
1039      !
1040      CASE ( 0 )                             ! Galperin stability functions
1041         !
1042         IF(lwp) WRITE(numout,*) 'Stability functions from Galperin'
1043         rc2     =  0._wp
1044         rc3     =  0._wp
1045         rc_diff =  1._wp
1046         rc0     =  0.5544_wp
1047         rcm_sf  =  0.9884_wp
1048         rghmin  = -0.28_wp
1049         rgh0    =  0.0233_wp
1050         rghcri  =  0.02_wp
1051         !
1052      CASE ( 1 )                             ! Kantha-Clayson stability functions
1053         !
1054         IF(lwp) WRITE(numout,*) 'Stability functions from Kantha-Clayson'
1055         rc2     =  0.7_wp
1056         rc3     =  0.2_wp
1057         rc_diff =  1._wp
1058         rc0     =  0.5544_wp
1059         rcm_sf  =  0.9884_wp
1060         rghmin  = -0.28_wp
1061         rgh0    =  0.0233_wp
1062         rghcri  =  0.02_wp
1063         !
1064      CASE ( 2 )                             ! Canuto A stability functions
1065         !
1066         IF(lwp) WRITE(numout,*) 'Stability functions from Canuto A'
1067         rs0 = 1.5_wp * rl1 * rl5*rl5
1068         rs1 = -rl4*(rl6+rl7) + 2._wp*rl4*rl5*(rl1-(1._wp/3._wp)*rl2-rl3) + 1.5_wp*rl1*rl5*rl8
1069         rs2 = -(3._wp/8._wp) * rl1*(rl6*rl6-rl7*rl7)
1070         rs4 = 2._wp * rl5
1071         rs5 = 2._wp * rl4
1072         rs6 = (2._wp/3._wp) * rl5 * ( 3._wp*rl3*rl3 - rl2*rl2 ) - 0.5_wp * rl5*rl1 * (3._wp*rl3-rl2)   &
1073            &                                                    + 0.75_wp * rl1 * ( rl6 - rl7 )
1074         rd0 = 3._wp * rl5*rl5
1075         rd1 = rl5 * ( 7._wp*rl4 + 3._wp*rl8 )
1076         rd2 = rl5*rl5 * ( 3._wp*rl3*rl3 - rl2*rl2 ) - 0.75_wp*(rl6*rl6 - rl7*rl7 )
1077         rd3 = rl4 * ( 4._wp*rl4 + 3._wp*rl8)
1078         rd4 = rl4 * ( rl2 * rl6 - 3._wp*rl3*rl7 - rl5*(rl2*rl2 - rl3*rl3 ) ) + rl5*rl8 * ( 3._wp*rl3*rl3 - rl2*rl2 )
1079         rd5 = 0.25_wp * ( rl2*rl2 - 3._wp *rl3*rl3 ) * ( rl6*rl6 - rl7*rl7 )
1080         rc0 = 0.5268_wp
1081         rf6 = 8._wp / (rc0**6._wp)
1082         rc_diff = SQRT(2._wp) / (rc0**3._wp)
1083         rcm_sf  =  0.7310_wp
1084         rghmin  = -0.28_wp
1085         rgh0    =  0.0329_wp
1086         rghcri  =  0.03_wp
1087         !
1088      CASE ( 3 )                             ! Canuto B stability functions
1089         !
1090         IF(lwp) WRITE(numout,*) 'Stability functions from Canuto B'
1091         rs0 = 1.5_wp * rm1 * rm5*rm5
1092         rs1 = -rm4 * (rm6+rm7) + 2._wp * rm4*rm5*(rm1-(1._wp/3._wp)*rm2-rm3) + 1.5_wp * rm1*rm5*rm8
1093         rs2 = -(3._wp/8._wp) * rm1 * (rm6*rm6-rm7*rm7 )
1094         rs4 = 2._wp * rm5
1095         rs5 = 2._wp * rm4
1096         rs6 = (2._wp/3._wp) * rm5 * (3._wp*rm3*rm3-rm2*rm2) - 0.5_wp * rm5*rm1*(3._wp*rm3-rm2) + 0.75_wp * rm1*(rm6-rm7)
1097         rd0 = 3._wp * rm5*rm5
1098         rd1 = rm5 * (7._wp*rm4 + 3._wp*rm8)
1099         rd2 = rm5*rm5 * (3._wp*rm3*rm3 - rm2*rm2) - 0.75_wp * (rm6*rm6 - rm7*rm7)
1100         rd3 = rm4 * ( 4._wp*rm4 + 3._wp*rm8 )
1101         rd4 = rm4 * ( rm2*rm6 -3._wp*rm3*rm7 - rm5*(rm2*rm2 - rm3*rm3) ) + rm5 * rm8 * ( 3._wp*rm3*rm3 - rm2*rm2 )
1102         rd5 = 0.25_wp * ( rm2*rm2 - 3._wp*rm3*rm3 ) * ( rm6*rm6 - rm7*rm7 )
1103         rc0 = 0.5268_wp            !!       rc0 = 0.5540_wp (Warner ...) to verify !
1104         rf6 = 8._wp / ( rc0**6._wp )
1105         rc_diff = SQRT(2._wp)/(rc0**3.)
1106         rcm_sf  =  0.7470_wp
1107         rghmin  = -0.28_wp
1108         rgh0    =  0.0444_wp
1109         rghcri  =  0.0414_wp
1110         !
1111      END SELECT
1112   
1113      !                                !* Set Schmidt number for psi diffusion in the wave breaking case
1114      !                                     ! See Eq. (13) of Carniel et al, OM, 30, 225-239, 2009
1115      !                                     !  or Eq. (17) of Burchard, JPO, 31, 3133-3145, 2001
1116      IF( ln_sigpsi .AND. ln_crban ) THEN
1117         zcr = SQRT( 1.5_wp*rsc_tke ) * rcm_sf / vkarmn
1118         rsc_psi0 = vkarmn*vkarmn / ( rpsi2 * rcm_sf*rcm_sf )                       & 
1119        &         * ( rnn*rnn - 4._wp/3._wp * zcr*rnn*rmm - 1._wp/3._wp * zcr*rnn   &
1120        &           + 2._wp/9._wp * rmm * zcr*zcr + 4._wp/9._wp * zcr*zcr * rmm*rmm )                                 
1121      ELSE
1122         rsc_psi0 = rsc_psi
1123      ENDIF
1124 
1125      !                                !* Shear free turbulence parameters
1126      !
1127      ra_sf  = -4._wp * rnn * SQRT( rsc_tke ) / ( (1._wp+4._wp*rmm) * SQRT( rsc_tke )   &
1128         &                                      - SQRT(rsc_tke + 24._wp*rsc_psi0*rpsi2 ) )
1129      rl_sf  = rc0 * SQRT( rc0 / rcm_sf )                                                                   &
1130         &         * SQRT(  (  (1._wp + 4._wp*rmm + 8._wp*rmm*rmm) * rsc_tke                                &
1131         &                   + 12._wp * rsc_psi0 * rpsi2                                                    &
1132         &                   - (1._wp + 4._wp*rmm) * SQRT( rsc_tke*(rsc_tke+ 24._wp*rsc_psi0*rpsi2) )  )    &
1133         &                / ( 12._wp*rnn*rnn )                                                              )
1134
1135      !
1136      IF(lwp) THEN                     !* Control print
1137         WRITE(numout,*)
1138         WRITE(numout,*) 'Limit values'
1139         WRITE(numout,*) '~~~~~~~~~~~~'
1140         WRITE(numout,*) 'Parameter  m = ',rmm
1141         WRITE(numout,*) 'Parameter  n = ',rnn
1142         WRITE(numout,*) 'Parameter  p = ',rpp
1143         WRITE(numout,*) 'rpsi1   = ',rpsi1
1144         WRITE(numout,*) 'rpsi2   = ',rpsi2
1145         WRITE(numout,*) 'rpsi3m  = ',rpsi3m
1146         WRITE(numout,*) 'rpsi3p  = ',rpsi3p
1147         WRITE(numout,*) 'rsc_tke = ',rsc_tke
1148         WRITE(numout,*) 'rsc_psi = ',rsc_psi
1149         WRITE(numout,*) 'rsc_psi0 = ',rsc_psi0
1150         WRITE(numout,*) 'rc0     = ',rc0
1151         WRITE(numout,*)
1152         WRITE(numout,*) 'Shear free turbulence parameters:'
1153         WRITE(numout,*) 'rcm_sf  = ',rcm_sf
1154         WRITE(numout,*) 'ra_sf   = ',ra_sf
1155         WRITE(numout,*) 'rl_sf   = ',rl_sf
1156         WRITE(numout,*)
1157      ENDIF
1158
1159      !                                !* Constants initialization
1160      rc02  = rc0  * rc0   ;   rc02r = 1. / rc02
1161      rc03  = rc02 * rc0
1162      rc04  = rc03 * rc0
1163      rc03_sqrt2_galp = rc03 / SQRT(2._wp) / rn_clim_galp
1164      rsbc_mb   = 0.5_wp * (15.8_wp*rn_crban)**(2._wp/3._wp)               ! Surf. bound. cond. from Mellor and Blumberg
1165      rsbc_std  = 3.75_wp                                                  ! Surf. bound. cond. standard (prod=diss)
1166      rsbc_tke1 = (-rsc_tke*rn_crban/(rcm_sf*ra_sf*rl_sf))**(2._wp/3._wp)  ! k_eps = 53.  Dirichlet + Wave breaking
1167      rsbc_tke2 = 0.5_wp / rau0
1168      rsbc_tke3 = rdt * rn_crban                                                         ! Neumann + Wave breaking
1169      rsbc_zs   = rn_charn / grav                                                        ! Charnock formula
1170      rsbc_psi1 = rc0**rpp * rsbc_tke1**rmm * rl_sf**rnn                           ! Dirichlet + Wave breaking
1171      rsbc_psi2 = -0.5_wp * rdt * rc0**rpp * rnn * vkarmn**rnn / rsc_psi                   ! Neumann + NO Wave breaking
1172      rsbc_psi3 = -0.5_wp * rdt * rc0**rpp * rl_sf**rnn / rsc_psi  * (rnn + rmm*ra_sf) ! Neumann + Wave breaking
1173      rfact_tke = -0.5_wp / rsc_tke * rdt               ! Cst used for the Diffusion term of tke
1174      rfact_psi = -0.5_wp / rsc_psi * rdt               ! Cst used for the Diffusion term of tke
1175
1176      !                                !* Wall proximity function
1177      zwall (:,:,:) = 1._wp * tmask(:,:,:)
1178
1179      !                                !* set vertical eddy coef. to the background value
1180      DO jk = 1, jpk
1181         avt (:,:,jk) = avtb(jk) * tmask(:,:,jk)
1182         avm (:,:,jk) = avmb(jk) * tmask(:,:,jk)
1183         avmu(:,:,jk) = avmb(jk) * umask(:,:,jk)
1184         avmv(:,:,jk) = avmb(jk) * vmask(:,:,jk)
1185      END DO
1186      !                             
1187      CALL gls_rst( nit000, 'READ' )   !* read or initialize all required files
1188      !
1189      IF( nn_timing == 1 )  CALL timing_stop('zdf_gls_init')
1190      !
1191   END SUBROUTINE zdf_gls_init
1192
1193
1194   SUBROUTINE gls_rst( kt, cdrw )
1195      !!---------------------------------------------------------------------
1196      !!                   ***  ROUTINE ts_rst  ***
1197      !!                     
1198      !! ** Purpose :   Read or write TKE file (en) in restart file
1199      !!
1200      !! ** Method  :   use of IOM library
1201      !!                if the restart does not contain TKE, en is either
1202      !!                set to rn_emin or recomputed (nn_igls/=0)
1203      !!----------------------------------------------------------------------
1204      INTEGER         , INTENT(in) ::   kt         ! ocean time-step
1205      CHARACTER(len=*), INTENT(in) ::   cdrw       ! "READ"/"WRITE" flag
1206      !
1207      INTEGER ::   jit, jk   ! dummy loop indices
1208      INTEGER ::   id1, id2, id3, id4, id5, id6
1209      INTEGER ::   ji, jj, ikbu, ikbv
1210      REAL(wp)::   cbx, cby
1211      !!----------------------------------------------------------------------
1212      !
1213      IF( TRIM(cdrw) == 'READ' ) THEN        ! Read/initialise
1214         !                                   ! ---------------
1215         IF( ln_rstart ) THEN                   !* Read the restart file
1216            id1 = iom_varid( numror, 'en'   , ldstop = .FALSE. )
1217            id2 = iom_varid( numror, 'avt'  , ldstop = .FALSE. )
1218            id3 = iom_varid( numror, 'avm'  , ldstop = .FALSE. )
1219            id4 = iom_varid( numror, 'avmu' , ldstop = .FALSE. )
1220            id5 = iom_varid( numror, 'avmv' , ldstop = .FALSE. )
1221            id6 = iom_varid( numror, 'mxln' , ldstop = .FALSE. )
1222            !
1223            IF( MIN( id1, id2, id3, id4, id5, id6 ) > 0 ) THEN        ! all required arrays exist
1224               CALL iom_get( numror, jpdom_autoglo, 'en'    , en     )
1225               CALL iom_get( numror, jpdom_autoglo, 'avt'   , avt    )
1226               CALL iom_get( numror, jpdom_autoglo, 'avm'   , avm    )
1227               CALL iom_get( numror, jpdom_autoglo, 'avmu'  , avmu   )
1228               CALL iom_get( numror, jpdom_autoglo, 'avmv'  , avmv   )
1229               CALL iom_get( numror, jpdom_autoglo, 'mxln'  , mxln   )
1230            ELSE                       
1231               IF(lwp) WRITE(numout,*) ' ===>>>> : previous run without gls scheme, en and mxln computed by iterative loop'
1232               en  (:,:,:) = rn_emin
1233               mxln(:,:,:) = 0.001       
1234               DO jit = nit000 + 1, nit000 + 10   ;   CALL zdf_gls( jit )   ;   END DO
1235            ENDIF
1236         ELSE                                   !* Start from rest
1237            IF(lwp) WRITE(numout,*) ' ===>>>> : Initialisation of en and mxln by background values'
1238            en  (:,:,:) = rn_emin
1239            mxln(:,:,:) = 0.001       
1240         ENDIF
1241         !
1242      ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN   ! Create restart file
1243         !                                   ! -------------------
1244         IF(lwp) WRITE(numout,*) '---- gls-rst ----'
1245         CALL iom_rstput( kt, nitrst, numrow, 'en'   , en    )
1246         CALL iom_rstput( kt, nitrst, numrow, 'avt'  , avt   )
1247         CALL iom_rstput( kt, nitrst, numrow, 'avm'  , avm   )
1248         CALL iom_rstput( kt, nitrst, numrow, 'avmu' , avmu  )
1249         CALL iom_rstput( kt, nitrst, numrow, 'avmv' , avmv  )
1250         CALL iom_rstput( kt, nitrst, numrow, 'mxln' , mxln  )
1251         !
1252      ENDIF
1253      !
1254   END SUBROUTINE gls_rst
1255
1256#else
1257   !!----------------------------------------------------------------------
1258   !!   Dummy module :                                        NO TKE scheme
1259   !!----------------------------------------------------------------------
1260   LOGICAL, PUBLIC, PARAMETER ::   lk_zdfgls = .FALSE.   !: TKE flag
1261CONTAINS
1262   SUBROUTINE zdf_gls_init           ! Empty routine
1263      WRITE(*,*) 'zdf_gls_init: You should not have seen this print! error?'
1264   END SUBROUTINE zdf_gls_init
1265   SUBROUTINE zdf_gls( kt )          ! Empty routine
1266      WRITE(*,*) 'zdf_gls: You should not have seen this print! error?', kt
1267   END SUBROUTINE zdf_gls
1268   SUBROUTINE gls_rst( kt, cdrw )          ! Empty routine
1269      INTEGER         , INTENT(in) ::   kt         ! ocean time-step
1270      CHARACTER(len=*), INTENT(in) ::   cdrw       ! "READ"/"WRITE" flag
1271      WRITE(*,*) 'gls_rst: You should not have seen this print! error?', kt, cdrw
1272   END SUBROUTINE gls_rst
1273#endif
1274
1275   !!======================================================================
1276END MODULE zdfgls
1277
Note: See TracBrowser for help on using the repository browser.